Die tutoriaal verduidelik hoe om karakters in Excel te tel. Jy sal die formules leer om die totale karaktertelling in 'n reeks te kry, en net spesifieke karakters in 'n sel of in verskeie selle tel.

Ons vorige tutoriaal het die Excel LEN-funksie bekendgestel, wat die tel van die totale aantal karakters in 'n sel.

Die LEN-formule is op sy eie nuttig, maar in skakeling met ander funksies soos SOM, SOMPRODUK en PLAASVERVANG, kan dit baie meer komplekse take hanteer. Verder in hierdie tutoriaal gaan ons 'n paar basiese en gevorderde formules van naderby kyk om karakters in Excel te tel.

Hoe om alle karakters in 'n reeks te tel

Wanneer dit kom by die tel van 'n totale aantal karakters in verskeie selle, is 'n onmiddellike oplossing wat by jou opkom om die karaktertelling vir elke sel te kry en dan daardie getalle bymekaar te tel:

=LEN(A2)+LEN(A3)+LEN(A4)

Of

=SUM(LEN(A2),LEN(A3),LEN(A4))

Bogenoemde formules kan dalk goed werk vir 'n klein reeks. Om totale karakters in 'n groter reeks te tel, moet ons beter met iets meer kompak vorendag kom, bv. die SUMPRODUCT-funksie, wat die skikkings vermenigvuldig en die som van die produkte terugstuur.

Hier is die generiese Excel-formule om karakters in 'n reeks te tel:

En jou werklike formule kan soortgelyk soos hierdie lyk:

=SUMPRODUCT(LEN(A1:A7))

'n Ander manier om karakters in 'n reeks te tel, is om die LEN funksie inkombinasie met SOM:

=SUM(LEN(A1:A7))

Anders as SUMPRODUCT, bereken die SOM-funksie nie skikkings by verstek nie, en jy moet Ctrl + Shift + Enter druk om dit in 'n skikkingsformule te verander.

Soos gedemonstreer in die volgende skermkiekie, gee die SOM-formule dieselfde totale karaktertelling:

Hoe hierdie reekskaraktertellingformule werk

Dit is een van die mees eenvoudige formules om karakters in Excel te tel. Die LEN-funksie bereken die stringlengte vir elke sel in die gespesifiseerde reeks en gee dit terug as 'n reeks getalle. En dan tel SUMPRODUCT of SUM daardie getalle bymekaar en gee die totale karaktertelling terug.

In die bostaande voorbeeld word 'n skikking van 7 getalle wat die lengtes van stringe in selle A1 tot A7 verteenwoordig, opgesom:

Let wel. Let asseblief daarop dat die Excel LEN-funksie absoluut alle karakters in elke sel tel , insluitend letters, syfers, leestekens, spesiale simbole en alle spasies (vooraan, agtervolg en spasies tussen woorde).

Hoe om spesifieke karakters in 'n sel te tel

Soms, in plaas daarvan om alle karakters binne 'n sel te tel, moet jy dalk net die voorkoms van 'n spesifieke letter, nommer of spesiale simbool tel.

Om die aantal kere wat 'n gegewe karakter in 'n sel voorkom te tel, gebruik die LEN-funksie saam met PLAASVERVANG:

Om die formule beter te verstaan, oorweeg die volgende voorbeeld.

Gestel jy hou 'n databasis van gelewerde items in stand, waar elke itemtipe sy eie unieke het identifiseerder. En elke sel bevat verskeie items geskei deur komma, spasie of enige ander afbakener. Die taak is om te tel hoeveel keer 'n gegewe unieke identifiseerder in elke sel verskyn.

As aanvaar word dat die lys van gelewerde items in kolom B is (begin in B2), en ons tel die aantal "A" voorkomste, is die formule soos volg:

=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))

Hoe hierdie Excel-karaktertellingformule werk

Om die formule se logika te verstaan, kom ons breek dit af in kleiner dele:

• Eers tel jy die totale stringlengte in B2:

LEN(B2)

SUBSTITUTE(B2,"A","")

LEN(SUBSTITUTE(B2,"A",""))

As gevolg hiervan kry jy die telling van "verwyderde" karakters, wat gelyk is aan 'n totale aantal van daardie karaktervoorkoms in die sel.

In plaas daarvan om die karakter te spesifiseer waarin jy wil tel. 'n formule, kan jy dit in een of ander sel tik, en dan na daardie sel in 'n formule verwys. Op hierdie manier, jou gebruikerssal die voorkoms van enige ander karakter wat hulle in daardie sel invoer, kan tel sonder om met jou formule te peuter:

Let wel. Excel se PLAASVERVANGER is 'n hooflettersensitiewe funksie, en daarom is bogenoemde formule ook hooflettergevoelig. Byvoorbeeld, in die skermkiekie hierbo, bevat sel B3 3 voorkomste van "A" - twee in hoofletters en een in kleinletters. Die formule het slegs die hoofletters getel omdat ons "A" aan die PLAASVERVANGER-funksie verskaf het.

Hoofletter-onsensitiewe Excel-formule om spesifieke karakters in 'n sel te tel

As jy 'n hoofletter-onsensitiewe karaktertelling nodig het, bederf die UPPER-funksie in SUBSTITUTE om die gespesifiseerde karakter na hoofletters om te skakel voordat die vervanging uitgevoer word. En maak seker dat jy die hoofletter in die formule invoer.

Om byvoorbeeld "A" en "a" items in sel B2 te tel, gebruik hierdie formule:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))

'n Ander manier is om geneste plaasvervangerfunksies te gebruik:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")

Soos jy in die skermkiekie hieronder kan sien, tel beide formules foutloos hoofletters en kleinletters van die gespesifiseerde karakter:

In sommige gevalle moet jy dalk baie verskillende karakters in 'n tabel tel, maar jy wil dalk nie die formule elke keer verander nie. In hierdie geval, nes een plaasvervanger-funksie binne 'n ander, tik die karakter wat jy wil tel in een of ander sel (D1 in hierdie voorbeeld), en skakel daardie sel se waarde om na hoofletters enkleinletters deur die HOOF- en LATER-funksies te gebruik:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))

Alternatiewelik, skakel beide die bronsel en die sel wat die karakter bevat na hoofletters of kleinletters om. Byvoorbeeld:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))

Die voordeel van hierdie benadering is dat ongeag of die hoofletter- of kleinletterkarakter in die verwysde sel ingevoer word, jou hoofletter-onsensitiewe karaktertellingformule sal die regte telling terugstuur:

Tel voorkomste van sekere teks of substring in 'n sel

As jy wil tel hoeveel keer 'n spesifieke kombinasie van karakters (d.w.s. sekere teks, of substring) verskyn in 'n gegewe sel, bv. "A2" of "SS", deel dan die aantal karakters wat deur die bogenoemde formules teruggestuur word deur die lengte van die substring.

Kleinlettergevoelig formule:

=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)

Hoofletter-onsensitiewe formule:

=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)

Waar B2 die sel is wat die hele teksstring bevat, en C1 die teks (substring) is wat jy wil tel.

Vir die gedetailleerde verduideliking van die formule, sien asseblief Hoe om spesifieke teks / woorde in 'n sel te tel.

Hoe om spesifiek te tel. karakter(s) in 'n reeks

Noudat jy 'n Excel-formule ken om karakters in 'n sel te tel, wil jy dit dalk verder verbeter om uit te vind hoeveel keer 'n sekere karakter in 'n reeks verskyn. Hiervoor sal ons die Excel LEN-formule gebruik om 'n spesifieke char in 'n sel wat bespreek is, te telin die vorige voorbeeld, en plaas dit binne die SUMPRODUCT-funksie wat skikkings kan hanteer:

In hierdie voorbeeld neem die formule die volgende vorm aan:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

En hier is nog 'n formule om te tel karakters in Excel se reeks:

=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

Vergeleke met die eerste formule, is die mees ooglopende verskil die gebruik van SOM in plaas van SOMPRODUK. Nog 'n verskil is dat dit vereis dat jy Ctrl + Shift + Enter druk, want anders as SUMPRODUCT, wat ontwerp is om skikkings te verwerk, kan SUM skikkings net hanteer wanneer dit in 'n skikkingformule gebruik word.

As jy dit nie doen nie. As jy nie die karakter in die formule hardkodeer nie, kan jy dit natuurlik in een of ander sel tik, sê D1, en na daardie sel in jou karaktertelling-formule verwys:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))

Let wel. In situasies wanneer jy die voorkoms van 'n spesifieke substring in 'n reeks tel (bv. bestellings wat met "KK" of "AA" begin), moet jy die karaktertelling deur die substringlengte deel, anders moet elke karakter in die substring sal individueel getel word. Byvoorbeeld:

=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))

Hoe hierdie karaktertelformule werk

Soos jy dalk onthou, word die SUBSTITUT-funksie gebruik om alle voorkomste van die gespesifiseerde karakter ("A" in hierdie voorbeeld te vervang ) met 'n leë teksstring ("").

Dan verskaf ons die teksstring wat deur SUBSTITUTE teruggestuur word na die Excel LENfunksie sodat dit die stringlengte sonder A's bereken. En dan trek ons ​​daardie karaktertelling af van die totale lengte van die teksstring. Die resultaat van hierdie berekeninge is 'n skikking van karaktertellings, met een karaktertelling per sel.

Laastens tel SUMPRODUCT die getalle in die skikking op en gee die totale telling van die gespesifiseerde karakter in die reeks terug.

'n Hoofletter-onsensitiewe formule om spesifieke karakters in 'n reeks te tel

Jy weet reeds dat SUBSTITUT 'n hoofletter-sensitiewe funksie is, wat ons Excel-formule vir karaktertelling ook hooflettergevoelig maak.

Om die formule hoofletters te ignoreer, volg die benaderings wat in die vorige voorbeeld gedemonstreer is: Hoofletter-onsensitiewe formule om spesifieke karakters in 'n sel te tel.

Jy kan veral een van die volgende formules gebruik om te tel spesifieke karakters in 'n reeks wat hoofletters ignoreer:

• Gebruik die HOOFSTE funksie en voer 'n karakter in hoofletters in:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A","")))

• Gebruik geneste PLAASVERVANG-funksies:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a","")))

• Gebruik HOOF- en LATER-funksies, tik 'n hoofletter- of kleinletterteken in een of ander sel, en verwys na daardie sel in jou formule:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))

Die onderstaande skermkiekie demonstreer die laaste formule in aksie:

Wenk. Om die voorkoms van 'n spesifieke teks (substring) in 'n reeks te tel, gebruik die formule gedemonstreer in Hoe om spesifieke teks / woorde in 'n reeks te tel.

Ditis hoe jy karakters in Excel kan tel deur die LEN-funksie te gebruik. As jy wil weet hoe om woorde te tel eerder as individuele karakters, sal jy 'n paar nuttige formules in ons volgende artikel vind, bly asseblief ingeskakel!

In die tussentyd kan jy 'n voorbeeldwerkboek met karaktertellingformule aflaai bespreek in hierdie tutoriaal, en kyk na 'n lys van verwante hulpbronne aan die einde van die bladsy. Ek bedank jou vir die lees en hoop om jou binnekort te sien!