Tutorial ini menjelaskan cara menghitung karakter di Excel. Anda akan mempelajari rumus untuk mendapatkan jumlah karakter total dalam suatu rentang, dan hanya menghitung karakter tertentu dalam sel atau dalam beberapa sel.

Tutorial kami sebelumnya memperkenalkan fungsi Excel LEN, yang memungkinkan penghitungan jumlah total karakter dalam sel.

Rumus LEN berguna dengan sendirinya, tetapi dalam hubungannya dengan fungsi lain seperti SUM, SUMPRODUCT, dan SUBSTITUTE, rumus ini dapat menangani tugas yang jauh lebih kompleks. Lebih lanjut dalam tutorial ini, kita akan melihat lebih dekat beberapa rumus dasar dan lanjutan untuk menghitung karakter di Excel.

Cara menghitung semua karakter dalam suatu rentang

Ketika datang untuk menghitung jumlah total karakter dalam beberapa sel, solusi langsung yang terlintas dalam pikiran adalah mendapatkan jumlah karakter untuk setiap sel, lalu menjumlahkan angka-angka itu:

=LEN(A2)+LEN(A3)+LEN(A4)

Atau

=SUM(LEN(A2),LEN(A3),LEN(A4))

Rumus di atas mungkin berfungsi dengan baik untuk rentang kecil. Untuk menghitung total karakter dalam rentang yang lebih besar, sebaiknya kita membuat sesuatu yang lebih ringkas, misalnya fungsi SUMPRODUCT, yang mengalikan larik dan mengembalikan jumlah produk.

Berikut rumus Excel umum untuk menghitung karakter dalam suatu rentang:

Dan formula kehidupan nyata Anda mungkin terlihat mirip dengan ini:

=SUMPRODUCT(LEN(A1:A7))

Cara lain untuk menghitung karakter dalam rentang adalah dengan menggunakan fungsi LEN yang dikombinasikan dengan SUM:

=SUM(LEN(A1:A7))

Tidak seperti SUMPRODUCT, fungsi SUM tidak menghitung array secara default, dan Anda perlu menekan Ctrl + Shift + Enter untuk mengubahnya menjadi rumus array.

Seperti yang ditunjukkan pada tangkapan layar berikut, rumus SUM mengembalikan jumlah karakter total yang sama:

Cara kerja rumus hitungan karakter rentang ini

Ini adalah salah satu rumus paling mudah untuk menghitung karakter di Excel. Fungsi LEN menghitung panjang string untuk setiap sel dalam rentang yang ditentukan dan mengembalikannya sebagai larik angka. Dan kemudian, SUMPRODUCT atau SUM menambahkan angka-angka itu dan mengembalikan jumlah karakter total.

Dalam contoh di atas, larik 7 angka yang mewakili panjang string di sel A1 hingga A7 dijumlahkan:

Catatan Harap perhatikan bahwa fungsi LEN Excel menghitung secara mutlak semua karakter di setiap sel , termasuk huruf, angka, tanda baca, simbol khusus, dan semua spasi (di depan, di belakang dan spasi di antara kata-kata).

Cara menghitung karakter tertentu dalam sel

Terkadang, alih-alih menghitung semua karakter di dalam sel, Anda mungkin hanya perlu menghitung kemunculan huruf, angka, atau simbol khusus tertentu.

Untuk menghitung berapa kali karakter tertentu muncul dalam sel, gunakan fungsi LEN bersama dengan SUBSTITUTE:

Untuk lebih memahami rumus, perhatikan contoh berikut ini.

Misalkan, Anda memelihara database item yang dikirimkan, di mana setiap jenis item memiliki pengidentifikasi uniknya sendiri. Dan setiap sel berisi beberapa item yang dipisahkan oleh koma, spasi, atau pembatas lainnya. Tugasnya adalah menghitung berapa kali pengidentifikasi unik yang diberikan muncul di setiap sel.

Dengan mengasumsikan bahwa daftar item yang dikirimkan ada di kolom B (dimulai dari B2), dan kita menghitung jumlah kemunculan "A", rumusnya adalah sebagai berikut:

=LEN(B2)-LEN(SUBSTITUTE(B2, "A",""))

Cara kerja rumus hitungan karakter Excel ini

Untuk memahami logika rumus ini, mari kita uraikan ke dalam bagian-bagian yang lebih kecil:

• Pertama, Anda menghitung total panjang string di B2:

LEN(B2)

SUBSTITUTE(B2, "A","")

LEN(SUBSTITUTE(B2, "A",""))

Hasilnya, Anda mendapatkan jumlah karakter yang "dihapus", yang sama dengan jumlah total kemunculan karakter tersebut di dalam sel.

Alih-alih menentukan karakter yang ingin kamu hitung dalam rumus, kamu bisa mengetikkannya di suatu cell, lalu mereferensikan cell tersebut dalam rumus. Dengan cara ini, penggunamu akan bisa menghitung kemunculan karakter lain yang mereka masukkan dalam cell tersebut tanpa mengutak-atik rumusmu:

Catatan. SUBSTITUTE Excel adalah fungsi peka huruf besar-kecil, dan oleh karena itu rumus di atas juga peka huruf besar-kecil. Misalnya, pada tangkapan layar di atas, sel B3 berisi 3 kemunculan "A" - dua dalam huruf besar, dan satu dalam huruf kecil. Rumus hanya menghitung karakter huruf besar karena kami memberikan "A" ke fungsi SUBSTITUTE.

Rumus Excel yang tidak peka huruf besar-kecil untuk menghitung karakter tertentu dalam sel

Jika Anda memerlukan hitungan karakter yang tidak peka huruf besar-kecil, sematkan fungsi UPPER di dalam SUBSTITUTE untuk mengonversi karakter yang ditentukan menjadi huruf besar sebelum menjalankan substitusi. Dan, pastikan untuk memasukkan karakter huruf besar dalam rumus.

Misalnya, untuk menghitung item "A" dan "a" di sel B2, gunakan rumus ini:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), "A",""))

Cara lainnya adalah dengan menggunakan fungsi Substitute bersarang:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2, "A",""), "a","")

Seperti yang Anda lihat pada gambar di bawah ini, kedua rumus dengan sempurna menghitung huruf besar dan kecil dari karakter yang ditentukan:

Dalam beberapa kasus, Anda mungkin perlu menghitung banyak karakter berbeda dalam tabel, tetapi Anda mungkin tidak ingin memodifikasi rumus setiap kali. Dalam kasus ini, sarangkan satu fungsi Pengganti di dalam fungsi lainnya, ketikkan karakter yang ingin Anda hitung di beberapa sel (D1 dalam contoh ini), dan ubah nilai sel itu menjadi huruf besar dan huruf kecil dengan menggunakan fungsi UPPER dan LOWER:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))

Alternatifnya, ubah sel sumber dan sel yang berisi karakter ke huruf besar atau huruf kecil. Misalnya:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))

Keuntungan dari pendekatan ini adalah bahwa terlepas dari apakah karakter huruf besar atau huruf kecil yang dimasukkan dalam cell yang direferensikan, karakter rumus hitungan karakter case-insensitive akan mengembalikan hitungan yang benar:

Hitung kemunculan teks atau substring tertentu dalam sel

Jika Anda ingin menghitung berapa kali kombinasi karakter tertentu (yaitu teks tertentu, atau substring) muncul di sel tertentu, misalnya "A2" atau "SS", lalu bagi jumlah karakter yang dikembalikan oleh rumus di atas dengan panjang substring.

Peka huruf besar-kecil formula:

=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)

Tidak peka huruf besar-kecil formula:

=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)

Di mana B2 adalah sel yang berisi seluruh string teks, dan C1 adalah teks (substring) yang ingin Anda hitung.

Untuk penjelasan rinci dari rumus tersebut, silakan lihat Cara menghitung teks / kata tertentu dalam sel.

Cara menghitung karakter tertentu dalam suatu rentang

