Udžbenik objašnjava kako brojati znakove u Excelu. Naučit ćete formule za dobivanje ukupnog broja znakova u rasponu i brojanje samo određenih znakova u ćeliji ili u nekoliko ćelija.

Naš prethodni vodič predstavio je funkciju Excel LEN koja omogućuje brojanje ukupan broj znakova u ćeliji.

LEN formula je korisna sama po sebi, ali u kombinaciji s drugim funkcijama kao što su SUM, SUMPRODUCT i SUBSTITUTE, može riješiti daleko složenije zadatke. Dalje u ovom vodiču pobliže ćemo pogledati nekoliko osnovnih i naprednih formula za brojanje znakova u Excelu.

Kako brojati sve znakove u rasponu

Kada se radi o brojanju ukupnog broja znakova u nekoliko ćelija, trenutno rješenje koje pada na pamet je dobiti broj znakova za svaku ćeliju, a zatim zbrojiti te brojeve:

=LEN(A2)+LEN(A3)+LEN(A4)

Ili

=SUM(LEN(A2),LEN(A3),LEN(A4))

Gore navedene formule mogle bi dobro funkcionirati za mali raspon. Za brojanje ukupnih znakova u većem rasponu, bolje da smislimo nešto kompaktnije, npr. funkcija SUMPRODUCT, koja množi nizove i vraća zbroj umnožaka.

Ovo je generička Excel formula za brojanje znakova u rasponu:

A vaša formula iz stvarnog života može izgledati slično ovoj:

=SUMPRODUCT(LEN(A1:A7))

Drugi način za brojanje znakova u rasponu je korištenje LEN funkcija ukombinacija sa SUM:

=SUM(LEN(A1:A7))

Za razliku od SUMPRODUCT, funkcija SUM ne izračunava nizove prema zadanim postavkama i morate pritisnuti Ctrl + Shift + Enter da biste je pretvorili u formulu polja.

Kao što je prikazano na sljedećoj snimci zaslona, ​​formula SUM vraća isti ukupni broj znakova:

Kako funkcionira ova formula broja znakova raspona

Ovo je jedna od najjednostavnijih formula za brojanje znakova u Excelu. Funkcija LEN izračunava duljinu niza za svaku ćeliju u navedenom rasponu i vraća ih kao niz brojeva. Zatim SUMPRODUCT ili SUM zbraja te brojeve i vraća ukupan broj znakova.

U gornjem primjeru, niz od 7 brojeva koji predstavljaju duljine nizova u ćelijama A1 do A7 zbraja se:

Napomena. Obratite pozornost da funkcija Excel LEN broji apsolutno sve znakove u svakoj ćeliji , uključujući slova, brojeve, interpunkcijske znakove, posebne simbole i sve razmake (na početku, na kraju i razmake između riječi).

Kako brojati određene znakove u ćeliji

Ponekad, umjesto brojanja svih znakova unutar ćelije, možda ćete morati brojati samo pojavljivanja određenog slova, broja ili posebnog simbola.

Da biste izbrojali koliko se puta određeni znak pojavljuje u ćeliji, koristite funkciju LEN zajedno sa ZAMJENOM:

Da biste bolje razumjeli formulu, razmotrite sljedeći primjer.

Pretpostavimo da održavate bazu podataka o isporučenim stavkama, gdje svaka vrsta stavke ima svoj jedinstveni identifikator. A svaka ćelija sadrži nekoliko stavki odvojenih zarezom, razmakom ili bilo kojim drugim graničnikom. Zadatak je izbrojati koliko se puta određeni jedinstveni identifikator pojavljuje u svakoj ćeliji.

Pod pretpostavkom da je popis isporučenih stavki u stupcu B (počevši od B2), a mi brojimo broj "A" pojavljivanja, formula je sljedeća:

=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))

Kako funkcionira ova Excelova formula broja znakova

Da bismo razumjeli logiku formule, idemo rastavite ga na manje dijelove:

• Prvo, računate ukupnu duljinu niza u B2:

LEN(B2)

SUBSTITUTE(B2,"A","")

LEN(SUBSTITUTE(B2,"A",""))

Kao rezultat, dobivate broj "uklonjenih" znakova, što je jednako ukupnom broju pojavljivanja tog znaka u ćeliji.

Umjesto navođenja znaka koji želite brojati u formulu, možete je upisati u neku ćeliju, a zatim referencirati tu ćeliju u formuli. Na taj način vaši korisnicimoći će prebrojati pojavljivanja bilo kojeg drugog znaka koji unesu u tu ćeliju bez diranja u vašu formulu:

Napomena. Excelova SUBSTITUTE je funkcija koja razlikuje velika i mala slova, pa stoga gornja formula također razlikuje velika i mala slova. Na primjer, na gornjoj snimci zaslona ćelija B3 sadrži 3 pojavljivanja "A" - dva velikim slovima i jedno malim slovima. Formula je brojala samo velika slova jer smo funkciji SUBSTITUTE dodali "A".

Excel formula koja ne razlikuje velika i mala slova za brojanje određenih znakova u ćeliji

Ako vam je potreban broj znakova koji ne razlikuje velika i mala slova, ugradite funkciju UPPER unutar SUBSTITUTE da biste navedeni znak pretvorili u velika slova prije pokretanja zamjene. I svakako u formulu unesite veliko slovo.

Na primjer, za brojanje stavki "A" i "a" u ćeliji B2 upotrijebite ovu formulu:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))

Drugi način je korištenje ugniježđenih zamjenskih funkcija:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")

