Hướng dẫn giải thích cách đếm ký tự trong Excel. Bạn sẽ tìm hiểu các công thức để tính tổng số ký tự trong một phạm vi và chỉ đếm các ký tự cụ thể trong một ô hoặc trong một số ô.

Hướng dẫn trước đây của chúng tôi đã giới thiệu hàm LEN trong Excel, cho phép đếm các ký tự tổng số ký tự trong một ô.

Bản thân công thức LEN rất hữu ích nhưng khi kết hợp với các hàm khác như SUM, SUMPRODUCT và SUBSTITUTE, công thức này có thể xử lý các tác vụ phức tạp hơn nhiều. Tiếp tục trong hướng dẫn này, chúng ta sẽ xem xét kỹ hơn một số công thức cơ bản và nâng cao để đếm ký tự trong Excel.

Cách đếm tất cả các ký tự trong một phạm vi

Khi cần đếm tổng số ký tự trong một số ô, một giải pháp tức thời xuất hiện trong đầu là lấy số ký tự cho từng ô, rồi cộng các số đó lại:

=LEN(A2)+LEN(A3)+LEN(A4)

Hoặc

=SUM(LEN(A2),LEN(A3),LEN(A4))

Các công thức trên có thể hoạt động tốt trong một phạm vi nhỏ. Để đếm tổng số ký tự trong phạm vi lớn hơn, tốt hơn hết chúng ta nên nghĩ ra thứ gì đó nhỏ gọn hơn, ví dụ: hàm SUMPRODUCT, hàm này nhân các mảng và trả về tổng của các tích.

Dưới đây là công thức Excel chung để đếm các ký tự trong một dải ô:

Và công thức thực tế của bạn có thể giống như sau:

=SUMPRODUCT(LEN(A1:A7))

Một cách khác để đếm các ký tự trong một phạm vi là sử dụng LEN chức năng trongkết hợp với SUM:

=SUM(LEN(A1:A7))

Khác với SUMPRODUCT, hàm SUM không tính toán mảng theo mặc định và bạn cần nhấn Ctrl + Shift + Enter để biến nó thành công thức mảng.

Như minh họa trong ảnh chụp màn hình sau, công thức SUM trả về tổng số ký tự giống nhau:

Cách thức hoạt động của công thức đếm ký tự phạm vi này

Công thức này là một trong những công thức đơn giản nhất để đếm ký tự trong Excel. Hàm LEN tính toán độ dài chuỗi cho từng ô trong phạm vi đã chỉ định và trả về chúng dưới dạng một mảng số. Sau đó, TÓM TẮT hoặc SUM cộng các số đó lại và trả về tổng số ký tự.

Trong ví dụ trên, một mảng gồm 7 số đại diện cho độ dài của chuỗi trong các ô từ A1 đến A7 được tính tổng:

Lưu ý. Xin lưu ý rằng hàm LEN của Excel đếm tuyệt đối tất cả các ký tự trong mỗi ô , bao gồm chữ cái, số, dấu chấm câu, ký hiệu đặc biệt và tất cả khoảng trắng (đầu, cuối và khoảng cách giữa các từ).

Cách đếm các ký tự cụ thể trong một ô

Đôi khi, thay vì đếm tất cả các ký tự trong một ô, bạn có thể chỉ cần đếm số lần xuất hiện của một chữ cái, số hoặc ký hiệu đặc biệt cụ thể.

Để đếm số lần một ký tự nhất định xuất hiện trong một ô, hãy sử dụng hàm LEN cùng với SUBSTITUTE:

Để hiểu rõ hơn về công thức, hãy xem xét ví dụ sau.

Giả sử bạn duy trì cơ sở dữ liệu về các mặt hàng đã giao, trong đó mỗi loại mặt hàng có một đặc điểm riêng định danh. Và mỗi ô chứa một số mục được phân tách bằng dấu phẩy, dấu cách hoặc bất kỳ dấu phân cách nào khác. Nhiệm vụ là đếm số lần một mã định danh duy nhất nhất định xuất hiện trong mỗi ô.

Giả sử rằng danh sách các mặt hàng được giao nằm trong cột B (bắt đầu từ B2) và chúng tôi đang đếm số lượng "A" công thức như sau:

=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))

Cách hoạt động của công thức đếm ký tự Excel này

