எக்செல் இல் எழுத்துகளை எப்படி எண்ணுவது என்பதை டுடோரியல் விளக்குகிறது. ஒரு வரம்பில் மொத்த எழுத்து எண்ணிக்கையைப் பெறுவதற்கான சூத்திரங்களைக் கற்றுக்கொள்வீர்கள், மேலும் ஒரு கலத்தில் அல்லது பல கலங்களில் குறிப்பிட்ட எழுத்துக்களை மட்டுமே எண்ணுவீர்கள்.

எங்கள் முந்தைய பயிற்சியானது Excel LEN செயல்பாட்டை அறிமுகப்படுத்தியது, இது ஒரு கலத்தில் உள்ள மொத்த எழுத்துகளின் எண்ணிக்கை.

LEN சூத்திரம் தானே பயனுள்ளதாக இருக்கும், ஆனால் SUM, SUMPRODUCT மற்றும் SUBSTITUTE போன்ற பிற செயல்பாடுகளுடன் தொடர்பு கொண்டு, இது மிகவும் சிக்கலான பணிகளைக் கையாளும். இந்த டுடோரியலில் மேலும், எக்செல் இல் உள்ள எழுத்துக்களைக் கணக்கிடுவதற்கான சில அடிப்படை மற்றும் மேம்பட்ட சூத்திரங்களை நாம் கூர்ந்து கவனிக்கப் போகிறோம்.

ஒரு வரம்பில் உள்ள அனைத்து எழுத்துகளையும் எப்படி எண்ணுவது

பல கலங்களில் உள்ள மொத்த எழுத்துகளின் எண்ணிக்கையை எண்ணும் போது, ​​உடனடியாக நினைவுக்கு வரும் தீர்வு, ஒவ்வொரு கலத்திற்கும் எழுத்து எண்ணிக்கையைப் பெறுவது, பின்னர் அந்த எண்களைக் கூட்டுவது:

=LEN(A2)+LEN(A3)+LEN(A4)

அல்லது

=SUM(LEN(A2),LEN(A3),LEN(A4))

மேலே உள்ள சூத்திரங்கள் சிறிய வரம்பிற்கு நன்றாக வேலை செய்யக்கூடும். ஒரு பெரிய வரம்பில் மொத்த எழுத்துக்களை கணக்கிட, நாங்கள் மிகவும் சிறிய ஒன்றைக் கொண்டு வருவோம், எ.கா. SUMPRODUCT செயல்பாடு, இது வரிசைகளை பெருக்கி, தயாரிப்புகளின் கூட்டுத்தொகையை வழங்குகிறது.

வரம்பில் உள்ள எழுத்துகளை கணக்கிடுவதற்கான பொதுவான எக்செல் சூத்திரம் இதோ:

உங்கள் நிஜ வாழ்க்கை சூத்திரம் இதைப் போலவே தோன்றலாம்:

=SUMPRODUCT(LEN(A1:A7))

ஒரு வரம்பில் உள்ள எழுத்துக்களைக் கணக்கிடுவதற்கான மற்றொரு வழி LEN செயல்பாடுSUM உடன் சேர்க்கை:

=SUM(LEN(A1:A7))

SUMPRODUCT போலல்லாமல், SUM செயல்பாடு வரிசைகளை முன்னிருப்பாக கணக்கிடாது, மேலும் அதை வரிசை சூத்திரமாக மாற்ற Ctrl + Shift + Enter ஐ அழுத்த வேண்டும்.

பின்வரும் ஸ்கிரீன்ஷாட்டில் காட்டப்பட்டுள்ளபடி, SUM சூத்திரம் அதே மொத்த எழுத்து எண்ணிக்கையை வழங்குகிறது:

இந்த வரம்பு எழுத்து எண்ணிக்கை சூத்திரம் எவ்வாறு செயல்படுகிறது

