Kennslan útskýrir hvernig á að telja stafi í Excel. Þú munt læra formúlurnar til að fá heildarfjölda stafa á bili, og telja aðeins tiltekna stafi í reit eða í nokkrum hólfum.

Fyrri kennsla okkar kynnti Excel LEN aðgerðina, sem gerir kleift að telja heildarfjöldi stafa í reit.

LEN formúlan er gagnleg ein og sér, en í tengslum við aðrar aðgerðir eins og SUM, SUMPRODUCT og SUBSTITUTE ræður hún við miklu flóknari verkefni. Nánar í þessari kennslu ætlum við að skoða nokkrar grunn- og háþróaðar formúlur til að telja stafi í Excel.

Hvernig á að telja alla stafi á bilinu

Þegar kemur að því að telja heildarfjölda stafa í nokkrum hólfum, þá er strax lausn sem kemur upp í hugann að fá stafafjöldann fyrir hvern reit og leggja síðan saman þessar tölur:

=LEN(A2)+LEN(A3)+LEN(A4)

Eða

=SUM(LEN(A2),LEN(A3),LEN(A4))

Oftangreindar formúlur gætu virkað vel fyrir lítið svið. Til að telja heildarstafi í stærra svið, ættum við að koma með eitthvað þéttara, t.d. SUMPRODUCT fallið, sem margfaldar fylkin og skilar summu afurðanna.

Hér er almenna Excel formúlan til að telja stafi á bilinu:

Og raunveruleikaformúlan þín gæti litið svipað út:

=SUMPRODUCT(LEN(A1:A7))

Önnur leið til að telja stafi á bilinu er að nota LEN virka ísamsetning með SUM:

=SUM(LEN(A1:A7))

Ólíkt SUMPRODUCT, reiknar SUM aðgerðin ekki fylki sjálfgefið og þú þarft að ýta á Ctrl + Shift + Enter til að breyta því í fylkisformúlu.

Eins og sýnt er á eftirfarandi skjámynd skilar SUM formúlan sama heildarfjölda stafa:

Hvernig þessi formúla fyrir tölustafafjölda virkar

Þetta er ein einfaldasta formúlan til að telja stafi í Excel. LEN fallið reiknar út lengd strengs fyrir hvern reit á tilgreindu bili og skilar þeim sem fylki af tölum. Og svo, SUMPRODUCT eða SUM leggur þessar tölur saman og skilar heildarfjölda stafa.

Í dæminu hér að ofan er fylki með 7 tölum sem tákna lengd strengja í hólfum A1 til A7 lagt saman:

Athugið. Vinsamlegast athugaðu að Excel LEN aðgerðin telur algerlega alla stafi í hverjum reit , þar á meðal bókstafi, tölustafi, greinarmerki, sérstök tákn og öll bil (frama, aftan og bil á milli orða).

Hvernig á að telja tiltekna stafi í reit

Stundum, í stað þess að telja alla stafi innan reits, gætir þú þurft að telja aðeins tilvik tiltekins bókstafs, tölu eða sérstákns.

Til að telja hversu oft tiltekinn stafur kemur fyrir í reit, notaðu LEN fallið ásamt SUBSTITUTE:

Til að skilja formúluna betur skaltu íhuga eftirfarandi dæmi.

Segjum að þú hafir gagnagrunn yfir afhentar vörur þar sem hver vörutegund hefur sína sérstöðu auðkenni. Og hver hólf inniheldur nokkra hluti aðskilin með kommu, bili eða öðrum afmörkun. Verkefnið er að telja hversu oft tiltekið einkvæmt auðkenni birtist í hverjum reit.

Að því gefnu að listi yfir afhenta hluti sé í dálki B (byrjar á B2), og við erum að telja fjölda "A" tilvik, formúlan er sem hér segir:

=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))

Hvernig þessi Excel stafatalningarformúla virkar

Til að skilja rökfræði formúlunnar skulum við skiptu því niður í smærri hluta:

• Fyrst telurðu heildarlengd strengsins í B2:

LEN(B2)

SUBSTITUTE(B2,"A","")

LEN(SUBSTITUTE(B2,"A",""))

Þar af leiðandi færðu fjölda „fjarlægða“ stafa, sem jafngildir heildarfjölda þeirra stafatilvika í reitnum.

Í stað þess að tilgreina stafinn sem þú vilt telja í formúlu, þú getur slegið hana inn í einhvern reit og vísað síðan í þann reit í formúlu. Á þennan hátt, notendur þínirmun geta talið tilvik af hvaða öðrum staf sem þeir setja inn í reitinn án þess að fikta við formúluna þína:

Athugið. STAÐARIÐI Excel er hástafanæm fall og því er formúlan hér að ofan líka há- og hástafanæm. Til dæmis, í skjámyndinni hér að ofan, inniheldur reit B3 3 tilvik af "A" - tvö með hástöfum og einn með lágstöfum. Formúlan hefur aðeins talið hástafina vegna þess að við gáfum „A“ til SUBSTITUTE fallsins.

Hástafa-ónæmir Excel formúla til að telja tiltekna stafi í reit

Ef þú þarft stafafjölda sem er óháð hástöfum, felldu UPPER fallið inn í SUBSTITUTE til að breyta tilgreindum staf í hástafi áður en skiptingin er keyrð. Og vertu viss um að slá inn hástafinn í formúlunni.

Til að telja „A“ og „a“ atriði í reit B2, notaðu þessa formúlu:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))

Önnur leið er að nota hreiður staðgengilsaðgerðir:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")

Eins og þú sérð á skjámyndinni hér að neðan, telja báðar formúlurnar gallalaust hástafi og lágstafi tiltekins stafa:

Í sumum tilfellum gætir þú þurft að telja marga mismunandi stafi í töflu, en þú vilt kannski ekki breyta formúlunni í hvert sinn. Í þessu tilviki skaltu hreiðra eina staðgengill fall inn í aðra, slá inn stafinn sem þú vilt telja í einhverjum reit (D1 í þessu dæmi) og umbreyta gildi þess hólfs í hástafi oglágstafi með því að nota UPPER og LOWER aðgerðir:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))

Að öðrum kosti, umbreyttu bæði frumhólfinu og hólfinu sem inniheldur stafinn annað hvort í hástafi eða lágstafi. Til dæmis:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))

Kosturinn við þessa aðferð er sá að óháð því hvort hástafir eða lágstafir eru settir inn í reitinn sem vísað er til, þá er hástafaónæmir stafatalningaformúlan þín mun skila réttri tölu:

Telja tilvik ákveðins texta eða undirstrengs í reit

Ef þú vilt telja hversu oft ákveðin samsetning stafa (þ.e. ákveðinn texti, eða undirstrengur) birtist í tilteknum reit, t.d. „A2“ eða „SS“, deilið síðan fjölda stafa sem ofangreindar formúlur skila með lengd undirstrengsins.

Hástafir og hástafir formúla:

=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)

Stafónæm formúla:

=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)

Þar sem B2 er hólfið sem inniheldur allan textastrenginn og C1 er textinn (undirstrengurinn) sem þú viltu telja.

Til að fá nákvæma útskýringu á formúlunni, vinsamlegast sjáðu Hvernig á að telja ákveðinn texta / orð í reit.

Hvernig á að telja tiltekna stafir/stafir á bili

Nú þegar þú þekkir Excel formúlu til að telja stafi í reit gætirðu viljað bæta hana enn frekar til að komast að því hversu oft ákveðinn stafur kemur fyrir á bilinu. Fyrir þetta munum við taka Excel LEN formúluna til að telja tiltekna bleikju í reit sem fjallað er umí fyrra dæminu, og settu það inn í SUMPRODUCT fallið sem getur séð um fylki:

Í þessu dæmi tekur formúlan eftirfarandi lögun:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

Og hér er önnur formúla til að telja stafir á sviði Excel:

=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

Í samanburði við fyrstu formúluna er augljósasti munurinn að nota SUM í stað SUMPRODUCT. Annar munur er að það þarf að ýta á Ctrl + Shift + Enter vegna þess að ólíkt SUMPRODUCT, sem er hannað til að vinna fylki, getur SUM aðeins séð um fylki þegar það er notað í fylkisformúlu .

Ef þú notar fylki Þú vilt ekki harðkóða stafinn í formúlunni, þú getur auðvitað slegið hann inn í einhvern reit, segjum D1, og vísað í þann reit í formúlu stafafjöldans:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))

Athugið. Í aðstæðum þegar þú telur tilvik tiltekins undirstrengs á bili (t.d. röð sem byrja á "KK" eða "AA"), þarftu að deila stafafjölda með lengd undirstrengs, annars hver stafur í undirstrengurinn verður talinn fyrir sig. Til dæmis:

=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))

Hvernig þessi stafatalningarformúla virkar

Eins og þú kannski manst er SUBSTITUTE aðgerðin notuð til að skipta út öllum tilvikum tilgreinds stafs ("A" í þessu dæmi ) með tómum textastreng ("").

Þá sendum við textastrenginn sem SUBSTITUTE skilar í Excel LENfall þannig að það reiknar út lengd strengsins án A. Og svo drögum við þann stafafjölda frá heildarlengd textastrengsins. Niðurstaða þessara útreikninga er fylki stafafjölda, með einum stafafjölda í hólf.

Að lokum leggur SUMPRODUCT saman tölurnar í fylkinu og skilar heildartalningu tilgreinds stafa á bilinu.

Hástafa-ónæmisformúla til að telja tiltekna stafi á bilinu

Þú veist nú þegar að SUBSTITUTE er há- og hástafanæm aðgerð, sem gerir Excel-formúluna okkar fyrir stafafjölda einnig há- og hástafanæm.

Til að láta formúluna hunsa hástöfum skaltu fylgja aðferðunum sem sýndar voru í fyrra dæmi: Hástafaónæmir formúla til að telja tiltekna stafi í reit.

Sérstaklega geturðu notað eina af eftirfarandi formúlum til að telja tilteknir stafir á bili sem hunsa hástafi:

• Notaðu UPPER aðgerðina og sláðu inn staf með hástöfum:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A","")))

• Notaðu hreiðrað SUBSTITUTE föll:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a","")))

• Notaðu UPPER og LOWER aðgerðir, sláðu annaðhvort inn hástafi eða lágstafi í einhverjum reit og vísaðu í þann reit í formúlunni þinni:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))

Skjámyndin hér að neðan sýnir síðustu formúluna í aðgerð:

Ábending. Til að telja tilvik tiltekins texta (undirstrengs) í bili, notaðu formúluna sem sýnd er í Hvernig á að telja tiltekinn texta / orð í bili.

Þettaer hvernig þú getur talið stafi í Excel með því að nota LEN aðgerðina. Ef þú vilt vita hvernig á að telja orð frekar en einstaka stafi, munt þú finna nokkrar gagnlegar formúlur í næstu grein okkar, vinsamlegast fylgstu með!

Í millitíðinni geturðu hlaðið niður sýnishornum úr vinnubókum með formúlu fyrir tölustafi. fjallað um í þessari kennslu og skoðaðu lista yfir tengd úrræði í lok síðunnar. Ég þakka þér fyrir lesturinn og sjáumst vonandi fljótlega!