Падручнік тлумачыць, як лічыць сімвалы ў Excel. Вы даведаецеся формулы для атрымання агульнай колькасці сімвалаў у дыяпазоне і падліку толькі пэўных сімвалаў у ячэйцы або ў некалькіх ячэйках.

У нашым папярэднім уроку была прадстаўлена функцыя Excel LEN, якая дазваляе падлічваць агульная колькасць сімвалаў у ячэйцы.

Формула LEN карысная сама па сабе, але ў спалучэнні з іншымі функцыямі, такімі як SUM, SUMPRODUCT і SUBSTITUTE, яна можа вырашаць значна больш складаныя задачы. Далей у гэтым уроку мы збіраемся больш падрабязна разгледзець некалькі асноўных і прасунутых формул для падліку сімвалаў у Excel.

Як падлічыць усе сімвалы ў дыяпазоне

Калі справа даходзіць да падліку агульнай колькасці сімвалаў у некалькіх ячэйках, непасрэднае рашэнне, якое прыходзіць на розум, гэта атрымаць колькасць сімвалаў для кожнай ячэйкі, а затым скласці гэтыя лічбы:

=LEN(A2)+LEN(A3)+LEN(A4)

Або

=SUM(LEN(A2),LEN(A3),LEN(A4))

Прыведзеныя вышэй формулы могуць добра працаваць для невялікага дыяпазону. Каб падлічыць агульную колькасць сімвалаў у большым дыяпазоне, нам лепш прыдумаць нешта больш кампактнае, напрыклад. функцыя SUMPRODUCT, якая памнажае масівы і вяртае суму здабыткаў.

Вось агульная формула Excel для падліку сімвалаў у дыяпазоне:

І ваша формула ў рэальным жыцці можа выглядаць прыкладна так:

=SUMPRODUCT(LEN(A1:A7))

Іншы спосаб падліку сімвалаў у дыяпазоне - гэта выкарыстанне Функцыя LEN сткамбінацыя з SUM:

=SUM(LEN(A1:A7))

У адрозненне ад SUMPRODUCT, функцыя SUM не разлічвае масівы па змаўчанні, і вам трэба націснуць Ctrl + Shift + Enter, каб ператварыць яго ў формулу масіва.

Як паказана на наступным скрыншоце, формула SUM вяртае тую ж агульную колькасць сімвалаў:

Як працуе гэтая формула падліку сімвалаў дыяпазону

Гэта гэта адна з самых простых формул для падліку сімвалаў у Excel. Функцыя LEN вылічае даўжыню радка для кожнай ячэйкі ў зададзеным дыяпазоне і вяртае іх у выглядзе масіва лікаў. Затым SUMPRODUCT або SUM складае гэтыя лічбы і вяртае агульную колькасць сімвалаў.

У прыведзеным вышэй прыкладзе, масіў з 7 лікаў, якія прадстаўляюць даўжыню радкоў у ячэйках ад A1 да A7, сумуецца:

Заўвага. Калі ласка, звярніце ўвагу, што функцыя Excel LEN падлічвае абсалютна ўсе сімвалы ў кожнай ячэйцы , уключаючы літары, лічбы, знакі прыпынку, спецыяльныя сімвалы і ўсе прабелы (у пачатку, у канцы і прабелы паміж словамі).

Як падлічыць пэўныя сімвалы ў ячэйцы

Часам замест таго, каб падлічваць усе сімвалы ў ячэйцы, вам можа спатрэбіцца падлічыць толькі ўваходжанне пэўнай літары, лічбы або спецыяльнага сімвала.

Каб падлічыць, колькі разоў дадзены сімвал з'яўляецца ў ячэйцы, выкарыстоўвайце функцыю LEN разам з SUBSTITUTE:

Каб лепш зразумець формулу, разгледзім наступны прыклад.

Выкажам здагадку, што вы падтрымліваеце базу дастаўленых тавараў, дзе кожны тып тавару мае свой унікальны ідэнтыфікатар. І кожная ячэйка змяшчае некалькі элементаў, падзеленых коскамі, прабелам або любым іншым падзельнікам. Задача складаецца ў тым, каб падлічыць, колькі разоў дадзены унікальны ідэнтыфікатар з'яўляецца ў кожнай ячэйцы.

Мяркуючы, што спіс дастаўленых тавараў знаходзіцца ў слупку B (пачынаючы з B2), і мы падлічваем колькасць "A" узнікнення, формула выглядае наступным чынам:

=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))

Як працуе гэтая формула падліку сімвалаў Excel

Каб зразумець логіку формулы, давайце разбіць яго на меншыя часткі:

• Спачатку вы падлічваеце агульную даўжыню радка ў B2:

LEN(B2)

SUBSTITUTE(B2,"A","")

LEN(SUBSTITUTE(B2,"A",""))

У выніку вы атрымаеце колькасць "выдаленых" сімвалаў, якая роўная агульнай колькасці ўваходжанняў гэтага сімвала ў ячэйку.

Замест таго, каб указваць сімвал, які вы хочаце падлічыць у формулу, вы можаце ўвесці яе ў нейкую ячэйку, а затым спасылацца на гэтую ячэйку ў формуле. Такім чынам, вашы карыстальнікізмогуць падлічыць любыя іншыя сімвалы, якія яны ўводзяць у гэтую ячэйку, не ўмешваючыся ў вашу формулу:

Заўвага. Функцыя SUBSTITUTE у Excel з'яўляецца адчувальнай да рэгістра, і таму прыведзеная вышэй формула таксама з'яўляецца адчувальнай да рэгістра. Напрыклад, на прыведзеным вышэй скрыншоце ячэйка B3 змяшчае 3 літары "A" - два ў верхнім рэгістры і адзін у ніжнім рэгістры. Формула падлічыла толькі вялікія літары, таму што мы паставілі "A" для функцыі SUBSTITUTE.

Формула Excel без уліку рэгістра для падліку пэўных сімвалаў у ячэйцы

Калі вам патрэбна падлік сімвалаў без уліку рэгістра, убудуйце функцыю UPPER у SUBSTITUTE, каб пераўтварыць названы сімвал у верхні рэгістр перад выкананнем замены. І не забудзьцеся ўвесці ў формулу верхні рэгістр.

Напрыклад, каб падлічыць элементы «A» і «a» у ячэйцы B2, выкарыстоўвайце наступную формулу:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))

Іншы спосаб заключаецца ў выкарыстанні ўкладзеных функцый-заменнікаў:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")

Як вы бачыце на скрыншоце ніжэй, абедзве формулы бездакорна падлічваюць ужыванне ўказанага сімвала ў верхнім і малым рэгістры:

У некаторых выпадках вам можа спатрэбіцца падлічыць шмат розных знакаў у табліцы, але вы не захочаце кожны раз змяняць формулу. У гэтым выпадку ўкладзіце адну функцыю Substitute у іншую, увядзіце сімвал, які вы хочаце падлічыць, у некаторую ячэйку (D1 у гэтым прыкладзе), і пераўтварыце значэнне гэтай ячэйкі ў верхні рэгістр іу ніжнім рэгістры з дапамогай функцый UPPER і LOWER:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))

У якасці альтэрнатывы можна пераўтварыць як зыходную ячэйку, так і ячэйку, якая змяшчае сімвал, у верхні або малы рэгістр. Напрыклад:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))

Перавага гэтага падыходу заключаецца ў тым, што незалежна ад таго, вялікія ці малыя літары ўводзяцца ў ячэйку, на якую спасылаюцца, ваша формула падліку сімвалаў без уліку рэгістра верне правільны падлік:

Палічыце ўваходжанні пэўнага тэксту або падрадка ў ячэйку

Калі вы хочаце падлічыць, колькі разоў пэўная камбінацыя сімвалаў (напрыклад, пэўны тэкст або падрадок) з'яўляецца ў дадзенай ячэйцы, напрыклад. "A2" або "SS", затым падзяліце колькасць сімвалаў, вернутых прыведзенымі вышэй формуламі, на даўжыню падрадка.

Формула з улікам рэгістра:

=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)

Формула без уліку рэгістра:

=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)

Дзе B2 - гэта ячэйка, якая змяшчае ўвесь тэкставы радок, а C1 - гэта тэкст (падрадок), які вы хочаце падлічыць.

Падрабязнае тлумачэнне формулы глядзіце, як падлічыць пэўны тэкст / словы ў ячэйцы.

Як падлічыць пэўны сімвал(ы) у дыяпазоне

Цяпер, калі вы ведаеце формулу Excel для падліку сімвалаў у ячэйцы, вы можаце палепшыць яе далей, каб даведацца, колькі разоў пэўны сімвал з'яўляецца ў дыяпазоне. Для гэтага мы возьмем формулу Excel LEN, каб падлічыць пэўны сімвал у абмяркоўваемай ячэйцыу папярэднім прыкладзе, і змесціце яго ў функцыю SUMPRODUCT, якая можа апрацоўваць масівы:

