ਟਿਊਟੋਰਿਅਲ ਦੱਸਦਾ ਹੈ ਕਿ ਐਕਸਲ ਵਿੱਚ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਿਵੇਂ ਕਰਨੀ ਹੈ। ਤੁਸੀਂ ਇੱਕ ਰੇਂਜ ਵਿੱਚ ਕੁੱਲ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਪ੍ਰਾਪਤ ਕਰਨ ਲਈ ਫਾਰਮੂਲੇ ਸਿੱਖੋਗੇ, ਅਤੇ ਇੱਕ ਸੈੱਲ ਜਾਂ ਕਈ ਸੈੱਲਾਂ ਵਿੱਚ ਸਿਰਫ਼ ਖਾਸ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰੋਗੇ।

ਸਾਡੇ ਪਿਛਲੇ ਟਿਊਟੋਰਿਅਲ ਵਿੱਚ ਐਕਸਲ LEN ਫੰਕਸ਼ਨ ਪੇਸ਼ ਕੀਤਾ ਗਿਆ ਸੀ, ਜੋ ਇੱਕ ਸੈੱਲ ਵਿੱਚ ਅੱਖਰਾਂ ਦੀ ਕੁੱਲ ਸੰਖਿਆ।

LEN ਫਾਰਮੂਲਾ ਆਪਣੇ ਆਪ ਲਾਭਦਾਇਕ ਹੈ, ਪਰ ਹੋਰ ਫੰਕਸ਼ਨਾਂ ਜਿਵੇਂ ਕਿ SUM, SUMPRODUCT ਅਤੇ SUBSTITUTE ਨਾਲ ਤਾਲਮੇਲ ਵਿੱਚ, ਇਹ ਬਹੁਤ ਜ਼ਿਆਦਾ ਗੁੰਝਲਦਾਰ ਕੰਮਾਂ ਨੂੰ ਸੰਭਾਲ ਸਕਦਾ ਹੈ। ਇਸ ਟਿਊਟੋਰਿਅਲ ਵਿੱਚ ਅੱਗੇ, ਅਸੀਂ ਐਕਸਲ ਵਿੱਚ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ ਕੁਝ ਬੁਨਿਆਦੀ ਅਤੇ ਉੱਨਤ ਫਾਰਮੂਲਿਆਂ 'ਤੇ ਡੂੰਘਾਈ ਨਾਲ ਵਿਚਾਰ ਕਰਨ ਜਾ ਰਹੇ ਹਾਂ।

ਇੱਕ ਰੇਂਜ ਵਿੱਚ ਸਾਰੇ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਿਵੇਂ ਕਰੀਏ

ਜਦੋਂ ਕਈ ਸੈੱਲਾਂ ਵਿੱਚ ਅੱਖਰਾਂ ਦੀ ਕੁੱਲ ਗਿਣਤੀ ਦੀ ਗਿਣਤੀ ਕਰਨ ਦੀ ਗੱਲ ਆਉਂਦੀ ਹੈ, ਤਾਂ ਇੱਕ ਤੁਰੰਤ ਹੱਲ ਜੋ ਦਿਮਾਗ ਵਿੱਚ ਆਉਂਦਾ ਹੈ ਉਹ ਹੈ ਹਰੇਕ ਸੈੱਲ ਲਈ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਪ੍ਰਾਪਤ ਕਰਨਾ, ਅਤੇ ਫਿਰ ਉਹਨਾਂ ਸੰਖਿਆਵਾਂ ਨੂੰ ਜੋੜਨਾ:

=LEN(A2)+LEN(A3)+LEN(A4)

ਜਾਂ

=SUM(LEN(A2),LEN(A3),LEN(A4))

ਉਪਰੋਕਤ ਫਾਰਮੂਲੇ ਛੋਟੀ ਰੇਂਜ ਲਈ ਵਧੀਆ ਕੰਮ ਕਰ ਸਕਦੇ ਹਨ। ਇੱਕ ਵੱਡੀ ਰੇਂਜ ਵਿੱਚ ਕੁੱਲ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ, ਅਸੀਂ ਬਿਹਤਰ ਕੁਝ ਹੋਰ ਸੰਖੇਪ ਲੈ ਕੇ ਆਵਾਂਗੇ, ਉਦਾਹਰਨ ਲਈ SUMPRODUCT ਫੰਕਸ਼ਨ, ਜੋ ਐਰੇ ਨੂੰ ਗੁਣਾ ਕਰਦਾ ਹੈ ਅਤੇ ਉਤਪਾਦਾਂ ਦਾ ਜੋੜ ਵਾਪਸ ਕਰਦਾ ਹੈ।

ਰੇਂਜ ਵਿੱਚ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ ਇੱਥੇ ਆਮ ਐਕਸਲ ਫਾਰਮੂਲਾ ਹੈ:

ਅਤੇ ਤੁਹਾਡਾ ਅਸਲ-ਜੀਵਨ ਦਾ ਫਾਰਮੂਲਾ ਇਸ ਤਰ੍ਹਾਂ ਦਿਖਾਈ ਦੇ ਸਕਦਾ ਹੈ:

=SUMPRODUCT(LEN(A1:A7))

