एक्सेलमध्ये अक्षरांची गणना कशी करायची हे ट्यूटोरियल स्पष्ट करते. तुम्ही एका श्रेणीमध्ये एकूण वर्ण संख्या मिळवण्यासाठी सूत्रे शिकाल आणि सेलमध्ये किंवा अनेक सेलमध्ये फक्त विशिष्ट वर्ण मोजा.

आमच्या मागील ट्युटोरियलने एक्सेल LEN फंक्शन सादर केले आहे, जे मोजण्यास अनुमती देते सेलमधील वर्णांची एकूण संख्या.

LEN सूत्र स्वतःच उपयुक्त आहे, परंतु SUM, SUMPRODUCT आणि SUBSTITUTE सारख्या इतर फंक्शन्सच्या संपर्कात ते अधिक जटिल कार्ये हाताळू शकते. या ट्युटोरियलमध्ये पुढे, आपण एक्सेलमध्ये अक्षरे मोजण्यासाठी काही मूलभूत आणि प्रगत सूत्रे पाहणार आहोत.

श्रेणीतील सर्व वर्ण कसे मोजायचे

जेव्हा अनेक सेलमधील एकूण वर्णांची संख्या मोजण्याचा विचार येतो, तेव्हा लक्षात येणारा तात्काळ उपाय म्हणजे प्रत्येक सेलसाठी अक्षरांची संख्या मिळवणे आणि नंतर ती संख्या जोडा:

=LEN(A2)+LEN(A3)+LEN(A4)

किंवा

=SUM(LEN(A2),LEN(A3),LEN(A4))

वरील सूत्रे लहान श्रेणीसाठी चांगले कार्य करू शकतात. मोठ्या श्रेणीत एकूण वर्ण मोजण्यासाठी, आम्ही अधिक संक्षिप्त काहीतरी घेऊन येऊ, उदा. SUMPRODUCT फंक्शन, जे अॅरेचा गुणाकार करते आणि उत्पादनांची बेरीज देते.

श्रेणीमध्ये वर्ण मोजण्यासाठी येथे जेनेरिक एक्सेल सूत्र आहे:

आणि तुमचे वास्तविक जीवनातील सूत्र यासारखे दिसू शकते:

=SUMPRODUCT(LEN(A1:A7))

श्रेणीमध्ये वर्ण मोजण्याचा दुसरा मार्ग म्हणजे मध्ये LEN फंक्शनSUM सह संयोजन:

=SUM(LEN(A1:A7))

SUMPRODUCT च्या विपरीत, SUM फंक्शन डिफॉल्टनुसार अॅरेची गणना करत नाही आणि तुम्हाला ते अॅरे फॉर्म्युलामध्ये बदलण्यासाठी Ctrl + Shift + Enter दाबावे लागेल.

खालील स्क्रीनशॉटमध्ये दाखवल्याप्रमाणे, SUM सूत्र समान एकूण वर्ण संख्या परत करतो:

ही श्रेणी वर्ण गणना सूत्र कसे कार्य करते

हे Excel मध्ये वर्ण मोजण्यासाठी सर्वात सोपा सूत्रांपैकी एक आहे. LEN फंक्शन निर्दिष्ट श्रेणीतील प्रत्येक सेलसाठी स्ट्रिंग लांबीची गणना करते आणि त्यांना संख्यांचा अॅरे म्हणून परत करते. आणि नंतर, SUMPRODUCT किंवा SUM त्या संख्या जोडतात आणि एकूण वर्ण संख्या परत करतात.

वरील उदाहरणात, A1 ते A7 सेलमधील स्ट्रिंगची लांबी दर्शविणारी 7 संख्यांची अॅरे बेरीज केली जाते:

टीप. कृपया लक्ष द्या की एक्सेल LEN फंक्शन अक्षरे, संख्या, विरामचिन्हे, विशेष चिन्हे, आणि सर्व स्पेस (अग्रणी, अनुगामी आणि शब्दांमधील मोकळी जागा) यासह प्रत्येक सेलमधील सर्व वर्ण पूर्णपणे मोजले जातात .

सेलमधील विशिष्ट वर्ण कसे मोजायचे