இது எக்செல் இல் எழுத்துகளை எண்ணுவதற்கான மிகவும் எளிமையான சூத்திரங்களில் ஒன்றாகும். LEN செயல்பாடு குறிப்பிட்ட வரம்பில் உள்ள ஒவ்வொரு கலத்திற்கும் சரத்தின் நீளத்தைக் கணக்கிட்டு அவற்றை எண்களின் வரிசையாக வழங்குகிறது. பின்னர், SUMPRODUCT அல்லது SUM அந்த எண்களைக் கூட்டி, மொத்த எழுத்து எண்ணிக்கையை வழங்கும்.

மேலே உள்ள எடுத்துக்காட்டில், A1 முதல் A7 வரையிலான கலங்களில் உள்ள சரங்களின் நீளத்தைக் குறிக்கும் 7 எண்களின் வரிசை சுருக்கப்பட்டுள்ளது:

குறிப்பு. எழுத்துகள், எண்கள், நிறுத்தற்குறிகள், சிறப்புக் குறியீடுகள் மற்றும் அனைத்து இடைவெளிகள் (முன்னணி, ட்ரைலிங் மற்றும் சொற்களுக்கு இடையே உள்ள இடைவெளிகள்) உட்பட, எக்செல் லென் செயல்பாடு முற்றிலும் ஒவ்வொரு கலத்திலும் உள்ள அனைத்து எழுத்துக்களையும் கணக்கிடுகிறது என்பதைக் கவனத்தில் கொள்ளவும்.

ஒரு கலத்தில் குறிப்பிட்ட எழுத்துகளை எப்படி எண்ணுவது

சில நேரங்களில், ஒரு கலத்தில் உள்ள அனைத்து எழுத்துக்களையும் எண்ணுவதற்குப் பதிலாக, குறிப்பிட்ட எழுத்து, எண் அல்லது சிறப்புக் குறியீட்டின் நிகழ்வுகளை மட்டும் எண்ண வேண்டியிருக்கும்.

ஒரு கலத்தில் கொடுக்கப்பட்ட எழுத்து எத்தனை முறை தோன்றும் என்பதைக் கணக்கிட, SUBSTITUTE உடன் LEN செயல்பாட்டைப் பயன்படுத்தவும்:

LEN(B2)

SUBSTITUTE(B2,"A","")

LEN(SUBSTITUTE(B2,"A",""))

இதன் விளைவாக, நீங்கள் "அகற்றப்பட்ட" எழுத்துகளின் எண்ணிக்கையைப் பெறுவீர்கள், இது கலத்தில் அந்த எழுத்து நிகழ்வுகளின் மொத்த எண்ணிக்கைக்கு சமம்.

நீங்கள் எண்ண விரும்பும் எழுத்தைக் குறிப்பிடுவதற்குப் பதிலாக. ஒரு சூத்திரம், நீங்கள் அதை சில கலத்தில் தட்டச்சு செய்யலாம், பின்னர் அந்த கலத்தை ஒரு சூத்திரத்தில் குறிப்பிடலாம். இந்த வழியில், உங்கள் பயனர்கள்உங்கள் சூத்திரத்தை சேதப்படுத்தாமல் அந்த கலத்தில் அவர்கள் உள்ளிடும் வேறு எந்த எழுத்துகளின் நிகழ்வுகளையும் கணக்கிட முடியும்:

குறிப்பு. எக்செல் இன் சப்ஸ்டிட்யூட் ஒரு கேஸ்-சென்சிட்டிவ் செயல்பாடு, எனவே மேலே உள்ள சூத்திரமும் கேஸ்-சென்சிட்டிவ் ஆகும். எடுத்துக்காட்டாக, மேலே உள்ள ஸ்கிரீன்ஷாட்டில், செல் B3 ஆனது "A" இன் 3 நிகழ்வுகளைக் கொண்டுள்ளது - இரண்டு பெரிய எழுத்துக்களிலும் ஒன்று சிறிய எழுத்திலும். SUBSTITUTE செயல்பாட்டிற்கு "A" ஐ வழங்கியதால் சூத்திரம் பெரிய எழுத்துகளை மட்டுமே கணக்கிடுகிறது.

ஒரு கலத்தில் குறிப்பிட்ட எழுத்துகளை எண்ணுவதற்கு கேஸ்-இன்சென்சிட்டிவ் எக்செல் ஃபார்முலா

