Taula de continguts
El tutorial explica com comptar caràcters a Excel. Aprendràs les fórmules per obtenir el recompte total de caràcters en un interval i comptar només caràcters específics en una cel·la o en diverses cel·les.
El nostre tutorial anterior va introduir la funció Excel LEN, que permet comptar els nombre total de caràcters en una cel·la.
La fórmula LEN és útil per si sola, però en relació amb altres funcions com SUMA, SUMAPRODUCT i SUBSTITUTE, pot gestionar tasques molt més complexes. Més endavant en aquest tutorial, veurem més de prop algunes fórmules bàsiques i avançades per comptar caràcters a Excel.
Com comptar tots els caràcters d'un interval
Quan es tracta de comptar un nombre total de caràcters en diverses cel·les, una solució immediata que ve al cap és obtenir el recompte de caràcters per a cada cel·la i després sumar aquests nombres:
=LEN(A2)+LEN(A3)+LEN(A4)
O
=SUM(LEN(A2),LEN(A3),LEN(A4))
Les fórmules anteriors poden funcionar bé per a un interval reduït. Per comptar el total de caràcters en un rang més gran, és millor que en inventem alguna cosa més compacta, p. la funció SUMAPRODUCTE, que multiplica les matrius i retorna la suma dels productes.
Aquí teniu la fórmula genèrica d'Excel per comptar els caràcters d'un interval:
=SUMAPRODUCTE(LEN( interval) )I la teva fórmula de la vida real pot semblar a aquesta:
=SUMPRODUCT(LEN(A1:A7))
Una altra manera de comptar els caràcters d'un interval és utilitzar el Funció LEN acombinació amb SUMA:
=SUM(LEN(A1:A7))
A diferència de SUMPRODUCT, la funció SUMA no calcula matrius de manera predeterminada i cal que premeu Ctrl + Maj + Retorn per convertir-la en una fórmula de matriu.
Com es mostra a la captura de pantalla següent, la fórmula SUMA retorna el mateix recompte total de caràcters:
Com funciona aquesta fórmula de recompte de caràcters d'interval
Això és una de les fórmules més senzilles per comptar caràcters a Excel. La funció LEN calcula la longitud de la cadena per a cada cel·la de l'interval especificat i les retorna com a matriu de números. A continuació, SUMPRODUCT o SUM suma aquests nombres i retorna el recompte total de caràcters.
A l'exemple anterior, es suma una matriu de 7 nombres que representen la longitud de les cadenes de les cel·les A1 a A7:
Nota. Si us plau, tingueu en compte que la funció LEN d'Excel compta absolutament tots els caràcters de cada cel·la , incloses les lletres, els números, els signes de puntuació, els símbols especials i tots els espais (principal, final i espais entre paraules).
Com comptar caràcters específics d'una cel·la
De vegades, en lloc de comptar tots els caràcters d'una cel·la, és possible que hàgiu de comptar només les aparicions d'una lletra, un número o un símbol especial específics.
Per comptar el nombre de vegades que apareix un caràcter determinat en una cel·la, utilitzeu la funció LEN juntament amb SUBSTITUTE:
=LEN( cel·la )-LEN(SUBSTITUTE( cel·la<2)>, caràcter ,""))Per entendre millor la fórmula, considereu l'exemple següent.
Suposem que manteniu una base de dades d'elements lliurats, on cada tipus d'element té el seu propi únic identificador. I cada cel·la conté diversos elements separats per comes, espais o qualsevol altre delimitador. La tasca és comptar quantes vegades apareix un identificador únic determinat a cada cel·la.
Suposant que la llista d'articles lliurats es troba a la columna B (començant per B2), i estem comptant el nombre de "A" casos, la fórmula és la següent:
=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))
Com funciona aquesta fórmula de recompte de caràcters d'Excel
Per entendre la lògica de la fórmula, dividiu-lo en parts més petites:
- Primer, compteu la longitud total de la cadena en B2:
LEN(B2)
SUBSTITUTE(B2,"A","")
LEN(SUBSTITUTE(B2,"A",""))
Com a resultat, obteniu el recompte de caràcters "eliminats", que equival a un nombre total d'ocurrències d'aquest caràcter a la cel·la.
En lloc d'especificar el caràcter en què voleu comptar una fórmula, podeu escriure-la en alguna cel·la i, a continuació, fer referència a aquesta cel·la en una fórmula. D'aquesta manera, els teus usuarispodrà comptar les ocurrències de qualsevol altre caràcter que introdueixin en aquesta cel·la sense manipular la fórmula:
Nota. El SUBSTITUTE d'Excel és una funció que distingeix entre majúscules i minúscules i, per tant, la fórmula anterior també distingeix entre majúscules i minúscules. Per exemple, a la captura de pantalla anterior, la cel·la B3 conté 3 ocurrències de "A": dues en majúscules i una en minúscula. La fórmula només ha comptat els caràcters en majúscules perquè hem proporcionat "A" a la funció SUBSTITUTE.
Fórmula d'Excel que no distingeix entre majúscules i minúscules per comptar caràcters específics d'una cel·la.
Si necessiteu un recompte de caràcters que no distingeix entre majúscules i minúscules, incrusteu la funció UPPER a SUBSTITUTE per convertir el caràcter especificat en majúscules abans d'executar la substitució. I, assegureu-vos d'introduir el caràcter en majúscula a la fórmula.
Per exemple, per comptar els elements "A" i "a" a la cel·la B2, utilitzeu aquesta fórmula:
=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))
Una altra manera és utilitzar funcions de substitució imbricades:
=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")
Com podeu veure a la captura de pantalla següent, ambdues fórmules compten perfectament les majúscules i minúscules del caràcter especificat:
En alguns casos, és possible que hàgiu de comptar molts caràcters diferents en una taula, però és possible que no vulgueu modificar la fórmula cada vegada. En aquest cas, niu una funció de substitució dins d'una altra, escriviu el caràcter que voleu comptar en alguna cel·la (D1 en aquest exemple) i convertiu el valor d'aquesta cel·la a majúscules iminúscules utilitzant les funcions MAJÚSCULA i MINÚSCULA:
=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))
Com a alternativa, convertiu tant la cel·la font com la cel·la que conté el caràcter en majúscules o minúscules. Per exemple:
=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))
L'avantatge d'aquest enfocament és que, independentment de si s'introdueix el caràcter majúscula o minúscula a la cel·la de referència, la vostra fórmula de recompte de caràcters que no distingeix entre majúscules i minúscules retornarà el recompte correcte:
Comptar les ocurrències de cert text o subcadena en una cel·la
Si voleu comptar quantes vegades un una combinació específica de caràcters (és a dir, cert text o subcadena) apareix en una cel·la determinada, p. ex. "A2" o "SS", després divideix el nombre de caràcters retornats per les fórmules anteriors per la longitud de la subcadena.
Fórmula que distingeix entre majúscules i minúscules :
=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1) Fórmula
No distingeix entre majúscules i minúscules :
=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)
On B2 és la cel·la que conté tota la cadena de text i C1 és el text (subcadena) que voleu comptar.
Per obtenir una explicació detallada de la fórmula, vegeu Com comptar text/paraules concrets en una cel·la.
Com comptar concrets caràcter(s) d'un interval
Ara que ja coneixeu una fórmula d'Excel per comptar caràcters en una cel·la, potser voldreu millorar-la encara més per saber quantes vegades apareix un caràcter determinat en un interval. Per a això, prendrem la fórmula Excel LEN per comptar un caràcter específic en una cel·la discutidaa l'exemple anterior i col·loqueu-lo dins de la funció SUMPRODUCT que pot gestionar matrius:
SUMPRODUCT(LEN( range )-LEN(SUBSTITUTE( range , caracter ,"")))En aquest exemple, la fórmula pren la forma següent:
=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))
I aquí hi ha una altra fórmula per comptar caràcters de l'interval d'Excel:
=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))
En comparació amb la primera fórmula, la diferència més òbvia és utilitzar SUMA en lloc de SUMAPRODUCTE. Una altra diferència és que requereix prémer Ctrl + Maj + Retorn perquè a diferència de SUMPRODUCT, que està dissenyat per processar matrius, SUM només pot gestionar matrius quan s'utilitza en una fórmula de matriu .
Si no No voleu codificar el caràcter de la fórmula, per descomptat, podeu escriure'l en alguna cel·la, per exemple D1, i fer referència a aquesta cel·la a la vostra fórmula de recompte de caràcters:
=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))
Nota. En situacions en què compteu les ocurrències d'una subcadena específica en un interval (per exemple, comandes que comencen per "KK" o "AA"), heu de dividir el recompte de caràcters per la longitud de la subcadena, en cas contrari, cada caràcter en la subcadena es comptarà individualment. Per exemple:
=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))
Com funciona aquesta fórmula de recompte de caràcters
Com recordareu, la funció SUBSTITUTE s'utilitza per substituir totes les ocurrències del caràcter especificat ("A" en aquest exemple). ) amb una cadena de text buida ("").
A continuació, proporcionem la cadena de text retornada per SUBSTITUTE a la LEN d'Excelfunció de manera que calculi la longitud de la cadena sense A. I després, restem aquest recompte de caràcters de la longitud total de la cadena de text. El resultat d'aquests càlculs és una matriu de recomptes de caràcters, amb un recompte de caràcters per cel·la.
Finalment, SUMPRODUCT suma els nombres de la matriu i retorna el recompte total del caràcter especificat a l'interval.
Una fórmula que no distingeix entre majúscules i minúscules per comptar caràcters específics en un interval.
Ja sabeu que SUBSTITUTE és una funció que distingeix entre majúscules i minúscules, la qual cosa fa que la nostra fórmula d'Excel per al recompte de caràcters també distingeix entre majúscules i minúscules.
Per fer que la fórmula ignori majúscules i minúscules, seguiu els enfocaments que es mostren a l'exemple anterior: Fórmula que no distingeix entre majúscules i minúscules per comptar caràcters específics d'una cel·la.
En particular, podeu utilitzar una de les fórmules següents per comptar caràcters específics d'un interval ignorant majúscules:
- Utilitzeu la funció MAJÚSCULA i introduïu un caràcter en majúscules:
=SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A",""))) - Utilitzeu funcions SUBSTITUTE imbricades:
=SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a",""))) - Utilitzeu les funcions UPPER i LOWER, escriviu un caràcter en majúscules o minúscules en alguna cel·la i feu referència a aquesta cel·la a la vostra fórmula:
=SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))
La captura de pantalla següent mostra l'última fórmula en acció:
Consell. Per comptar les ocurrències d'un text específic (subcadena) en un interval, utilitzeu la fórmula que es mostra a Com comptar un text o paraules concrets en un interval.
Aixòés com podeu comptar caràcters a Excel mitjançant la funció LEN. Si voleu saber com comptar paraules en comptes de caràcters individuals, trobareu algunes fórmules útils al nostre article següent, si us plau, estigueu atents!
Mentrestant, podeu descarregar una mostra de llibres de treball amb fórmula de recompte de caràcters. es parla en aquest tutorial i consulteu una llista de recursos relacionats al final de la pàgina. Us agraeixo la lectura i espero veure-us aviat!