ਇੱਕ ਰੇਂਜ ਵਿੱਚ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਦਾ ਇੱਕ ਹੋਰ ਤਰੀਕਾ ਹੈ ਵਿੱਚ LEN ਫੰਕਸ਼ਨSUM:

=SUM(LEN(A1:A7))

SUMPRODUCT ਦੇ ਉਲਟ, SUM ਫੰਕਸ਼ਨ ਮੂਲ ਰੂਪ ਵਿੱਚ ਐਰੇ ਦੀ ਗਣਨਾ ਨਹੀਂ ਕਰਦਾ ਹੈ, ਅਤੇ ਤੁਹਾਨੂੰ ਇਸਨੂੰ ਇੱਕ ਐਰੇ ਫਾਰਮੂਲੇ ਵਿੱਚ ਬਦਲਣ ਲਈ Ctrl + Shift + Enter ਦਬਾਉਣ ਦੀ ਲੋੜ ਹੈ।

ਜਿਵੇਂ ਕਿ ਹੇਠਾਂ ਦਿੱਤੇ ਸਕ੍ਰੀਨਸ਼ੌਟ ਵਿੱਚ ਪ੍ਰਦਰਸ਼ਿਤ ਕੀਤਾ ਗਿਆ ਹੈ, SUM ਫਾਰਮੂਲਾ ਉਹੀ ਕੁੱਲ ਅੱਖਰ ਗਿਣਤੀ ਵਾਪਸ ਕਰਦਾ ਹੈ:

ਇਹ ਰੇਂਜ ਅੱਖਰ ਗਿਣਤੀ ਫਾਰਮੂਲਾ ਕਿਵੇਂ ਕੰਮ ਕਰਦਾ ਹੈ

ਇਹ ਐਕਸਲ ਵਿੱਚ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ ਸਭ ਤੋਂ ਸਿੱਧੇ ਫਾਰਮੂਲੇ ਵਿੱਚੋਂ ਇੱਕ ਹੈ। LEN ਫੰਕਸ਼ਨ ਨਿਰਧਾਰਤ ਰੇਂਜ ਵਿੱਚ ਹਰੇਕ ਸੈੱਲ ਲਈ ਸਟ੍ਰਿੰਗ ਦੀ ਲੰਬਾਈ ਦੀ ਗਣਨਾ ਕਰਦਾ ਹੈ ਅਤੇ ਉਹਨਾਂ ਨੂੰ ਸੰਖਿਆਵਾਂ ਦੀ ਇੱਕ ਐਰੇ ਵਜੋਂ ਵਾਪਸ ਕਰਦਾ ਹੈ। ਅਤੇ ਫਿਰ, SUMPRODUCT ਜਾਂ SUM ਉਹਨਾਂ ਸੰਖਿਆਵਾਂ ਨੂੰ ਜੋੜਦਾ ਹੈ ਅਤੇ ਕੁੱਲ ਅੱਖਰ ਗਿਣਤੀ ਵਾਪਸ ਕਰਦਾ ਹੈ।

ਉਪਰੋਕਤ ਉਦਾਹਰਨ ਵਿੱਚ, 7 ਸੰਖਿਆਵਾਂ ਦੀ ਇੱਕ ਐਰੇ ਜੋ ਸੈੱਲ A1 ਤੋਂ A7 ਵਿੱਚ ਸਤਰ ਦੀ ਲੰਬਾਈ ਨੂੰ ਦਰਸਾਉਂਦੀ ਹੈ:

ਨੋਟ। ਕਿਰਪਾ ਕਰਕੇ ਧਿਆਨ ਦਿਓ ਕਿ ਐਕਸਲ LEN ਫੰਕਸ਼ਨ ਪੂਰੀ ਤਰ੍ਹਾਂ ਨਾਲ ਹਰੇਕ ਸੈੱਲ ਵਿੱਚ ਸਾਰੇ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰਦਾ ਹੈ , ਜਿਸ ਵਿੱਚ ਅੱਖਰ, ਸੰਖਿਆਵਾਂ, ਵਿਰਾਮ ਚਿੰਨ੍ਹ, ਵਿਸ਼ੇਸ਼ ਚਿੰਨ੍ਹ, ਅਤੇ ਸਾਰੀਆਂ ਖਾਲੀ ਥਾਂਵਾਂ (ਅਗਲੇ, ਪਿੱਛੇ ਅਤੇ ਸ਼ਬਦਾਂ ਦੇ ਵਿਚਕਾਰ ਖਾਲੀ ਥਾਂਵਾਂ) ਸ਼ਾਮਲ ਹਨ।

ਕਿਸੇ ਸੈੱਲ ਵਿੱਚ ਖਾਸ ਅੱਖਰਾਂ ਨੂੰ ਕਿਵੇਂ ਗਿਣਿਆ ਜਾਵੇ

ਕਈ ਵਾਰ, ਇੱਕ ਸੈੱਲ ਦੇ ਅੰਦਰ ਸਾਰੇ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਦੀ ਬਜਾਏ, ਤੁਹਾਨੂੰ ਸਿਰਫ਼ ਇੱਕ ਖਾਸ ਅੱਖਰ, ਸੰਖਿਆ, ਜਾਂ ਵਿਸ਼ੇਸ਼ ਚਿੰਨ੍ਹ ਦੀਆਂ ਘਟਨਾਵਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਦੀ ਲੋੜ ਹੋ ਸਕਦੀ ਹੈ।

