De tutorial leit út hoe't jo karakters telle yn Excel. Jo sille de formules leare om it totale oantal tekens yn in berik te krijen, en allinich spesifike tekens yn in sel of yn ferskate sellen telle.

Us foarige tutorial yntrodusearre de Excel LEN-funksje, wêrtroch it tellen fan de totaal oantal tekens yn in sel.

De LEN-formule is op himsels nuttich, mar yn ferbân mei oare funksjes lykas SUM, SUMPRODUCT en SUBSTITUTE kin it folle kompleksere taken oan. Fierderop yn dizze tutorial sille wy in pear basis- en avansearre formules fan tichterby besjen om karakters yn Excel te tellen.

Hoe kinne jo alle tekens yn in berik telle

As it giet om it tellen fan in totaal oantal karakters yn ferskate sellen, is in direkte oplossing dy't yn 't sin komt om it oantal tekens foar elke sel te krijen, en dan dizze nûmers op te tellen:

=LEN(A2)+LEN(A3)+LEN(A4)

Of

=SUM(LEN(A2),LEN(A3),LEN(A4))

De boppesteande formules kinne goed wurkje foar in lyts berik. Om totale karakters yn in grutter berik te tellen, kinne wy ​​better mei wat kompakter komme, bgl. de SUMPRODUCT-funksje, dy't de arrays fermannichfâldiget en de som fan de produkten werombringt.

Hjir is de generike Excel-formule om karakters yn in berik te tellen:

En jo echte formule kin sa lykje:

=SUMPRODUCT(LEN(A1:A7))

In oare manier om karakters yn in berik te tellen is troch de LEN funksje ynkombinaasje mei SUM:

=SUM(LEN(A1:A7))

Oars as SUMPRODUCT, de SUM-funksje berekkent standert gjin arrays, en jo moatte Ctrl + Shift + Enter drukke om it yn in arrayformule te feroarjen.

Lykas oantoand yn it folgjende skermôfbylding, jout de SUM-formule itselde totale oantal tekens werom:

Hoe't dizze formule foar karaktertelling wurket

Dit is ien fan de meast rjochtlinige formules te tellen karakters yn Excel. De LEN-funksje berekkent de tekenrige lingte foar elke sel yn it opjûne berik en jout se werom as in array fan nûmers. En dan, SUMPRODUCT of SUM telt dy nûmers byinoar en jout it totale oantal tekens werom.

Yn it boppesteande foarbyld wurdt in array fan 7 nûmers dy't de lingten fan stringen yn sellen A1 oant A7 fertsjintwurdigje, gearfette:

Opmerking. Soargje asjebleaft dat de Excel LEN-funksje absolút alle tekens yn elke sel telt , ynklusyf letters, sifers, ynterpunksjetekens, spesjale symboalen en alle spaasjes (foarrinnend, efterfolgjend en spaasjes tusken wurden).

Hoe kinne jo spesifike tekens yn in sel telle

Soms, ynstee fan alle tekens binnen in sel te tellen, moatte jo miskien allinich it foarkommen fan in spesifike letter, nûmer of spesjaal symboal telle.

Om it oantal kearen te tellen dat in opjûn karakter yn in sel ferskynt, brûk de LEN-funksje tegearre mei SUBSTITUTE:

Om de formule better te begripen, beskôgje it folgjende foarbyld.

Stel, jo ûnderhâlde in database fan levere items, wêrby't elk itemtype syn eigen unike hat identifier. En elke sel befettet ferskate items skieden troch komma, romte, of in oare delimiter. De taak is om te tellen hoefolle kearen in opjûne unike identifier ferskynt yn elke sel.

Trochwiisd fan dat de list fan levere items is yn kolom B (begjinnend yn B2), en wy telle it oantal "A" foarkommen, is de formule as folget:

=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))

Hoe't dizze Excel-tekentellingformule wurket

Om de logika fan 'e formule te begripen, litte wy brek it op yn lytsere dielen:

• Earst telle jo de totale snaarlengte yn B2:

LEN(B2)

SUBSTITUTE(B2,"A","")

LEN(SUBSTITUTE(B2,"A",""))

As resultaat krije jo it oantal "ferwidere" karakters, dat is lyk oan in totaal oantal fan dat karakterfoarfallen yn 'e sel.

Ynstee fan it karakter oan te jaan wêryn jo telle wolle in formule, kinne jo type it yn guon sel, en dan ferwize dy sel yn in formule. Op dizze manier, jo brûkerssil yn steat wêze om foarfallen te tellen fan elk oar karakter dat se yn dy sel ynfiere sûnder te manipulearjen mei jo formule:

Opmerking. Excel's SUBSTITUTE is in haadlettergefoelige funksje, en dêrom is de boppesteande formule ek haadlettergefoelich. Bygelyks, yn it boppesteande skermôfbylding befettet sel B3 3 foarfallen fan "A" - twa yn haadletters, en ien yn lytse letters. De formule hat allinich de haadletters teld, om't wy "A" levere hawwe oan de SUBSTITUTE-funksje.

Hoofdletter-ûngefoelige Excel-formule om spesifike tekens yn in sel te tellen

As jo ​​in tellen net-gefoelige tekens nedich hawwe, ynbêde dan de UPPER-funksje yn SUBSTITUTE om it opjûne karakter te konvertearjen nei haadletters foardat jo de substitúsje útfiere. En, wês wis dat jo de haadletter yn 'e formule ynfiere.

Bygelyks, om "A" en "a" items te tellen yn sel B2, brûk dizze formule:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))

In oare manier is it brûken fan geneste Substitute-funksjes:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")