Để hiểu logic của công thức, hãy chia nó thành các phần nhỏ hơn:

• Đầu tiên, bạn đếm tổng độ dài chuỗi trong B2:

LEN(B2)

SUBSTITUTE(B2,"A","")

LEN(SUBSTITUTE(B2,"A",""))

Kết quả là bạn nhận được số lượng ký tự "đã xóa", tương đương với tổng số lần xuất hiện của ký tự đó trong ô.

Thay vì chỉ định ký tự bạn muốn đếm trong một công thức, bạn có thể nhập nó vào một số ô, rồi tham chiếu ô đó trong một công thức. Bằng cách này, người dùng của bạnsẽ có thể đếm số lần xuất hiện của bất kỳ ký tự nào khác mà họ nhập vào ô đó mà không can thiệp vào công thức của bạn:

Lưu ý. SUBSTITUTE của Excel là một hàm phân biệt chữ hoa chữ thường và do đó, công thức trên cũng phân biệt chữ hoa chữ thường. Ví dụ: trong ảnh chụp màn hình ở trên, ô B3 chứa 3 lần xuất hiện của "A" - hai lần viết hoa và một lần viết thường. Công thức chỉ tính các ký tự viết hoa vì chúng tôi đã cung cấp "A" cho hàm SUBSTITUTE.

Công thức Excel không phân biệt chữ hoa chữ thường để đếm các ký tự cụ thể trong một ô

Nếu bạn cần đếm ký tự không phân biệt chữ hoa chữ thường, hãy nhúng hàm UPPER bên trong SUBSTITUTE để chuyển đổi ký tự đã chỉ định thành chữ hoa trước khi chạy thay thế. Và hãy nhớ nhập ký tự viết hoa trong công thức.

Ví dụ: để đếm các mục "A" và "a" trong ô B2, hãy sử dụng công thức sau:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))

Một cách khác là sử dụng các hàm Thay thế lồng nhau:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")

Như bạn có thể thấy trong ảnh chụp màn hình bên dưới, cả hai công thức đều đếm số lần xuất hiện chữ hoa và chữ thường của ký tự được chỉ định một cách hoàn hảo:

Trong một số trường hợp, bạn có thể cần đếm nhiều ký tự khác nhau trong một bảng, nhưng bạn có thể không muốn sửa đổi công thức mỗi lần. Trong trường hợp này, hãy lồng một hàm Thay thế vào trong một hàm khác, nhập ký tự bạn muốn đếm vào ô nào đó (D1 trong ví dụ này) và chuyển đổi giá trị của ô đó thành chữ hoa vàchữ thường bằng cách sử dụng các hàm UPPER và LOWER:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))

Hoặc, chuyển đổi cả ô nguồn và ô chứa ký tự thành chữ hoa hoặc chữ thường. Ví dụ:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))

Ưu điểm của phương pháp này là bất kể ký tự viết hoa hay viết thường được nhập vào ô được tham chiếu, công thức đếm ký tự không phân biệt chữ hoa chữ thường của bạn sẽ trả về số đúng:

Đếm số lần xuất hiện của văn bản hoặc chuỗi con nhất định trong một ô

Nếu bạn muốn đếm số lần sự kết hợp cụ thể của các ký tự (tức là văn bản hoặc chuỗi con nhất định) xuất hiện trong một ô nhất định, ví dụ: "A2" hoặc "SS", sau đó chia số ký tự mà các công thức trên trả về cho độ dài của chuỗi con.

Công thức phân biệt chữ hoa chữ thường:

=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1) Công thức

Không phân biệt chữ hoa chữ thường :

=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)

Trong đó B2 là ô chứa toàn bộ chuỗi văn bản và C1 là văn bản (chuỗi con) của bạn muốn đếm.

Để biết giải thích chi tiết về công thức, vui lòng xem Cách đếm văn bản/từ cụ thể trong một ô.

Cách đếm cụ thể (các) ký tự trong một dải ô

Bây giờ bạn đã biết một công thức Excel để đếm các ký tự trong một ô, bạn có thể muốn cải thiện công thức này hơn nữa để tìm hiểu số lần một ký tự nhất định xuất hiện trong một dải ô. Đối với điều này, chúng tôi sẽ sử dụng công thức LEN của Excel để đếm một ký tự cụ thể trong một ô được thảo luậntrong ví dụ trước và đặt nó bên trong hàm SUMPRODUCT có thể xử lý các mảng:

Trong ví dụ này, công thức có dạng sau:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

Và đây là một công thức khác để đếm các ký tự trong phạm vi của Excel:

=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

So với công thức đầu tiên, sự khác biệt rõ ràng nhất là sử dụng SUM thay vì TÓM TẮT. Một điểm khác biệt nữa là nó yêu cầu nhấn Ctrl + Shift + Enter vì không giống như SUMPRODUCT được thiết kế để xử lý mảng, SUM chỉ có thể xử lý mảng khi được sử dụng trong công thức mảng .

Nếu bạn không Nếu không muốn mã hóa cứng ký tự trong công thức, tất nhiên bạn có thể nhập ký tự đó vào một số ô, chẳng hạn như D1 và tham chiếu ô đó trong công thức đếm ký tự của bạn:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))

Lưu ý. Trong các trường hợp khi bạn đếm số lần xuất hiện của một chuỗi con cụ thể trong một phạm vi (ví dụ: các đơn hàng bắt đầu bằng "KK" hoặc "AA"), bạn cần chia số ký tự cho độ dài chuỗi con, nếu không thì mỗi ký tự trong chuỗi con sẽ được tính riêng lẻ. Ví dụ:

=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))

Cách thức hoạt động của công thức đếm ký tự này

Như bạn có thể nhớ, hàm SUBSTITUTE được sử dụng để thay thế tất cả các lần xuất hiện của ký tự đã chỉ định (trong ví dụ này là "A" ) bằng một chuỗi văn bản trống ("").

Sau đó, chúng tôi cung cấp chuỗi văn bản do SUBSTITUTE trả về cho LEN Excelđể nó tính toán độ dài chuỗi không có A. Và sau đó, chúng tôi trừ đi số ký tự đó khỏi tổng độ dài của chuỗi văn bản. Kết quả của những tính toán này là một mảng gồm các số ký tự, với một số ký tự cho mỗi ô.

Cuối cùng, SUMPRODUCT tính tổng các số trong mảng và trả về tổng số ký tự được chỉ định trong phạm vi.

Một công thức không phân biệt chữ hoa chữ thường để đếm các ký tự cụ thể trong một phạm vi

Bạn đã biết rằng SUBSTITUTE là một hàm phân biệt chữ hoa chữ thường, điều này làm cho công thức đếm ký tự trong Excel của chúng ta cũng phân biệt chữ hoa chữ thường.

Để làm cho công thức bỏ qua chữ hoa chữ thường, hãy làm theo các phương pháp được trình bày trong ví dụ trước: Công thức không phân biệt chữ hoa chữ thường để đếm các ký tự cụ thể trong một ô.

Cụ thể, bạn có thể sử dụng một trong các công thức sau để đếm các ký tự cụ thể trong một phạm vi bỏ qua chữ hoa/thường:

• Sử dụng hàm UPPER và nhập một ký tự viết hoa:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A","")))

  Xem thêm: Hàm Excel XIRR để tính IRR cho dòng tiền không định kỳ
• Sử dụng các hàm SUBSTITUTE lồng nhau:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a","")))

• Sử dụng các hàm UPPER và LOWER, nhập ký tự chữ hoa hoặc chữ thường vào một số ô và tham chiếu ô đó trong công thức của bạn:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))

Ảnh chụp màn hình bên dưới minh họa công thức cuối cùng đang hoạt động:

Mẹo. Để đếm số lần xuất hiện của văn bản cụ thể (chuỗi con) trong một phạm vi, hãy sử dụng công thức được trình bày trong Cách đếm văn bản/từ cụ thể trong một phạm vi.

Cái nàylà cách bạn có thể đếm ký tự trong Excel bằng hàm LEN. Nếu bạn muốn biết cách đếm từ chứ không phải các ký tự riêng lẻ, bạn sẽ tìm thấy một số công thức hữu ích trong bài viết tiếp theo của chúng tôi, hãy chú ý theo dõi!

Trong thời gian chờ đợi, bạn có thể tải xuống sổ làm việc mẫu với công thức đếm ký tự được thảo luận trong hướng dẫn này và xem danh sách các tài nguyên liên quan ở cuối trang. Tôi cảm ơn bạn đã đọc và hy vọng sớm gặp lại bạn!