உங்களுக்கு கேஸ்-இன்சென்சிட்டிவ் கேரக்டர் எண்ணிக்கை தேவைப்பட்டால், மாற்றீட்டை இயக்கும் முன் குறிப்பிட்ட எழுத்தை பெரிய எழுத்தாக மாற்ற UPPER செயல்பாட்டை SUBSTITUTE க்குள் உட்பொதிக்கவும். மேலும், சூத்திரத்தில் பெரிய எழுத்தை உள்ளிடுவதை உறுதிசெய்யவும்.

எடுத்துக்காட்டாக, செல் B2 இல் உள்ள "A" மற்றும் "a" உருப்படிகளை எண்ண, இந்த சூத்திரத்தைப் பயன்படுத்தவும்:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))

மற்றொரு வழி, உள்ளமைக்கப்பட்ட மாற்று செயல்பாடுகளைப் பயன்படுத்துவதாகும்:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")

கீழே உள்ள ஸ்கிரீன்ஷாட்டில் நீங்கள் பார்ப்பது போல், இரண்டு சூத்திரங்களும் குறிப்பிட்ட எழுத்தின் பெரிய எழுத்து மற்றும் சிறிய எழுத்து நிகழ்வுகளை பிழையின்றி கணக்கிடுகின்றன:

சில சமயங்களில், ஒரு அட்டவணையில் உள்ள பல்வேறு எழுத்துக்களை நீங்கள் எண்ண வேண்டியிருக்கலாம், ஆனால் ஒவ்வொரு முறையும் நீங்கள் சூத்திரத்தை மாற்ற விரும்பாமல் இருக்கலாம். இந்த வழக்கில், நெஸ்ட் ஒரு மாற்று செயல்பாட்டை மற்றொன்றுக்குள் வைத்து, சில கலத்தில் நீங்கள் எண்ண விரும்பும் எழுத்தை தட்டச்சு செய்து (இந்த எடுத்துக்காட்டில் D1), அந்த கலத்தின் மதிப்பை பெரிய எழுத்துக்கு மாற்றவும்.UPPER மற்றும் LOWER செயல்பாடுகளைப் பயன்படுத்தி சிற்றெழுத்து:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))

மாற்றாக, மூலக் கலம் மற்றும் எழுத்துகளைக் கொண்ட கலம் இரண்டையும் பெரிய எழுத்து அல்லது சிறிய எழுத்துக்கு மாற்றவும். எடுத்துக்காட்டாக:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))

இந்த அணுகுமுறையின் நன்மை என்னவென்றால், குறிப்பிடப்பட்ட கலத்தில் பெரிய எழுத்து அல்லது சிற்றெழுத்து உள்ளீடு செய்யப்பட்டுள்ளதா என்பதைப் பொருட்படுத்தாமல், உங்கள் கேஸ்-சென்சிட்டிவ் எழுத்து எண்ணிக்கை சூத்திரம் சரியான எண்ணிக்கையை வழங்கும்:

ஒரு கலத்தில் குறிப்பிட்ட உரை அல்லது துணைச்சரத்தின் நிகழ்வுகளை எண்ணுங்கள்

நீங்கள் எத்தனை முறை எண்ண வேண்டும் என்றால் குறிப்பிட்ட கலத்தில் (அதாவது குறிப்பிட்ட உரை, அல்லது சப்ஸ்ட்ரிங்) குறிப்பிட்ட கலவை தோன்றும், எ.கா. "A2" அல்லது "SS", பின்னர் மேலே உள்ள சூத்திரங்களால் வழங்கப்பட்ட எழுத்துகளின் எண்ணிக்கையை துணைச்சரத்தின் நீளத்தால் வகுக்கவும்.

Case-sensitive சூத்திரம்:

=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)

Case-insensitive சூத்திரம்:

=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)

இங்கு B2 என்பது முழு உரைச் சரத்தையும் உள்ளடக்கிய கலமாகும், மேலும் C1 என்பது உரை (துணைச்சரம்) ஆகும். எண்ண வேண்டும்.

சூத்திரத்தின் விரிவான விளக்கத்திற்கு, கலத்தில் குறிப்பிட்ட உரை / சொற்களை எப்படி எண்ணுவது என்பதைப் பார்க்கவும்.

