이 자습서에서는 Excel에서 문자를 계산하는 방법을 설명합니다. 범위의 총 문자 수를 구하고 한 셀 또는 여러 셀의 특정 문자만 계산하는 공식을 배웁니다.

이전 자습서에서는 셀 수를 계산할 수 있는 Excel LEN 함수를 소개했습니다. 셀의 총 문자 수입니다.

LEN 수식은 그 자체로도 유용하지만 SUM, SUMPRODUCT 및 SUBSTITUTE와 같은 다른 함수와 연계하여 훨씬 더 복잡한 작업을 처리할 수 있습니다. 이 자습서에서는 Excel에서 문자를 계산하는 몇 가지 기본 및 고급 수식을 자세히 살펴보겠습니다.

범위의 모든 문자를 계산하는 방법

여러 셀의 총 문자 수를 계산할 때 떠오르는 즉각적인 해결책은 각 셀의 문자 수를 가져온 다음 해당 숫자를 더하는 것입니다.

=LEN(A2)+LEN(A3)+LEN(A4)

또는

=SUM(LEN(A2),LEN(A3),LEN(A4))

위의 수식은 작은 범위에서 잘 작동할 수 있습니다. 더 큰 범위의 총 문자 수를 계산하려면 더 간결한 것을 제시하는 것이 좋습니다. 배열을 곱하고 곱의 합계를 반환하는 SUMPRODUCT 함수.

다음은 범위의 문자 수를 계산하는 일반 Excel 수식입니다.

실제 공식은 다음과 유사할 수 있습니다.

=SUMPRODUCT(LEN(A1:A7))

범위의 문자를 계산하는 또 다른 방법은 LEN 기능SUM과 조합:

=SUM(LEN(A1:A7))

SUMPRODUCT와 달리 SUM 함수는 기본적으로 배열을 계산하지 않으며 배열 수식으로 변환하려면 Ctrl + Shift + Enter를 눌러야 합니다.

다음 스크린샷에서 볼 수 있듯이 SUM 수식은 동일한 총 문자 수를 반환합니다.

이 범위 문자 수 수식의 작동 방식

이 Excel에서 문자를 계산하는 가장 간단한 수식 중 하나입니다. LEN 함수는 지정된 범위의 각 셀에 대한 문자열 길이를 계산하고 숫자 배열로 반환합니다. 그런 다음 SUMPRODUCT 또는 SUM은 해당 숫자를 더하고 총 문자 수를 반환합니다.

위의 예에서 A1~A7 셀의 문자열 길이를 나타내는 7개의 숫자 배열이 합산됩니다.

참고. Excel LEN 함수는 문자, 숫자, 구두점, 특수 기호 및 모든 공백(선행, 후행 및 단어 사이의 공백)을 포함하여 각 셀 의 모든 문자를 절대적으로 계산한다는 점에 유의하십시오.

셀의 특정 문자 수를 세는 방법

경우에 따라 셀 내의 모든 문자를 세는 대신 특정 문자, 숫자 또는 특수 기호의 발생만 계산해야 할 수도 있습니다.

주어진 문자가 셀에 나타나는 횟수를 계산하려면 SUBSTITUTE와 함께 LEN 함수를 사용하십시오.

공식을 더 잘 이해하려면 다음 예를 살펴보세요.

각 항목 유형마다 고유한 항목이 있는 배송된 항목의 데이터베이스를 유지 관리한다고 가정합니다. 식별자. 그리고 각 셀에는 쉼표, 공백 또는 기타 구분 기호로 구분된 여러 항목이 포함됩니다. 작업은 주어진 고유 식별자가 각 셀에 나타나는 횟수를 세는 것입니다.

배달된 항목 목록이 B열(B2에서 시작)에 있다고 가정하고 "A"의 수를 세고 있습니다.

=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))

이 Excel 문자 수 수식이 작동하는 방식

수식의 논리를 이해하기 위해 더 작은 부분으로 나눕니다.

• 먼저 B2의 총 문자열 길이를 계산합니다.

LEN(B2)

SUBSTITUTE(B2,"A","")

LEN(SUBSTITUTE(B2,"A",""))

결과적으로 셀에서 해당 문자가 발생한 총 수와 동일한 "제거된" 문자 수를 가져옵니다.

계산할 문자를 지정하는 대신 수식을 셀에 입력한 다음 수식에서 해당 셀을 참조할 수 있습니다. 이렇게 하면 사용자가수식을 변경하지 않고 해당 셀에 입력한 다른 문자의 발생을 계산할 수 있습니다.

참고. Excel의 SUBSTITUTE는 대소문자를 구분하는 함수이므로 위 수식도 대소문자를 구분합니다. 예를 들어 위의 스크린샷에서 셀 B3에는 "A"가 3개(대문자 2개, 소문자 1개) 포함되어 있습니다. SUBSTITUTE 함수에 "A"를 제공했기 때문에 수식은 대문자만 계산했습니다.

셀의 특정 문자를 계산하는 대소문자를 구분하지 않는 Excel 수식

대소문자를 구분하지 않고 문자 개수를 계산해야 하는 경우 SUBSTITUTE 내부에 UPPER 함수를 포함하여 대체를 실행하기 전에 지정된 문자를 대문자로 변환합니다. 그리고 수식에 반드시 대문자를 입력해야 합니다.

예를 들어 B2 셀의 "A" 및 "a" 항목을 계산하려면 다음 수식을 사용하십시오.

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))

또 다른 방법은 중첩 대체 함수를 사용하는 것입니다.

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")