ਕਿਸੇ ਸੈੱਲ ਵਿੱਚ ਦਿੱਤੇ ਗਏ ਅੱਖਰ ਦੇ ਦਿਖਾਈ ਦੇਣ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ, LEN ਫੰਕਸ਼ਨ ਨੂੰ SUBSTITUTE ਦੇ ਨਾਲ ਵਰਤੋ:

ਫਾਰਮੂਲੇ ਨੂੰ ਬਿਹਤਰ ਤਰੀਕੇ ਨਾਲ ਸਮਝਣ ਲਈ, ਹੇਠਾਂ ਦਿੱਤੀ ਉਦਾਹਰਣ 'ਤੇ ਵਿਚਾਰ ਕਰੋ।

ਮੰਨ ਲਓ, ਤੁਸੀਂ ਡਿਲੀਵਰ ਕੀਤੀਆਂ ਆਈਟਮਾਂ ਦਾ ਇੱਕ ਡੇਟਾਬੇਸ ਬਣਾਈ ਰੱਖਦੇ ਹੋ, ਜਿੱਥੇ ਹਰੇਕ ਆਈਟਮ ਦੀ ਕਿਸਮ ਦੀ ਆਪਣੀ ਵਿਲੱਖਣ ਹੁੰਦੀ ਹੈ। ਪਛਾਣਕਰਤਾ ਅਤੇ ਹਰੇਕ ਸੈੱਲ ਵਿੱਚ ਕੌਮੇ, ਸਪੇਸ, ਜਾਂ ਕਿਸੇ ਹੋਰ ਡੀਲੀਮੀਟਰ ਦੁਆਰਾ ਵੱਖ ਕੀਤੀਆਂ ਕਈ ਆਈਟਮਾਂ ਸ਼ਾਮਲ ਹੁੰਦੀਆਂ ਹਨ। ਕੰਮ ਇਹ ਗਿਣਨਾ ਹੈ ਕਿ ਹਰੇਕ ਸੈੱਲ ਵਿੱਚ ਦਿੱਤੀ ਗਈ ਵਿਲੱਖਣ ਪਛਾਣਕਰਤਾ ਕਿੰਨੀ ਵਾਰ ਦਿਖਾਈ ਦਿੰਦਾ ਹੈ।

ਇਹ ਮੰਨ ਕੇ ਕਿ ਡਿਲੀਵਰ ਕੀਤੀਆਂ ਆਈਟਮਾਂ ਦੀ ਸੂਚੀ ਕਾਲਮ B ਵਿੱਚ ਹੈ (B2 ਤੋਂ ਸ਼ੁਰੂ ਹੁੰਦੀ ਹੈ), ਅਤੇ ਅਸੀਂ "A" ਦੀ ਗਿਣਤੀ ਗਿਣ ਰਹੇ ਹਾਂ। ਮੌਜੂਦਗੀ, ਫਾਰਮੂਲਾ ਇਸ ਤਰ੍ਹਾਂ ਹੈ:

=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))

ਇਹ ਐਕਸਲ ਅੱਖਰ ਗਿਣਤੀ ਫਾਰਮੂਲਾ ਕਿਵੇਂ ਕੰਮ ਕਰਦਾ ਹੈ

ਫਾਰਮੂਲੇ ਦੇ ਤਰਕ ਨੂੰ ਸਮਝਣ ਲਈ, ਆਓ ਕਰੀਏ ਇਸਨੂੰ ਛੋਟੇ ਹਿੱਸਿਆਂ ਵਿੱਚ ਵੰਡੋ:

• ਪਹਿਲਾਂ, ਤੁਸੀਂ B2 ਵਿੱਚ ਕੁੱਲ ਸਤਰ ਦੀ ਲੰਬਾਈ ਗਿਣਦੇ ਹੋ:

LEN(B2)

SUBSTITUTE(B2,"A","")

LEN(SUBSTITUTE(B2,"A",""))

ਨਤੀਜੇ ਵਜੋਂ, ਤੁਸੀਂ "ਹਟਾਏ" ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਪ੍ਰਾਪਤ ਕਰਦੇ ਹੋ, ਜੋ ਕਿ ਸੈੱਲ ਵਿੱਚ ਉਸ ਅੱਖਰ ਦੀ ਸੰਖਿਆ ਦੀ ਕੁੱਲ ਗਿਣਤੀ ਦੇ ਬਰਾਬਰ ਹੈ।

