අන්තර්ගත වගුව
Excel හි අක්ෂර ගණන් කරන ආකාරය නිබන්ධනය පැහැදිලි කරයි. ඔබ පරාසයක සම්පූර්ණ අක්ෂර ගණන ලබා ගැනීමට සූත්‍ර ඉගෙන ගනු ඇත, සහ සෛලයක හෝ සෛල කිහිපයක නිශ්චිත අක්ෂර පමණක් ගණන් කරන්න.
අපගේ පෙර නිබන්ධනය විසින් ගණන් කිරීමට ඉඩ දෙන Excel LEN ශ්‍රිතය හඳුන්වා දෙන ලදී. සෛලයක ඇති සම්පූර්ණ අක්ෂර ගණන.
LEN සූත්‍රය තනියම ප්‍රයෝජනවත් වේ, නමුත් SUM, SUMPRODUCT සහ SUBSTITUTE වැනි අනෙකුත් කාර්යයන් සමඟ සම්බන්ධව, එයට වඩා සංකීර්ණ කාර්යයන් හැසිරවිය හැක. මෙම නිබන්ධනය තුළ තවදුරටත්, අපි Excel හි අක්ෂර ගණන් කිරීම සඳහා මූලික සහ උසස් සූත්‍ර කිහිපයක් දෙස සමීපව බැලීමට යන්නෙමු.
පරාසයක සියලුම අක්ෂර ගණන් කරන්නේ කෙසේද
කොටු කිහිපයක මුළු අක්ෂර සංඛ්‍යාව ගණනය කිරීමේදී, ක්ෂණික විසඳුම වන්නේ එක් එක් කොටුව සඳහා අක්ෂර ගණන ලබා ගැනීම සහ එම සංඛ්‍යා එකතු කිරීමයි:
=LEN(A2)+LEN(A3)+LEN(A4)
නැතහොත්
=SUM(LEN(A2),LEN(A3),LEN(A4))
ඉහත සූත්‍ර කුඩා පරාසයක් සඳහා හොඳින් ක්‍රියා කරයි. විශාල පරාසයක සම්පූර්ණ අක්ෂර ගණන් කිරීමට, අපි වඩාත් සංයුක්ත යමක් ඉදිරිපත් කිරීම වඩා හොඳය, උදා. SUMPRODUCT ශ්‍රිතය, එය අරා ගුණ කර නිෂ්පාදනවල එකතුව ලබා දෙයි.
පරාසයක අක්ෂර ගණන් කිරීමට සාමාන්‍ය Excel සූත්‍රය මෙන්න:
=SUMPRODUCT(LEN( පරාස) )සහ ඔබේ සැබෑ ජීවිත සූත්‍රය මෙයට සමාන විය හැක:
=SUMPRODUCT(LEN(A1:A7))
පරාසයක අක්ෂර ගණන් කිරීමේ තවත් ක්‍රමයක් නම් LEN ක්‍රියාකාරිත්වයSUM සමඟ සංයෝජනය:
=SUM(LEN(A1:A7))
SUMPRODUCT මෙන් නොව, SUM ශ්‍රිතය පෙරනිමියෙන් අරා ගණනය නොකරන අතර, එය අරා සූත්‍රයක් බවට පත් කිරීමට ඔබ Ctrl + Shift + Enter ඔබන්න.
පහත තිර රුවෙහි පෙන්නුම් කර ඇති පරිදි, SUM සූත්‍රය එකම සම්පූර්ණ අක්ෂර ගණන ලබා දෙයි:
මෙම පරාස අක්ෂර ගණන් කිරීමේ සූත්‍රය ක්‍රියා කරන ආකාරය
මෙය එක්සෙල් හි අක්ෂර ගණන් කිරීම සඳහා වඩාත් සරල සූත්‍රවලින් එකකි. LEN ශ්‍රිතය නිශ්චිත පරාසයේ එක් එක් කොටුව සඳහා තන්තු දිග ගණනය කර ඒවා සංඛ්‍යා අරාවක් ලෙස ලබා දෙයි. ඉන්පසුව, SUMPRODUCT හෝ SUM එම සංඛ්‍යා එකතු කර සම්පූර්ණ අක්ෂර ගණන ලබා දෙයි.
ඉහත උදාහරණයේ, A1 සිට A7 දක්වා සෛලවල නූල්වල දිග නියෝජනය කරන සංඛ්‍යා 7ක අරාවක් සාරාංශ කර ඇත:
සටහන. අකුරු, ඉලක්කම්, විරාම ලකුණු, විශේෂ සංකේත, සහ සියලු හිස්තැන් (ඉදිරිපත්, ටේ්‍රලිං සහ වචන අතර ඇති හිස්තැන්) ඇතුළුව, Excel LEN ශ්‍රිතය නිරපේක්ෂ එක් එක් කොටුවේ ඇති සියලුම අක්ෂර ගණන් කරන බව කරුණාවෙන් සලකන්න.
කොටුවක නිශ්චිත අක්ෂර ගණන් කරන්නේ කෙසේද
සමහර විට, කොටුවක් තුළ ඇති සියලුම අක්ෂර ගණන් කිරීම වෙනුවට, ඔබට නිශ්චිත අකුරක, අංකයක හෝ විශේෂ සංකේතයක සිදුවීම් පමණක් ගණන් කිරීමට අවශ්‍ය විය හැක.
දී ඇති අක්ෂරයක් කොටුවක දිස්වන වාර ගණන ගණන් කිරීමට, LEN ශ්‍රිතය SUBSTITUTE සමඟින් භාවිතා කරන්න:
=LEN( cell )-LEN(SUBSTITUTE( cell<2)>, අක්ෂර ,""))සූත්‍රය වඩා හොඳින් අවබෝධ කර ගැනීම සඳහා පහත උදාහරණය සලකා බලන්න.
ඔබ විසින් බෙදා හරින ලද අයිතමවල දත්ත සමුදායක් පවත්වා ගෙන යන අතර, එහිදී එක් එක් අයිතම වර්ගයට එයටම ආවේණික වූවක් ඇත. හඳුනාගැනීම. තවද සෑම කොටුවකම කොමාවකින්, අවකාශයකින් හෝ වෙනත් පරිසීමකයකින් වෙන් කරන ලද අයිතම කිහිපයක් අඩංගු වේ. කර්තව්‍යය වන්නේ ලබා දී ඇති අනන්‍ය හඳුනාගැනීමක් එක් එක් කොටුව තුළ කොපමණ වාර ගණනක් දිස් වේද යන්න ගණනය කිරීමයි.
බෙදා හරින ලද අයිතම ලැයිස්තුව B තීරුවේ (B2 ආරම්භයේ) ඇතැයි උපකල්පනය කර අපි "A" ගණන ගණන් කරන්නෙමු. සංසිද්ධි, සූත්‍රය පහත පරිදි වේ:
=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))
මෙම Excel අක්ෂර ගණන් කිරීමේ සූත්‍රය ක්‍රියා කරන ආකාරය
සූත්‍රයේ තර්කනය තේරුම් ගැනීමට, අපි බලමු එය කුඩා කොටස් වලට කඩා දමන්න:
- පළමුව, ඔබ මුළු තන්තු දිග B2 වලින් ගණන් කරන්න:
LEN(B2)
SUBSTITUTE(B2,"A","")
LEN(SUBSTITUTE(B2,"A",""))
ප්‍රතිඵලයක් ලෙස, ඔබට "ඉවත් කළ" අක්ෂර ගණන ලැබේ, එය කොටුවේ ඇති එම අක්ෂර සංසිද්ධිවල සම්පූර්ණ සංඛ්‍යාවට සමාන වේ.
ඔබට ගණන් කිරීමට අවශ්‍ය අක්ෂරය සඳහන් කරනවා වෙනුවට. සූත්‍රයක්, ඔබට එය යම් කොටුවක ටයිප් කළ හැක, පසුව එම කොටුව සූත්‍රයක සඳහන් කළ හැක. මේ ආකාරයෙන්, ඔබේ පරිශීලකයන්ඔබේ සූත්‍රය වෙනස් නොකර ඔවුන් එම කොටුව තුළ ආදානය කරන වෙනත් ඕනෑම අක්ෂරයක සිදුවීම් ගණන් කිරීමට හැකි වනු ඇත:
සටහන. Excel හි ආදේශක යනු සිද්ධි සංවේදී ශ්‍රිතයක් වන අතර එම නිසා ඉහත සූත්‍රය ද සිද්ධි සංවේදී වේ. උදාහරණයක් ලෙස, ඉහත තිර පිටපතෙහි, Cell B3 හි "A" හි සිදුවීම් 3 ක් අඩංගු වේ - දෙකක් ලොකු අකුරින් සහ එකක් කුඩා අකුරින්. අපි SUBSTITUTE ශ්‍රිතයට "A" සැපයූ නිසා සූත්‍රය විශාල අකුරු පමණක් ගණන් කර ඇත.
Case-insensitive Excel සූත්‍රය සෛලයක නිශ්චිත අක්ෂර ගණන් කිරීමට
ඔබට සිද්ධි සංවේදී නොවන අක්ෂර ගණන අවශ්‍ය නම්, ආදේශනය ක්‍රියාත්මක කිරීමට පෙර සඳහන් කළ අක්ෂරය ලොකු අකුරට පරිවර්තනය කිරීමට UPPER ශ්‍රිතය SUBSTITUTE තුළට ඇතුළත් කරන්න. තවද, සූත්‍රයේ ලොකු අකුරු ඇතුළත් කිරීමට වග බලා ගන්න.
උදාහරණයක් ලෙස, කොටුව B2 හි "A" සහ "a" අයිතම ගණන් කිරීමට, මෙම සූත්‍රය භාවිතා කරන්න:
=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))
තවත් ක්‍රමයක් වන්නේ කැදලි ආදේශක ශ්‍රිත භාවිතා කිරීමයි:
=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")
ඔබට පහත තිර රුවෙහි දැකිය හැකි පරිදි, සූත්‍ර දෙකම නිශ්චිත අක්ෂරයේ කැපිටල් සහ සිම්පල් අකුරු සංසිද්ධීන් දෝෂ රහිතව ගණන් කරයි:
සමහර අවස්ථාවලදී, ඔබට වගුවක විවිධ අක්ෂර ගණන් කිරීමට අවශ්‍ය විය හැක, නමුත් ඔබට සෑම අවස්ථාවකදීම සූත්‍රය වෙනස් කිරීමට අවශ්‍ය නොවනු ඇත. මෙම අවස්ථාවෙහිදී, එක් ආදේශක ශ්‍රිතයක් තවත් එකක් තුළට ගෙන, ඔබට යම් කොටුවක ගණන් කිරීමට අවශ්‍ය අක්ෂරය ටයිප් කරන්න (මෙම උදාහරණයේ D1), සහ එම කොටුවේ අගය විශාල අකුරට පරිවර්තනය කරන්න සහUPPER සහ LOWER ශ්‍රිත භාවිතයෙන් කුඩා අකුරු:
=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))
විකල්පයක් ලෙස, ප්‍රභව සෛලය සහ අක්ෂරය අඩංගු කොටුව විශාල අකුරු හෝ කුඩා අකුරට පරිවර්තනය කරන්න. උදාහරණයක් ලෙස:
=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))
මෙම ප්‍රවේශයේ වාසිය නම්, යොමු කළ කොටුවේ ලොකු අකුරු හෝ කුඩා අකුරු ආදානය කළත්, ඔබේ අවද්‍ය-සංවේදී අක්ෂර ගණන් කිරීමේ සූත්‍රය නිවැරදි සංඛ්‍යාව ලබා දෙනු ඇත:
ඇතැම් පෙළ හෝ උප තන්ත්‍රය සෛලයක ඇති වූ අවස්ථා ගණන් කරන්න
ඔබට කොපමණ වාර ගණනක් ගණන් කිරීමට අවශ්‍ය නම් නිශ්චිත අක්ෂර එකතුවක් (එනම් නිශ්චිත පෙළ, හෝ උප තන්තුව) ලබා දී ඇති කොටුවක දිස් වේ, උදා. "A2" හෝ "SS", පසුව ඉහත සූත්‍ර මගින් ආපසු ලබා දෙන අක්ෂර ගණන උපස්ථරයේ දිගෙන් බෙදන්න.
අවස්ථා සංවේදී සූත්‍රය:
=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)
අවස්ථාව-සංවේදී සූත්‍රය:
=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)
B2 යනු සම්පූර්ණ පෙළ තන්තුව අඩංගු කොටුව වන අතර C1 යනු ඔබ පෙළ (උප පෙළ) වේ ගණන් කිරීමට අවශ්‍යයි.
සූත්‍රයේ සවිස්තරාත්මක පැහැදිලි කිරීම සඳහා කරුණාකර කොටුවක නිශ්චිත පෙළ / වචන ගණන් කරන ආකාරය බලන්න.
නිශ්චිත ගණන් කරන්නේ කෙසේද? පරාසයක අක්ෂර(ය)
දැන් ඔබ සෛලයක අක්ෂර ගණන් කිරීමට Excel සූත්‍රයක් දන්නා බැවින්, යම් අක්ෂරයක් පරාසයක කොපමණ වාර ගණනක් දිස් වේද යන්න සොයා ගැනීමට ඔබට එය තවදුරටත් වැඩිදියුණු කිරීමට අවශ්‍ය විය හැක. මේ සඳහා, අපි සාකච්ඡා කළ කොටුවක නිශ්චිත අක්ෂරයක් ගණනය කිරීමට Excel LEN සූත්‍රය ගනිමුපෙර උදාහරණයේ, සහ අරාවන් හැසිරවිය හැකි SUMPRODUCT ශ්‍රිතය තුළ තබන්න:
SUMPRODUCT(LEN( පරාස )-LEN(SUBSTITUTE( පරාසය , අක්ෂර ,"")))මෙම උදාහරණයේ, සූත්‍රය පහත හැඩය ගනී:
=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))
තව මෙහි ගණන් කිරීමට තවත් සූත්‍රයක් ඇත Excel හි පරාසයේ අක්ෂර:
=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))
පළමු සූත්‍රය හා සසඳන විට, වඩාත්ම පැහැදිලි වෙනස වන්නේ SUMPRODUCT වෙනුවට SUM භාවිතා කිරීමයි. තවත් වෙනසක් නම් එයට Ctrl + Shift + Enter එබීම අවශ්‍ය වන නිසා SUMPRODUCT ලෙස අරාවන් සැකසීමට නිර්මාණය කර ඇති බැවින්, SUM හට අරා හැසිරවිය හැක්කේ අරා සූත්‍රයක භාවිතා කළ විට පමණි.
ඔබ එසේ නොකරන්නේ නම්. සූත්‍රයෙහි අක්ෂරය දෘඪ කේත කිරීමට අවශ්‍ය නැත, ඔබට එය යම් කොටුවක ටයිප් කළ හැක, D1 කියන්න, සහ එම කොටුව ඔබේ අක්ෂර ගණන් කිරීමේ සූත්‍රයේ සඳහන් කරන්න:
=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))
සටහන. ඔබ නිශ්චිත උප පෙළක සිදුවීම් පරාසයක (උදා: "KK" හෝ "AA" වලින් ආරම්භ වන ඇණවුම්) ගණන් කරන විට, ඔබ අනුලකුණු ගණන අනුලකුණු දිගෙන් බෙදිය යුතුය, එසේ නොමැතිනම් එක් එක් අක්ෂරය තුළ උපස්ථරය තනි තනිව ගණනය කරනු ලැබේ. උදාහරණයක් ලෙස:
=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))
මෙම අනුලකුණු ගණන් කිරීමේ සූත්‍රය ක්‍රියා කරන ආකාරය
ඔබට මතක ඇති පරිදි, SUBSTITUTE ශ්‍රිතය නිශ්චිත අක්ෂරයේ සියලුම සිදුවීම් ප්‍රතිස්ථාපනය කිරීමට භාවිතා කරයි (මෙම උදාහරණයේ "A" ) හිස් පෙළ තන්තුවක් සමඟ ("").
ඉන්පසු, අපි Excel LEN වෙත ආදේශ කිරීමෙන් ආපසු ලබා දෙන පෙළ තන්තුව සපයන්නෙමු.ශ්‍රිතය නිසා එය A වලින් තොරව නූල් දිග ගණනය කරයි. ඉන්පසුව, අපි එම අක්ෂර ගණන පෙළ තන්තුවේ මුළු දිගෙන් අඩු කරමු. මෙම ගණනය කිරීම් වල ප්‍රතිඵලය වන්නේ එක් කොටුවකට එක් අක්ෂර ගණනක් සහිත අක්ෂර ගණනකි.
අවසානයේ, SUMPRODUCT විසින් අරාවේ ඇති සංඛ්‍යා එකතු කර පරාසයේ සඳහන් කර ඇති අක්ෂරවල මුළු ගණන ලබා දෙයි.
පරාසයක නිශ්චිත අක්ෂර ගණන් කිරීම සඳහා සිද්ධි සංවේදී නොවන සූත්‍රයක්
ඔබ දැනටමත් දන්නවා SUBSTITUTE යනු අවස්ථා-සංවේදී ශ්‍රිතයක් වන අතර, එය අනුලකුණු ගණන සඳහා වන අපගේ Excel සූත්‍රය අවස්ථා-සංවේදී කරයි.
සූත්‍රය නොසලකා හැරීම සිදු කිරීම සඳහා, පෙර උදාහරණයේ පෙන්වා ඇති ප්‍රවේශයන් අනුගමනය කරන්න: කොටුවක නිශ්චිත අක්ෂර ගණන් කිරීමට සිද්ධි සංවේදී නොවන සූත්‍රය.
විශේෂයෙන්, ඔබට ගණන් කිරීමට පහත සූත්‍රවලින් එකක් භාවිත කළ හැක. පරාසයක ඇති විශේෂිත අක්ෂර නොසලකා හැර ඇති අක්ෂර:
- UPPER ශ්‍රිතය භාවිත කර විශාල අකුරින් අක්ෂරයක් ඇතුළත් කරන්න:
=SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A",""))) - නෙස්ටඩ් ආදේශක ශ්‍රිත භාවිත කරන්න:
=SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a",""))) - ඉහළ සහ පහළ ශ්‍රිත භාවිත කරන්න, යම් කොටුවක ලොකු අකුරු හෝ කුඩා අකුරු ටයිප් කර, එම කොටුව ඔබේ සූත්‍රයේ සඳහන් කරන්න:
=SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))
පහත තිර රුවක් ක්‍රියාත්මක වන අවසාන සූත්‍රය පෙන්නුම් කරයි:
ඉඟිය. පරාසයක විශේෂිත පෙළ (උප පෙළ) සිදුවීම ගණන් කිරීමට, පරාසයක නිශ්චිත පෙළ / වචන ගණන් කරන්නේ කෙසේද යන්නෙහි නිරූපණය කර ඇති සූත්‍රය භාවිතා කරන්න.
මෙයLEN ශ්‍රිතය භාවිතයෙන් Excel හි අක්ෂර ගණන් කළ හැක්කේ කෙසේද යන්නයි. ඔබට තනි අක්ෂරවලට වඩා වචන ගණන් කරන්නේ කෙසේදැයි දැන ගැනීමට අවශ්‍ය නම්, අපගේ මීළඟ ලිපියෙන් ඔබට ප්‍රයෝජනවත් සූත්‍ර කිහිපයක් සොයා ගත හැකි වනු ඇත, කරුණාකර රැඳී සිටින්න!
මේ අතරතුර, ඔබට අක්ෂර ගණන් කිරීමේ සූත්‍රය සහිත නියැදි වැඩපොත් බාගත කළ හැකිය. මෙම නිබන්ධනය තුළ සාකච්ඡා කර ඇති අතර පිටුවේ අවසානයේ ඇති අදාළ සම්පත් ලැයිස්තුවක් පරීක්ෂා කරන්න. කියවීම ගැන මම ඔබට ස්තූතිවන්ත වන අතර ඉක්මනින් ඔබව දැකීමට බලාපොරොත්තු වෙමි!