아래 스크린샷에서 볼 수 있듯이 두 수식 모두 지정된 문자의 대문자와 소문자를 완벽하게 계산합니다.

경우에 따라 테이블에서 서로 다른 많은 문자를 계산해야 할 수 있지만 매번 수식을 수정하고 싶지 않을 수 있습니다. 이 경우 하나의 Substitute 함수를 다른 함수 안에 중첩하고 일부 셀(이 예에서는 D1)에 계산할 문자를 입력한 다음 해당 셀의 값을 대문자로 변환하고UPPER 및 LOWER 함수를 사용하여 소문자로 변경:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))

또는 원본 셀과 해당 문자가 포함된 셀을 모두 대문자 또는 소문자로 변환합니다. 예를 들면 다음과 같습니다.

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))

이 방법의 장점은 참조 셀에 대소문자 입력 여부에 관계없이 대소문자를 구분하지 않는 문자 수식 는 올바른 수를 반환합니다.

셀에서 특정 텍스트 또는 하위 문자열의 수를 계산합니다.

특정 문자 조합 (즉, 특정 텍스트 또는 하위 문자열)이 주어진 셀에 나타납니다. "A2" 또는 "SS" 그런 다음 위 수식에서 반환된 문자 수를 하위 문자열의 길이로 나눕니다.

대소문자 구분 수식:

=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)

대소문자 구분 안 함 공식:

=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)

여기서 B2는 전체 텍스트 문자열을 포함하는 셀이고 C1은 입력할 텍스트(하위 문자열)입니다. 계산하고 싶습니다.

수식에 대한 자세한 설명은 셀의 특정 텍스트/단어 계산 방법을 참조하세요.

특정 텍스트/단어 계산 방법 범위의 문자

이제 셀의 문자 수를 계산하는 Excel 수식을 알았으므로 특정 문자가 범위에 나타나는 횟수를 알아보기 위해 이를 더 개선할 수 있습니다. 이를 위해 Excel LEN 공식을 사용하여 논의된 셀의 특정 문자를 계산합니다.이전 예제에서 배열을 처리할 수 있는 SUMPRODUCT 함수 안에 넣습니다.

이 예에서 수식은 다음과 같은 형태를 취합니다.

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

여기에 계산할 또 다른 수식이 있습니다. Excel 범위의 문자:

=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

첫 번째 수식과 비교할 때 가장 분명한 차이점은 SUMPRODUCT 대신 SUM을 사용한다는 것입니다. 또 다른 차이점은 배열을 처리하도록 설계된 SUMPRODUCT와 달리 배열 수식 에 사용될 때만 배열을 처리할 수 있기 때문에 Ctrl + Shift + Enter를 눌러야 한다는 점입니다.

수식의 문자를 하드코딩하고 싶지 않다면 물론 D1과 같은 일부 셀에 입력하고 문자 수 수식에서 해당 셀을 참조할 수 있습니다.

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))

참고. 범위에서 특정 하위 문자열 의 발생 횟수를 세는 경우(예: "KK" 또는 "AA"로 시작하는 주문) 문자 수를 하위 문자열 길이로 나누어야 합니다. 하위 문자열은 개별적으로 계산됩니다. 예를 들면 다음과 같습니다.

=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))

이 문자 계산 공식 작동 방식

기억하시겠지만 SUBSTITUTE 함수는 지정된 문자(이 예에서는 "A")의 모든 항목을 바꾸는 데 사용됩니다. )와 빈 텍스트 문자열("")을 사용합니다.

그런 다음 SUBSTITUTE에서 반환된 텍스트 문자열을 Excel LEN에 제공합니다.함수를 사용하여 A 없이 문자열 길이를 계산합니다. 그런 다음 텍스트 문자열의 총 길이에서 해당 문자 수를 뺍니다. 이러한 계산의 결과는 문자 수의 배열이며 셀당 하나의 문자 수입니다.

마지막으로 SUMPRODUCT는 배열의 숫자를 합산하고 범위에서 지정된 문자의 총 수를 반환합니다.

범위의 특정 문자를 계산하는 대소문자를 구분하지 않는 수식

SUBSTITUTE가 대소문자를 구분하는 함수라는 사실을 이미 알고 계실 것입니다.

수식에서 대소문자를 무시하도록 하려면 이전 예에서 설명한 접근 방식을 따르십시오. 대소문자를 무시하는 범위의 특정 문자:

• UPPER 함수를 사용하고 대문자로 문자 입력:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A","")))

• 중첩된 SUBSTITUTE 함수 사용:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a","")))

• UPPER 및 LOWER 함수를 사용하고 일부 셀에 대문자 또는 소문자를 입력하고 수식에서 해당 셀을 참조하십시오.

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))

아래 스크린샷은 작동 중인 마지막 수식을 보여줍니다.

팁. 범위에서 특정 텍스트 (하위 문자열)의 발생 횟수를 계산하려면 범위에서 특정 텍스트/단어를 계산하는 방법에 설명된 수식을 사용합니다.

이LEN 함수를 사용하여 Excel에서 문자를 계산하는 방법입니다. 개별 문자가 아닌 단어 수를 계산하는 방법을 알고 싶다면 다음 기사에서 몇 가지 유용한 수식을 찾을 수 있습니다. 계속 지켜봐 주시기 바랍니다!

그동안 문자 수 수식이 포함된 샘플 통합 문서를 다운로드할 수 있습니다. 이 자습서에서 설명하고 페이지 끝에서 관련 리소스 목록을 확인하십시오. 읽어주셔서 감사하고 곧 뵙기를 바랍니다!