સામગ્રીઓનું કોષ્ટક
ટ્યુટોરીયલ એક્સેલમાં અક્ષરોની ગણતરી કેવી રીતે કરવી તે સમજાવે છે. તમે શ્રેણીમાં કુલ અક્ષરોની ગણતરી મેળવવા માટેના સૂત્રો શીખી શકશો, અને કોષમાં અથવા કેટલાક કોષોમાં માત્ર ચોક્કસ અક્ષરોની ગણતરી કરશો.
અમારા અગાઉના ટ્યુટોરીયલમાં એક્સેલ LEN ફંક્શન રજૂ કરવામાં આવ્યું છે, જે કોષમાં અક્ષરોની કુલ સંખ્યા.
LEN ફોર્મ્યુલા તેના પોતાના પર ઉપયોગી છે, પરંતુ SUM, SUMPRODUCT અને SUBSTITUTE જેવા અન્ય કાર્યો સાથે સંપર્કમાં, તે વધુ જટિલ કાર્યોને સંભાળી શકે છે. આ ટ્યુટોરીયલમાં આગળ, આપણે એક્સેલમાં અક્ષરોની ગણતરી કરવા માટેના કેટલાક મૂળભૂત અને અદ્યતન સૂત્રોને નજીકથી જોઈશું.
શ્રેણીમાં બધા અક્ષરોની ગણતરી કેવી રીતે કરવી
જ્યારે કેટલાક કોષોમાં કુલ અક્ષરોની સંખ્યાની ગણતરી કરવાની વાત આવે છે, ત્યારે એક તાત્કાલિક ઉકેલ જે ધ્યાનમાં આવે છે તે દરેક કોષ માટે અક્ષરોની ગણતરી મેળવવાનો છે, અને પછી તે સંખ્યાઓ ઉમેરો:
=LEN(A2)+LEN(A3)+LEN(A4)
અથવા
=SUM(LEN(A2),LEN(A3),LEN(A4))
ઉપરોક્ત સૂત્રો નાની શ્રેણી માટે સારું કામ કરી શકે છે. મોટી શ્રેણીમાં કુલ અક્ષરોની ગણતરી કરવા માટે, અમે વધુ સારી રીતે કંઈક વધુ કોમ્પેક્ટ સાથે આવીશું, દા.ત. SUMPRODUCT ફંક્શન, જે એરેનો ગુણાકાર કરે છે અને ઉત્પાદનોનો સરવાળો આપે છે.
શ્રેણીમાં અક્ષરોની ગણતરી કરવા માટે અહીં સામાન્ય એક્સેલ ફોર્મ્યુલા છે:
=SUMPRODUCT(LEN( રેન્જ) )અને તમારું વાસ્તવિક જીવન સૂત્ર આના જેવું જ દેખાઈ શકે છે:
=SUMPRODUCT(LEN(A1:A7))
શ્રેણીમાં અક્ષરોની ગણતરી કરવાની બીજી રીત છે માં LEN કાર્યSUM સાથે સંયોજન:
=SUM(LEN(A1:A7))
SUMPRODUCT થી વિપરીત, SUM ફંક્શન ડિફૉલ્ટ રૂપે એરેની ગણતરી કરતું નથી, અને તમારે તેને એરે ફોર્મ્યુલામાં ફેરવવા માટે Ctrl + Shift + Enter દબાવવાની જરૂર છે.
નીચેના સ્ક્રીનશોટમાં દર્શાવ્યા મુજબ, SUM ફોર્મ્યુલા સમાન કુલ અક્ષરોની સંખ્યા પરત કરે છે:
આ શ્રેણી અક્ષર ગણતરી સૂત્ર કેવી રીતે કાર્ય કરે છે
આ Excel માં અક્ષરોની ગણતરી કરવા માટે સૌથી સરળ ફોર્મ્યુલા છે. LEN ફંક્શન નિર્દિષ્ટ શ્રેણીમાં દરેક કોષ માટે સ્ટ્રિંગ લંબાઈની ગણતરી કરે છે અને તેમને સંખ્યાઓની શ્રેણી તરીકે પરત કરે છે. અને પછી, SUMPRODUCT અથવા SUM તે સંખ્યાઓ ઉમેરે છે અને કુલ અક્ષરોની સંખ્યા પરત કરે છે.
ઉપરોક્ત ઉદાહરણમાં, 7 સંખ્યાઓની એરે જે A1 થી A7 કોષોમાં શબ્દમાળાઓની લંબાઈ દર્શાવે છે તેનો સરવાળો કરવામાં આવે છે:
નોંધ. કૃપા કરીને ધ્યાન આપો કે એક્સેલ LEN ફંક્શન સંપૂર્ણપણે દરેક કોષમાં તમામ અક્ષરોની ગણતરી કરે છે , જેમાં અક્ષરો, સંખ્યાઓ, વિરામચિહ્નો, વિશિષ્ટ પ્રતીકો અને તમામ જગ્યાઓ (અગ્રણી, પાછળની અને શબ્દો વચ્ચેની જગ્યાઓ)નો સમાવેશ થાય છે.
કોષમાં ચોક્કસ અક્ષરોની ગણતરી કેવી રીતે કરવી
કેટલીકવાર, કોષની અંદરના તમામ અક્ષરોની ગણતરી કરવાને બદલે, તમારે ચોક્કસ અક્ષર, સંખ્યા અથવા વિશિષ્ટ પ્રતીકની માત્ર ઘટનાઓની ગણતરી કરવાની જરૂર પડી શકે છે.
કોષમાં આપેલ અક્ષર કેટલી વખત દેખાય છે તેની ગણતરી કરવા માટે, SUBSTITUTE સાથે LEN ફંક્શનનો ઉપયોગ કરો:
=LEN( cell )-LEN(SUBSTITUTE( cell )>, અક્ષર ,""))સૂત્રને વધુ સારી રીતે સમજવા માટે, નીચેના ઉદાહરણને ધ્યાનમાં લો.
ધારો કે, તમે વિતરિત વસ્તુઓનો ડેટાબેઝ જાળવી રાખો છો, જ્યાં દરેક આઇટમ પ્રકારનું પોતાનું આગવું વિશિષ્ટ હોય છે. ઓળખકર્તા અને દરેક કોષમાં અલ્પવિરામ, અવકાશ અથવા અન્ય કોઈપણ સીમાંક દ્વારા અલગ કરાયેલી ઘણી વસ્તુઓ હોય છે. કાર્ય એ ગણતરી કરવાનું છે કે આપેલ અનન્ય ઓળખકર્તા દરેક કોષમાં કેટલી વાર દેખાય છે.
વિતરિત વસ્તુઓની સૂચિ કૉલમ B (B2 માં શરૂ થાય છે) માં છે એમ માનીને, અને અમે "A" ની સંખ્યા ગણી રહ્યા છીએ. ઘટનાઓ, સૂત્ર નીચે મુજબ છે:
=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))
આ એક્સેલ અક્ષર ગણતરી ફોર્મ્યુલા કેવી રીતે કાર્ય કરે છે
ફોર્મ્યુલાના તર્કને સમજવા માટે, ચાલો જોઈએ તેને નાના ભાગોમાં વિભાજીત કરો:
- પ્રથમ, તમે B2 માં કુલ સ્ટ્રિંગ લંબાઈ ગણો:
LEN(B2)
SUBSTITUTE(B2,"A","")
LEN(SUBSTITUTE(B2,"A",""))
પરિણામે, તમે "દૂર કરેલ" અક્ષરોની ગણતરી મેળવો છો, જે કોષમાં તે અક્ષરની ઘટનાઓની કુલ સંખ્યાની બરાબર છે.
તમે જે અક્ષરમાં ગણવા માંગો છો તેનો ઉલ્લેખ કરવાને બદલે એક સૂત્ર, તમે તેને અમુક કોષમાં લખી શકો છો અને પછી તે કોષને સૂત્રમાં સંદર્ભિત કરી શકો છો. આ રીતે, તમારા વપરાશકર્તાઓતમારા ફોર્મ્યુલા સાથે છેડછાડ કર્યા વિના તે કોષમાં તેઓ જે અન્ય કેરેક્ટર ઇનપુટ કરે છે તેની ઘટનાઓની ગણતરી કરવામાં સક્ષમ હશે:
નોંધ. એક્સેલનું SUBSTITUTE એ કેસ-સંવેદનશીલ કાર્ય છે, અને તેથી ઉપરોક્ત સૂત્ર કેસ-સંવેદનશીલ પણ છે. ઉદાહરણ તરીકે, ઉપરોક્ત સ્ક્રીનશોટમાં, સેલ B3 માં "A" ની 3 ઘટનાઓ છે - બે અપરકેસમાં અને એક લોઅરકેસમાં. સૂત્રમાં ફક્ત મોટા અક્ષરોની ગણતરી કરવામાં આવી છે કારણ કે અમે SUBSTITUTE ફંક્શનને "A" સપ્લાય કર્યું છે.
કોષમાં વિશિષ્ટ અક્ષરોની ગણતરી કરવા માટે કેસ-અસંવેદનશીલ એક્સેલ ફોર્મ્યુલા
જો તમને કેસ-અસંવેદનશીલ અક્ષરોની ગણતરીની જરૂર હોય, તો અવેજી ચલાવતા પહેલા ઉલ્લેખિત અક્ષરને અપરકેસમાં કન્વર્ટ કરવા માટે SUBSTITUTE ની અંદર UPPER ફંક્શનને એમ્બેડ કરો. અને, સૂત્રમાં અપરકેસ અક્ષર દાખલ કરવાનું સુનિશ્ચિત કરો.
ઉદાહરણ તરીકે, સેલ B2 માં "A" અને "a" વસ્તુઓની ગણતરી કરવા માટે, આ સૂત્રનો ઉપયોગ કરો:
=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))
બીજી રીત નેસ્ટેડ સબસ્ટિટ્યુટ ફંક્શન્સનો ઉપયોગ કરવાની છે:
=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")
જેમ તમે નીચેના સ્ક્રીનશોટમાં જોઈ શકો છો, બંને ફોર્મ્યુલા નિર્દિષ્ટ અક્ષરની અપરકેસ અને લોઅરકેસ ઘટનાઓને દોષરહિત રીતે ગણે છે:
કેટલાક કિસ્સાઓમાં, તમારે કોષ્ટકમાં ઘણાં વિવિધ અક્ષરોની ગણતરી કરવાની જરૂર પડી શકે છે, પરંતુ તમે દરેક વખતે સૂત્રને સંશોધિત કરવા માંગતા નથી. આ કિસ્સામાં, એક અવેજી ફંક્શનને બીજામાં નેસ્ટ કરો, તમે અમુક કોષમાં ગણવા માંગતા હો તે અક્ષર લખો (આ ઉદાહરણમાં D1), અને તે કોષના મૂલ્યને અપરકેસમાં કન્વર્ટ કરો અનેUPPER અને LOWER ફંક્શન્સનો ઉપયોગ કરીને લોઅરકેસ:
=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))
વૈકલ્પિક રીતે, સ્ત્રોત સેલ અને કેરેક્ટર ધરાવતા કોષ બંનેને અપરકેસ અથવા લોઅરકેસમાં કન્વર્ટ કરો. ઉદાહરણ તરીકે:
=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))
કોષમાં અમુક ટેક્સ્ટ અથવા સબસ્ટ્રિંગની ઘટનાઓની ગણતરી કરો
જો તમે ગણતરી કરવા માંગતા હોવ તો કેટલી વખત અક્ષરોનું ચોક્કસ સંયોજન (એટલે કે ચોક્કસ ટેક્સ્ટ અથવા સબસ્ટ્રિંગ) આપેલ કોષમાં દેખાય છે, દા.ત. "A2" અથવા "SS", પછી ઉપરોક્ત સૂત્રો દ્વારા પરત કરાયેલા અક્ષરોની સંખ્યાને સબસ્ટ્રિંગની લંબાઈથી વિભાજીત કરો.
કેસ-સંવેદનશીલ સૂત્ર:
=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)
કેસ-સંવેદનશીલ સૂત્ર:
=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)
જ્યાં B2 એ સંપૂર્ણ ટેક્સ્ટ સ્ટ્રિંગ ધરાવતો કોષ છે, અને C1 એ ટેક્સ્ટ (સબસ્ટ્રિંગ) છે જે તમે ગણતરી કરવા માંગો છો.
સૂત્રની વિગતવાર સમજૂતી માટે, કૃપા કરીને કોષમાં ચોક્કસ ટેક્સ્ટ / શબ્દોની ગણતરી કેવી રીતે કરવી તે જુઓ.
વિશિષ્ટની ગણતરી કેવી રીતે કરવી શ્રેણીમાંના અક્ષર(ઓ)
હવે જ્યારે તમે કોષમાં અક્ષરોની ગણતરી કરવા માટે એક્સેલ ફોર્મ્યુલા જાણો છો, તો તમે શ્રેણીમાં ચોક્કસ અક્ષર કેટલી વાર દેખાય છે તે શોધવા માટે તેને વધુ સુધારી શકો છો. આ માટે, આપણે ચર્ચા કરેલ સેલમાં ચોક્કસ અક્ષર ગણવા માટે એક્સેલ LEN ફોર્મ્યુલા લઈશુંપાછલા ઉદાહરણમાં, અને તેને SUMPRODUCT ફંક્શનની અંદર મૂકો જે એરેને હેન્ડલ કરી શકે છે:
SUMPRODUCT(LEN( range )-LEN(SUBSTITUTE( range , character ,"")))આ ઉદાહરણમાં, સૂત્ર નીચેનો આકાર લે છે:
=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))
અને અહીં ગણતરી કરવા માટેનું બીજું સૂત્ર છે એક્સેલની શ્રેણીમાં અક્ષરો:
=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))
પ્રથમ સૂત્રની તુલનામાં, સૌથી સ્પષ્ટ તફાવત SUMPRODUCT ને બદલે SUM નો ઉપયોગ કરવાનો છે. બીજો તફાવત એ છે કે તેને Ctrl + Shift + Enter દબાવવાની જરૂર છે કારણ કે SUMPRODUCT, જે એરે પર પ્રક્રિયા કરવા માટે રચાયેલ છે તેનાથી વિપરીત, SUM એરેને ત્યારે જ હેન્ડલ કરી શકે છે જ્યારે એરે ફોર્મ્યુલા માં વપરાય છે.
જો તમે ન કરો ફોર્મ્યુલામાં અક્ષરને હાર્ડકોડ કરવા નથી માંગતા, તમે અલબત્ત તેને અમુક કોષમાં લખી શકો છો, D1 કહો, અને તે કોષને તમારા અક્ષર ગણતરી સૂત્રમાં સંદર્ભિત કરી શકો છો:
=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))
નોંધ. એવી પરિસ્થિતિઓમાં જ્યારે તમે શ્રેણીમાં ચોક્કસ સબસ્ટ્રિંગ ની ઘટનાઓની ગણતરી કરો છો (દા.ત. "KK" અથવા "AA" થી શરૂ થતા ઓર્ડર), તમારે સબસ્ટ્રિંગ લંબાઈ દ્વારા અક્ષરોની ગણતરીને વિભાજિત કરવાની જરૂર છે, અન્યથા દરેક અક્ષર સબસ્ટ્રિંગ વ્યક્તિગત રીતે ગણવામાં આવશે. ઉદાહરણ તરીકે:
=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))
આ અક્ષર ગણવાનું સૂત્ર કેવી રીતે કાર્ય કરે છે
તમને યાદ હશે તેમ, SUBSTITUTE ફંક્શનનો ઉપયોગ ઉલ્લેખિત અક્ષરની બધી ઘટનાઓને બદલવા માટે થાય છે (આ ઉદાહરણમાં "A" ) ખાલી ટેક્સ્ટ સ્ટ્રિંગ ("") સાથે.
પછી, અમે એક્સેલ LEN ને SUBSTITUTE દ્વારા પરત કરાયેલ ટેક્સ્ટ સ્ટ્રિંગ સપ્લાય કરીએ છીએ.ફંક્શન જેથી તે A ના વગર સ્ટ્રિંગ લંબાઈની ગણતરી કરે. અને પછી, અમે ટેક્સ્ટ સ્ટ્રિંગની કુલ લંબાઈમાંથી તે અક્ષરની ગણતરી બાદ કરીએ છીએ. આ ગણતરીઓનું પરિણામ એ કોષ દીઠ એક અક્ષરની ગણતરી સાથે, અક્ષરોની ગણતરીની એરે છે.
છેવટે, SUMPRODUCT એરેમાંની સંખ્યાઓનો સરવાળો કરે છે અને શ્રેણીમાં ઉલ્લેખિત અક્ષરોની કુલ ગણતરી આપે છે.
વિશિષ્ટ અક્ષરોની શ્રેણીમાં ગણતરી કરવા માટે એક કેસ-સંવેદનશીલ સૂત્ર
તમે પહેલાથી જ જાણો છો કે SUBSTITUTE એ કેસ-સંવેદનશીલ કાર્ય છે, જે અક્ષરોની ગણતરી માટેના અમારા એક્સેલ સૂત્રને પણ કેસ-સંવેદી બનાવે છે.
0 અવગણના કેસમાં ચોક્કસ અક્ષરો:- UPPER ફંક્શનનો ઉપયોગ કરો અને અપરકેસમાં અક્ષર દાખલ કરો:
=SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A",""))) - નેસ્ટેડ સબસ્ટીટ્યુટ ફંક્શનનો ઉપયોગ કરો:
=SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a",""))) - UPPER અને LOWER ફંક્શનનો ઉપયોગ કરો, અમુક સેલમાં અપરકેસ અથવા લોઅરકેસ અક્ષર લખો અને તમારા ફોર્મ્યુલામાં તે કોષનો સંદર્ભ આપો:
=SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))
નીચેનો સ્ક્રીનશોટ ક્રિયામાં છેલ્લું સૂત્ર દર્શાવે છે:
ટીપ. શ્રેણીમાં ચોક્કસ ટેક્સ્ટ (સબસ્ટ્રિંગ) ની ઘટનાઓની ગણતરી કરવા માટે, શ્રેણીમાં ચોક્કસ ટેક્સ્ટ/શબ્દોની ગણતરી કેવી રીતે કરવી તેમાં દર્શાવેલ ફોર્મ્યુલાનો ઉપયોગ કરો.
આતમે કેવી રીતે LEN ફંક્શનનો ઉપયોગ કરીને એક્સેલમાં અક્ષરોની ગણતરી કરી શકો છો. જો તમે વ્યક્તિગત અક્ષરોને બદલે શબ્દોની ગણતરી કેવી રીતે કરવી તે જાણવા માંગતા હો, તો તમને અમારા આગલા લેખમાં થોડા ઉપયોગી સૂત્રો મળશે, કૃપા કરીને ટ્યુન રહો!
તે દરમિયાન, તમે અક્ષર ગણતરી સૂત્ર સાથે નમૂના વર્કબુક ડાઉનલોડ કરી શકો છો. આ ટ્યુટોરીયલમાં ચર્ચા કરી છે, અને પૃષ્ઠના અંતે સંબંધિત સંસાધનોની સૂચિ તપાસો. હું વાંચવા બદલ તમારો આભાર માનું છું અને તમને જલ્દી મળવાની આશા રાખું છું!
