Το σεμινάριο εξηγεί πώς να μετράτε χαρακτήρες στο Excel. Θα μάθετε τους τύπους για να λαμβάνετε το συνολικό αριθμό χαρακτήρων σε μια περιοχή και να μετράτε μόνο συγκεκριμένους χαρακτήρες σε ένα κελί ή σε πολλά κελιά.

Το προηγούμενο σεμινάριό μας εισήγαγε τη συνάρτηση LEN του Excel, η οποία επιτρέπει την καταμέτρηση του συνολικού αριθμού των χαρακτήρων σε ένα κελί.

Ο τύπος LEN είναι χρήσιμος από μόνος του, αλλά σε συνδυασμό με άλλες συναρτήσεις, όπως οι SUM, SUMPRODUCT και SUBSTITUTE, μπορεί να χειριστεί πολύ πιο σύνθετες εργασίες. Στη συνέχεια αυτού του σεμιναρίου, θα εξετάσουμε από κοντά μερικούς βασικούς και προηγμένους τύπους για την καταμέτρηση χαρακτήρων στο Excel.

Πώς να μετρήσετε όλους τους χαρακτήρες σε μια περιοχή

Όταν πρόκειται για την καταμέτρηση ενός συνολικού αριθμού χαρακτήρων σε διάφορα κελιά, μια άμεση λύση που έρχεται στο μυαλό σας είναι να λάβετε τον αριθμό χαρακτήρων για κάθε κελί και στη συνέχεια να αθροίσετε αυτούς τους αριθμούς:

=LEN(A2)+LEN(A3)+LEN(A4)

Ή

=SUM(LEN(A2),LEN(A3),LEN(A4))

Οι παραπάνω τύποι μπορεί να λειτουργούν καλά για ένα μικρό εύρος. Για να μετρήσουμε τους συνολικούς χαρακτήρες σε ένα μεγαλύτερο εύρος, θα πρέπει να βρούμε κάτι πιο συμπαγές, π.χ. τη συνάρτηση SUMPRODUCT, η οποία πολλαπλασιάζει τους πίνακες και επιστρέφει το άθροισμα των προϊόντων.

Ακολουθεί ο γενικός τύπος του Excel για την καταμέτρηση χαρακτήρων σε μια περιοχή:

Και η φόρμουλα της πραγματικής σας ζωής μπορεί να μοιάζει με αυτή:

=SUMPRODUCT(LEN(A1:A7))

Ένας άλλος τρόπος για να μετρήσετε χαρακτήρες σε ένα εύρος είναι να χρησιμοποιήσετε τη συνάρτηση LEN σε συνδυασμό με το SUM:

=SUM(LEN(A1:A7))

Σε αντίθεση με τη SUMPRODUCT, η συνάρτηση SUM δεν υπολογίζει πίνακες από προεπιλογή και πρέπει να πατήσετε Ctrl + Shift + Enter για να τη μετατρέψετε σε τύπο πίνακα.

Όπως φαίνεται στο ακόλουθο στιγμιότυπο οθόνης, ο τύπος SUM επιστρέφει τον ίδιο συνολικό αριθμό χαρακτήρων:

Πώς λειτουργεί αυτός ο τύπος καταμέτρησης χαρακτήρων εύρους

Πρόκειται για έναν από τους πιο απλούς τύπους για την καταμέτρηση χαρακτήρων στο Excel. Η συνάρτηση LEN υπολογίζει το μήκος συμβολοσειράς για κάθε κελί στην καθορισμένη περιοχή και τα επιστρέφει ως πίνακα αριθμών. Και στη συνέχεια, η SUMPRODUCT ή SUM προσθέτει αυτούς τους αριθμούς και επιστρέφει το συνολικό αριθμό χαρακτήρων.

Στο παραπάνω παράδειγμα, αθροίζεται ένας πίνακας 7 αριθμών που αντιπροσωπεύουν τα μήκη των συμβολοσειρών στα κελιά Α1 έως Α7:

Σημείωση. Προσέξτε ότι η συνάρτηση LEN του Excel μετράει απολύτως όλοι οι χαρακτήρες σε κάθε κελί , συμπεριλαμβανομένων των γραμμάτων, των αριθμών, των σημείων στίξης, των ειδικών συμβόλων και όλων των διαστημάτων (αρχικών, τελικών και διαστημάτων μεταξύ των λέξεων).

Πώς να μετρήσετε συγκεκριμένους χαρακτήρες σε ένα κελί

