Упатството објаснува како да броите знаци во Excel. Ќе ги научите формулите за да го добиете вкупниот број на знаци во опсег и да броите само одредени знаци во ќелија или во неколку ќелии.

Нашето претходно упатство ја претстави функцијата Excel LEN, која овозможува броење на вкупен број на знаци во ќелија.

Формулата LEN е корисна сама по себе, но во врска со други функции како SUM, SUMPRODUCT и SUBSTITUTE, може да се справи со многу посложени задачи. Понатаму во ова упатство, ќе разгледаме неколку основни и напредни формули за броење знаци во Excel.

Како да ги броиме сите знаци во опсег

Кога станува збор за броење вкупен број знаци во неколку ќелии, веднаш решение што ми паѓа на ум е да го добиете бројот на знаци за секоја ќелија, а потоа да ги соберете тие броеви:

=LEN(A2)+LEN(A3)+LEN(A4)

Или

=SUM(LEN(A2),LEN(A3),LEN(A4))

Горените формули може да работат добро за мал опсег. За да броиме вкупни знаци во поголем опсег, подобро е да смислиме нешто покомпактно, на пр. функцијата SUMPRODUCT, која ги множи низите и го враќа збирот на производите.

Еве ја генеричката формула на Excel за броење знаци во опсег:

И вашата реална формула може да изгледа слична на ова:

=SUMPRODUCT(LEN(A1:A7))

Друг начин за броење знаци во опсег е да се користи Функцијата LEN вокомбинација со SUM:

=SUM(LEN(A1:A7))

За разлика од SUMPRODUCT, функцијата SUM стандардно не пресметува низи и треба да притиснете Ctrl + Shift + Enter за да ја претворите во формула за низа.

Како што е прикажано на следната слика од екранот, формулата SUM го враќа истиот вкупен број на знаци:

Како функционира оваа формула за броење знаци на опсег

Ова е една од наједноставните формули за броење знаци во Excel. Функцијата LEN ја пресметува должината на низата за секоја ќелија во наведениот опсег и ги враќа како низа од броеви. А потоа, SUMPRODUCT или SUM ги собира тие броеви и го враќа вкупниот број на знаци.

Во горниот пример, се сумира низа од 7 броеви што ги претставуваат должините на низите во ќелиите A1 до A7:

Забелешка. Обрнете внимание дека функцијата Excel LEN ги брои апсолутно сите знаци во секоја ќелија , вклучувајќи ги буквите, бројките, интерпункциските знаци, специјалните симболи и сите празни места (водни, заостанати и празни места помеѓу зборовите).

Како да броите одредени знаци во ќелија

Понекогаш, наместо да ги броите сите знаци во ќелијата, можеби ќе треба да ги броите само појавувањата на одредена буква, број или посебен симбол.

За да броите колку пати даден знак се појавува во ќелија, користете ја функцијата LEN заедно со SUBSTITUTE:

За подобро да ја разберете формулата, разгледајте го следниов пример.

Да претпоставиме дека одржувате база на податоци за испорачани ставки, каде што секој тип на ставка има свој уникатен идентификатор. И секоја ќелија содржи неколку ставки одделени со запирка, празно место или кој било друг разграничувач. Задачата е да се брои колку пати даден уникатен идентификатор се појавува во секоја ќелија.

Претпоставувајќи дека листата на доставени ставки е во колоната Б (почнува во Б2), а ние го броиме бројот на „А“ појави, формулата е следна:

=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))

Како работи оваа формула за броење знаци во Excel

За да ја разбереме логиката на формулата, ајде да разделете го на помали делови:

• Прво, ја броите вкупната должина на низата во B2:

LEN(B2)

SUBSTITUTE(B2,"A","")

LEN(SUBSTITUTE(B2,"A",""))

Како резултат на тоа, го добивате бројот на „отстранети“ знаци, што е еднакво на вкупниот број на појавувања на тие знаци во ќелијата.

Наместо да го наведете знакот што сакате да го броите во формула, можете да ја напишете во некоја ќелија, а потоа да ја упатите таа ќелија во формула. На овој начин, вашите кориснициќе може да ги брои појавите на кој било друг знак што ќе го внесат во таа ќелија без да ја помешаат вашата формула:

Забелешка. SUBSTITUTE на Excel е функција чувствителна на големи букви, и затоа горната формула е исто така чувствителна на букви. На пример, во горната слика од екранот, ќелијата B3 содржи 3 појави на „А“ - две со големи букви и една со мали букви. Формулата ги брои само големите знаци затоа што и дадовме „A“ на функцијата SUBSTITUTE.

Ексел формула без чувствителност на големи букви за броење одредени знаци во ќелија

Ако ви треба број на знаци без букви, вметнете ја функцијата UPPER во SUBSTITUTE за да го конвертирате наведениот знак во големи букви пред да ја извршите замената. И, не заборавајте да внесете големи букви во формулата.

На пример, за броење ставки „A“ и „a“ во ќелијата B2, користете ја оваа формула:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))