ਉਸ ਅੱਖਰ ਨੂੰ ਨਿਰਧਾਰਤ ਕਰਨ ਦੀ ਬਜਾਏ ਜਿਸ ਵਿੱਚ ਤੁਸੀਂ ਗਿਣਨਾ ਚਾਹੁੰਦੇ ਹੋ ਇੱਕ ਫਾਰਮੂਲਾ, ਤੁਸੀਂ ਇਸਨੂੰ ਕਿਸੇ ਸੈੱਲ ਵਿੱਚ ਟਾਈਪ ਕਰ ਸਕਦੇ ਹੋ, ਅਤੇ ਫਿਰ ਇੱਕ ਫਾਰਮੂਲੇ ਵਿੱਚ ਉਸ ਸੈੱਲ ਦਾ ਹਵਾਲਾ ਦੇ ਸਕਦੇ ਹੋ। ਇਸ ਤਰੀਕੇ ਨਾਲ, ਤੁਹਾਡੇ ਉਪਭੋਗਤਾਤੁਹਾਡੇ ਫ਼ਾਰਮੂਲੇ ਨਾਲ ਛੇੜਛਾੜ ਕੀਤੇ ਬਿਨਾਂ ਕਿਸੇ ਹੋਰ ਅੱਖਰ ਦੀ ਮੌਜੂਦਗੀ ਨੂੰ ਗਿਣਨ ਦੇ ਯੋਗ ਹੋਵੇਗਾ ਜੋ ਉਹ ਸੈੱਲ ਵਿੱਚ ਦਾਖਲ ਕਰਦੇ ਹਨ:

ਨੋਟ ਕਰੋ। ਐਕਸਲ ਦਾ ਸਬਸਟੀਟਿਊਟ ਇੱਕ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਫੰਕਸ਼ਨ ਹੈ, ਅਤੇ ਇਸਲਈ ਉਪਰੋਕਤ ਫਾਰਮੂਲਾ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਵੀ ਹੈ। ਉਦਾਹਰਨ ਲਈ, ਉਪਰੋਕਤ ਸਕ੍ਰੀਨਸ਼ੌਟ ਵਿੱਚ, ਸੈੱਲ B3 ਵਿੱਚ "A" ਦੀਆਂ 3 ਘਟਨਾਵਾਂ ਹਨ - ਦੋ ਵੱਡੇ ਅੱਖਰਾਂ ਵਿੱਚ, ਅਤੇ ਇੱਕ ਛੋਟੇ ਅੱਖਰਾਂ ਵਿੱਚ। ਫਾਰਮੂਲੇ ਵਿੱਚ ਸਿਰਫ਼ ਵੱਡੇ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕੀਤੀ ਗਈ ਹੈ ਕਿਉਂਕਿ ਅਸੀਂ SUBSTITUTE ਫੰਕਸ਼ਨ ਨੂੰ "A" ਸਪਲਾਈ ਕੀਤਾ ਹੈ।

ਕਿਸੇ ਸੈੱਲ ਵਿੱਚ ਖਾਸ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਐਕਸਲ ਫਾਰਮੂਲਾ

ਜੇਕਰ ਤੁਹਾਨੂੰ ਇੱਕ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਅੱਖਰ ਗਿਣਤੀ ਦੀ ਲੋੜ ਹੈ, ਤਾਂ ਬਦਲ ਨੂੰ ਚਲਾਉਣ ਤੋਂ ਪਹਿਲਾਂ ਦਿੱਤੇ ਅੱਖਰ ਨੂੰ ਵੱਡੇ ਅੱਖਰਾਂ ਵਿੱਚ ਬਦਲਣ ਲਈ SUBSTITUTE ਦੇ ਅੰਦਰ UPPER ਫੰਕਸ਼ਨ ਨੂੰ ਏਮਬੇਡ ਕਰੋ। ਅਤੇ, ਫਾਰਮੂਲੇ ਵਿੱਚ ਵੱਡੇ ਅੱਖਰ ਦਰਜ ਕਰਨਾ ਯਕੀਨੀ ਬਣਾਓ।

ਉਦਾਹਰਨ ਲਈ, ਸੈੱਲ B2 ਵਿੱਚ "A" ਅਤੇ "a" ਆਈਟਮਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ, ਇਹ ਫਾਰਮੂਲਾ ਵਰਤੋ:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))

ਇੱਕ ਹੋਰ ਤਰੀਕਾ ਹੈ ਨੇਸਟਡ ਸਬਸਟੀਟਿਊਟ ਫੰਕਸ਼ਨਾਂ ਦੀ ਵਰਤੋਂ ਕਰਨਾ:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")

ਜਿਵੇਂ ਕਿ ਤੁਸੀਂ ਹੇਠਾਂ ਦਿੱਤੇ ਸਕ੍ਰੀਨਸ਼ੌਟ ਵਿੱਚ ਦੇਖ ਸਕਦੇ ਹੋ, ਦੋਵੇਂ ਫਾਰਮੂਲੇ ਨਿਰਧਾਰਿਤ ਅੱਖਰ ਦੇ ਵੱਡੇ ਅਤੇ ਛੋਟੇ ਅੱਖਰਾਂ ਦੀਆਂ ਘਟਨਾਵਾਂ ਨੂੰ ਨਿਰਵਿਘਨ ਗਿਣਦੇ ਹਨ:

ਕੁਝ ਮਾਮਲਿਆਂ ਵਿੱਚ, ਤੁਹਾਨੂੰ ਇੱਕ ਸਾਰਣੀ ਵਿੱਚ ਕਈ ਵੱਖ-ਵੱਖ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਦੀ ਲੋੜ ਹੋ ਸਕਦੀ ਹੈ, ਪਰ ਹੋ ਸਕਦਾ ਹੈ ਕਿ ਤੁਸੀਂ ਹਰ ਵਾਰ ਫਾਰਮੂਲੇ ਨੂੰ ਸੋਧਣਾ ਨਾ ਚਾਹੋ। ਇਸ ਸਥਿਤੀ ਵਿੱਚ, ਨੇਸਟ ਇੱਕ ਸਬਸਟੀਟਿਊਟ ਫੰਕਸ਼ਨ ਦੂਜੇ ਦੇ ਅੰਦਰ, ਉਹ ਅੱਖਰ ਟਾਈਪ ਕਰੋ ਜਿਸਨੂੰ ਤੁਸੀਂ ਕਿਸੇ ਸੈੱਲ ਵਿੱਚ ਗਿਣਨਾ ਚਾਹੁੰਦੇ ਹੋ (ਇਸ ਉਦਾਹਰਨ ਵਿੱਚ D1), ਅਤੇ ਉਸ ਸੈੱਲ ਦੇ ਮੁੱਲ ਨੂੰ ਵੱਡੇ ਅੱਖਰਾਂ ਵਿੱਚ ਬਦਲੋ ਅਤੇUPPER ਅਤੇ LOWER ਫੰਕਸ਼ਨਾਂ ਦੀ ਵਰਤੋਂ ਕਰਕੇ ਛੋਟੇ ਅੱਖਰ:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))

ਵਿਕਲਪਿਕ ਤੌਰ 'ਤੇ, ਸਰੋਤ ਸੈੱਲ ਅਤੇ ਅੱਖਰ ਵਾਲੇ ਸੈੱਲ ਦੋਵਾਂ ਨੂੰ ਵੱਡੇ ਜਾਂ ਛੋਟੇ ਅੱਖਰ ਵਿੱਚ ਬਦਲੋ। ਉਦਾਹਰਨ ਲਈ:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))

ਇਸ ਪਹੁੰਚ ਦਾ ਫਾਇਦਾ ਇਹ ਹੈ ਕਿ ਭਾਵੇਂ ਵੱਡੇ ਅੱਖਰ ਜਾਂ ਛੋਟੇ ਅੱਖਰ ਸੰਦਰਭ ਵਾਲੇ ਸੈੱਲ ਵਿੱਚ ਇਨਪੁਟ ਹਨ, ਤੁਹਾਡਾ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਅੱਖਰ ਗਿਣਤੀ ਫਾਰਮੂਲਾ ਸਹੀ ਗਿਣਤੀ ਵਾਪਸ ਕਰੇਗਾ:

ਕਿਸੇ ਸੈੱਲ ਵਿੱਚ ਕੁਝ ਟੈਕਸਟ ਜਾਂ ਸਬਸਟਰਿੰਗ ਦੀਆਂ ਘਟਨਾਵਾਂ ਦੀ ਗਿਣਤੀ ਕਰੋ

ਜੇ ਤੁਸੀਂ ਇਹ ਗਿਣਨਾ ਚਾਹੁੰਦੇ ਹੋ ਕਿ ਕਿੰਨੀ ਵਾਰ ਅੱਖਰਾਂ ਦਾ ਖਾਸ ਸੁਮੇਲ (ਜਿਵੇਂ ਕਿ ਕੁਝ ਟੈਕਸਟ, ਜਾਂ ਸਬਸਟ੍ਰਿੰਗ) ਦਿੱਤੇ ਗਏ ਸੈੱਲ ਵਿੱਚ ਦਿਖਾਈ ਦਿੰਦਾ ਹੈ, ਉਦਾਹਰਨ ਲਈ "A2" ਜਾਂ "SS", ਫਿਰ ਉਪਰੋਕਤ ਫ਼ਾਰਮੂਲੇ ਦੁਆਰਾ ਦਿੱਤੇ ਅੱਖਰਾਂ ਦੀ ਸੰਖਿਆ ਨੂੰ ਸਬਸਟਰਿੰਗ ਦੀ ਲੰਬਾਈ ਨਾਲ ਵੰਡੋ।

ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਫਾਰਮੂਲਾ:

=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)

ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਫਾਰਮੂਲਾ:

=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)

ਜਿੱਥੇ B2 ਪੂਰੀ ਟੈਕਸਟ ਸਟ੍ਰਿੰਗ ਵਾਲਾ ਸੈੱਲ ਹੈ, ਅਤੇ C1 ਟੈਕਸਟ (ਸਬਸਟ੍ਰਿੰਗ) ਹੈ ਜੋ ਤੁਸੀਂ ਗਿਣਤੀ ਕਰਨਾ ਚਾਹੁੰਦੇ ਹੋ।

ਫਾਰਮੂਲੇ ਦੀ ਵਿਸਤ੍ਰਿਤ ਵਿਆਖਿਆ ਲਈ, ਕਿਰਪਾ ਕਰਕੇ ਦੇਖੋ ਕਿ ਸੈੱਲ ਵਿੱਚ ਖਾਸ ਟੈਕਸਟ / ਸ਼ਬਦਾਂ ਨੂੰ ਕਿਵੇਂ ਗਿਣਿਆ ਜਾਵੇ।