Μερικές φορές, αντί να μετράτε όλους τους χαρακτήρες σε ένα κελί, μπορεί να χρειαστεί να μετρήσετε μόνο τις εμφανίσεις ενός συγκεκριμένου γράμματος, αριθμού ή ειδικού συμβόλου.

Για να μετρήσετε τον αριθμό των φορών που εμφανίζεται ένας συγκεκριμένος χαρακτήρας σε ένα κελί, χρησιμοποιήστε τη συνάρτηση LEN μαζί με τη συνάρτηση SUBSTITUTE:

Για να κατανοήσετε καλύτερα τον τύπο, αναλογιστείτε το ακόλουθο παράδειγμα.

Ας υποθέσουμε ότι διατηρείτε μια βάση δεδομένων με παραδοτέα αντικείμενα, όπου κάθε τύπος αντικειμένου έχει το δικό του μοναδικό αναγνωριστικό. Και κάθε κελί περιέχει πολλά αντικείμενα που χωρίζονται με κόμμα, κενό ή οποιοδήποτε άλλο διαχωριστικό. Το καθήκον είναι να μετρήσετε πόσες φορές εμφανίζεται ένα συγκεκριμένο μοναδικό αναγνωριστικό σε κάθε κελί.

Αν υποθέσουμε ότι ο κατάλογος των παραδοτέων στοιχείων βρίσκεται στη στήλη Β (ξεκινώντας από το Β2) και μετράμε τον αριθμό των εμφανίσεων του "Α", ο τύπος έχει ως εξής:

=LEN(B2)-LEN(SUBSTITUTE(B2, "A",""))

Πώς λειτουργεί αυτός ο τύπος καταμέτρησης χαρακτήρων του Excel

Για να κατανοήσουμε τη λογική του τύπου, ας τον αναλύσουμε σε μικρότερα μέρη:

• Πρώτον, μετράτε το συνολικό μήκος της συμβολοσειράς σε Β2:

LEN(B2)

SUBSTITUTE(B2, "A","")

LEN(SUBSTITUTE(B2, "A",""))

Ως αποτέλεσμα, λαμβάνετε τον αριθμό των "αφαιρεθέντων" χαρακτήρων, ο οποίος ισούται με τον συνολικό αριθμό των εμφανίσεων του συγκεκριμένου χαρακτήρα στο κελί.

Αντί να καθορίσετε τον χαρακτήρα που θέλετε να μετρήσετε σε έναν τύπο, μπορείτε να τον πληκτρολογήσετε σε κάποιο κελί και, στη συνέχεια, να αναφερθείτε σε αυτό το κελί σε έναν τύπο. Με αυτόν τον τρόπο, οι χρήστες σας θα είναι σε θέση να μετρήσουν τις εμφανίσεις οποιουδήποτε άλλου χαρακτήρα που εισάγουν σε αυτό το κελί χωρίς να αλλοιώσουν τον τύπο σας:

Σημείωση. Η SUBSTITUTE του Excel είναι μια συνάρτηση που λαμβάνει υπόψη την πεζότητα, και επομένως ο παραπάνω τύπος λαμβάνει υπόψη την πεζότητα. Για παράδειγμα, στο παραπάνω στιγμιότυπο οθόνης, το κελί B3 περιέχει 3 εμφανίσεις του "A" - δύο σε κεφαλαία και μία σε πεζά. Ο τύπος έχει μετρήσει μόνο τους κεφαλαίους χαρακτήρες επειδή δώσαμε το "A" στη συνάρτηση SUBSTITUTE.

Τύπος Excel χωρίς ευαισθησία στην πεζότητα για την καταμέτρηση συγκεκριμένων χαρακτήρων σε ένα κελί

Εάν χρειάζεστε μια καταμέτρηση χαρακτήρων χωρίς ευαισθησία στη πεζότητα, ενσωματώστε τη συνάρτηση UPPER μέσα στο SUBSTITUTE για να μετατρέψετε τον καθορισμένο χαρακτήρα σε κεφαλαίο πριν εκτελέσετε την αντικατάσταση. Και, φροντίστε να εισαγάγετε τον κεφαλαίο χαρακτήρα στον τύπο.

Για παράδειγμα, για να μετρήσετε τα στοιχεία "A" και "a" στο κελί B2, χρησιμοποιήστε αυτόν τον τύπο:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), "A",""))

Ένας άλλος τρόπος είναι η χρήση ένθετων συναρτήσεων Substitute:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2, "A",""), "a","")

Όπως μπορείτε να δείτε στο παρακάτω στιγμιότυπο οθόνης, και οι δύο τύποι μετρούν άψογα τις περιπτώσεις εμφάνισης του καθορισμένου χαρακτήρα σε κεφαλαία και πεζά γράμματα:

Σε ορισμένες περιπτώσεις, μπορεί να χρειαστεί να μετρήσετε πολλούς διαφορετικούς χαρακτήρες σε έναν πίνακα, αλλά μπορεί να μην θέλετε να τροποποιείτε τον τύπο κάθε φορά. Σε αυτή την περίπτωση, φωλιάστε μια συνάρτηση Substitute μέσα σε μια άλλη, πληκτρολογήστε τον χαρακτήρα που θέλετε να μετρήσετε σε κάποιο κελί (D1 σε αυτό το παράδειγμα) και μετατρέψτε την τιμή αυτού του κελιού σε κεφαλαία και πεζά χρησιμοποιώντας τις συναρτήσεις UPPER και LOWER:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))

Εναλλακτικά, μετατρέψτε τόσο το αρχικό κελί όσο και το κελί που περιέχει τον χαρακτήρα είτε σε κεφαλαίο είτε σε πεζό. Για παράδειγμα:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))

Το πλεονέκτημα αυτής της προσέγγισης είναι ότι ανεξάρτητα από το αν ο κεφαλαίος ή ο πεζός χαρακτήρας εισάγεται στο κελί στο οποίο αναφέρεται, το τύπος απαρίθμησης χαρακτήρων χωρίς ευαισθησία στην πεζότητα θα επιστρέψει το σωστό αριθμό:

Μετρήστε τις εμφανίσεις συγκεκριμένου κειμένου ή υποσυνόλου σε ένα κελί

Αν θέλετε να μετρήσετε πόσες φορές ένα συγκεκριμένος συνδυασμός χαρακτήρων (δηλ. συγκεκριμένο κείμενο ή υποσέλιδο) εμφανίζεται σε ένα δεδομένο κελί, π.χ. "A2" ή "SS", τότε διαιρέστε τον αριθμό των χαρακτήρων που επιστρέφονται από τους παραπάνω τύπους με το μήκος του υποσυνόλου.

Ευαίσθητη ως προς την πεζότητα φόρμουλα:

=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)

Χωρίς ευαισθησία στην πεζότητα φόρμουλα:

=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)

Όπου B2 είναι το κελί που περιέχει ολόκληρη τη συμβολοσειρά κειμένου και C1 είναι το κείμενο (υποσυμβολοσειρά) που θέλετε να μετρήσετε.

Για την αναλυτική εξήγηση του τύπου, ανατρέξτε στην ενότητα Πώς να μετρήσετε συγκεκριμένο κείμενο/λέξεις σε ένα κελί.

Πώς να μετρήσετε συγκεκριμένους χαρακτήρες σε μια περιοχή

Τώρα που γνωρίζετε έναν τύπο του Excel για την καταμέτρηση χαρακτήρων σε ένα κελί, ίσως θελήσετε να τον βελτιώσετε περαιτέρω για να μάθετε πόσες φορές εμφανίζεται ένας συγκεκριμένος χαρακτήρας σε μια περιοχή. Για το σκοπό αυτό, θα πάρουμε τον τύπο LEN του Excel για την καταμέτρηση ενός συγκεκριμένου χαρακτήρα σε ένα κελί που συζητήθηκε στο προηγούμενο παράδειγμα και θα τον τοποθετήσουμε μέσα στη συνάρτηση SUMPRODUCT που μπορεί να χειριστεί πίνακες:

Σε αυτό το παράδειγμα, ο τύπος έχει την ακόλουθη μορφή:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

Και εδώ είναι ένας άλλος τύπος για να μετρήσετε τους χαρακτήρες στην περιοχή του Excel:

=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

Σε σύγκριση με τον πρώτο τύπο, η πιο προφανής διαφορά είναι η χρήση του SUM αντί του SUMPRODUCT. Μια άλλη διαφορά είναι ότι απαιτείται το πάτημα των πλήκτρων Ctrl + Shift + Enter, επειδή σε αντίθεση με το SUMPRODUCT, το οποίο έχει σχεδιαστεί για την επεξεργασία πινάκων, το SUM μπορεί να χειριστεί πίνακες μόνο όταν χρησιμοποιείται σε μια τύπος συστοιχίας .

Αν δεν θέλετε να καταχωρίσετε τον χαρακτήρα στον τύπο, μπορείτε φυσικά να τον πληκτρολογήσετε σε κάποιο κελί, π.χ. στο D1, και να αναφέρετε αυτό το κελί στον τύπο καταμέτρησης χαρακτήρων:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))

