سبق ٻڌائي ٿو ته ايڪسل ۾ اکرن کي ڪيئن ڳڻجي. توهان فارمولا سکندا ته ڪل اکرن جي ڳڻپ حاصل ڪرڻ لاءِ هڪ رينج ۾، ۽ صرف مخصوص اکرن کي سيل ۾ يا ڪيترن سيلن ۾ ڳڻيو.

اسان جي پوئين سبق کي متعارف ڪرايو ويو ايڪسل LEN فنڪشن، جيڪو ڳڻڻ جي اجازت ڏئي ٿو. سيل ۾ اکرن جو ڪل تعداد.

LEN فارمولا پنهنجي طور تي مفيد آهي، پر ٻين ڪمن جهڙوڪ SUM، SUMPRODUCT ۽ SUBSTITUTE سان رابطي ۾، اهو تمام گهڻو پيچيده ڪم سنڀالي سگهي ٿو. هن سبق ۾ اڳتي هلي، اسان ايڪسل ۾ اکرن کي ڳڻڻ لاءِ ڪجهه بنيادي ۽ جديد فارمولن تي تفصيلي نظر وجهنداسين.

هڪ حد ۾ سڀني اکرن کي ڪيئن ڳڻجي

جڏهن اهو اچي ٿو ته ڪيترن ئي سيلن ۾ اکرن جي مجموعي تعداد کي ڳڻڻ، هڪ فوري حل جيڪو ذهن ۾ اچي ٿو اهو آهي هر سيل لاء ڪردارن جي ڳڻپ حاصل ڪرڻ، ۽ پوء انهن نمبرن کي شامل ڪريو:

=LEN(A2)+LEN(A3)+LEN(A4)

يا

=SUM(LEN(A2),LEN(A3),LEN(A4))

مٿين فارمولن کي ٿوري حد تائين ٺيڪ ڪم ڪري سگھي ٿو. مجموعي اکرن کي وڏي رينج ۾ ڳڻڻ لاءِ، اسان کي بهتر آهي ته ڪجهه وڌيڪ ٺهڪندڙ، مثال طور. SUMPRODUCT فنڪشن، جيڪو صفن کي ضرب ڪري ٿو ۽ پراڊڪٽس جو مجموعو واپس ڪري ٿو.

هتي آهي عام ايڪسل فارمولا هڪ حد ۾ اکرن کي ڳڻڻ لاءِ:

۽ توھان جو حقيقي زندگيءَ جو فارمولا ھن جھڙو نظر اچي سگھي ٿو:

=SUMPRODUCT(LEN(A1:A7))

ھڪ رينج ۾ اکرن کي ڳڻڻ جو ٻيو طريقو آھي استعمال ڪرڻ LEN فنڪشن ۾SUM سان ميلاپ:

=SUM(LEN(A1:A7))

SUMPRODUCT جي برعڪس، SUM فنڪشن ڊفالٽ طور صفن کي ڳڻپ نٿو ڪري، ۽ توھان کي Ctrl + Shift + Enter کي دٻائڻو پوندو ان کي صف جي فارمولا ۾ تبديل ڪرڻ لاءِ.

جيئن هيٺ ڏنل اسڪرين شاٽ ۾ ڏيکاريو ويو آهي، SUM فارمولا ساڳيو ڪل اکر ڳڻپ ڏئي ٿو:

ڪيئن هي رينج ڪرڪٽر ڳڻپ فارمولا ڪم ڪري ٿو

هي Excel ۾ اکرن کي ڳڻڻ لاءِ سڀ کان سولو فارمولن مان ھڪڙو آھي. LEN فنڪشن مخصوص رينج ۾ هر سيل جي اسٽرنگ جي ڊيگهه کي حساب ڪري ٿو ۽ انهن کي انگن جي صف طور واپس ڪري ٿو. ۽ پوءِ، SUMPRODUCT يا SUM انهن انگن کي شامل ڪري ٿو ۽ ڪل اکر جي ڳڻپ واپس ڪري ٿو.

مٿين مثال ۾، 7 انگن جو هڪ مجموعو جيڪو سيل A1 کان A7 ۾ تارن جي ڊگھائي جي نمائندگي ڪري ٿو خلاصو:

نوٽ. مهرباني ڪري ڌيان ڏيو ته Excel LEN فنڪشن بلڪل ڳڻپ ڪري ٿو هر سيل ۾ سڀني اکرن کي ، بشمول اکر، انگ، اوقاف جا نشان، خاص علامتون، ۽ سڀ اسپيس (اڳوڻي، پيچيدگي ۽ لفظن جي وچ ۾ اسپيس).