कधीकधी, सेलमधील सर्व वर्ण मोजण्याऐवजी, आपल्याला विशिष्ट अक्षर, संख्या किंवा विशेष चिन्हाच्या घटना मोजण्याची आवश्यकता असू शकते.

सेलमध्ये दिलेले वर्ण किती वेळा दिसले याची मोजणी करण्यासाठी, SUBSTITUTE सह LEN फंक्शन वापरा:

सूत्र अधिक चांगल्या प्रकारे समजून घेण्यासाठी, खालील उदाहरणाचा विचार करा.

समजा, तुम्ही वितरित आयटमचा डेटाबेस राखता, जिथे प्रत्येक आयटम प्रकाराचे स्वतःचे वेगळे असते. ओळखकर्ता आणि प्रत्येक सेलमध्ये स्वल्पविराम, जागा किंवा इतर कोणत्याही परिसीमकाने विभक्त केलेल्या अनेक आयटम असतात. प्रत्येक सेलमध्ये दिलेला युनिक आयडेंटिफायर किती वेळा दिसतो हे मोजण्याचे काम आहे.

डिलिव्हर केलेल्या वस्तूंची सूची स्तंभ B मध्ये आहे असे गृहीत धरून (B2 पासून सुरुवात होते), आणि आम्ही "A" ची संख्या मोजत आहोत. घटना, सूत्र खालीलप्रमाणे आहे:

=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))

हे एक्सेल वर्ण गणना सूत्र कसे कार्य करते

फॉर्म्युलाचे तर्क समजून घेण्यासाठी, चला ते लहान भागांमध्ये विभाजित करा:

• प्रथम, तुम्ही B2 मध्ये एकूण स्ट्रिंग लांबी मोजता:

LEN(B2)

SUBSTITUTE(B2,"A","")

LEN(SUBSTITUTE(B2,"A",""))

परिणामी, तुम्हाला "काढलेल्या" वर्णांची संख्या मिळते, जी सेलमधील त्या वर्ण घटनांच्या एकूण संख्येइतकी असते.

तुम्हाला ज्या वर्णांमध्ये मोजायचे आहे ते निर्दिष्ट करण्याऐवजी एक सूत्र, तुम्ही ते काही सेलमध्ये टाइप करू शकता आणि नंतर त्या सेलचा सूत्रामध्ये संदर्भ देऊ शकता. अशा प्रकारे, आपले वापरकर्तेतुमच्या फॉर्म्युलाशी छेडछाड न करता त्या सेलमध्ये त्यांनी इनपुट केलेल्या इतर कोणत्याही वर्णांच्या घटना मोजण्यात सक्षम होतील:

टीप. Excel चे SUBSTITUTE हे केस-सेन्सिटिव्ह फंक्शन आहे, आणि म्हणून वरील फॉर्म्युला केस-सेन्सेटिव्ह देखील आहे. उदाहरणार्थ, वरील स्क्रीनशॉटमध्ये, सेल B3 मध्ये "A" च्या 3 घटना आहेत - दोन अपरकेसमध्ये आणि एक लोअरकेसमध्ये. सूत्राने फक्त अप्परकेस वर्ण मोजले आहेत कारण आम्ही SUBSTITUTE फंक्शनला "A" पुरवले आहे.

सेलमधील विशिष्ट वर्ण मोजण्यासाठी केस-संवेदनशील एक्सेल सूत्र

तुम्हाला केस-असंवेदनशील वर्ण संख्या आवश्यक असल्यास, प्रतिस्थापन चालवण्यापूर्वी निर्दिष्ट वर्ण अपरकेसमध्ये रूपांतरित करण्यासाठी SUBSTITUTE मध्ये UPPER फंक्शन एम्बेड करा. आणि, सूत्रामध्ये अप्परकेस वर्ण प्रविष्ट करण्याचे सुनिश्चित करा.

उदाहरणार्थ, सेल B2 मध्ये "A" आणि "a" आयटम मोजण्यासाठी, हे सूत्र वापरा:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))

दुसरा मार्ग म्हणजे नेस्टेड सबस्टिट्यूट फंक्शन्स वापरणे:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")

जसे तुम्ही खालील स्क्रीनशॉटमध्ये पाहू शकता, दोन्ही सूत्रे निर्दिष्‍ट वर्णाच्या अपरकेस आणि लोअरकेस घटनांची निर्दोषपणे गणना करतात:

काही प्रकरणांमध्ये, तुम्हाला सारणीमध्ये अनेक भिन्न वर्ण मोजावे लागतील, परंतु तुम्ही प्रत्येक वेळी सूत्र बदलू इच्छित नाही. या प्रकरणात, नेस्ट वन सबस्टिट्यूट फंक्शन दुसर्‍यामध्ये, तुम्हाला काही सेलमध्ये मोजायचे असलेले कॅरेक्टर टाइप करा (या उदाहरणात डी1), आणि त्या सेलचे व्हॅल्यू अपरकेसमध्ये बदला आणिUPPER आणि LOWER फंक्शन्स वापरून लोअरकेस:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))

वैकल्पिकपणे, स्त्रोत सेल आणि कॅरेक्टर असलेले सेल दोन्ही एकतर अपरकेस किंवा लोअरकेसमध्ये रूपांतरित करा. उदाहरणार्थ:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))

या दृष्टिकोनाचा फायदा असा आहे की संदर्भित सेलमध्ये अप्परकेस किंवा लोअरकेस कॅरेक्टर इनपुट आहे की नाही याची पर्वा न करता, तुमचे केस-असंवेदनशील वर्ण गणना सूत्र योग्य संख्या परत करेल:

सेलमधील ठराविक मजकूर किंवा सबस्ट्रिंगच्या घटनांची गणना करा

तुम्हाला किती वेळा मोजायचे असल्यास वर्णांचे विशिष्ट संयोजन (म्हणजे ठराविक मजकूर किंवा सबस्ट्रिंग) दिलेल्या सेलमध्ये दिसते, उदा. "A2" किंवा "SS", नंतर उपरोक्त सूत्रांद्वारे परत आलेल्या वर्णांची संख्या सबस्ट्रिंगच्या लांबीने विभाजित करा.

केस-संवेदी सूत्र:

=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)

केस-संवेदनशील सूत्र:

=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)

जेथे B2 संपूर्ण मजकूर स्ट्रिंग असलेला सेल आहे आणि C1 हा मजकूर (सबस्ट्रिंग) आहे मोजायचे आहे.

सूत्राच्या तपशीलवार स्पष्टीकरणासाठी, कृपया सेलमधील विशिष्ट मजकूर / शब्द कसे मोजायचे ते पहा.

विशिष्ट कसे मोजायचे श्रेणीतील वर्ण

आता तुम्हाला सेलमधील वर्ण मोजण्यासाठी एक्सेल फॉर्म्युला माहित असल्याने, विशिष्ट वर्ण श्रेणीमध्ये किती वेळा दिसतात हे शोधण्यासाठी तुम्ही त्यात आणखी सुधारणा करू शकता. यासाठी, चर्चा केलेल्या सेलमधील विशिष्ट वर्ण मोजण्यासाठी आपण Excel LEN सूत्र घेऊमागील उदाहरणात, आणि ते SUMPRODUCT फंक्शनमध्ये ठेवा जे अॅरे हाताळू शकते:

या उदाहरणात, सूत्र खालील आकार घेते:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

आणि येथे मोजण्यासाठी दुसरे सूत्र आहे एक्सेलच्या श्रेणीतील वर्ण:

=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

पहिल्या सूत्राच्या तुलनेत, सर्वात स्पष्ट फरक म्हणजे SUMPRODUCT ऐवजी SUM वापरणे. आणखी एक फरक असा आहे की यासाठी Ctrl + Shift + Enter दाबणे आवश्यक आहे कारण SUMPRODUCT च्या विपरीत, जे अॅरेवर प्रक्रिया करण्यासाठी डिझाइन केलेले आहे, SUM केवळ अॅरे फॉर्म्युला मध्ये वापरल्यास अॅरे हाताळू शकते.

तुम्ही नसल्यास सूत्रातील वर्ण हार्डकोड करू इच्छित नाही, तुम्ही अर्थातच काही सेलमध्ये टाइप करू शकता, D1 म्हणा आणि त्या सेलचा तुमच्या वर्ण संख्या सूत्रामध्ये संदर्भ द्या:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))