குறிப்பிட்டதை எப்படி எண்ணுவது வரம்பில் உள்ள எழுத்து(கள்)

இப்போது கலத்தில் உள்ள எழுத்துகளை எண்ணுவதற்கான எக்செல் சூத்திரம் உங்களுக்குத் தெரியும், ஒரு குறிப்பிட்ட எழுத்து வரம்பில் எத்தனை முறை தோன்றும் என்பதைக் கண்டறிய அதை மேலும் மேம்படுத்த விரும்பலாம். இதற்கு, எக்செல் லென் ஃபார்முலாவைப் பயன்படுத்தி, விவாதிக்கப்பட்ட கலத்தில் ஒரு குறிப்பிட்ட எழுத்தை எண்ணுவோம்முந்தைய எடுத்துக்காட்டில், அணிவரிசைகளைக் கையாளக்கூடிய SUMPRODUCT செயல்பாட்டிற்குள் வைக்கவும்:

இந்த எடுத்துக்காட்டில், சூத்திரம் பின்வரும் வடிவத்தை எடுக்கும்:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

மேலும் எண்ணுவதற்கு மற்றொரு சூத்திரம் உள்ளது எக்செல் வரம்பில் உள்ள எழுத்துக்கள்:

=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

முதல் சூத்திரத்துடன் ஒப்பிடுகையில், SUMPRODUCT க்குப் பதிலாக SUM ஐப் பயன்படுத்துவது மிகவும் வெளிப்படையான வேறுபாடு. மற்றொரு வித்தியாசம் என்னவென்றால், இதற்கு Ctrl + Shift + Enter ஐ அழுத்த வேண்டும், ஏனெனில் SUMPRODUCT ஆனது வரிசைகளைச் செயலாக்க வடிவமைக்கப்பட்டுள்ளது போலல்லாமல், SUM ஆனது வரிசை சூத்திரத்தில் பயன்படுத்தும் போது மட்டுமே வரிசைகளைக் கையாள முடியும்.

நீங்கள் செய்யாவிட்டால் 'சூத்திரத்தில் உள்ள எழுத்தை ஹார்ட்கோட் செய்ய விரும்பவில்லை, நீங்கள் நிச்சயமாக அதை ஏதேனும் ஒரு கலத்தில் தட்டச்சு செய்து, D1 என்று சொல்லலாம், மேலும் அந்த கலத்தை உங்கள் எழுத்து எண்ணிக்கை சூத்திரத்தில் குறிப்பிடலாம்:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))

குறிப்பு. ஒரு குறிப்பிட்ட சப்ஸ்ட்ரிங் நிகழ்வுகளை வரம்பில் கணக்கிடும் போது (எ.கா. "KK" அல்லது "AA" உடன் தொடங்கும் ஆர்டர்கள்), நீங்கள் எழுத்துகளின் எண்ணிக்கையை சப்ஸ்ட்ரிங் நீளத்தால் வகுக்க வேண்டும், இல்லையெனில் ஒவ்வொரு எழுத்துக்குறியிலும் சப்ஸ்ட்ரிங் தனித்தனியாக கணக்கிடப்படும். எடுத்துக்காட்டாக:

=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))

இந்த எழுத்து எண்ணும் சூத்திரம் எவ்வாறு செயல்படுகிறது

நீங்கள் நினைவில் வைத்திருப்பது போல், குறிப்பிட்ட எழுத்தின் அனைத்து நிகழ்வுகளையும் மாற்ற SUBSTITUTE செயல்பாடு பயன்படுத்தப்படுகிறது (இந்த எடுத்துக்காட்டில் "A" ) வெற்று உரைச் சரத்துடன் ("").

பின்னர், எக்செல் லெனுக்கு மாற்றாகத் திரும்பிய உரைச் சரத்தை வழங்குகிறோம்.இது A இல்லாமல் சரத்தின் நீளத்தைக் கணக்கிடும் வகையில் செயல்படும். பின்னர், உரை சரத்தின் மொத்த நீளத்திலிருந்து அந்த எழுத்து எண்ணிக்கையைக் கழிப்போம். இந்தக் கணக்கீடுகளின் விளைவாக, ஒரு கலத்திற்கு ஒரு எழுத்து எண்ணிக்கையுடன், எழுத்து எண்ணிக்கைகளின் வரிசையாகும்.

