이 자습서에서는 IFERROR 및 VLOOKUP 함수를 함께 사용하여 다양한 오류를 포착하고 처리하는 방법을 살펴보겠습니다. 또한 여러 IFERROR 함수를 서로 중첩하여 Excel에서 순차적 vlookup을 수행하는 방법을 배우게 됩니다.

Excel VLOOKUP 및 IFERROR - 이 두 기능은 결합된 경우는 고사하고 개별적으로도 이해하기 어려울 수 있습니다. 이 문서에서는 일반적인 용도를 다루고 수식의 논리를 명확하게 설명하는 따라하기 쉬운 몇 가지 예를 찾을 수 있습니다.

IFERROR 및 VLOOKUP 함수에 대한 경험이 많지 않은 경우 위의 링크를 따라 기본 사항을 먼저 수정하는 것이 좋습니다.

#N/A 및 기타 오류를 처리하는 IFERROR VLOOKUP 수식

Excel Vlookup에서 찾을 수 없는 경우 조회 값을 사용하면 다음과 같은 #N/A 오류가 발생합니다.

비즈니스 요구 사항에 따라 고유한 텍스트(0)로 오류를 위장할 수 있습니다. , 또는 빈 셀.

예제 1. VLOOKUP 수식을 사용한 IFERROR로 오류를 자신의 텍스트로 교체

표준 오류 표기법을 사용자 지정 텍스트로 바꾸려면 IFERROR의 VLOOKUP 수식을 입력하고 두 번째 인수( value_if_error )에 원하는 텍스트를 입력합니다(예: "찾을 수 없음":

기본 테이블의 B2에 있는 조회 값과 조회의 조회 범위 A2:B4

=IFERROR(VLOOKUP(B2,'Lookup table'!$A$2:$B$5, 2, FALSE), "Not found")

아래 스크린샷은 작동 중인 Excel IFERROR VLOOKUP 수식을 보여줍니다.

결과가 훨씬 더 이해하기 쉽고 덜 위협적으로 보이죠?

유사한 방식으로 INDEX MATCH를 IFERROR와 함께 사용할 수 있습니다.

=IFERROR(INDEX('Lookup table'!$B$2:$B$5,MATCH(B2,'Lookup table'!$A$2:$A$5,0)), "Not found")

IFERROR INDEX MATCH 수식은 조회 열(왼쪽 조회)의 왼쪽에 있는 열에서 값을 가져오고 아무것도 찾을 수 없을 때 자신의 텍스트를 반환하려는 경우에 특히 유용합니다.

예제 2. IFERROR with 빈 문자열을 반환하거나 아무것도 찾지 못한 경우 0을 반환하는 VLOOKUP

조회 값을 찾을 수 없을 때 아무 것도 표시하지 않으려면 IFERROR에서 빈 문자열 ("")을 표시하도록 합니다.

예제에서 수식은 다음과 같습니다.

=IFERROR(VLOOKUP(B2,'Lookup table'!$A$2:$B$5, 2, FALSE), "")

보시는 바와 같이 조회 값이 검색 목록에 없으면 아무 것도 반환하지 않습니다.

오류를 0 값 으로 바꾸려면 0 마지막 a rgument:

=IFERROR(VLOOKUP(B2,'Lookup table'!$A$2:$B$5, 2, FALSE), 0)

주의 사항! Excel IFERROR 함수는 #N/A뿐만 아니라 모든 종류의 오류를 포착합니다. 좋은가요 나쁜가요? 모두 당신의 목표에 달려 있습니다. 가능한 모든 오류를 숨기려면 IFERROR Vlookup을 사용하십시오. 그러나 이는 많은 상황에서 현명하지 못한 기술일 수 있습니다.

예를 들어 테이블 데이터에 대해 이름이 지정된 범위를 만들고 해당 이름의 철자를Vlookup 공식, IFERROR는 #NAME을 잡을 것입니까? 오류 및 "찾을 수 없음" 또는 제공한 다른 텍스트로 바꿉니다. 결과적으로 오타를 직접 발견하지 않는 한 수식이 잘못된 결과를 제공하는지 알 수 없습니다. 이러한 경우 보다 합리적인 접근 방식은 #N/A 오류만 트래핑하는 것입니다. 이를 위해 Excel 2013 이상에서 IFNA Vlookup 수식을 사용하고 모든 Excel 버전에서 IF ISNA VLOOKUP을 사용합니다.

결론은: VLOOKUP 수식에 대한 컴패니언을 선택할 때 매우 주의해야 합니다 :)

항상 무언가를 찾기 위해 VLOOKUP 내에 IFERROR를 중첩

