이 자습서에서는 Excel YEAR 함수의 구문 및 사용법을 설명하고 날짜에서 연도를 추출하고, 날짜를 월과 연도로 변환하고, 생년월일에서 나이를 계산하고 결정하는 수식 예제를 제공합니다. 윤년.

최근 몇몇 게시물에서 Excel에서 날짜와 시간을 계산하는 다양한 방법을 살펴보고 WEEKDAY, WEEKNUM, MONTH 및 DAY와 같은 다양하고 유용한 함수를 배웠습니다. 오늘은 더 큰 시간 단위에 초점을 맞추고 Excel 워크시트에서 연도를 계산하는 방법에 대해 이야기하겠습니다.

이 자습서에서는 다음을 배웁니다.

YEAR 함수 in Excel

Excel의 YEAR 함수는 주어진 날짜에 해당하는 4자리 연도를 1900에서 9999까지의 정수로 반환합니다.

Excel YEAR 함수의 구문은 다음과 같이 간단합니다. 다음과 같을 수 있습니다.

여기서 serial_number는 찾으려는 연도의 유효한 날짜입니다.

Excel YEAR 수식

Excel에서 YEAR 수식을 만들려면 여러 가지 방법으로 소스 날짜를 제공할 수 있습니다.

DATE 함수 사용

Excel에서 날짜를 제공하는 가장 안정적인 방법은 DATE 함수를 사용하는 것입니다.

예를 들어 다음 수식은 2015년 4월 28일의 연도를 반환합니다.

=YEAR(DATE(2015, 4, 28))

As 날짜를 나타내는 일련 번호

내부 Excel 시스템에서 날짜는 1900년 1월 1일부터 시작하는 일련 번호로 저장되며 숫자 1로 저장됩니다. 자세한 내용은Excel에서 날짜를 저장하는 방법에 대한 자세한 내용은 Excel 날짜 형식을 참조하세요.

2015년 4월 28일은 42122로 저장되므로 이 숫자를 수식에 직접 입력할 수 있습니다.

=YEAR(42122)

이 방법은 허용되지만 시스템마다 날짜 번호가 다를 수 있으므로 권장하지 않습니다.

셀 참조로

일부 셀에 유효한 날짜가 있다고 가정하면 단순히 해당 셀을 참조할 수 있습니다. 예:

=YEAR(A1)

다른 수식의 결과

예를 들어 TODAY() 함수를 사용하여 현재 날짜에서 연도를 추출할 수 있습니다.

=YEAR(TODAY())

텍스트로

간단한 경우 YEAR 수식은 다음과 같이 텍스트로 입력된 날짜도 이해할 수 있습니다.

=YEAR("28-Apr-2015")

이 방법을 사용할 때 Excel이 인식하는 형식으로 날짜를 입력했는지 다시 한 번 확인하십시오. 또한 Microsoft는 날짜가 텍스트 값으로 제공될 때 올바른 결과를 보장하지 않는다는 점을 기억하십시오.

다음 스크린샷은 위의 모든 YEAR 공식이 작동하는 것을 보여 주며 모두 예상한 대로 2015를 반환합니다 :)

Excel에서 날짜를 연도로 변환하는 방법

Excel에서 날짜 정보로 작업할 때 워크시트에는 일반적으로 월, 일, 연도를 포함한 전체 날짜가 표시됩니다. . 그러나 제품 출시 또는 자산 인수와 같은 주요 이정표 및 중요한 이벤트의 경우 연도를 다시 입력하거나 수정하지 않고 연도만 보고 싶을 수 있습니다.원본 데이터. 아래에서 이를 수행하는 3가지 빠른 방법을 찾을 수 있습니다.

예 1. YEAR 함수를 사용하여 날짜에서 연도 추출

사실 Excel에서 YEAR 함수를 사용하는 방법은 이미 알고 있습니다. 날짜를 년으로 변환합니다. 위의 스크린샷은 여러 수식을 보여 주며 아래 스크린샷에서 몇 가지 예를 더 볼 수 있습니다. YEAR 함수는 가능한 모든 형식의 날짜를 완벽하게 이해합니다.

예 2. Excel에서 날짜를 월과 연도로 변환

주어진 날짜를 변환하려면 TEXT 함수를 사용하여 각 단위를 개별적으로 추출한 다음 이러한 함수를 하나의 공식 내에서 연결할 수 있습니다.

TEXT 함수에서 다음과 같이 월과 연도에 대해 다른 코드를 사용할 수 있습니다.

• "mmm" - 월 - 12월과 같은 축약된 월 이름.
• "mmmm" - 1월 - 12월과 같은 전체 월 이름.
• "yy" - 2자리 연도
• "yyyy" - 4자리 연도

출력을 더 쉽게 읽을 수 있도록 코드를 쉼표, 하이픈 또는 기타 문자로 구분할 수 있습니다. 다음 날짜에서 월 및 연도로 수식과 같습니다.

=TEXT(B2, "mmmm") & ", " & TEXT(B2, "yyyy")

또는

=TEXT(B2, "mmm") & "-" & TEXT(B2, "yy")