இறுதியாக, SUMPRODUCT ஆனது அணிவரிசையில் உள்ள எண்களைத் தொகுத்து, வரம்பில் உள்ள குறிப்பிட்ட எழுத்தின் மொத்த எண்ணிக்கையை வழங்குகிறது.

குறிப்பிட்ட எழுத்துக்குறிகளை வரம்பில் எண்ணுவதற்கான கேஸ்-இன்சென்சிட்டிவ் ஃபார்முலா

உங்களுக்கு ஏற்கனவே தெரியும், SUBSTITUTE என்பது ஒரு கேஸ்-சென்சிட்டிவ் ஃபங்ஷன், இது எக்செல் ஃபார்முலாவை கேஸ்-சென்சிட்டிவ் ஆகவும் செய்கிறது.

சூத்திரத்தை புறக்கணிக்க, முந்தைய எடுத்துக்காட்டில் காட்டப்பட்டுள்ள அணுகுமுறைகளைப் பின்பற்றவும்: ஒரு கலத்தில் குறிப்பிட்ட எழுத்துகளை எண்ணுவதற்கு கேஸ்-சென்சிட்டிவ் ஃபார்முலா.

குறிப்பாக, பின்வரும் சூத்திரங்களில் ஒன்றை எண்ணிப் பயன்படுத்தலாம் ஒரு வரம்பில் உள்ள குறிப்பிட்ட எழுத்துக்கள் புறக்கணிக்கப்படுகின்றன:

• UPPER செயல்பாட்டைப் பயன்படுத்தவும் மற்றும் பெரிய எழுத்தில் ஒரு எழுத்தை உள்ளிடவும்:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A","")))

• உள்ளமைக்கப்பட்ட SUBSTITUTE செயல்பாடுகளைப் பயன்படுத்தவும்:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a","")))

• மேல் மற்றும் குறைந்த செயல்பாடுகளைப் பயன்படுத்தவும், சில கலத்தில் பெரிய எழுத்து அல்லது சிற்றெழுத்து எழுத்தை தட்டச்சு செய்து, அந்த கலத்தை உங்கள் சூத்திரத்தில் குறிப்பிடவும்:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))

  <17

கீழே உள்ள ஸ்கிரீன் ஷாட் கடைசியாக செயல்பாட்டில் உள்ள சூத்திரத்தைக் காட்டுகிறது:

உதவிக்குறிப்பு. ஒரு வரம்பில் குறிப்பிட்ட உரை (சப்ஸ்ட்ரிங்) நிகழ்வுகளைக் கணக்கிட, வரம்பில் குறிப்பிட்ட உரை / சொற்களை எப்படி எண்ணுவது என்பதில் காட்டப்பட்டுள்ள சூத்திரத்தைப் பயன்படுத்தவும்.

இதுலென் செயல்பாட்டைப் பயன்படுத்தி எக்செல் இல் உள்ள எழுத்துக்களை எப்படி எண்ணலாம். தனிப்பட்ட எழுத்துக்களைக் காட்டிலும் சொற்களை எப்படி எண்ணுவது என்பதை நீங்கள் அறிய விரும்பினால், எங்கள் அடுத்த கட்டுரையில் சில பயனுள்ள சூத்திரங்களைக் காண்பீர்கள், தயவுசெய்து காத்திருங்கள்!

இதற்கிடையில், எழுத்து எண்ணிக்கை சூத்திரத்துடன் மாதிரி பணிப்புத்தகங்களை நீங்கள் பதிவிறக்கலாம். இந்த டுடோரியலில் விவாதிக்கப்பட்டது, மேலும் பக்கத்தின் முடிவில் தொடர்புடைய ஆதாரங்களின் பட்டியலைப் பார்க்கவும். படித்ததற்கு நன்றி மற்றும் விரைவில் உங்களை சந்திப்பேன் என்று நம்புகிறேன்!