Kao što možete vidjeti na snimci zaslona u nastavku, obje formule besprijekorno broje pojavljivanja velikih i malih slova navedenog znaka:

U nekim slučajevima, možda ćete morati prebrojati mnogo različitih znakova u tablici, ali možda nećete htjeti mijenjati formulu svaki put. U ovom slučaju, ugniježdite jednu Zamjensku funkciju unutar druge, upišite znak koji želite brojati u neku ćeliju (D1 u ovom primjeru) i pretvorite vrijednost te ćelije u velika slova imala slova pomoću funkcija UPPER i LOWER:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))

Alternativno, pretvorite i izvornu ćeliju i ćeliju koja sadrži znak u velika ili mala slova. Na primjer:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))

Prednost ovog pristupa je ta da bez obzira na to jesu li u referentnu ćeliju unesena velika ili mala slova, vaša formula za brojanje znakova koja ne razlikuje velika i mala slova vratit će točan broj:

Broji pojavljivanja određenog teksta ili podniza u ćeliji

Ako želiš izbrojati koliko puta određena kombinacija znakova (tj. određeni tekst ili podniz) pojavljuje se u danoj ćeliji, npr. "A2" ili "SS", zatim podijelite broj znakova koje vraćaju gornje formule s duljinom podniza.

Formula koja razlikuje velika i mala slova:

=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)

Formula koja ne razlikuje velika i mala slova:

=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)

Gdje je B2 ćelija koja sadrži cijeli tekstualni niz, a C1 je tekst (podniz) koji želite prebrojati.

Za detaljno objašnjenje formule pogledajte Kako prebrojati određeni tekst/riječi u ćeliji.

Kako prebrojati određene znakova u rasponu

Sada kada znate Excel formulu za brojanje znakova u ćeliji, možda biste je željeli dodatno poboljšati kako biste saznali koliko se puta određeni znak pojavljuje u rasponu. Za ovo ćemo uzeti formulu Excel LEN za brojanje određenog znaka u ćeliji o kojoj se govoriu prethodnom primjeru i stavite ga unutar funkcije SUMPRODUCT koja može rukovati nizovima:

U ovom primjeru formula ima sljedeći oblik:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

I evo još jedne formule za brojanje znakova u Excelovom rasponu:

=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

U usporedbi s prvom formulom, najočitija razlika je korištenje SUM umjesto SUMPRODUCT. Druga je razlika u tome što zahtijeva pritiskanje Ctrl + Shift + Enter jer za razliku od SUMPRODUCT, koji je dizajniran za obradu nizova, SUM može rukovati nizovima samo kada se koristi u formuli polja .

Ako ne Ako ne želite čvrsto kodirati znak u formuli, možete ga naravno upisati u neku ćeliju, recimo D1, i referencirati tu ćeliju u svojoj formuli brojanja znakova:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))

Napomena. U situacijama kada brojite pojavljivanja određenog podniza u rasponu (npr. narudžbe koje počinju s "KK" ili "AA"), trebate podijeliti broj znakova s ​​duljinom podniza, inače svaki znak u podniz će se brojati pojedinačno. Na primjer:

=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))

Kako funkcionira ova formula za brojanje znakova

Kao što se možda sjećate, funkcija SUBSTITUTE koristi se za zamjenu svih pojavljivanja navedenog znaka ("A" u ovom primjeru ) s praznim tekstualnim nizom ("").

Zatim dostavljamo tekstualni niz koji vraća SUBSTITUTE u Excel LENfunkciju tako da izračunava duljinu niza bez A. Zatim oduzimamo taj broj znakova od ukupne duljine tekstualnog niza. Rezultat ovih izračuna je niz broja znakova, s jednim brojem znakova po ćeliji.

Konačno, SUMPRODUCT zbraja brojeve u nizu i vraća ukupni broj navedenog znaka u rasponu.

Formula koja ne razlikuje velika i mala slova za brojanje određenih znakova u rasponu

Već znate da je SUBSTITUTE funkcija koja razlikuje velika i mala slova, što našu Excel formulu za brojanje znakova također čini osjetljivom na velika i mala slova.

Kako bi formula zanemarila velika i mala slova, slijedite pristupe prikazane u prethodnom primjeru: Formula koja ne razlikuje velika i mala slova za brojanje određenih znakova u ćeliji.

Konkretno, možete koristiti jednu od sljedećih formula za brojanje specifični znakovi u rasponu zanemarujući velika i mala slova:

• Koristite funkciju UPPER i unesite znak velikim slovima:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A","")))

• Koristite ugniježđene funkcije SUBSTITUTE:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a","")))

• Koristite UPPER i LOWER funkcije, upišite ili velika ili mala slova u neku ćeliju i referencirajte tu ćeliju u svojoj formuli:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))

Donji snimak zaslona pokazuje posljednju formulu na djelu:

Savjet. Za brojanje pojavljivanja određenog teksta (podniz) u rasponu, koristite formulu prikazanu u Kako brojati određeni tekst/riječi u rasponu.

Ovoje način na koji možete brojati znakove u Excelu pomoću funkcije LEN. Ako želite znati kako brojati riječi, a ne pojedinačne znakove, pronaći ćete nekoliko korisnih formula u našem sljedećem članku, ostanite s nama!

U međuvremenu, možete preuzeti ogledne radne knjige s formulom za brojanje znakova o kojima se govori u ovom vodiču i pogledajte popis povezanih izvora na kraju stranice. Zahvaljujem vam na čitanju i nadam se da se vidimo uskoro!