El tutorial explica cómo contar caracteres en Excel. Aprenderás las fórmulas para obtener el recuento total de caracteres en un rango, y contar sólo caracteres específicos en una celda o en varias celdas.

En nuestro tutorial anterior presentamos la función LEN de Excel, que permite contar el número total de caracteres de una celda.

La fórmula LEN es útil por sí sola, pero en combinación con otras funciones como SUM, SUMPRODUCT y SUBSTITUTE, puede manejar tareas mucho más complejas. Más adelante en este tutorial, vamos a echar un vistazo más de cerca a algunas fórmulas básicas y avanzadas para contar caracteres en Excel.

Cómo contar todos los caracteres de un rango

Cuando se trata de contar un número total de caracteres en varias celdas, una solución inmediata que viene a la mente es obtener el recuento de caracteres para cada celda, y luego sumar esos números:

=LEN(A2)+LEN(A3)+LEN(A4)

O

=SUMA(LEN(A2),LEN(A3),LEN(A4))

Las fórmulas anteriores pueden funcionar bien para un rango pequeño. Para contar el total de caracteres en un rango mayor, será mejor que inventemos algo más compacto, por ejemplo, la función SUMPRODUCT, que multiplica las matrices y devuelve la suma de los productos.

Esta es la fórmula genérica de Excel para contar los caracteres de un rango:

Y tu fórmula en la vida real puede parecerse a esto:

=SUMPRODUCTO(LEN(A1:A7))

Otra forma de contar caracteres en un rango es utilizar la función LEN en combinación con SUM:

=SUMA(LEN(A1:A7))

A diferencia de SUMPRODUCT, la función SUMA no calcula matrices por defecto, y es necesario pulsar Ctrl + Mayús + Intro para convertirla en una fórmula de matriz.

Como se muestra en la siguiente captura de pantalla, la fórmula SUM devuelve el mismo recuento total de caracteres:

Cómo funciona esta fórmula de recuento de caracteres

Esta es una de las fórmulas más sencillas para contar caracteres en Excel. La función LEN calcula la longitud de la cadena para cada celda en el rango especificado y los devuelve como una matriz de números. Y luego, SUMPRODUCT o SUM suma esos números y devuelve el recuento total de caracteres.

En el ejemplo anterior, se suma una matriz de 7 números que representan las longitudes de las cadenas en las celdas A1 a A7:

Nota: Tenga en cuenta que la función LEN de Excel cuenta absolutamente todos los caracteres de cada celda incluyendo letras, números, signos de puntuación, símbolos especiales y todos los espacios (iniciales, finales y entre palabras).

Cómo contar caracteres específicos en una celda

A veces, en lugar de contar todos los caracteres de una celda, puede ser necesario contar sólo las apariciones de una letra, número o símbolo especial concreto.

Para contar el número de veces que aparece un carácter determinado en una celda, utilice la función LEN junto con SUSTITUIR:

Para entender mejor la fórmula, considere el siguiente ejemplo.

Suponga que mantiene una base de datos de artículos entregados, donde cada tipo de artículo tiene su propio identificador único. Y cada celda contiene varios artículos separados por coma, espacio o cualquier otro delimitador. La tarea consiste en contar cuántas veces aparece un identificador único dado en cada celda.

Suponiendo que la lista de artículos entregados está en la columna B (empezando en B2), y que estamos contando el número de apariciones de "A", la fórmula es la siguiente:

=LEN(B2)-LEN(SUBSTITUTE(B2, "A",""))

Cómo funciona esta fórmula de Excel para contar caracteres

Para entender la lógica de la fórmula, dividámosla en partes más pequeñas:

• En primer lugar, se cuenta la longitud total de la cadena en B2:

LEN(B2)

SUBSTITUTE(B2, "A","")

LEN(SUBSTITUTE(B2, "A",""))

Como resultado, se obtiene el recuento de caracteres "eliminados", que equivale al número total de apariciones de ese carácter en la celda.

En lugar de especificar el carácter que desea contar en una fórmula, puede escribirlo en alguna celda y, a continuación, hacer referencia a esa celda en una fórmula. De este modo, sus usuarios podrán contar las apariciones de cualquier otro carácter que introduzcan en esa celda sin alterar su fórmula:

Nota: la función SUSTITUIR de Excel distingue entre mayúsculas y minúsculas y, por lo tanto, la fórmula anterior también distingue entre mayúsculas y minúsculas. Por ejemplo, en la captura de pantalla anterior, la celda B3 contiene 3 apariciones de "A": dos en mayúsculas y una en minúsculas. La fórmula sólo ha contado los caracteres en mayúsculas porque hemos proporcionado "A" a la función SUSTITUIR.

Fórmula de Excel que no distingue mayúsculas de minúsculas para contar caracteres específicos en una celda

Si necesita un recuento de caracteres que no distinga entre mayúsculas y minúsculas, incruste la función UPPER dentro de SUBSTITUTE para convertir el carácter especificado a mayúsculas antes de ejecutar la sustitución. Y, asegúrese de introducir el carácter en mayúsculas en la fórmula.

Por ejemplo, para contar los elementos "A" y "a" en la celda B2, utilice esta fórmula:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), "A",""))

Otra forma es utilizar funciones de sustitución anidadas:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2, "A",""), "a","")

Como puede ver en la siguiente captura de pantalla, ambas fórmulas cuentan perfectamente las apariciones en mayúsculas y minúsculas del carácter especificado:

