O titorial explica como contar caracteres en Excel. Aprenderá as fórmulas para obter o reconto total de caracteres nun intervalo e contar só caracteres específicos nunha cela ou en varias celas.

O noso tutorial anterior introduciu a función LEN de Excel, que permite contar os número total de caracteres nunha cela.

A fórmula LEN é útil por si mesma, pero en relación con outras funcións como SUMA, SUMAPRODUTO e SUBSTITUTO, pode xestionar tarefas moito máis complexas. Máis adiante neste titorial, imos ter unha ollada máis detallada a algunhas fórmulas básicas e avanzadas para contar caracteres en Excel.

Como contar todos os caracteres nun intervalo

Cando se trata de contar un número total de caracteres en varias celas, unha solución inmediata que vén á mente é obter o reconto de caracteres para cada cela e, a continuación, sumar eses números:

=LEN(A2)+LEN(A3)+LEN(A4)

Ou

=SUM(LEN(A2),LEN(A3),LEN(A4))

As fórmulas anteriores poden funcionar ben para un intervalo pequeno. Para contar o total de caracteres nun intervalo maior, é mellor que creamos algo máis compacto, p. ex. a función SUMAPRODUTO, que multiplica as matrices e devolve a suma dos produtos.

Aquí está a fórmula xenérica de Excel para contar caracteres nun intervalo:

E a túa fórmula real pode parecer semellante a esta:

=SUMPRODUCT(LEN(A1:A7))

Outra forma de contar os caracteres dun intervalo é usar o Función LEN encombinación con SUM:

=SUM(LEN(A1:A7))

A diferenza de SUMPRODUCT, a función SUM non calcula matrices de forma predeterminada e cómpre premer Ctrl + Maiús + Intro para convertela nunha fórmula matricial.

Como se demostra na seguinte captura de pantalla, a fórmula SUMA devolve o mesmo número total de caracteres:

Como funciona esta fórmula de reconto de caracteres de intervalo

Este é unha das fórmulas máis sinxelas para contar caracteres en Excel. A función LEN calcula a lonxitude da cadea para cada cela no intervalo especificado e devólvese como unha matriz de números. E despois, SUMPRODUCT ou SUM suma eses números e devolve o reconto total de caracteres.

No exemplo anterior, súmase unha matriz de 7 números que representan a lonxitude das cadeas nas celas A1 a A7:

Nota. Preste atención a que a función LEN de Excel conta absolutamente todos os caracteres de cada cela , incluíndo letras, números, signos de puntuación, símbolos especiais e todos os espazos (inicial, final e espazos entre palabras).

Como contar caracteres específicos nunha cela

Ás veces, en lugar de contar todos os caracteres dunha cela, pode ter que contar só as aparicións dunha letra, número ou símbolo especial específicos.

Para contar o número de veces que aparece un determinado carácter nunha cela, use a función LEN xunto con SUBSTITUTE:

Para comprender mellor a fórmula, considere o seguinte exemplo.

Supoñamos que mantén unha base de datos de elementos entregados, onde cada tipo de elemento ten o seu propio identificador. E cada cela contén varios elementos separados por coma, espazo ou calquera outro delimitador. A tarefa consiste en contar cantas veces aparece un identificador único determinado en cada cela.

Asumindo que a lista de artigos entregados está na columna B (que comeza en B2), e estamos contando o número de "A" ocorrencias, a fórmula é a seguinte:

=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))

Como funciona esta fórmula de reconto de caracteres de Excel

Para comprender a lóxica da fórmula, imos dividilo en partes máis pequenas:

• Primeiro, contas a lonxitude total da cadea en B2:

LEN(B2)

SUBSTITUTE(B2,"A","")

LEN(SUBSTITUTE(B2,"A",""))

Como resultado, obtén o reconto de caracteres "eliminados", que equivale ao número total de aparicións dese carácter na cela.

En lugar de especificar o carácter no que queres contar. unha fórmula, pode tecleala nalgunha cela e, a continuación, facer referencia a esa cela nunha fórmula. Deste xeito, os teus usuariospoderá contar as ocorrencias de calquera outro carácter que introduzan nesa cela sen alterar a súa fórmula:

Nota. O SUBSTITUTO de Excel é unha función que distingue entre maiúsculas e minúsculas e, polo tanto, a fórmula anterior tamén distingue entre maiúsculas e minúsculas. Por exemplo, na captura de pantalla anterior, a cela B3 contén 3 ocorrencias de "A": dúas en maiúscula e unha en minúscula. A fórmula contou só os caracteres en maiúscula porque fornecemos "A" á función SUBSTITUTE.

Fórmula de Excel que non distingue entre maiúsculas e minúsculas para contar caracteres específicos nunha cela

Se precisa un reconto de caracteres que non distinga entre maiúsculas e minúsculas, incruste a función UPPER dentro de SUBSTITUTE para converter o carácter especificado en maiúsculas antes de executar a substitución. E, asegúrese de introducir o carácter en maiúscula na fórmula.

Por exemplo, para contar os elementos "A" e "a" na cela B2, use esta fórmula:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))

Outra forma é usar funcións de substitución aniñadas:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")

Como podes ver na seguinte captura de pantalla, ambas fórmulas contan perfectamente as aparicións de maiúsculas e minúsculas do carácter especificado:

Nalgúns casos, pode ter que contar moitos caracteres diferentes nunha táboa, pero quizais non queira modificar a fórmula cada vez. Neste caso, aniñe unha función de substitución dentro doutra, escriba o carácter que quere contar nalgunha cela (D1 neste exemplo) e converte o valor desa cela en maiúsculas eminúsculas empregando as funcións UPPER e LOWER:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))

Como alternativa, converte tanto a cela de orixe como a cela que contén o carácter en maiúsculas ou minúsculas. Por exemplo:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))

A vantaxe deste enfoque é que, independentemente de que se introduza o carácter en maiúscula ou minúscula na cela referenciada, a súa fórmula de reconto de caracteres que non distingue entre maiúsculas e minúsculas devolverá o reconto correcto:

Conta as ocorrencias de determinado texto ou subcadea nunha cela

Se queres contar cantas veces un unha combinación específica de caracteres (é dicir, determinado texto ou subcadea) aparece nunha determinada cela, p. ex. "A2" ou "SS", despois divida o número de caracteres devoltos polas fórmulas anteriores pola lonxitude da subcadea.

Fórmula que distingue entre maiúsculas e minúsculas :

=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)

Fórmula que non distingue entre maiúsculas e minúsculas :

=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)

Onde B2 é a cela que contén a cadea de texto completa e C1 é o texto (subcadea) que quere contar.

Para obter unha explicación detallada da fórmula, consulte Como contar texto/palabras específicos nunha cela.

Como contar específicos carácter(s) nun intervalo

Agora que coñece unha fórmula de Excel para contar caracteres nunha cela, quizais queira mellorala aínda máis para saber cantas veces aparece un determinado carácter nun intervalo. Para iso, tomaremos a fórmula LEN de Excel para contar un carácter específico nunha cela discutidano exemplo anterior e colócao dentro da función SUMPRODUCT que pode manexar matrices:

Neste exemplo, a fórmula toma a seguinte forma:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

E aquí tes outra fórmula para contar caracteres no rango de Excel:

=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

En comparación coa primeira fórmula, a diferenza máis obvia é usar SUMA en lugar de SUMAPRODUTO. Outra diferenza é que require premer Ctrl + Maiús + Intro porque, a diferenza de SUMPRODUCT, que está deseñado para procesar matrices, SUM só pode xestionar matrices cando se usa nunha fórmula de matriz .

Se non Non quere codificar o carácter na fórmula, por suposto pode tecleo nalgunha cela, digamos D1, e facer referencia a esa cela na súa fórmula de conta de caracteres:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))

Nota. Nas situacións nas que conta as aparicións dunha subcadea específica nun intervalo (por exemplo, ordes que comezan por "KK" ou "AA"), cómpre dividir o reconto de caracteres pola lonxitude da subcadea, se non, cada carácter en a subcadea contarase individualmente. Por exemplo:

=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))

Como funciona esta fórmula de reconto de caracteres

Como recordarás, a función SUBSTITUTE úsase para substituír todas as ocorrencias do carácter especificado ("A" neste exemplo). ) cunha cadea de texto baleira ("").

Entón, fornecemos a cadea de texto devolta por SUBSTITUTE á LEN de Excelfunción para que calcule a lonxitude da cadea sen A. E entón, restamos ese reconto de caracteres da lonxitude total da cadea de texto. O resultado destes cálculos é unha matriz de recontos de caracteres, cun reconto de caracteres por cela.

Finalmente, SUMPRODUCT suma os números da matriz e devolve o reconto total do carácter especificado no intervalo.

Unha fórmula que non distingue entre maiúsculas e minúsculas para contar caracteres específicos nun intervalo.

Xa sabes que SUBSTITUTE é unha función que distingue entre maiúsculas e minúsculas, o que fai que a nosa fórmula de Excel para o reconto de caracteres distinga tamén entre maiúsculas e minúsculas.

Para que a fórmula ignore maiúsculas e minúsculas, siga os enfoques demostrados no exemplo anterior: Fórmula que non distingue entre maiúsculas e minúsculas para contar caracteres específicos nunha cela.

En particular, pode utilizar unha das seguintes fórmulas para contar. caracteres específicos nun intervalo ignorando maiúsculas e minúsculas:

• Utilice a función UPPER e introduza un carácter en maiúsculas:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A","")))

• Utilice funcións SUBSTITUTE aniñadas:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a","")))

• Utilice as funcións UPPER e LOWER, escriba un carácter en maiúscula ou minúscula nalgunha cela e faga referencia a esa cela na súa fórmula:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))

A seguinte captura de pantalla mostra a última fórmula en acción:

Consello. Para contar as ocorrencias dun texto específico (subcadea) nun intervalo, use a fórmula que se mostra en Como contar texto/palabras específicos nun intervalo.

Istoé como pode contar caracteres en Excel usando a función LEN. Se queres saber como contar palabras en lugar de caracteres individuais, atoparás algunhas fórmulas útiles no noso seguinte artigo, estade atentos!

Mentres tanto, podes descargar unha mostra de libros de traballo coa fórmula de reconto de caracteres. discutido neste tutorial e consulta unha lista de recursos relacionados ao final da páxina. Grazas por ler e espero verte pronto!