سيل ۾ مخصوص اکرن کي ڪيئن ڳڻجي

ڪڏهن ڪڏهن، سيل جي اندر سڀني اکرن کي ڳڻڻ بدران، توهان کي صرف هڪ مخصوص اکر، انگ، يا خاص علامت جا واقعا ڳڻڻ گهرجن.

سيل ۾ ڏنل ڪردار جي ظاهر ٿيڻ جي تعداد کي ڳڻڻ لاءِ، SUBSTITUTE سان گڏ LEN فنڪشن استعمال ڪريو:

فارمولا کي بھتر سمجھڻ لاءِ، ھيٺين مثال تي غور ڪريو.

فرض ڪريو، توھان ڊيليور ٿيل شين جو ڊيٽابيس برقرار رکون ٿا، جتي ھر شيءِ جي قسم جو پنھنجو ھڪڙو منفرد آھي. سڃاڻپ ڪندڙ. ۽ هر سيل ۾ ڪاما، اسپيس، يا ڪنهن ٻئي ڊيليميٽر سان الڳ ڪيل ڪيتريون ئي شيون شامل آهن. اهو ڪم ڳڻڻ آهي ته هر سيل ۾ هڪ منفرد سڃاڻپ ڪندڙ ڪيترا ڀيرا ظاهر ٿئي ٿو.

فرض ڪيو ته ترسيل شين جي فهرست ڪالمن B ۾ آهي (B2 جي شروعات ۾)، ۽ اسان "A" جي تعداد کي ڳڻائي رهيا آهيون. واقعن ۾، فارمولا هن ريت آهي:

=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))

ڪيئن هي ايڪسل ڪردار ڳڻڻ وارو فارمولا ڪم ڪندو آهي

فارمولا جي منطق کي سمجهڻ لاءِ، اچو ته ان کي ننڍن حصن ۾ ورهايو:

• پهريون، توهان مجموعي اسٽرنگ جي ڊيگهه کي B2 ۾ ڳڻيو:

LEN(B2)

SUBSTITUTE(B2,"A","")

LEN(SUBSTITUTE(B2,"A",""))

ان جي نتيجي ۾، توهان کي "هٽايو" اکرن جي ڳڻپ ملي ٿي، جيڪا سيل ۾ انهن ڪردارن جي مجموعي تعداد جي برابر آهي.

جنهن ڪردار کي توهان ڳڻڻ چاهيو ٿا ان جي وضاحت ڪرڻ بدران. هڪ فارمولا، توهان ان کي ڪجهه سيل ۾ ٽائيپ ڪري سگهو ٿا، ۽ پوء انهي سيل کي فارمولا ۾ حوالي ڪري سگهو ٿا. هن طريقي سان، توهان جي صارفينڪنهن ٻئي ڪردار جي واقعن کي ڳڻڻ جي قابل ٿي ويندا جيڪي اهي توهان جي فارمولا سان ڇڪتاڻ جي بغير انهي سيل ۾ داخل ڪن ٿا:

نوٽ. Excel جو SUBSTITUTE هڪ ڪيس-حساس فعل آهي، ۽ تنهن ڪري مٿي ڏنل فارمولا پڻ ڪيس-حساس آهي. مثال طور، مٿي ڏنل اسڪرين شاٽ ۾، سيل B3 ۾ "A" جا 3 واقعا شامل آهن - ٻه وڏي ۾، ۽ هڪ ننڍي ۾. فارمولا صرف وڏي اکرن کي ڳڻيو آهي ڇاڪاڻ ته اسان SUBSTITUTE فنڪشن کي "A" فراهم ڪيو آهي.

Case-insensitive Excel فارمولا سيل ۾ مخصوص اکرن کي ڳڻڻ لاءِ

جيڪڏهن توهان کي هڪ ڪيس-غير حساس ڪردار جي ڳڻپ جي ضرورت آهي، متبادل کي هلائڻ کان اڳ مخصوص اکر کي اپر اکر ۾ تبديل ڪرڻ لاءِ SUBSTITUTE اندر UPPER فنڪشن کي شامل ڪريو. ۽، فارمولا ۾ وڏي اکر کي ضرور داخل ڪريو.

مثال طور، سيل B2 ۾ "A" ۽ "a" شيون ڳڻڻ لاءِ، ھي فارمولا استعمال ڪريو:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))

ٻيو طريقو استعمال ڪرڻ آهي nested Substitute functions:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")

جيئن ته توهان هيٺ ڏنل اسڪرين شاٽ ۾ ڏسي سگهو ٿا، ٻنهي فارمولين کي بي عيب انداز ۾ ڳڻيو وڃي ٿو اپر ڪيز ۽ لوئر ڪيس جي واقعن کي مخصوص ڪيل ڪردار جي:

ڪجهه حالتن ۾، توهان کي ٽيبل ۾ ڪيترن ئي مختلف اکرن کي ڳڻڻ جي ضرورت پوندي، پر توهان هر ڀيري فارمولا تبديل ڪرڻ نٿا چاهيو. انهي صورت ۾، هڪ ٻئي جي اندر اندر هڪ متبادل فنڪشن، جيڪو ڪردار توهان کي ڪجهه سيل ۾ ڳڻڻ چاهيو ٿا ان کي ٽائيپ ڪريو (هن مثال ۾ D1)، ۽ ان سيل جي قيمت کي اپر ڪيز ۾ تبديل ڪريو ۽UPPER ۽ LOWER ڪمن کي استعمال ڪندي لوئر ڪيس:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))

متبادل طور، ٻئي ماخذ سيل ۽ سيل کي تبديل ڪريو جنهن ۾ ڪردار هجي يا ته اپر ڪيز يا لوئر ڪيز ۾. مثال طور:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))

هن طريقي جو فائدو اهو آهي ته ڇا اپر ڪيس يا لوئر ڪيس اکر ريفرنس ٿيل سيل ۾ انپٽ آهي، توهان جو ڪيس غير حساس ڪردار جي ڳڻپ جو فارمولا صحيح ڳڻپ واپس آڻيندو:

جيڪڏهن توهان ڳڻڻ چاهيو ته ڪيترا ڀيرا اکرن جو مخصوص ميلاپ (يعني مخصوص متن، يا ذيلي اسٽرينگ) ڏنل سيل ۾ ظاهر ٿئي ٿو، مثال طور. "A2" يا "SS"، پوءِ مٿي ڏنل فارمولن جي موٽ ۾ ڏنل اکرن جي تعداد کي ذيلي اسٽرنگ جي ڊيگهه سان ورهايو.

ڪيس-حساس فارمولا:

=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)

ڪيس غير حساس فارمولا:

=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)

جتي B2 سيل آهي جنهن ۾ پوري ٽيڪسٽ اسٽرنگ آهي، ۽ C1 آهي ٽيڪسٽ (سبسٽرنگ) توهان ڳڻڻ چاھيو ٿا.

فارمولا جي تفصيلي وضاحت لاءِ، مھرباني ڪري ڏسو ته ڪيئن ڳڻجي مخصوص متن/لفظن کي سيل ۾.

ڪيئن ڳڻجي مخصوص هڪ حد ۾ اکر

هاڻي جڏهن توهان ڄاڻو ٿا هڪ ايڪسل فارمولا هڪ سيل ۾ اکرن کي ڳڻڻ لاءِ، توهان شايد ان کي وڌيڪ بهتر ڪرڻ چاهيو ٿا ته اهو معلوم ڪرڻ لاءِ ته ڪي خاص ڪردار ڪيترا دفعا حد ۾ ظاهر ٿين ٿا. ان لاءِ، اسان ايڪسل LEN فارمولا کڻنداسين ته بحث ڪيل سيل ۾ مخصوص چار کي ڳڻڻ لاءِپوئين مثال ۾، ۽ ان کي اندر رکو SUMPRODUCT فنڪشن جيڪو صفن کي سنڀالي سگھي ٿو:

هن مثال ۾، فارمولا هيٺ ڏنل شڪل وٺي ٿو:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

24>

۽ هتي ڳڻڻ لاءِ هڪ ٻيو فارمولا آهي اکرن ۾ ايڪسل جي حد:

=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

پهرين فارمولي جي مقابلي ۾، سڀ کان واضح فرق SUM استعمال ڪرڻ آهي SUMPRODUCT جي بدران. ٻيو فرق اهو آهي ته ان لاءِ Ctrl + Shift + Enter کي دٻائڻ جي ضرورت آهي ڇو ته SUMPRODUCT جي برعڪس، جيڪا arrays کي پروسيس ڪرڻ لاءِ ٺاهي وئي آهي، SUM صرف arrays کي سنڀالي سگهي ٿي جڏهن هڪ array فارمولا ۾ استعمال ڪيو وڃي.

جيڪڏهن توهان نٿا ڪريو فارمولا ۾ ڪردار کي هارڊ ڪوڊ ڪرڻ نٿا چاهيو، توهان يقيناً ان کي ڪجهه سيل ۾ ٽائيپ ڪري سگهو ٿا، چئو D1، ۽ ان سيل کي پنهنجي ڪردار جي ڳڻپ واري فارمولا ۾ حوالو ڏيو:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))