ਖਾਸ ਨੂੰ ਕਿਵੇਂ ਗਿਣਿਆ ਜਾਵੇ ਇੱਕ ਰੇਂਜ ਵਿੱਚ ਅੱਖਰ(ਆਂ)

ਹੁਣ ਜਦੋਂ ਤੁਸੀਂ ਇੱਕ ਸੈੱਲ ਵਿੱਚ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ ਇੱਕ ਐਕਸਲ ਫਾਰਮੂਲਾ ਜਾਣਦੇ ਹੋ, ਤਾਂ ਤੁਸੀਂ ਇਹ ਪਤਾ ਲਗਾਉਣ ਲਈ ਇਸ ਵਿੱਚ ਹੋਰ ਸੁਧਾਰ ਕਰ ਸਕਦੇ ਹੋ ਕਿ ਇੱਕ ਖਾਸ ਅੱਖਰ ਇੱਕ ਰੇਂਜ ਵਿੱਚ ਕਿੰਨੀ ਵਾਰ ਦਿਖਾਈ ਦਿੰਦਾ ਹੈ। ਇਸਦੇ ਲਈ, ਅਸੀਂ ਚਰਚਾ ਕੀਤੇ ਸੈੱਲ ਵਿੱਚ ਇੱਕ ਖਾਸ ਅੱਖਰ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ ਐਕਸਲ LEN ਫਾਰਮੂਲਾ ਲਵਾਂਗੇਪਿਛਲੀ ਉਦਾਹਰਨ ਵਿੱਚ, ਅਤੇ ਇਸਨੂੰ SUMPRODUCT ਫੰਕਸ਼ਨ ਦੇ ਅੰਦਰ ਰੱਖੋ ਜੋ ਐਰੇ ਨੂੰ ਸੰਭਾਲ ਸਕਦਾ ਹੈ:

ਇਸ ਉਦਾਹਰਨ ਵਿੱਚ, ਫਾਰਮੂਲਾ ਹੇਠਾਂ ਦਿੱਤੀ ਸ਼ਕਲ ਲੈਂਦਾ ਹੈ:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

ਅਤੇ ਇੱਥੇ ਗਿਣਨ ਲਈ ਇੱਕ ਹੋਰ ਫਾਰਮੂਲਾ ਹੈ ਐਕਸਲ ਦੀ ਰੇਂਜ ਵਿੱਚ ਅੱਖਰ:

=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

ਪਹਿਲੇ ਫਾਰਮੂਲੇ ਦੀ ਤੁਲਨਾ ਵਿੱਚ, ਸਭ ਤੋਂ ਸਪੱਸ਼ਟ ਅੰਤਰ SUMPRODUCT ਦੀ ਬਜਾਏ SUM ਦੀ ਵਰਤੋਂ ਕਰਨਾ ਹੈ। ਇੱਕ ਹੋਰ ਅੰਤਰ ਇਹ ਹੈ ਕਿ ਇਸਨੂੰ Ctrl + Shift + Enter ਦਬਾਉਣ ਦੀ ਲੋੜ ਹੁੰਦੀ ਹੈ ਕਿਉਂਕਿ SUMPRODUCT, ਜੋ ਕਿ ਐਰੇ ਨੂੰ ਪ੍ਰੋਸੈਸ ਕਰਨ ਲਈ ਤਿਆਰ ਕੀਤਾ ਗਿਆ ਹੈ, ਦੇ ਉਲਟ, SUM ਐਰੇ ਨੂੰ ਸਿਰਫ਼ ਉਦੋਂ ਹੀ ਸੰਭਾਲ ਸਕਦਾ ਹੈ ਜਦੋਂ ਇੱਕ ਐਰੇ ਫਾਰਮੂਲੇ ਵਿੱਚ ਵਰਤਿਆ ਜਾਂਦਾ ਹੈ।

ਜੇਕਰ ਤੁਸੀਂ ਨਹੀਂ ਕਰਦੇ ਫਾਰਮੂਲੇ ਵਿੱਚ ਅੱਖਰ ਨੂੰ ਹਾਰਡਕੋਡ ਨਹੀਂ ਕਰਨਾ ਚਾਹੁੰਦੇ, ਤੁਸੀਂ ਬੇਸ਼ਕ ਇਸਨੂੰ ਕਿਸੇ ਸੈੱਲ ਵਿੱਚ ਟਾਈਪ ਕਰ ਸਕਦੇ ਹੋ, D1 ਕਹੋ, ਅਤੇ ਆਪਣੇ ਅੱਖਰ ਗਿਣਤੀ ਫਾਰਮੂਲੇ ਵਿੱਚ ਉਸ ਸੈੱਲ ਦਾ ਹਵਾਲਾ ਦੇ ਸਕਦੇ ਹੋ:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))

