Kennslan sýnir hvernig á að sameina V LOOKUP og IF fall saman í v-leit með if condition í Excel. Þú munt einnig læra hvernig á að nota IF ISNA VLOOKUP formúlur til að skipta um #N/A villur fyrir þinn eigin texta, núll eða auðan reit.

Þó að FLOKUP og IF aðgerðirnar séu gagnlegar einar og sér, saman þeir skila enn verðmætari reynslu. Þessi kennsla gefur til kynna að þú manst vel setningafræði aðgerðanna tveggja, annars gætirðu viljað bæta þekkingu þína með því að fylgja hlekkjunum hér að ofan.

Vlookup with If statement: return True/ Rangt, Já/Nei o.s.frv.

Ein algengasta atburðarás þegar þú sameinar If og Vlookup saman er að bera saman gildið sem Vlookup skilar við sýnishornsgildi og skila Já / Nei eða True / False sem afleiðing.

Í flestum tilfellum myndi eftirfarandi almenna formúla virka vel:

Þýdd á venjulegri ensku, formúlan gefur Excel fyrirmæli um að skila True ef Vlookup er satt (þ.e. jafnt tilgreindu gildi). Ef Vlookup er rangt (ekki jafnt tilgreindu gildi), skilar formúlan False .

Hér að neðan finnurðu nokkrar raunverulegar notkunaraðferðir þessarar IF Vlookup formúlu.

Dæmi 1. Flettu upp ákveðnu gildi

Segjum að þú hafir lista yfir hluti í dálki A og magn í dálki B. Þú ert að búa til mælaborð fyrir notendur þína og þarft formúlusem myndi athuga magn vöru í E1 og upplýsa notandann um hvort varan sé til á lager eða uppseld.

Þú dregur magnið með venjulegri Vlookup með nákvæmri samsvörun formúlu svona:

=VLOOKUP(E1,$A$2:$B$10,2,FALSE)

Skrifaðu síðan IF setningu sem ber niðurstöðu Vlookup saman við núll og skilar "Nei" ef það er jafnt og 0, "Já" annars:

=IF(VLOOKUP(E1,$A$2:$B$10,2,FALSE)=0,"No","Yes")

Í stað Já/Nei geturðu skilað SATT/Ósatt eða Á lager/Uppseld eða öðrum tveimur val. Til dæmis:

=IF(VLOOKUP(E1,$A$2:$B$10,2)=0,"Sold out","In stock")

Þú getur líka borið saman gildið sem Vlookup skilar við sýnishorn texta . Í þessu tilviki, vertu viss um að setja textastreng innan gæsalappa, eins og þetta:

=IF(VLOOKUP(E1,$A$2:$B$10,2)="sample text",TRUE,FALSE)

Dæmi 2. Berðu saman niðurstöður Vlookup við annan reit

Annað dæmigert dæmi um Vlookup með If ástand í Excel er að bera saman Vlookup úttakið við gildi í öðrum reit. Til dæmis getum við athugað hvort það sé stærra en eða jafnt og tölu í reit G2:

=IF(VLOOKUP(E1,$A$2:$B$10,2)>=G2,"Yes!","No")

Og hér er Ef formúlan okkar með Vlookup í aðgerð:

Á svipaðan hátt geturðu notað hvaða annan rökrænan rekstraraðila sem er ásamt frumutilvísun í Excel If Vlookup formúlunni.

Dæmi 3. Vlookup gildi í styttri lista

Til að bera saman hverja reit í markdálknum við annan lista og skila True eða Já ef samsvörun finnst, False eða Nei annars, notaðu þessa almennu IF ISNA VLOOKUP formúlu:

Ef Vlookup leiðir til #N/A villu, þá skilar formúlan "Nei", sem þýðir að uppflettingargildið finnst ekki í uppflettilistanum. Ef samsvörun finnst er "Já" skilað. Til dæmis:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"No","Yes")

Ef viðskiptarökfræði þín krefst gagnstæða niðurstöðu skaltu einfaldlega skipta um "Já" og "Nei" til að snúa við rökfræði formúlunnar:

=IF(ISNA(VLOOKUP(A2,$D$2:$D$4,1,FALSE)),"Yes","No")

Excel If Vlookup formúla til að framkvæma mismunandi útreikninga

Auk þess að birta eigin textaskilaboð, getur If aðgerð með Vlookup framkvæmt mismunandi útreikninga byggt á þeim forsendum sem þú tilgreinir.

Tökum dæmi okkar lengra, við skulum reikna þóknun tiltekins seljanda (F1) eftir skilvirkni þeirra: 20% þóknun fyrir þá sem græddu $200 og meira, 10% fyrir alla aðra .

Til þess athugarðu hvort gildið sem Vlookup skilar sé stærra en eða jafnt og 200, og ef það er, margfaldarðu það með 20%, annars með 10%:

=IF(VLOOKUP(F1,$A$2:$C$10,3,FALSE )>=200, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*20%, VLOOKUP(F1,$A$2:$C$10,3,FALSE)*10%)

Þar sem A2:A10 eru nöfn seljanda og C2:C10 eru sala.

EF ISNA VLOOKUP til að fela #N/A villur

Ef VLOOKUP aðgerðin getur ekki fundið tilgreint gildi, varpar hún #N/A villu. Til að ná þessari villu og skipta henni út fyrir þinn eigin texta skaltu fella inn Vlookup formúlu í rökréttu prófinu á IF fallinu, svona:

Að sjálfsögðu geturðu slegið inn hvaða texta sem þér líkar í staðinn fyrir „Finnst ekki“.

Svona að þú hafir lista yfir seljandanöfn í einum dálki og söluupphæðir í öðrum dálki. Verkefni þitt er að draga tölu sem samsvarar nafninu sem notandinn slær inn í F1. Ef nafnið finnst ekki, birtu skilaboð sem gefa til kynna það.

Með nöfnunum í A2:A10 og upphæðum C2:C10 er hægt að framkvæma verkefnið með eftirfarandi If Vlookup formúlu:

=IF(ISNA(VLOOKUP(F1,$A$2:$C$10,3,FALSE)), "Not found", VLOOKUP(F1,$A$2:$C$10,3,FALSE))

Ef nafnið finnst er samsvarandi söluupphæð skilað:

Ef uppflettingargildið finnst ekki er Finn ekki skilaboðin birtast í stað #N/A villunnar:

Hvernig þessi formúla virkar

Rökfræði formúlunnar er mjög einföld: þú notar ISNA aðgerðina til að athuga Vlookup fyrir #N/A villur. Ef villa kemur upp skilar ISNA TRUE, annars FALSE. Ofangreind gildi fara í rökrétt próf IF fallsins, sem gerir eitt af eftirfarandi:

• Ef rökfræðilega prófið er TRUE (#N/A villa), birtast skilaboðin þín.
• Ef rökfræðilega prófið er FALSE (uppflettingargildi finnst), skilar Vlookup samsvörun venjulega.

IFNA VLOOKUP í nýrri Excel útgáfum

Frá og með Excel 2013, þú getur notað IFNA fallið í stað IF ISNA til að ná og meðhöndla #N/A villur:

Í okkar dæmi myndi formúlan taka eftirfarandi form:

=IFNA(VLOOKUP(F1,$A$2:$C$10,3, FALSE), "Not found")

Ábending. Ef þú vilt fanga alls kyns villur, ekki aðeins #N/A, notaðu VLOOKUP ásamt IFERROR aðgerðinni. Nánari upplýsingar má finna hér: IFERRORVLOOKUP í Excel.

Excel Vlookup: ef ekki finnst skila 0

Þegar unnið er með tölugildi gætirðu viljað skila núlli þegar uppflettingargildið finnst ekki. Til að gera það skaltu nota IF ISNA VLOOKUP formúluna sem fjallað er um hér að ofan með smá breytingu: í stað textaskilaboða, gefðu upp 0 í gildi_ef_true röksemdafærslu IF fallsins:

Í sýnistöflunni okkar myndi formúlan vera sem hér segir:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), 0, VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Í nýlegar útgáfur af Excel 2016 og 2013, þú getur notað IFNA Vlookup samsetninguna aftur:

=IFNA(VLOOKUP(I2,$A$2:$C$10,3, FALSE), 0)

Excel Vlookup: ef það finnst ekki skila auðu hólfinu

Þetta er enn ein afbrigðið af "Vlookup if then" yfirlýsingunni: skila engu þegar uppflettingargildið finnst ekki. Til að gera þetta, gefðu uppskriftinni þinni fyrirmæli um að skila tómum streng ("") í stað #N/A villunnar:

Hér fyrir neðan eru nokkur heill formúludæmi:

Fyrir allar Excel útgáfur:

=IF(ISNA(VLOOKUP(F2,$A$2:$C$10,3,FALSE)), "", VLOOKUP(F2,$A$2:$C$10,3,FALSE))

Fyrir Excel 2016 og Excel 2013:

=IFNA(VLOOKUP(F2,$A$2:$C$10,3, FALSE), "")

Ef með Index Match - vinstri vlookup með If condition

Vannir Excel notendur vita að VLOOKUP aðgerðin er ekki eina leiðin til að gera lóðrétt uppflettingu í Excel. Einnig er hægt að nota INDEX MATCH samsetninguna í þessum tilgangi og hún er enn öflugri og fjölhæfari. Góðu fréttirnar eru þær að Index Match getur unnið saman með IF á nákvæmlega sama hátt ogVlookup.

Til dæmis, þú ert með pöntunarnúmer í dálki A og nöfn seljanda í dálki B. Þú ert að leita að formúlu til að draga pöntunarnúmerið fyrir tiltekinn seljanda.

Vlookup getur ekki verið notað í þessu tilfelli vegna þess að það getur ekki leitað frá hægri til vinstri. Index Match mun virka án áfalls svo lengi sem uppflettingargildið er að finna í uppflettisdálknum. Ef ekki, mun #N/A villa birtast. Til að skipta út venjulegu villumerkinu fyrir eigin texta skaltu setja Index Match inni í IF ISNA:

=IF(ISNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0))), "Not found", INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)))

Í Excel 2016 og 2016 geturðu notað IFNA í stað IF ISNA til að gera formúluna meira compact:

=IFNA(INDEX(A2:A10, MATCH(F1, $B$2:$B$10, 0)), "Not found")

Á svipaðan hátt geturðu notað Index Match í öðrum If formúlum.

Svona notarðu Vlookup og IF yfirlýsing saman í Excel. Til að skoða betur formúlurnar sem fjallað er um í þessari kennslu er þér velkomið að hlaða niður sýnishornsvinnubókinni okkar hér að neðan. Ég þakka þér fyrir lesturinn og vonast til að sjá þig á blogginu okkar í næstu viku!

Æfingabók til niðurhals

Excel IF Vlookup - formúludæmi (.xlsx skrá)