टीप. अशा परिस्थितीत जेव्हा तुम्ही विशिष्ट सबस्ट्रिंग च्या घटना एका श्रेणीत मोजता (उदा. "KK" किंवा "AA" ने सुरू होणारे ऑर्डर), तुम्हाला सबस्ट्रिंग लांबीने वर्ण संख्या विभाजित करणे आवश्यक आहे, अन्यथा प्रत्येक वर्ण सबस्ट्रिंग वैयक्तिकरित्या मोजले जाईल. उदाहरणार्थ:

=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))

हे वर्ण मोजण्याचे सूत्र कसे कार्य करते

तुम्हाला आठवत असेल की, SUBSTITUTE फंक्शनचा वापर निर्दिष्ट वर्णाच्या सर्व घटना बदलण्यासाठी केला जातो (या उदाहरणातील "A" ) रिकाम्या मजकूर स्ट्रिंगसह ("").

नंतर, आम्ही एक्सेल LEN ला SUBSTITUTE द्वारे परत केलेला मजकूर स्ट्रिंग पुरवतो.फंक्शन जेणेकरून ते A च्या शिवाय स्ट्रिंग लांबीची गणना करते. आणि मग, आम्ही मजकूर स्ट्रिंगच्या एकूण लांबीमधून ती वर्ण संख्या वजा करतो. या गणनेचा परिणाम म्हणजे प्रति सेल एक वर्ण गणनेसह वर्ण संख्यांचा एक अॅरे आहे.

शेवटी, SUMPRODUCT अॅरेमधील संख्यांची बेरीज करते आणि श्रेणीतील निर्दिष्ट वर्णांची एकूण संख्या मिळवते.

श्रेणीतील विशिष्ट वर्णांची गणना करण्यासाठी केस-संवेदनशील सूत्र

तुम्हाला आधीच माहित आहे की SUBSTITUTE हे केस-संवेदनशील कार्य आहे, जे कॅरेक्टर गणनेसाठी आमचे एक्सेल सूत्र केस-संवेदी देखील बनवते.

सूत्राकडे दुर्लक्ष केस बनवण्यासाठी, मागील उदाहरणामध्ये दाखवलेल्या पद्धतींचे अनुसरण करा: सेलमधील विशिष्ट वर्ण मोजण्यासाठी केस-असंवेदनशील सूत्र.

विशेषतः, मोजण्यासाठी तुम्ही खालीलपैकी एक सूत्र वापरू शकता श्रेणीकडे दुर्लक्ष करून विशिष्ट वर्ण:

• UPPER फंक्शन वापरा आणि अप्परकेसमध्ये एक वर्ण प्रविष्ट करा:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A","")))

• नेस्टेड SUBSTITUTE फंक्शन्स वापरा:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a","")))

• UPPER आणि LOWER फंक्शन्स वापरा, काही सेलमध्ये एकतर अपरकेस किंवा लोअरकेस वर्ण टाइप करा आणि तुमच्या सूत्रामध्ये त्या सेलचा संदर्भ द्या:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))

  <17

खालील स्क्रीनशॉट कृतीतील शेवटचे सूत्र दाखवतो:

टीप. श्रेणीतील विशिष्ट मजकूर (सबस्ट्रिंग) च्या घटना मोजण्यासाठी, श्रेणीतील विशिष्ट मजकूर/शब्द कसे मोजावेत हे दाखवलेले सूत्र वापरा.

हेLEN फंक्शन वापरून तुम्ही एक्सेलमध्ये अक्षरे कशी मोजू शकता. तुम्हाला वैयक्तिक वर्णांऐवजी शब्द कसे मोजायचे हे जाणून घ्यायचे असल्यास, आमच्या पुढील लेखात तुम्हाला काही उपयुक्त सूत्रे सापडतील, कृपया संपर्कात रहा!

यादरम्यान, तुम्ही वर्ण गणना सूत्रासह नमुना वर्कबुक डाउनलोड करू शकता. या ट्यूटोरियलमध्ये चर्चा केली आहे आणि पृष्ठाच्या शेवटी संबंधित संसाधनांची सूची पहा. वाचल्याबद्दल मी तुमचा आभारी आहे आणि तुम्हाला लवकरच भेटण्याची आशा आहे!