ਨੋਟ। ਉਹਨਾਂ ਸਥਿਤੀਆਂ ਵਿੱਚ ਜਦੋਂ ਤੁਸੀਂ ਇੱਕ ਰੇਂਜ ਵਿੱਚ ਇੱਕ ਖਾਸ ਸਬਸਟ੍ਰਿੰਗ ਦੀਆਂ ਘਟਨਾਵਾਂ ਨੂੰ ਗਿਣਦੇ ਹੋ (ਜਿਵੇਂ ਕਿ "KK" ਜਾਂ "AA" ਨਾਲ ਸ਼ੁਰੂ ਹੋਣ ਵਾਲੇ ਆਰਡਰ), ਤੁਹਾਨੂੰ ਅੱਖਰ ਦੀ ਗਿਣਤੀ ਨੂੰ ਸਬਸਟਰਿੰਗ ਲੰਬਾਈ ਦੁਆਰਾ ਵੰਡਣ ਦੀ ਲੋੜ ਹੁੰਦੀ ਹੈ, ਨਹੀਂ ਤਾਂ ਹਰੇਕ ਅੱਖਰ ਵਿੱਚ ਸਬਸਟਰਿੰਗ ਨੂੰ ਵੱਖਰੇ ਤੌਰ 'ਤੇ ਗਿਣਿਆ ਜਾਵੇਗਾ। ਉਦਾਹਰਨ ਲਈ:

=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))

ਇਹ ਅੱਖਰ ਗਿਣਨ ਵਾਲਾ ਫਾਰਮੂਲਾ ਕਿਵੇਂ ਕੰਮ ਕਰਦਾ ਹੈ

ਜਿਵੇਂ ਕਿ ਤੁਹਾਨੂੰ ਯਾਦ ਹੋਵੇਗਾ, SUBSTITUTE ਫੰਕਸ਼ਨ ਨੂੰ ਇਸ ਉਦਾਹਰਨ ਵਿੱਚ ਦਿੱਤੇ ਅੱਖਰ ("A") ਦੀਆਂ ਸਾਰੀਆਂ ਘਟਨਾਵਾਂ ਨੂੰ ਬਦਲਣ ਲਈ ਵਰਤਿਆ ਜਾਂਦਾ ਹੈ ) ਇੱਕ ਖਾਲੀ ਟੈਕਸਟ ਸਤਰ ("") ਦੇ ਨਾਲ।

ਫਿਰ, ਅਸੀਂ ਐਕਸਲ LEN ਨੂੰ SUBSTITUTE ਦੁਆਰਾ ਵਾਪਸ ਕੀਤੀ ਟੈਕਸਟ ਸਤਰ ਦੀ ਸਪਲਾਈ ਕਰਦੇ ਹਾਂ।ਫੰਕਸ਼ਨ ਤਾਂ ਕਿ ਇਹ A ਦੇ ਬਿਨਾਂ ਸਤਰ ਦੀ ਲੰਬਾਈ ਦੀ ਗਣਨਾ ਕਰੇ। ਅਤੇ ਫਿਰ, ਅਸੀਂ ਟੈਕਸਟ ਸਤਰ ਦੀ ਕੁੱਲ ਲੰਬਾਈ ਤੋਂ ਉਸ ਅੱਖਰ ਦੀ ਗਿਣਤੀ ਨੂੰ ਘਟਾਉਂਦੇ ਹਾਂ। ਇਹਨਾਂ ਗਣਨਾਵਾਂ ਦਾ ਨਤੀਜਾ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਦੀ ਇੱਕ ਐਰੇ ਹੈ, ਪ੍ਰਤੀ ਸੈੱਲ ਇੱਕ ਅੱਖਰ ਦੀ ਗਿਣਤੀ ਦੇ ਨਾਲ।

ਅੰਤ ਵਿੱਚ, SUMPRODUCT ਐਰੇ ਵਿੱਚ ਸੰਖਿਆਵਾਂ ਨੂੰ ਜੋੜਦਾ ਹੈ ਅਤੇ ਰੇਂਜ ਵਿੱਚ ਦਿੱਤੇ ਗਏ ਅੱਖਰ ਦੀ ਕੁੱਲ ਗਿਣਤੀ ਵਾਪਸ ਕਰਦਾ ਹੈ।

ਇੱਕ ਰੇਂਜ ਵਿੱਚ ਖਾਸ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ ਇੱਕ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਫਾਰਮੂਲਾ

ਤੁਸੀਂ ਪਹਿਲਾਂ ਹੀ ਜਾਣਦੇ ਹੋ ਕਿ SUBSTITUTE ਇੱਕ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਫੰਕਸ਼ਨ ਹੈ, ਜੋ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਲਈ ਸਾਡੇ ਐਕਸਲ ਫਾਰਮੂਲੇ ਨੂੰ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਵੀ ਬਣਾਉਂਦਾ ਹੈ।

ਫਾਰਮੂਲੇ ਨੂੰ ਅਣਡਿੱਠਾ ਕੇਸ ਬਣਾਉਣ ਲਈ, ਪਿਛਲੀ ਉਦਾਹਰਨ ਵਿੱਚ ਪ੍ਰਦਰਸ਼ਿਤ ਪਹੁੰਚਾਂ ਦੀ ਪਾਲਣਾ ਕਰੋ: ਇੱਕ ਸੈੱਲ ਵਿੱਚ ਖਾਸ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਫਾਰਮੂਲਾ।

ਖਾਸ ਤੌਰ 'ਤੇ, ਤੁਸੀਂ ਗਿਣਨ ਲਈ ਹੇਠਾਂ ਦਿੱਤੇ ਫਾਰਮੂਲਿਆਂ ਵਿੱਚੋਂ ਇੱਕ ਦੀ ਵਰਤੋਂ ਕਰ ਸਕਦੇ ਹੋ। ਇੱਕ ਰੇਂਜ ਨੂੰ ਅਣਡਿੱਠ ਕਰਨ ਵਾਲੇ ਕੇਸ ਵਿੱਚ ਖਾਸ ਅੱਖਰ:

• UPPER ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰੋ ਅਤੇ ਵੱਡੇ ਅੱਖਰ ਵਿੱਚ ਇੱਕ ਅੱਖਰ ਦਰਜ ਕਰੋ:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A","")))

• ਨੇਸਟਡ ਸਬਸਟੀਟਿਊਟ ਫੰਕਸ਼ਨਾਂ ਦੀ ਵਰਤੋਂ ਕਰੋ:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a","")))

• UPPER ਅਤੇ LOWER ਫੰਕਸ਼ਨਾਂ ਦੀ ਵਰਤੋਂ ਕਰੋ, ਕਿਸੇ ਸੈੱਲ ਵਿੱਚ ਜਾਂ ਤਾਂ ਇੱਕ ਵੱਡੇ ਜਾਂ ਛੋਟੇ ਅੱਖਰ ਟਾਈਪ ਕਰੋ, ਅਤੇ ਆਪਣੇ ਫਾਰਮੂਲੇ ਵਿੱਚ ਉਸ ਸੈੱਲ ਦਾ ਹਵਾਲਾ ਦਿਓ:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))

ਹੇਠਾਂ ਦਿੱਤਾ ਗਿਆ ਸਕ੍ਰੀਨਸ਼ੌਟ ਕਾਰਵਾਈ ਵਿੱਚ ਆਖਰੀ ਫਾਰਮੂਲਾ ਦਰਸਾਉਂਦਾ ਹੈ:

ਟਿਪ। ਇੱਕ ਰੇਂਜ ਵਿੱਚ ਖਾਸ ਟੈਕਸਟ (ਸਬਸਟ੍ਰਿੰਗ) ਦੀਆਂ ਘਟਨਾਵਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ, ਇੱਕ ਰੇਂਜ ਵਿੱਚ ਖਾਸ ਟੈਕਸਟ / ਸ਼ਬਦਾਂ ਦੀ ਗਿਣਤੀ ਕਿਵੇਂ ਕਰੀਏ ਵਿੱਚ ਪ੍ਰਦਰਸ਼ਿਤ ਫਾਰਮੂਲੇ ਦੀ ਵਰਤੋਂ ਕਰੋ।

ਇਹਇਹ ਹੈ ਕਿ ਤੁਸੀਂ LEN ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰਕੇ ਐਕਸਲ ਵਿੱਚ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਕਿਵੇਂ ਕਰ ਸਕਦੇ ਹੋ। ਜੇਕਰ ਤੁਸੀਂ ਇਹ ਜਾਣਨਾ ਚਾਹੁੰਦੇ ਹੋ ਕਿ ਵਿਅਕਤੀਗਤ ਅੱਖਰਾਂ ਦੀ ਬਜਾਏ ਸ਼ਬਦਾਂ ਦੀ ਗਿਣਤੀ ਕਿਵੇਂ ਕਰਨੀ ਹੈ, ਤਾਂ ਤੁਹਾਨੂੰ ਸਾਡੇ ਅਗਲੇ ਲੇਖ ਵਿੱਚ ਕੁਝ ਉਪਯੋਗੀ ਫਾਰਮੂਲੇ ਮਿਲਣਗੇ, ਕਿਰਪਾ ਕਰਕੇ ਬਣੇ ਰਹੋ!

ਇਸ ਦੌਰਾਨ, ਤੁਸੀਂ ਅੱਖਰਾਂ ਦੀ ਗਿਣਤੀ ਦੇ ਫਾਰਮੂਲੇ ਨਾਲ ਇੱਕ ਨਮੂਨਾ ਵਰਕਬੁੱਕ ਡਾਊਨਲੋਡ ਕਰ ਸਕਦੇ ਹੋ। ਇਸ ਟਿਊਟੋਰਿਅਲ ਵਿੱਚ ਚਰਚਾ ਕੀਤੀ ਗਈ ਹੈ, ਅਤੇ ਪੰਨੇ ਦੇ ਅੰਤ ਵਿੱਚ ਸੰਬੰਧਿਤ ਸਰੋਤਾਂ ਦੀ ਸੂਚੀ ਦੇਖੋ। ਮੈਂ ਪੜ੍ਹਨ ਲਈ ਤੁਹਾਡਾ ਧੰਨਵਾਦ ਕਰਦਾ ਹਾਂ ਅਤੇ ਤੁਹਾਨੂੰ ਜਲਦੀ ਮਿਲਣ ਦੀ ਉਮੀਦ ਕਰਦਾ ਹਾਂ!