여기서 B2는 다음을 포함하는 셀입니다. 날짜.

예제 3. 날짜를 연도로 표시

통합 문서에 날짜를 저장하는 방법이 중요하지 않은 경우 다음을 수행할 수 있습니다. 연도만 표시되도록 Excel 가져오기 ut 원래 날짜를 변경합니다. 다시 말해, 당신은 가질 수 있습니다전체 날짜는 셀에 저장되지만 연도만 표시됩니다.

이 경우 수식이 필요하지 않습니다. Ctrl + 1을 눌러 셀 서식 대화 상자를 열고 숫자 탭에서 사용자 지정 범주를 선택한 다음 Type box:

• yy - 2자리 연도를 00 - 99로 표시합니다.
• yyyy - 4자리 연도를 1900 - 9999로 표시합니다. .

이 방법은 원래 날짜를 변경하지 않고 워크시트에 날짜가 표시되는 방식만 변경한다는 점을 기억하십시오. 수식에서 이러한 셀을 참조하는 경우 Microsoft Excel은 연도 계산이 아닌 날짜 계산을 수행합니다.

날짜 형식 변경에 대한 자세한 내용은 Excel에서 날짜 형식을 변경하는 방법 자습서에서 확인할 수 있습니다.

엑셀에서 생년월일로 계산하는 방법

엑셀에서 생년월일을 계산하는 방법에는 여러 가지가 있습니다. DATEDIF, YEARFRAC 또는 INT 함수를 TODAY()와 함께 사용합니다. TODAY 함수는 나이를 계산할 날짜를 제공하여 수식이 항상 올바른 나이를 반환하도록 합니다.

생년월일로부터 나이 계산

사람의 나이를 계산하는 전통적인 방법 년 단위는 현재 날짜에서 생년월일을 뺍니다. 이 접근 방식은 일상 생활에서 잘 작동하지만 유사한 Excel 연령 계산 공식은 완벽하게 사실이 아닙니다.

여기서 DOB는 생년월일입니다.

공식의 첫 번째 부분(TODAY()-B2)은 다음을 계산합니다. 차이는 일이며 365로 나누어 년 수를 얻습니다. 대부분의 경우 이 등식의 결과는 십진수이며 INT 함수는 가장 가까운 정수로 내림합니다.

생년월일이 B2 셀에 있다고 가정하면 전체 수식은 다음과 같습니다. :

=INT((TODAY()-B2)/365)

위에서 언급한 바와 같이 이 연령 계산 공식이 항상 완벽한 것은 아니며 그 이유는 다음과 같습니다. 4번째 해는 366일을 포함하는 윤년인데, 공식은 일수를 365로 나눈 것입니다. 따라서 2월 29일에 태어난 사람이 오늘이 2월 28일이라면 이 나이 공식은 사람을 하루 더 늙게 합니다. 3>

365 대신 365.25로 나누는 것도 완벽하지 않습니다. 예를 들어 아직 윤년을 거치지 않은 어린이의 나이를 계산할 때입니다. 정상적인 생활을 위해 나이를 계산하는 이 방법을 저장하고 다음 공식 중 하나를 사용하여 Excel에서 생년월일부터 나이를 계산하십시오.

위 수식에 대한 자세한 설명은 Excel에서 나이를 계산하는 방법에 나와 있습니다. 다음 스크린샷은 실제 나이 계산 공식을 보여줍니다.

=DATEDIF(B2, TODAY(), "y")

정확한 나이 계산생년월일(년, 월, 일)

연, 월, 일로 정확한 나이를 계산하려면 마지막 인수에 다음 단위를 사용하여 세 개의 DATEDIF 함수를 작성합니다.

• Y - 전체 연도 수를 계산합니다.
• YM - 연도를 무시하고 월 간의 차이를 구합니다.
• MD - 연도와 월을 무시하고 일 간의 차이를 구합니다. .

그런 다음 3개의 DATEDIF 함수를 단일 수식으로 연결하고 각 함수에서 반환된 숫자를 쉼표로 구분하고 각 숫자의 의미를 정의합니다.

출생은 셀 B2에 있으며 전체 수식은 다음과 같습니다.

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

이 연령 수식은 예를 들어 의사가 환자의 정확한 나이를 표시하거나 모든 직원의 정확한 나이를 알기 위한 인사 담당관:

특정 날짜 또는 특정 연도의 나이 계산과 같은 더 많은 수식 예제는 다음을 확인하십시오. 자습서: Excel에서 나이를 계산하는 방법.

연도의 일수(1-365)를 얻는 방법

이 예는 1년에서 365일(윤년의 경우 1-366) 사이의 특정 일수를 얻는 방법을 보여줍니다. 1월 1일이 1일로 간주됩니다.

이를 위해 다음과 같이 DATE와 함께 YEAR 함수를 사용합니다.

=A2-DATE(YEAR(A2), 1, 0)

여기서 A2는 날짜를 포함하는 셀입니다.