Sa't jo kinne sjen yn 'e ûnderste skermôfbylding, telle beide formules feilloos haadletters en lytse letters fan it opjûne karakter:

Yn guon gefallen moatte jo miskien in protte ferskillende tekens yn in tabel telle, mar jo wolle de formule miskien net elke kear feroarje. Nestje yn dit gefal ien Substitute-funksje yn in oare, typ it karakter dat jo wolle telle yn guon sel (D1 yn dit foarbyld), en konvertearje de wearde fan dy sel nei haadletters enlytse letters troch de UPPER en LOWER funksjes te brûken:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))

As alternatyf konvertearje sawol de boarnesel as de sel mei it karakter nei haadletters of lytse letters. Bygelyks:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))

It foardiel fan dizze oanpak is dat, nettsjinsteande oft it haadletter of lytse letter wurdt ynfierd yn de ferwiisde sel, jo case-unsensitive karakter count formule sil de juste telling werombringe:

Tel foarkommen fan bepaalde tekst of substring yn in sel

As jo ​​​​wolle telle hoefolle kear in spesifike kombinaasje fan tekens (d.w.s. bepaalde tekst, of substring) ferskynt yn in opjûne sel, bgl. "A2" of "SS", diel dan it oantal karakters weromjûn troch de boppesteande formules troch de lingte fan de substring.

Hoofdlettergefoelige formule:

=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)

Case-insensitive formule:

=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)

Dêr't B2 de sel is mei de hiele tekststring, en C1 de tekst (substring) is dy't jo wolle telle.

Foar de detaillearre útlis fan de formule, sjoch asjebleaft Hoe spesifike tekst / wurden yn in sel telle.

Hoe spesifyk telle karakter(s) yn in berik

No't jo in Excel-formule kenne om karakters yn in sel te tellen, kinne jo dizze fierder ferbetterje om út te finen hoefolle kearen in bepaald karakter yn in berik ferskynt. Hjirfoar sille wy de Excel LEN-formule nimme om in spesifike char te tellen yn in besprutsen selyn it foarige foarbyld, en set it yn de SUMPRODUCT-funksje dy't arrays kin behannelje:

Yn dit foarbyld nimt de formule de folgjende foarm oan:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

En hjir is in oare formule om te tellen karakters yn it berik fan Excel:

=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

Yn ferliking mei de earste formule is it meast foar de hân lizzende ferskil it brûken fan SUM ynstee fan SUMPRODUCT. In oar ferskil is dat it drukken op Ctrl + Shift + Enter fereasket, om't yn tsjinstelling ta SUMPRODUCT, dat is ûntworpen om arrays te ferwurkjen, SUM arrays allinich kin behannelje as se brûkt wurde yn in arrayformule .

As jo ​​​​dogge As jo ​​​​it karakter yn 'e formule net hardcode wolle, kinne jo it fansels typearje yn guon sel, sis D1, en ferwize nei dy sel yn jo karaktertellingformule:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))

Opmerking. Yn situaasjes as jo it foarkommen fan in spesifike substring yn in berik telle (bgl de substring sil yndividueel teld wurde. Bygelyks:

=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))

Hoe't dizze formule foar it tellen fan tekens wurket

Sa't jo miskien ûnthâlde, wurdt de SUBSTITUTE-funksje brûkt om alle foarkommen fan it opjûne karakter te ferfangen ("A" yn dit foarbyld ) mei in lege tekststring ("").

Dan leverje wy de tekststring weromjûn troch SUBSTITUTE oan de Excel LENfunksje sadat it berekkent de string lingte sûnder A's. En dan, wy lûke dat karakter count fan de totale lingte fan de tekst tekenrige. It resultaat fan dizze berekkeningen is in array fan karakter counts, mei ien karakter count per sel.

Uteinlik somt SUMPRODUCT de nûmers yn 'e array en jout it totale oantal fan it opjûne karakter yn it berik werom.

In formule-ûngefoelige formule om spesifike tekens yn in berik te tellen

Jo witte al dat SUBSTITUTE in haadlettergefoelige funksje is, wat ús Excel-formule foar karaktertelling ek haadlettergefoelich makket.

Om de formule it gefal te negearjen, folgje de oanwêzigen dy't yn it foarige foarbyld oantoand binne: Case-ûngefoelige formule om spesifike tekens yn in sel te tellen.

Yn it bysûnder kinne jo ien fan 'e folgjende formules brûke om te tellen spesifike tekens yn in berik wêrby't haadletters negearje:

• Brûk de UPPER-funksje en fier in karakter yn mei haadletters:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A","")))

• Brûk nestede SUBSTITUTE-funksjes:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a","")))

• Brûk UPPER en LOWER funksjes, typ in haadletter as in lytse letter yn guon sel, en ferwize dy sel yn jo formule:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))

De ûndersteande skermôfbylding toant de lêste formule yn aksje:

Tip. Om it foarkommen fan in spesifike tekst (substring) yn in berik te tellen, brûk de formule demonstrearre yn Hoe spesifike tekst / wurden yn in berik telle.

Ditis hoe't jo karakters yn Excel kinne telle mei de LEN-funksje. As jo ​​​​wolle witte hoe't jo wurden telle ynstee fan yndividuele karakters, sille jo in pear nuttige formules fine yn ús folgjende artikel, bliuw dan op 'e hichte!

Yn 'e tuskentiid kinne jo in foarbyld fan wurkboeken downloade mei formule foar karaktertelling besprutsen yn dizze tutorial, en besjoch in list mei relatearre boarnen oan 'e ein fan' e side. Ik tankje jo foar it lêzen en hoopje dy gau te sjen!