Jedwali la yaliyomo
Mafunzo yanaeleza jinsi ya kuhesabu herufi katika Excel. Utajifunza fomula ili kupata jumla ya hesabu ya herufi katika safu, na kuhesabu herufi maalum pekee kwenye seli au katika seli kadhaa.
Mafunzo yetu ya awali yalianzisha kitendakazi cha Excel LEN, ambacho kinaruhusu kuhesabu nambari. jumla ya idadi ya vibambo katika kisanduku.
Fomula ya LEN ni muhimu yenyewe, lakini kwa kuunganishwa na vitendaji vingine kama vile SUM, SUMPRODUCT na SUBSTITUTE, inaweza kushughulikia kazi ngumu zaidi. Zaidi katika somo hili, tutaangalia kwa karibu fomula chache za kimsingi na za kina za kuhesabu herufi katika Excel.
Jinsi ya kuhesabu herufi zote katika safu
Inapokuja katika kuhesabu jumla ya idadi ya herufi katika seli kadhaa, suluhu ya haraka inayokuja akilini ni kupata hesabu ya herufi kwa kila seli, na kisha kujumlisha nambari hizo:
=LEN(A2)+LEN(A3)+LEN(A4)
Au
=SUM(LEN(A2),LEN(A3),LEN(A4))
Fomula zilizo hapo juu zinaweza kufanya kazi vizuri kwa safu ndogo. Ili kuhesabu jumla ya herufi katika safu kubwa zaidi, ni afadhali tupate kitu kifupi zaidi, k.m. chaguo za kukokotoa za SUMPRODUCT, ambayo huzidisha mkusanyiko na kurudisha jumla ya bidhaa.
Hii hapa ni fomula ya jumla ya Excel ya kuhesabu herufi katika masafa:
=SUMPRODUCT(LEN( fungu) )Na fomula yako ya maisha halisi inaweza kuonekana sawa na hii:
=SUMPRODUCT(LEN(A1:A7))
Njia nyingine ya kuhesabu herufi katika masafa ni kutumia Chaguo za kukokotoa za LEN ndanimchanganyiko na SUM:
=SUM(LEN(A1:A7))
Tofauti na SUMPRODUCT, kitendakazi cha SUM hakikokotoa safu kwa chaguomsingi, na unahitaji kubonyeza Ctrl + Shift + Enter ili kuigeuza kuwa fomula ya mkusanyiko.
Kama inavyoonyeshwa katika picha ya skrini ifuatayo, fomula ya SUM hurejesha jumla ya idadi sawa ya herufi:
Jinsi fomula hii ya hesabu ya herufi mbalimbali inavyofanya kazi
Hii ni mojawapo ya fomula zilizo wazi zaidi za kuhesabu herufi katika Excel. Chaguo za kukokotoa za LEN hukokotoa urefu wa mfuatano kwa kila seli katika safu maalum na kuzirudisha kama safu ya nambari. Kisha, SUMPRODUCT au SUM huongeza nambari hizo na kurudisha jumla ya hesabu ya herufi.
Katika mfano ulio hapo juu, safu ya nambari 7 zinazowakilisha urefu wa mifuatano katika seli A1 hadi A7 inajumlishwa:
Kumbuka. Tafadhali zingatia kwamba kitendakazi cha Excel LEN kinahesabu kabisa herufi zote katika kila seli , ikijumuisha herufi, nambari, alama za uakifishaji, alama maalum, na nafasi zote (kinachoongoza, kifuatacho na nafasi kati ya maneno).
Jinsi ya kuhesabu herufi mahususi katika kisanduku
Wakati mwingine, badala ya kuhesabu herufi zote ndani ya kisanduku, unaweza kuhitaji kuhesabu tu matukio ya herufi, nambari au alama maalum.
Ili kuhesabu idadi ya mara herufi fulani inaonekana kwenye kisanduku, tumia kitendakazi cha LEN pamoja na SUBSTITUTE:
=LEN( seli )-LEN(SUBSTITUTE( seli<2)>, herufi ,""))Ili kuelewa zaidi fomula, zingatia mfano ufuatao.
Tuseme, unadumisha hifadhidata ya vipengee vilivyowasilishwa, ambapo kila aina ya kipengee ina kipekee yake ya kipekee. kitambulisho. Na kila seli ina vipengee kadhaa vilivyotenganishwa na koma, nafasi, au kikomo kingine chochote. Jukumu ni kuhesabu ni mara ngapi kitambulishi cha kipekee kilichotolewa kinaonekana katika kila seli.
Tukichukulia kuwa orodha ya vipengee vilivyowasilishwa iko kwenye safu wima B (kuanzia B2), na tunahesabu nambari ya "A" matukio, fomula ni kama ifuatavyo:
=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))
Jinsi fomula hii ya kuhesabu herufi za Excel inavyofanya kazi
Ili kuelewa mantiki ya fomula, hebu igawanye katika sehemu ndogo:
- Kwanza, unahesabu jumla ya urefu wa kamba katika B2:
LEN(B2)
SUBSTITUTE(B2,"A","")
LEN(SUBSTITUTE(B2,"A",""))
Kwa matokeo, unapata hesabu ya herufi "zilizoondolewa", ambayo ni sawa na jumla ya idadi ya matukio ya herufi kwenye kisanduku.
Badala ya kubainisha herufi unayotaka kuhesabu. fomula, unaweza kuiandika katika kisanduku fulani, na kisha kurejelea kisanduku hicho katika fomula. Kwa njia hii, watumiaji wakoitaweza kuhesabu matukio ya herufi nyingine yoyote wanayoingiza kwenye kisanduku hicho bila kuchezea fomula yako:
Kumbuka. Excel's SUBSTITUTE ni chaguo la kukokotoa ambalo ni nyeti kwa kadiri, na kwa hivyo fomula iliyo hapo juu ni nyeti kwa kadhia pia. Kwa mfano, katika picha ya skrini iliyo hapo juu, seli B3 ina matukio 3 ya "A" - mawili kwa herufi kubwa, na moja kwa herufi ndogo. Fomula imehesabu herufi kubwa pekee kwa sababu tulitoa "A" kwa chaguo la kukokotoa SUBSTITUTE.
Fomula ya Excel isiyojali herufi ya kuhesabu herufi mahususi katika kisanduku
Ikiwa unahitaji hesabu ya herufi isiyojali herufi, pachika chaguo la kukokotoa la UPPER ndani ya SUBSTITUTE ili kubadilisha herufi iliyobainishwa kuwa herufi kubwa kabla ya kutekeleza kibadala. Na, hakikisha umeingiza herufi kubwa katika fomula.
Kwa mfano, ili kuhesabu vipengee "A" na "a" katika kisanduku B2, tumia fomula hii:
=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))
Njia nyingine ni kutumia vitendaji vya Kibadala vilivyoorodheshwa:
=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")
Kama unavyoona kwenye picha ya skrini iliyo hapa chini, fomula zote mbili huhesabu bila dosari matukio ya herufi kubwa na ndogo ya herufi maalum:
Katika baadhi ya matukio, huenda ukahitaji kuhesabu herufi nyingi tofauti kwenye jedwali, lakini huenda usitake kurekebisha fomula kila wakati. Katika hali hii, weka kitendakazi cha Kibadala kimoja ndani ya kingine, charaza herufi unayotaka kuhesabu katika kisanduku fulani (D1 katika mfano huu), na ubadilishe thamani ya kisanduku hicho kuwa herufi kubwa naherufi ndogo kwa kutumia vitendaji vya JUU na CHINI:
=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))
Vinginevyo, badilisha kisanduku chanzo na seli iliyo na herufi iwe herufi kubwa au ndogo. Kwa mfano:
=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))
Faida ya mbinu hii ni kwamba bila kujali kama herufi kubwa au ndogo imeingizwa katika kisanduku kilichorejelewa, fomula yako ya isiyojali herufi itarejesha hesabu sahihi:
Hesabu matukio ya maandishi fulani au kamba ndogo kwenye kisanduku
Ikiwa ungependa kuhesabu ni mara ngapi mchanganyiko maalum wa vibambo (yaani maandishi fulani, au kamba ndogo) huonekana katika kisanduku fulani, k.m. "A2" au "SS", kisha ugawanye idadi ya herufi zilizorejeshwa na fomula zilizo hapo juu kwa urefu wa kamba ndogo.
fomula nyeti kwa kesi :
=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)
Haijalishi fomula:
=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)
B2 iko wapi kisanduku kilicho na mfuatano wote wa maandishi, na C1 ni maandishi (mfuatano mdogo) wewe unataka kuhesabu.
Kwa maelezo ya kina ya fomula, tafadhali angalia Jinsi ya kuhesabu maandishi/maneno mahususi katika kisanduku.
Jinsi ya kuhesabu mahususi. herufi katika safu
Kwa kuwa sasa unajua fomula ya Excel ya kuhesabu herufi katika kisanduku, unaweza kutaka kuiboresha zaidi ili kujua ni mara ngapi herufi fulani inaonekana katika safu. Kwa hili, tutachukua fomula ya Excel LEN ili kuhesabu char maalum katika seli iliyojadiliwakatika mfano uliotangulia, na uiweke ndani ya kitendakazi cha SUMPRODUCT ambacho kinaweza kushughulikia safu:
SUMPRODUCT(LEN( range )-LEN(SUBSTITUTE( fungu , herufi ,"")))Katika mfano huu, fomula inachukua umbo lifuatalo:
=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))
Na hapa kuna fomula nyingine ya kuhesabu. herufi katika safu ya Excel:
=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))
Ikilinganishwa na fomula ya kwanza, tofauti iliyo wazi zaidi ni kutumia SUM badala ya SUMPRODUCT. Tofauti nyingine ni kwamba inahitaji kubonyeza Ctrl + Shift + Enter kwa sababu tofauti na SUMPRODUCT, ambayo imeundwa kuchakata safu, SUM inaweza kushughulikia safu tu inapotumiwa katika fomula ya safu .
Usipofanya hivyo. Sitaki kuweka herufi ngumu kwenye fomula, bila shaka unaweza kuiandika katika kisanduku fulani, sema D1, na urejelee kisanduku hicho katika fomula ya hesabu ya herufi:
=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))
Kumbuka. Katika hali unapohesabu matukio ya mfuatano mdogo mahususi (k.m. maagizo yanayoanza na "KK" au "AA"), unahitaji kugawanya hesabu ya herufi kwa urefu wa kamba ndogo, vinginevyo kila herufi ndani kifungu kidogo kitahesabiwa kila mmoja. Kwa mfano:
=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))
Jinsi fomula hii ya kuhesabu herufi inavyofanya kazi
Kama unavyoweza kukumbuka, kitendakazi SUBSTITUTE kinatumika kuchukua nafasi ya matukio yote ya herufi iliyobainishwa ("A" katika mfano huu. ) na mfuatano tupu wa maandishi ("").
Kisha, tunasambaza mfuatano wa maandishi uliorejeshwa na SUBSTITUTE kwa Excel LEN.kazi ili kuhesabu urefu wa kamba bila A. Na kisha, tunaondoa hesabu hiyo ya wahusika kutoka kwa urefu wa jumla wa mfuatano wa maandishi. Matokeo ya hesabu hizi ni safu ya hesabu za herufi, na hesabu ya herufi moja kwa kila seli.
Mwishowe, SUMPRODUCT hujumlisha nambari katika safu na kurudisha hesabu ya jumla ya herufi maalum katika safu.
Mchanganyiko usiojali kifani wa kuhesabu herufi mahususi katika safu
Tayari unajua kuwa SUBSTITUTE ni chaguo la kukokotoa ambalo ni nyeti, jambo ambalo hufanya fomula yetu ya Excel ya hesabu ya herufi kuwa nyeti pia.
Ili kufanya fomula ya kupuuza, fuata mbinu zilizoonyeshwa katika mfano uliopita: Fomula isiyojali kesi ya kuhesabu herufi mahususi katika kisanduku.
Hasa, unaweza kutumia mojawapo ya fomula zifuatazo kuhesabu. herufi mahususi katika visanduku vya kupuuza:
- Tumia kitendakazi cha JUU na uweke herufi kwa herufi kubwa:
=SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A",""))) - Tumia vitendaji vya SUBSTITUTE vilivyofurushwa:
=SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a",""))) - Tumia vitendaji vya JUU na CHINI, andika herufi kubwa au ndogo katika kisanduku fulani, na urejelee kisanduku hicho katika fomula yako:
=SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))
Picha ya skrini iliyo hapa chini inaonyesha fomula ya mwisho inayotumika:
Kidokezo. Ili kuhesabu matukio ya maandishi maalum (substring) katika masafa, tumia fomula iliyoonyeshwa katika Jinsi ya kuhesabu maandishi/maneno mahususi katika masafa.
Hiini jinsi unavyoweza kuhesabu herufi katika Excel ukitumia kitendakazi cha LEN. Iwapo ungependa kujua jinsi ya kuhesabu maneno badala ya herufi moja moja, utapata fomula chache muhimu katika makala yetu inayofuata, tafadhali endelea kufuatilia!
Kwa sasa, unaweza kupakua sampuli ya vitabu vya kazi vilivyo na fomula ya kuhesabu wahusika. kujadiliwa katika mafunzo haya, na angalia orodha ya nyenzo zinazohusiana mwishoni mwa ukurasa. Ninakushukuru kwa kusoma na natumai kukuona hivi karibuni!
