Sadržaj
Vodič objašnjava kako brojati znakove u Excelu. Naučit ćete formule za dobivanje ukupnog broja znakova u rasponu i brojanje samo određenih znakova u ćeliji ili u nekoliko ćelija.
Naš prethodni tutorijal uveo je funkciju Excel LEN, koja omogućava brojanje ukupan broj znakova u ćeliji.
LEN formula je korisna sama po sebi, ali u vezi s drugim funkcijama kao što su SUM, SUMPRODUCT i SUBSTITUTE, može se nositi sa daleko složenijim zadacima. Dalje, u ovom vodiču, imaćemo detaljniji pogled na nekoliko osnovnih i naprednih formula za brojanje znakova u Excelu.
Kako prebrojati sve znakove u rasponu
Kada dođe do brojanja ukupnog broja znakova u nekoliko ćelija, trenutno rješenje koje vam pada na pamet je da dobijete broj znakova za svaku ćeliju, a zatim zbrojite te brojeve:
=LEN(A2)+LEN(A3)+LEN(A4)
Ili
=SUM(LEN(A2),LEN(A3),LEN(A4))
Gore formule mogu dobro funkcionirati za mali raspon. Da bismo izbrojali ukupan broj znakova u većem rasponu, bolje bi bilo da smislimo nešto kompaktnije, npr. funkcija SUMPRODUCT, koja množi nizove i vraća zbroj proizvoda.
Evo generičke Excel formule za brojanje znakova u rasponu:
=SUMPRODUCT(LEN( opseg) )I vaša formula iz stvarnog života može izgledati slično ovome:
=SUMPRODUCT(LEN(A1:A7))
Drugi način za brojanje znakova u rasponu je korištenje LEN funkcija ukombinacija sa SUM:
=SUM(LEN(A1:A7))
Za razliku od SUMPRODUCT, funkcija SUM ne izračunava nizove prema zadanim postavkama, i morate pritisnuti Ctrl + Shift + Enter da je pretvorite u formulu niza.
Kao što je prikazano na sljedećem snimku ekrana, formula SUM vraća isti ukupan broj znakova:
Kako funkcionira formula za ovaj raspon znakova
Ovo je jedna od najjednostavnijih formula za brojanje znakova u Excelu. Funkcija LEN izračunava dužinu niza za svaku ćeliju u navedenom rasponu i vraća ih kao niz brojeva. A zatim, SUMPRODUCT ili SUM zbraja te brojeve i vraća ukupan broj znakova.
U gornjem primjeru, niz od 7 brojeva koji predstavljaju dužine nizova u ćelijama od A1 do A7 se zbraja:
Napomena. Obratite pažnju da Excel LEN funkcija broji apsolutno sve znakove u svakoj ćeliji , uključujući slova, brojeve, interpunkcijske znakove, posebne simbole i sve razmake (početne, završne i razmake između riječi).
Kako prebrojati određene znakove u ćeliji
Ponekad, umjesto brojanja svih znakova unutar ćelije, možda ćete morati brojati samo pojavljivanja određenog slova, broja ili posebnog simbola.
Da izbrojite koliko puta se dati znak pojavljuje u ćeliji, koristite funkciju LEN zajedno sa SUBSTITUTE:
=LEN( cell )-LEN(SUBSTITUTE( cell<2)>, znak ,""))Da biste bolje razumjeli formulu, razmotrite sljedeći primjer.
Pretpostavimo da održavate bazu podataka isporučenih stavki, gdje svaki tip stavke ima svoju jedinstvenu identifikator. I svaka ćelija sadrži nekoliko stavki odvojenih zarezom, razmakom ili bilo kojim drugim graničnikom. Zadatak je izbrojati koliko se puta dati jedinstveni identifikator pojavljuje u svakoj ćeliji.
Pod pretpostavkom da je lista isporučenih stavki u koloni B (počinje u B2), a mi brojimo broj "A" pojava, formula je sljedeća:
=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))
Kako ova Excel formula za broj znakova funkcionira
Da bismo razumjeli logiku formule, hajde da podijelite ga na manje dijelove:
- Prvo, računate ukupnu dužinu niza u B2:
LEN(B2)
SUBSTITUTE(B2,"A","")
LEN(SUBSTITUTE(B2,"A",""))
Kao rezultat, dobijate broj "uklonjenih" znakova, koji je jednak ukupnom broju pojavljivanja tih znakova u ćeliji.
Umjesto da navedete znak u koji želite da se brojite formulu, možete je upisati u neku ćeliju, a zatim referencirati tu ćeliju u formuli. Na taj način vaši korisnicimoći će brojati pojavljivanja bilo kojeg drugog znaka koji unesu u tu ćeliju bez mijenjanja vaše formule:
Napomena. Excelov SUBSTITUTE je funkcija koja razlikuje velika i mala slova, pa je stoga i gornja formula također osjetljiva na velika i mala slova. Na primjer, na gornjoj slici ekrana, ćelija B3 sadrži 3 pojavljivanja "A" - dva velika i jedno mala. Formula je brojala samo velika slova jer smo dali "A" funkciji SUBSTITUTE.
Excel formula bez obzira na velika i mala slova za brojanje specifičnih znakova u ćeliji
Ako vam je potreban broj znakova bez obzira na velika i mala slova, ugradite funkciju UPPER unutar SUBSTITUTE da konvertujete navedeni znak u velika slova prije pokretanja zamjene. I obavezno u formulu unesite veliko slovo.
Na primjer, da biste brojali stavke "A" i "a" u ćeliji B2, koristite ovu formulu:
=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))
Drugi način je da koristite ugniježđene zamjenske funkcije:
=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")
Kao što možete vidjeti na snimku ekrana ispod, obje formule besprijekorno broje velika i mala slova pojavljivanja navedenog znaka:
U nekim slučajevima, možda ćete morati prebrojati mnogo različitih znakova u tabeli, ali možda nećete htjeti mijenjati formulu svaki put. U ovom slučaju, ugniježdite jednu zamjensku funkciju u drugu, upišite znak koji želite da brojite u nekoj ćeliji (D1 u ovom primjeru) i pretvorite vrijednost te ćelije u velika slova imala slova pomoću funkcija UPPER i LOWER:
=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))
Alternativno, pretvorite i izvornu ćeliju i ćeliju koja sadrži znak u velika ili mala slova. Na primjer:
=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))
Prednost ovog pristupa je da bez obzira da li se u referenciranu ćeliju unose velika ili mala slova, vaša formula za brojanje znakova bez obzira na velika i mala slova će vratiti pravi broj:
Broj pojavljivanja određenog teksta ili podniza u ćeliji
Ako želite izbrojati koliko puta je specifična kombinacija znakova (tj. određeni tekst ili podniz) se pojavljuje u datoj ćeliji, npr. "A2" ili "SS", zatim podijelite broj znakova koje vraćaju gornje formule dužinom podniza.
Formula osjetljiva na velika i mala slova :
=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)
Formula bez obzira na velika i mala slova :
=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)
Gdje je B2 ćelija koja sadrži cijeli tekstualni niz, a C1 je tekst (podniz) koji želite prebrojati.
Za detaljno objašnjenje formule, pogledajte Kako prebrojati određeni tekst/riječi u ćeliji.
Kako prebrojati određene karakter(i) u rasponu
Sada kada znate Excel formulu za brojanje znakova u ćeliji, možda biste željeli da je dodatno poboljšate kako biste saznali koliko puta se određeni znak pojavljuje u rasponu. Za ovo ćemo uzeti Excel LEN formulu da izbrojimo određeni znak u ćeliji o kojoj se raspravljau prethodnom primjeru i stavite ga unutar funkcije SUMPRODUCT koja može rukovati nizovima:
SUMPRODUCT(LEN( opseg )-LEN(SUBSTITUTE( opseg , znak ,"")))U ovom primjeru, formula ima sljedeći oblik:
=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))
I evo još jedne formule za brojanje znakovi u Excelovom rasponu:
=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))
U poređenju s prvom formulom, najočitija razlika je korištenje ZBIR umjesto ZBIR PROIZVODA. Druga razlika je u tome što zahtijeva pritiskanje Ctrl + Shift + Enter jer za razliku od SUMPRODUCT, koji je dizajniran za obradu nizova, SUM može rukovati nizovima samo kada se koristi u formuli niza .
Ako ne Ako ne želite tvrdo kodirati znak u formuli, možete ga naravno upisati u neku ćeliju, recimo D1, i referencirati tu ćeliju u formuli za broj znakova:
=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))
Napomena. U situacijama kada brojite pojavljivanja određenog podniza u rasponu (npr. narudžbe koje počinju s "KK" ili "AA"), morate podijeliti broj znakova dužinom podniza, inače svaki znak u podniz će se računati pojedinačno. Na primjer:
=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))
Kako funkcionira ova formula za brojanje znakova
Kao što se sjećate, funkcija SUBSTITUTE se koristi za zamjenu svih pojavljivanja navedenog znaka ("A" u ovom primjeru ) s praznim tekstualnim nizom ("").
Zatim, dobavljamo tekstualni niz koji vraća SUBSTITUTE u Excel LENfunkciju tako da izračunava dužinu niza bez A. Zatim oduzimamo taj broj znakova od ukupne dužine tekstualnog niza. Rezultat ovih proračuna je niz broja znakova, s jednim brojem znakova po ćeliji.
Konačno, SUMPRODUCT zbraja brojeve u nizu i vraća ukupan broj specificiranog znaka u rasponu.
Formula koja ne razlikuje velika i mala slova za brojanje određenih znakova u rasponu
Već znate da je SUBSTITUTE funkcija osjetljiva na velika i mala slova, što našu Excel formulu za brojanje znakova također razlikuje velika i mala slova.
Da bi formula zanemarila velika i mala slova, slijedite pristupe prikazane u prethodnom primjeru: Formula bez obzira na velika i mala slova za brojanje određenih znakova u ćeliji.
Konkretno, možete koristiti jednu od sljedećih formula za brojanje specifični znakovi u rasponu zanemarujući velika i mala slova:
- Koristite funkciju UPPER i unesite znak velikim slovima:
=SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A",""))) - Koristite ugniježđene funkcije SUBSTITUTE:
=SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a",""))) - Koristite funkcije UPPER i LOWER, upišite znak velikih ili malih slova u neku ćeliju i referencirajte tu ćeliju u svojoj formuli:
=SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))
Snimka ekrana ispod prikazuje posljednju formulu u akciji:
Savjet. Za brojanje pojavljivanja specifičnog teksta (podniza) u rasponu, koristite formulu prikazanu u Kako prebrojati određeni tekst/riječi u rasponu.
Ovoje način na koji možete brojati znakove u Excelu koristeći LEN funkciju. Ako želite znati kako brojati riječi, a ne pojedinačne znakove, u našem sljedećem članku pronaći ćete nekoliko korisnih formula, ostanite sa nama!
U međuvremenu, možete preuzeti primjer radne knjige s formulom za brojanje znakova o kojima se raspravlja u ovom vodiču i pogledajte listu povezanih resursa na kraju stranice. Zahvaljujem vam na čitanju i nadam se da se uskoro vidimo!