Sekarang setelah Anda mengetahui rumus Excel untuk menghitung karakter dalam sel, Anda mungkin ingin memperbaikinya lebih lanjut untuk mengetahui berapa kali karakter tertentu muncul dalam rentang. Untuk ini, kita akan mengambil rumus Excel LEN untuk menghitung karakter tertentu dalam sel yang dibahas pada contoh sebelumnya, dan memasukkannya ke dalam fungsi SUMPRODUCT yang dapat menangani array:

Dalam contoh ini, rumusnya mengambil bentuk berikut ini:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A",""))))

Dan inilah rumus lain untuk menghitung karakter dalam rentang Excel:

=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A",""))))

Dibandingkan dengan rumus pertama, perbedaan yang paling jelas adalah menggunakan SUM, bukan SUMPRODUCT. Perbedaan lainnya adalah bahwa rumus ini membutuhkan penekanan Ctrl + Shift + Enter karena tidak seperti SUMPRODUCT, yang dirancang untuk memproses array, SUM dapat menangani array hanya jika digunakan dalam rumus rumus larik .

Jika kamu tidak ingin meng-hardcode karakter dalam rumusnya, kamu tentu saja bisa mengetikkannya di suatu cell, misalnya D1, dan mereferensikan cell tersebut dalam rumus jumlah karaktermu:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,""))))

Catatan. Dalam situasi ketika Anda menghitung kemunculan dari suatu substring dalam suatu rentang (misalnya, perintah yang dimulai dengan "KK" atau "AA"), Anda perlu membagi jumlah karakter dengan panjang substring, jika tidak, setiap karakter dalam substring akan dihitung satu per satu:

=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))

Cara kerja rumus penghitungan karakter ini

Seperti yang mungkin Anda ingat, fungsi SUBSTITUTE digunakan untuk mengganti semua kemunculan karakter yang ditentukan ("A" dalam contoh ini) dengan string teks kosong ("").

Kemudian, kami menyediakan string teks yang dikembalikan oleh SUBSTITUTE ke fungsi Excel LEN sehingga menghitung panjang string tanpa A. Dan kemudian, kami mengurangi jumlah karakter tersebut dari total panjang string teks. Hasil dari kalkulasi ini adalah larik hitungan karakter, dengan satu hitungan karakter per sel.

Terakhir, SUMPRODUCT menjumlahkan angka-angka dalam larik dan mengembalikan jumlah total karakter yang ditentukan dalam rentang tersebut.

Rumus case-insensitive untuk menghitung karakter tertentu dalam suatu rentang

Anda sudah tahu bahwa SUBSTITUTE adalah fungsi peka huruf besar-kecil, yang membuat rumus Excel kita untuk hitungan karakter peka huruf besar-kecil juga.

Untuk membuat rumus mengabaikan huruf besar-kecil, ikuti pendekatan yang ditunjukkan pada contoh sebelumnya: Rumus case-insensitive untuk menghitung karakter tertentu dalam sel.

Secara khusus, Anda dapat menggunakan salah satu rumus berikut untuk menghitung karakter tertentu dalam rentang mengabaikan kasus:

• Gunakan fungsi UPPER dan masukkan karakter dalam huruf besar:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8), "A","")))

• Gunakan fungsi SUBSTITUTE bersarang:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), "A",""), "a",""))))

• Gunakan fungsi UPPER dan LOWER, ketik karakter huruf besar atau huruf kecil di suatu cell, dan referensikan cell tersebut dalam rumusmu:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))

Tangkapan layar di bawah ini mendemonstrasikan formula terakhir dalam tindakan:

Tip. Untuk menghitung kemunculan suatu teks tertentu (substring) dalam suatu rentang, gunakan rumus yang ditunjukkan dalam Cara menghitung teks / kata tertentu dalam suatu rentang.

Ini adalah bagaimana Anda dapat menghitung karakter di Excel menggunakan fungsi LEN. Jika Anda ingin tahu cara menghitung kata daripada karakter individu, Anda akan menemukan beberapa rumus berguna di artikel kami berikutnya, harap pantau terus!

Sementara itu, kamu dapat mengunduh contoh buku kerja dengan rumus jumlah karakter yang dibahas dalam tutorial ini, dan melihat daftar sumber daya terkait di akhir halaman. Saya berterima kasih telah membaca dan berharap dapat bertemu denganmu segera!