Σημείωση. Σε περιπτώσεις που μετράτε τις εμφανίσεις ενός συγκεκριμένου substring σε ένα εύρος (π.χ. εντολές που αρχίζουν με "KK" ή "AA"), πρέπει να διαιρέσετε τον αριθμό χαρακτήρων με το μήκος της υποσειράς, διαφορετικά κάθε χαρακτήρας στην υποσειρά θα μετρηθεί ξεχωριστά. Για παράδειγμα:

=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))

Πώς λειτουργεί αυτός ο τύπος μέτρησης χαρακτήρων

Όπως ίσως θυμάστε, η συνάρτηση SUBSTITUTE χρησιμοποιείται για την αντικατάσταση όλων των εμφανίσεων του καθορισμένου χαρακτήρα ("A" σε αυτό το παράδειγμα) με μια κενή συμβολοσειρά κειμένου ("").

Στη συνέχεια, παρέχουμε τη συμβολοσειρά κειμένου που επιστρέφεται από την SUBSTITUTE στη συνάρτηση LEN του Excel, ώστε να υπολογίσει το μήκος της συμβολοσειράς χωρίς τα Α. Και στη συνέχεια, αφαιρούμε αυτόν τον αριθμό χαρακτήρων από το συνολικό μήκος της συμβολοσειράς κειμένου. Το αποτέλεσμα αυτών των υπολογισμών είναι ένας πίνακας με αριθμούς χαρακτήρων, με έναν αριθμό χαρακτήρων ανά κελί.

Τέλος, η SUMPRODUCT αθροίζει τους αριθμούς στον πίνακα και επιστρέφει το συνολικό αριθμό του καθορισμένου χαρακτήρα στην περιοχή.

Ένας τύπος χωρίς ευαισθησία στη πεζότητα για την καταμέτρηση συγκεκριμένων χαρακτήρων σε ένα εύρος

Γνωρίζετε ήδη ότι η SUBSTITUTE είναι μια συνάρτηση με ευαισθησία στην πεζότητα, γεγονός που καθιστά τον τύπο του Excel για τον αριθμό χαρακτήρων επίσης ευαίσθητο στην πεζότητα.

Για να κάνετε τον τύπο να αγνοεί την πεζότητα, ακολουθήστε τις προσεγγίσεις που παρουσιάστηκαν στο προηγούμενο παράδειγμα: Τύπος χωρίς ευαισθησία στην πεζότητα για την καταμέτρηση συγκεκριμένων χαρακτήρων σε ένα κελί.

Συγκεκριμένα, μπορείτε να χρησιμοποιήσετε έναν από τους ακόλουθους τύπους για να μετρήσετε συγκεκριμένους χαρακτήρες σε μια περιοχή αγνοώντας την περίπτωση:

• Χρησιμοποιήστε τη λειτουργία UPPER και πληκτρολογήστε έναν χαρακτήρα με κεφαλαία γράμματα:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8), "A","")))

• Χρησιμοποιήστε ένθετες συναρτήσεις SUBSTITUTE:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), "A",""), "a",""))))

• Χρησιμοποιήστε τις συναρτήσεις UPPER και LOWER, πληκτρολογήστε είτε ένα κεφαλαίο είτε ένα πεζό γράμμα σε κάποιο κελί και αναφερθείτε σε αυτό το κελί στον τύπο σας:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))))

Το παρακάτω στιγμιότυπο οθόνης δείχνει τον τελευταίο τύπο σε δράση:

Συμβουλή. Για να μετρήσετε τις εμφανίσεις ενός συγκεκριμένο κείμενο (υποσέλιδο) σε ένα εύρος, χρησιμοποιήστε τον τύπο που παρουσιάζεται στην ενότητα Πώς να μετρήσετε συγκεκριμένο κείμενο/λέξεις σε ένα εύρος.

Με αυτόν τον τρόπο μπορείτε να μετράτε χαρακτήρες στο Excel χρησιμοποιώντας τη συνάρτηση LEN. Αν θέλετε να μάθετε πώς να μετράτε λέξεις και όχι μεμονωμένους χαρακτήρες, θα βρείτε μερικούς χρήσιμους τύπους στο επόμενο άρθρο μας, μείνετε συντονισμένοι!

Εν τω μεταξύ, μπορείτε να κατεβάσετε ένα δείγμα βιβλίου εργασίας με τον τύπο καταμέτρησης χαρακτήρων που συζητείται σε αυτό το σεμινάριο και να δείτε μια λίστα με σχετικούς πόρους στο τέλος της σελίδας. Σας ευχαριστώ για την ανάγνωση και ελπίζω να σας δω σύντομα!