이제 수식이 실제로 무엇을 하는지 살펴보겠습니다. 그만큼 YEAR 함수는 셀 A2에서 날짜의 연도를 검색하여 특정 날짜를 나타내는 일련 번호를 반환하는 DATE(년, 월, 일) 함수에 전달합니다.

그래서 우리 공식에서 year 는 원래 날짜(A2)에서 추출되고 month 은 1(1월)이고 day 은 0입니다. , 1월 1일이 1일로 취급되기를 원하기 때문입니다. 그런 다음 원래 날짜(Excel에도 일련 번호로 저장됨)에서 DATE 수식으로 반환된 일련 번호를 빼면 그 차이가 찾고 있는 연도의 날짜입니다. 예를 들어 2015년 1월 5일은 42009로 저장되고 2014년 12월 31일은 42004이므로 42009 - 42004 = 5입니다.

0일의 개념이 적절하지 않은 경우 다음을 사용할 수 있습니다. 대신 공식:

=A2-DATE(YEAR(A2), 1, 1)+1

한 해의 남은 일수 계산 방법

한 해의 남은 일수를 계산하기 위해 다음을 사용합니다. DATE 및 YEAR가 다시 작동합니다. 수식은 위의 예 3과 동일한 접근 방식을 기반으로 하므로 논리를 이해하는 데 어려움이 없을 것입니다.

=DATE(YEAR(A2),12,31)-A2

현재 날짜를 기준으로 연말까지 남은 날짜를 알고 싶으면 다음과 같이 Excel TODAY() 함수를 사용합니다.

=DATE(2015, 12, 31)-TODAY()

2015는 현재 연도입니다. .

계산 중Excel의 윤년

아시다시피 거의 4년마다 2월 29일에 하루가 추가되어 윤년이라고 합니다. Microsoft Excel 시트에서 특정 날짜가 윤년인지 평년인지 다양한 방법으로 확인할 수 있습니다. 제 생각에는 이해하기 가장 쉬운 몇 가지 공식만 보여드리겠습니다.

공식 1. 2월이 29일인지 확인

이것은 매우 분명한 테스트입니다. 2월은 윤년이 29일이므로 해당 연도의 2월 일수를 계산하여 29일과 비교합니다. 예를 들면 다음과 같습니다.

=DAY(DATE(2015,3,1)-1)=29

이 공식에서 DATE(2015,3,1) 함수는 2015년 3월 1일을 반환하고 여기서 1을 뺍니다. DAY 함수는 이 날짜에서 일 번호를 추출하고 해당 숫자를 29와 비교합니다. 숫자가 일치하면 수식은 TRUE를 반환하고 그렇지 않으면 FALSE를 반환합니다.

Excel 워크시트에 이미 날짜 목록이 있고 어느 것이 윤년인지 알고 싶다면 수식에 YEAR 함수를 통합하여 연도를 추출합니다. 날짜:

=DAY(DATE(YEAR(A2),3,1)-1)=29

여기서 A2는 날짜가 포함된 셀입니다.

수식으로 반환된 결과는 다음과 같습니다.

또는 EOMONTH 함수를 사용하여 2월의 마지막 날을 반환하고 해당 숫자를 29와 비교할 수 있습니다.

=DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29

수식을 보다 사용자 친화적으로 만들기 위해 , IF 기능을 사용하고TRUE 및 FALSE 대신 "윤년" 및 "평년"을 반환합니다.

=IF(DAY(DATE(YEAR(A2),3,1)-1)=29, "Leap year", "Common year")

=IF(DAY(EOMONTH(DATE(YEAR(A2),2,1),0))=29, "Leap year", "Common year")

공식 2 1년이 366일인지 확인

설명이 거의 필요 없는 또 하나의 뻔한 테스트입니다. 하나의 DATE 함수를 사용하여 내년 1월 1일을 반환하고, 또 다른 DATE 함수를 사용하여 올해 1월 1일을 가져오고 전자에서 후자를 빼고 차이가 366:

=DATE(2016,1,1) - DATE(2015,1,1)=366 <인지 확인합니다. 3>

일부 셀에 입력한 날짜를 기준으로 연도를 계산하려면 앞의 예에서와 동일한 방식으로 Excel YEAR 함수를 사용합니다.

=DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366

여기서 A2는 날짜를 포함하는 셀입니다.

그리고 당연히 TRUE 및 FALSE의 부울 값보다 더 의미 있는 값을 반환하도록 위의 DATE/YEAR 수식을 IF 함수에 묶을 수 있습니다.

=IF(DATE(YEAR(A2)+1,1,1) - DATE(YEAR(A2),1,1)=366, "Leap year", "Non-leap year")

이미 언급했듯이 Excel에서 윤년을 계산하는 유일한 방법은 아닙니다. 다른 솔루션이 궁금하시다면 마이크로소프트에서 제안하는 방법을 확인하시면 됩니다. 늘 그렇듯이 Microsoft 사람들은 쉬운 방법을 찾고 있지 않습니까?

이 기사가 Excel에서 연도를 계산하는 데 도움이 되었기를 바랍니다. 읽어 주셔서 감사합니다. 다음 주에 뵙겠습니다.