Друг начин е да се користат вгнездени функции за замена:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")

Како што можете да видите на сликата подолу од екранот, и двете формули беспрекорно ги бројат големите и малите букви појави на наведениот знак:

Во некои случаи, можеби ќе треба да броите многу различни знаци во табела, но можеби нема да сакате да ја менувате формулата секој пат. Во овој случај, вметнете една функција замена во друга, напишете го знакот што сакате да го броите во некоја ќелија (D1 во овој пример) и претворете ја вредноста на таа ќелија во големи букви имали букви со користење на функциите UPPER и LOWER:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))

Алтернативно, конвертирај ја и изворната ќелија и ќелијата што го содржи знакот или во големи или мали букви. На пример:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))

Предноста на овој пристап е што без разлика дали големите или малите букви се внесени во референцираната ќелија, вашата формула за броење знаци нечувствителна на букви ќе го врати вистинското броење:

Број на појави на одреден текст или подниза во ќелија

Ако сакате да броите колку пати специфична комбинација на знаци (т.е. одреден текст или подниза) се појавува во дадена ќелија, на пр. „A2“ или „SS“, потоа поделете го бројот на знаци вратени со горенаведените формули со должината на поднизата.

Осетливи на букви формула:

=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)

Без чувствителност на букви формула:

=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)

каде B2 е ќелијата што ја содржи целата текстуална низа, а C1 е текстот (поднизата) што вие сакате да броите.

За детално објаснување на формулата, погледнете Како да броите одреден текст/зборови во ќелија.

Како да броите одредени знак(и) во опсег

Сега кога знаете формула на Excel за броење знаци во ќелија, можеби ќе сакате дополнително да ја подобрите за да дознаете колку пати одреден знак се појавува во опсегот. За ова, ќе ја земеме формулата Excel LEN за да броиме специфичен знак во ќелијата што се дискутираво претходниот пример и ставете ја во функцијата SUMPRODUCT која може да ракува со низи:

Во овој пример, формулата ја добива следната форма:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

И еве уште една формула за броење знаци во опсегот на Excel:

=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

Во споредба со првата формула, најочигледната разлика е користењето SUM наместо SUMPRODUCT. Друга разлика е во тоа што бара притискање на Ctrl + Shift + Enter бидејќи за разлика од SUMPRODUCT, кој е дизајниран да обработува низи, SUM може да ракува со низи само кога се користи во формула за низа .

Ако не Ако сакате да го шифрирате знакот во формулата, секако можете да го напишете во некоја ќелија, да речеме D1, и да ја наведете таа ќелија во формулата за броење знаци:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))

Забелешка. Во ситуации кога ги броите појавите на специфична подниза во опсег (на пр. нарачки кои започнуваат со „KK“ или „AA“), треба да го поделите бројот на знаци со должината на поднизата, инаку секој знак во поднизата ќе се брои поединечно. На пример:

=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))

Како функционира оваа формула за броење знаци

Како што се сеќавате, функцијата SUBSTITUTE се користи за замена на сите појави на наведениот знак („A“ во овој пример ) со празна текстуална низа ("").

Потоа, ја снабдуваме текстуалната низа вратена од SUBSTITUTE во Excel LENфункција така што ја пресметува должината на низата без А. А потоа, го одземаме тој број на знаци од вкупната должина на текстуалната низа. Резултатот од овие пресметки е низа брои знаци, со еден број на знаци по ќелија.

На крајот, SUMPRODUCT ги сумира броевите во низата и го враќа вкупниот број на наведениот знак во опсегот.

Формула без чувствителност на букви за броење одредени знаци во опсег

Веќе знаете дека SUBSTITUTE е функција осетлива на големи букви, што ја прави нашата формула на Excel за број на знаци чувствителна и на големи букви.

За да направите формулата да игнорира букви, следете ги пристапите прикажани во претходниот пример: Формула без букви за броење одредени знаци во ќелија.

Особено, можете да користите една од следниве формули за броење специфични знаци во опсег што игнорира букви:

• Користете ја функцијата UPPER и внесете знак со големи букви:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A","")))

• Користете вгнездени SUBSTITUTE функции:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a","")))

• Користете ги функциите UPPER и LOWER, внесете големи или мали букви во некоја ќелија и упатете ја таа ќелија во вашата формула:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))

Подолу скриншот ја прикажува последната формула во акција:

Совет. За да ги броите појавувањата на специфичен текст (подниза) во опсег, користете ја формулата демонстрирана во Како да броите одреден текст/зборови во опсег.

Овае како можете да броите знаци во Excel користејќи ја функцијата LEN. Ако сакате да знаете како да броите зборови, а не поединечни знаци, ќе најдете неколку корисни формули во нашата следна статија, ве молиме останете присутни!

Во меѓувреме, можете да преземете примерок од работни книги со формула за броење знаци дискутирано во ова упатство и проверете список на поврзани ресурси на крајот од страницата. Ви благодарам што прочитавте и се надевам дека ќе се видиме наскоро!