En algunos casos, puede que necesites contar muchos caracteres diferentes en una tabla, pero no quieras modificar la fórmula cada vez. En este caso, anida una función Sustituir dentro de otra, escribe el carácter que quieras contar en alguna celda (D1 en este ejemplo), y convierte el valor de esa celda a mayúsculas y minúsculas utilizando las funciones UPPER y LOWER:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))

Alternativamente, convierta tanto la celda de origen como la celda que contiene el carácter a mayúsculas o minúsculas. Por ejemplo:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))

La ventaja de este enfoque es que, independientemente de si el carácter en mayúsculas o minúsculas se introduce en la celda de referencia, su fórmula de recuento de caracteres sin distinción entre mayúsculas y minúsculas devolverá la cuenta correcta:

Contar las apariciones de un determinado texto o subcadena en una celda

Si quiere contar cuántas veces un combinación específica de caracteres (es decir, cierto texto, o subcadena) aparece en una celda determinada, por ejemplo, "A2" o "SS", entonces divida el número de caracteres devueltos por las fórmulas anteriores por la longitud de la subcadena.

Mayúsculas y minúsculas fórmula:

=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)

No distingue entre mayúsculas y minúsculas fórmula:

=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)

Donde B2 es la celda que contiene toda la cadena de texto, y C1 es el texto (subcadena) que quieres contar.

Para una explicación detallada de la fórmula, consulte Cómo contar texto / palabras específicas en una celda.

Cómo contar caracteres específicos en un rango

Ahora que conoces una fórmula de Excel para contar caracteres en una celda, puede que quieras mejorarla aún más para averiguar cuántas veces aparece un determinado carácter en un rango. Para ello, tomaremos la fórmula LEN de Excel para contar un carácter específico en una celda comentada en el ejemplo anterior, y la pondremos dentro de la función SUMPRODUCT que puede manejar matrices:

En este ejemplo, la fórmula adopta la siguiente forma:

=SUMPRODUCTO(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

Y aquí hay otra fórmula para contar caracteres en el rango de Excel:

=SUMA(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A",""))

En comparación con la primera fórmula, la diferencia más obvia es el uso de SUM en lugar de SUMPRODUCT. Otra diferencia es que requiere pulsar Ctrl + Mayús + Intro porque, a diferencia de SUMPRODUCT, que está diseñado para procesar matrices, SUM sólo puede manejar matrices cuando se utiliza en una fórmula fórmula de matriz .

Si no desea codificar el carácter en la fórmula, puede escribirlo en una celda, por ejemplo D1, y hacer referencia a esa celda en la fórmula de recuento de caracteres:

=SUMPRODUCTO(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))

Nota: En situaciones en las que se cuentan las ocurrencias de un subcadena en un rango (por ejemplo, órdenes que empiecen por "KK" o "AA"), deberá dividir el recuento de caracteres por la longitud de la subcadena, ya que, de lo contrario, cada carácter de la subcadena se contará individualmente. Por ejemplo:

=SUMA((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))

Cómo funciona esta fórmula de recuento de caracteres

Como recordará, la función SUBSTITUTE se utiliza para sustituir todas las apariciones del carácter especificado ("A" en este ejemplo) por una cadena de texto vacía ("").

A continuación, suministramos la cadena de texto devuelta por SUSTITUIR a la función LEN de Excel para que calcule la longitud de la cadena sin A. Y luego, restamos ese recuento de caracteres de la longitud total de la cadena de texto. El resultado de estos cálculos es una matriz de recuentos de caracteres, con un recuento de caracteres por celda.

Por último, SUMPRODUCT suma los números de la matriz y devuelve el recuento total del carácter especificado en el rango.

Una fórmula que no distingue entre mayúsculas y minúsculas para contar caracteres específicos en un rango

Ya sabes que SUBSTITUTE es una función que distingue entre mayúsculas y minúsculas, lo que hace que nuestra fórmula Excel para el recuento de caracteres también distinga entre mayúsculas y minúsculas.

Para hacer que la fórmula ignore mayúsculas y minúsculas, siga los planteamientos demostrados en el ejemplo anterior: Fórmula que no distingue mayúsculas de minúsculas para contar caracteres específicos en una celda.

En particular, puede utilizar una de las siguientes fórmulas para contar caracteres específicos en un rango ignorando el caso:

• Utilice la función MAYÚSCULA e introduzca un carácter en mayúsculas:

  =SUMPRODUCTO(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8), "A","")))

• Utilice funciones SUBSTITUTE anidadas:

  =SUMPRODUCTO(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), "A",""), "a","")))

• Utilice las funciones UPPER y LOWER, escriba un carácter en mayúscula o minúscula en alguna celda y haga referencia a esa celda en su fórmula:

  =SUMPRODUCTO(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))

La siguiente captura de pantalla muestra la última fórmula en acción:

Consejo. Para contar las ocurrencias de un texto específico (subcadena) en un rango, utilice la fórmula demostrada en Cómo contar texto / palabras específicas en un rango.

Así es como puedes contar caracteres en Excel utilizando la función LEN. Si quieres saber cómo contar palabras en lugar de caracteres individuales, encontrarás unas cuantas fórmulas útiles en nuestro próximo artículo, ¡por favor, permanece atento!

Mientras tanto, puedes descargarte un ejemplo de libro de ejercicios con la fórmula de recuento de caracteres que se explica en este tutorial, y consultar una lista de recursos relacionados al final de la página. Te agradezco tu lectura y ¡espero verte pronto!