نوٽ. حالتن ۾ جڏهن توهان هڪ مخصوص سبسٽرنگ جي واقعن کي هڪ حد ۾ ڳڻيو ٿا (مثال طور آرڊر "KK" يا "AA" سان شروع ٿين ٿا)، توهان کي ضرورت آهي ته ڪردار جي ڳڻپ کي ذيلي اسٽرنگ جي ڊيگهه سان ورهايو وڃي، ٻي صورت ۾ هر ڪردار ذيلي اسٽرنگ کي انفرادي طور شمار ڪيو ويندو. مثال طور:

=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))

هي ڪردار ڳڻڻ وارو فارمولا ڪيئن ڪم ڪندو آهي

جيئن توهان کي ياد هوندو، SUBSTITUTE فنڪشن استعمال ڪيو ويندو آهي سڀني واقعن کي مٽائڻ لاءِ مخصوص ڪيل ڪردار ("اي" هن مثال ۾ ) هڪ خالي ٽيڪسٽ اسٽرنگ سان ("").

پوءِ، اسان SUBSTITUTE پاران واپس ڪيل ٽيڪسٽ اسٽرنگ کي ايڪسل LEN کي فراهم ڪريون ٿا.فنڪشن ته جيئن اهو A کان سواءِ اسٽرنگ جي ڊيگهه کي ڳڻائي. ۽ پوء، اسان متن جي تار جي ڪل ڊگھائي مان ان ڪردار جي ڳڻپ کي گھٽائينداسين. انهن حسابن جو نتيجو آهي ڪردارن جي ڳڻپ جو هڪ صف، هڪ اکر جي ڳڻپ في سيل سان.

آخرڪار، SUMPRODUCT صف ۾ انگن جو مجموعو ڪري ٿو ۽ رينج ۾ مخصوص ڪيل اکر جي ڪل ڳڻپ ڏي ٿو.

مخصوص اکرن کي رينج ۾ ڳڻڻ لاءِ هڪ ڪيس-غير حساس فارمولا

توهان پهريان ئي ڄاڻو ٿا ته SUBSTITUTE هڪ ڪيس-حساس فنڪشن آهي، جيڪو اسان جي ايڪسل فارمولا کي ڪردار جي ڳڻپ لاءِ پڻ ڪيس-حساس ڪري ٿو.

فارمولا کي نظر انداز ڪرڻ جي صورت ۾، پوئين مثال ۾ ڏيکاريل طريقن تي عمل ڪريو: سيل ۾ مخصوص اکرن کي ڳڻڻ لاءِ Case-insensitive فارمولا.

خاص طور تي، توھان ھيٺ ڏنل فارمولن مان ھڪڙو استعمال ڪري سگھو ٿا ڳڻڻ لاءِ مخصوص اکر هڪ حد ۾ نظر انداز ڪرڻ واري صورت ۾:

• UPPER فنڪشن استعمال ڪريو ۽ هڪ اکر اپر ڪيز ۾ داخل ڪريو:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A","")))

• استعمال ڪريو NESTED SUBSTITUTE افعال:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a","")))

• UPPER ۽ LOWER فنڪشن استعمال ڪريو، ٽائيپ ڪريو يا ته اپر ڪيس يا لوئر ڪيز چار ڪي سيل ۾، ۽ ان سيل کي پنھنجي فارمولا ۾ حوالو ڏيو:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))

هيٺ ڏنل اسڪرين شاٽ عمل ۾ آخري فارمولا ڏيکاري ٿو:

هياهو آهي ته توهان LEN فنڪشن استعمال ڪندي ايڪسل ۾ اکرن کي ڪيئن ڳڻائي سگهو ٿا. جيڪڏھن توھان ڄاڻڻ چاھيو ٿا ته لفظن جي ڳڻپ ڪيئن ڪجي انفرادي اکرن جي بجاءِ، توھان کي اسان جي ايندڙ مضمون ۾ ڪجھ ڪارآمد فارمولي ملندا، مھرباني ڪري ڏسندا رھو!

ان وقت ۾، توھان ڊائون لوڊ ڪري سگھو ٿا ھڪڙي نموني ڪم بڪ بڪ اکرن جي ڳڻپ واري فارمولا سان. هن سبق ۾ بحث ڪيو ويو، ۽ صفحي جي آخر ۾ لاڳاپيل وسيلن جي هڪ فهرست چيڪ ڪريو. مان توهان جي پڙهڻ لاءِ مهرباني ڪريان ٿو ۽ توهان کي جلد ڏسڻ جي اميد آهي!