다음과 같은 상황을 상상해 보십시오. 목록에서 특정 값을 조회했지만 찾을 수 없습니다. 어떤 선택이 있습니까? N/A 오류가 표시되거나 자신의 메시지를 표시하십시오. 실제로 세 번째 옵션이 있습니다. 기본 vlookup이 잘못되면 확실히 있는 다른 항목을 검색하세요!

예를 더 들어 사용자에게 확장 프로그램을 표시하는 일종의 대시보드를 만들어 보겠습니다. 특정 사무실 번호. 다음과 같습니다.

그러면 D2의 사무실 번호를 기준으로 B열에서 내선 번호를 어떻게 가져옵니까? 이 일반 Vlookup 수식을 사용하면:

=VLOOKUP($D$2,$A$2:$B$7,2,FALSE)

사용자가 D2에 유효한 숫자를 입력하는 한 잘 작동합니다. 하지만 사용자가 존재하지 않는 숫자를 입력하면 어떻게 될까요? 이 경우 중앙 사무실에 전화하게하십시오! 이를 위해 위의 수식을IFERROR의 value 인수, value_if_error 인수에 다른 Vlookup을 넣습니다.

완전한 공식은 약간 길지만 완벽하게 작동합니다.

=IFERROR(VLOOKUP("office "&$D$2,$A$2:$B$7,2,FALSE),VLOOKUP("central office",$A$2:$B$7,2,FALSE))

사무실 번호를 찾으면 사용자는 해당 내선 번호를 받습니다.

사무실 번호를 찾지 못하면 본사 내선 번호 다음과 같이 표시됩니다.

수식을 좀 더 간결하게 만들려면 다른 방법을 사용할 수 있습니다.

먼저 D2에 숫자가 있는지 확인합니다. 조회 열에서( col_index_num 를 조회하여 열 A에서 값을 반환하는 수식에 대해 1로 설정했음에 유의하십시오.): VLOOKUP(D2,$A$2:$B$7,1,FALSE)

지정된 사무실 번호가 없으면 조회 목록에 확실히 있는 문자열 "central office"를 검색합니다. 이를 위해 첫 번째 VLOOKUP을 IFERROR로 래핑하고 이 전체 조합을 다른 VLOOKUP 함수 안에 중첩합니다.

그런데 '중앙청사'를 찾는 이유가 뭐냐고 물을 수 있습니다. IFERROR에서 직접 내선 번호를 제공하지 않는 이유는 무엇입니까? 확장자는 향후 어느 시점에서 변경될 수 있기 때문입니다. 이 경우 각 VLOOKUP 수식 업데이트에 대해 걱정하지 않고 소스 테이블에서 데이터를 한 번만 업데이트해야 합니다.

Excel에서 순차적 VLOOKUP을 수행하는 방법

다음과 같은 상황에서 당신은 필요가이전 조회의 성공 또는 실패 여부에 따라 Excel에서 이른바 순차 또는 체인 Vlookup을 수행하고, 두 개 이상의 IFERROR 함수를 중첩하여 Vlookup을 하나씩 실행합니다.

수식은 다음 논리와 함께 작동합니다.

첫 번째 VLOOKUP에서 아무 것도 찾지 못하면 첫 번째 IFERROR에서 오류를 포착하고 다른 VLOOKUP을 실행합니다. 두 번째 VLOOKUP이 실패하면 두 번째 IFERROR가 오류를 포착하고 세 번째 VLOOKUP을 실행하는 식입니다. 모든 Vlookup이 실패하면 마지막 IFERROR가 메시지를 반환합니다.

이 중첩된 IFERROR 수식은 아래 예와 같이 여러 시트 에서 Vlookup해야 할 때 특히 유용합니다.

3개의 서로 다른 워크시트(이 예에서는 사무실 번호)에 3개의 동종 데이터 목록이 있고 특정 번호에 대한 내선 번호를 얻고 싶다고 가정해 보겠습니다.

조회 값이 셀 A2에 있다고 가정합니다. 현재 시트에서 조회 범위는 3개의 다른 워크시트(North, South 및 West)에서 A2:B5입니다. 다음 수식은 유용합니다.

=IFERROR(VLOOKUP(A2,North!$A$2:$B$5,2,FALSE), IFERROR(VLOOKUP(A2,South!$A$2:$B$5,2,FALSE), IFERROR(VLOOKUP(A2,West!$A$2:$B$5,2,FALSE),"Not found")))

Vlookups" 수식은 세 개의 다른 시트를 수식에 중첩한 순서대로 검색하고 찾은 첫 번째 일치 항목을 가져옵니다.

다음에서 VLOOKUP과 함께 IFERROR를 사용하는 방법 뛰어나다. 읽어주셔서 감사하고 뵙기를 바랍니다다음 주 블로그에서!

사용 가능한 다운로드

Excel IFERROR VLOOKUP 수식 예제