У гэтым прыкладзе формула прымае наступную форму:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

І вось яшчэ адна формула для падліку сімвалаў у дыяпазоне Excel:

=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

У параўнанні з першай формулай найбольш відавочная розніца заключаецца ў выкарыстанні SUM замест SUMPRODUCT. Яшчэ адно адрозненне заключаецца ў тым, што патрабуецца націснуць Ctrl + Shift + Enter, таму што ў адрозненне ад SUMPRODUCT, які прызначаны для апрацоўкі масіваў, SUM можа апрацоўваць масівы толькі пры выкарыстанні ў формуле масіва .

Калі вы не Калі вы не жадаеце жорстка закадзіраваць сімвал у формуле, вы, вядома, можаце ўвесці яго ў нейкую ячэйку, скажам, D1, і спасылацца на гэтую ячэйку ў вашай формуле падліку сімвалаў:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))

Заўвага. У сітуацыях, калі вы падлічваеце ўваходжанне пэўнага падрадка ў дыяпазоне (напрыклад, парадкі, якія пачынаюцца з "KK" ці "AA"), вам трэба падзяліць колькасць сімвалаў на даўжыню падрадка, інакш кожны сімвал у падрадок будзе падлічвацца індывідуальна. Напрыклад:

=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))

Як працуе гэтая формула падліку сімвалаў

Як вы памятаеце, функцыя SUBSTITUTE выкарыстоўваецца для замены ўсіх уваходжанняў названага сімвала (у гэтым прыкладзе "A" ) з пустым тэкставым радком ("").

Затым мы даем тэкставы радок, вернуты SUBSTITUTE, у Excel LENтак што яна вылічае даўжыню радка без літар. А потым мы адымаем гэты лік сімвалаў з агульнай даўжыні тэкставага радка. Вынікам гэтых вылічэнняў з'яўляецца масіў колькасці сімвалаў, з адной колькасцю сімвалаў у ячэйцы.

Нарэшце, SUMPRODUCT сумуе лічбы ў масіве і вяртае агульную колькасць названага сімвала ў дыяпазоне.

Формула без уліку рэгістра для падліку пэўных сімвалаў у дыяпазоне

Вы ўжо ведаеце, што SUBSTITUTE з'яўляецца функцыяй з улікам рэгістра, што робіць нашу формулу Excel для падліку сімвалаў таксама адчувальнай да рэгістра.

Каб прымусіць формулу ігнараваць рэгістр, прытрымлівайцеся падыходаў, прадэманстраваных у папярэднім прыкладзе: формула без уліку рэгістра для падліку пэўных сімвалаў у ячэйцы.

У прыватнасці, вы можаце выкарыстоўваць адну з наступных формул для падліку пэўныя сімвалы ў дыяпазоне без уліку рэгістра:

• Выкарыстоўвайце функцыю UPPER і ўвядзіце сімвал у верхнім рэгістры:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A","")))

  Глядзі_таксама: Як атрымаць больш шаблонаў дакументаў і табліц Google
• Выкарыстоўвайце ўкладзеныя функцыі SUBSTITUTE:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a","")))

• Выкарыстоўвайце функцыі UPPER і LOWER, увядзіце сімвал у верхнім ці малым рэгістры ў нейкую ячэйку і спасылайцеся на гэтую ячэйку ў сваёй формуле:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))

Скрыншот ніжэй дэманструе апошнюю формулу ў дзеянні:

Савет. Каб падлічыць колькасць канкрэтнага тэксту (падрадок) у дыяпазоне, выкарыстоўвайце формулу, прадэманстраваную ў раздзеле Як падлічыць пэўны тэкст / словы ў дыяпазоне.

Гэтаяк вы можаце лічыць сімвалы ў Excel з дапамогай функцыі LEN. Калі вы жадаеце ведаць, як лічыць словы, а не асобныя сімвалы, вы знойдзеце некалькі карысных формул у нашым наступным артыкуле, сачыце за абнаўленнямі!

Тым часам вы можаце спампаваць прыклады рабочых сшыткаў з формулай падліку сімвалаў абмяркоўваецца ў гэтым падручніку, і азнаёмцеся са спісам адпаведных рэсурсаў у канцы старонкі. Я дзякую вам за чытанне і спадзяюся хутка ўбачымся!