विषयसूची
ट्यूटोरियल समझाता है कि Excel में वर्णों की गणना कैसे करें। आप एक श्रेणी में कुल वर्णों की संख्या प्राप्त करने के लिए सूत्र सीखेंगे, और एक कक्ष या कई कक्षों में केवल विशिष्ट वर्णों की गणना करेंगे। सेल में वर्णों की कुल संख्या।
LEN सूत्र अपने आप में उपयोगी है, लेकिन SUM, SUMPRODUCT और स्थानापन्न जैसे अन्य कार्यों के संपर्क में, यह कहीं अधिक जटिल कार्यों को संभाल सकता है। इस ट्यूटोरियल में आगे, हम एक्सेल में वर्णों की गणना करने के लिए कुछ बुनियादी और उन्नत सूत्रों पर करीब से नज़र डालने जा रहे हैं।
एक श्रेणी में सभी वर्णों की गणना कैसे करें
जब कई सेल में वर्णों की कुल संख्या की गणना करने की बात आती है, तो एक तत्काल समाधान जो दिमाग में आता है वह है प्रत्येक सेल के लिए वर्णों की गणना करना, और फिर उन संख्याओं को जोड़ना:
=LEN(A2)+LEN(A3)+LEN(A4) <3
या
=SUM(LEN(A2),LEN(A3),LEN(A4))
उपरोक्त सूत्र एक छोटी सी श्रेणी के लिए ठीक काम कर सकते हैं। कुल वर्णों को एक बड़ी श्रेणी में गिनने के लिए, हम बेहतर कुछ अधिक कॉम्पैक्ट के साथ आएंगे, उदा। SUMPRODUCT फ़ंक्शन, जो सरणियों को गुणा करता है और उत्पादों का योग लौटाता है।
यहां एक श्रेणी में वर्णों की गणना करने के लिए सामान्य एक्सेल सूत्र है: )
और आपका वास्तविक जीवन सूत्र इसके समान दिख सकता है:
=SUMPRODUCT(LEN(A1:A7))
एक श्रेणी में वर्णों की गणना करने का दूसरा तरीका है LEN कार्य करता हैSUM के साथ संयोजन:
=SUM(LEN(A1:A7))
SUMPRODUCT के विपरीत, SUM फ़ंक्शन डिफ़ॉल्ट रूप से सरणियों की गणना नहीं करता है, और इसे सरणी सूत्र में बदलने के लिए आपको Ctrl + Shift + Enter दबाना होगा।<3
जैसा कि नीचे दिए गए स्क्रीनशॉट में दिखाया गया है, SUM फ़ॉर्मूला वही कुल कैरेक्टर काउंट लौटाता है:
यह रेंज कैरेक्टर काउंट फ़ॉर्मूला कैसे काम करता है
यह एक्सेल में वर्णों की गणना करने के लिए सबसे सरल सूत्रों में से एक है। LEN फ़ंक्शन निर्दिष्ट श्रेणी में प्रत्येक सेल के लिए स्ट्रिंग की लंबाई की गणना करता है और उन्हें संख्याओं की एक सरणी के रूप में लौटाता है। और फिर, SUMPRODUCT या SUM उन संख्याओं को जोड़ते हैं और कुल वर्णों की संख्या लौटाते हैं।
उपरोक्त उदाहरण में, 7 संख्याओं की एक सरणी जो कोशिकाओं A1 से A7 में स्ट्रिंग की लंबाई का प्रतिनिधित्व करती है:
ध्यान दें। कृपया ध्यान दें कि एक्सेल LEN फ़ंक्शन बिल्कुल प्रत्येक सेल में सभी वर्णों की गणना करता है, जिसमें अक्षर, संख्याएं, विराम चिह्न, विशेष प्रतीक और सभी रिक्त स्थान (शब्दों के बीच अग्रणी, अनुगामी और रिक्त स्थान) शामिल हैं।
सेल में विशिष्ट वर्णों की गणना कैसे करें
कभी-कभी, सेल के भीतर सभी वर्णों की गणना करने के बजाय, आपको केवल एक विशिष्ट अक्षर, संख्या या विशेष प्रतीक की घटनाओं को गिनने की आवश्यकता हो सकती है।
सेल में दिए गए कैरेक्टर के प्रकट होने की संख्या की गणना करने के लिए, LEN फ़ंक्शन का उपयोग SUBSTITUTE के साथ करें:
=LEN( cell )-LEN(SUBSTITUTE( cell<2)>, चरित्र ,""))सूत्र को बेहतर ढंग से समझने के लिए, निम्नलिखित उदाहरण पर विचार करें।
मान लीजिए, आप वितरित वस्तुओं का एक डेटाबेस बनाए रखते हैं, जहां प्रत्येक आइटम प्रकार का अपना अनूठा होता है पहचानकर्ता। और प्रत्येक सेल में अल्पविराम, स्थान, या किसी अन्य सीमांकक द्वारा अलग किए गए कई आइटम होते हैं। कार्य यह गिनना है कि प्रत्येक सेल में दिया गया विशिष्ट पहचानकर्ता कितनी बार प्रकट होता है।
यह मानते हुए कि वितरित वस्तुओं की सूची कॉलम बी (बी2 से शुरू) में है, और हम "ए" की संख्या की गणना कर रहे हैं। घटनाएँ, सूत्र इस प्रकार है:
=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))
यह एक्सेल वर्ण गणना सूत्र कैसे काम करता है
सूत्र के तर्क को समझने के लिए, आइए इसे छोटे भागों में विभाजित करें:
- सबसे पहले, आप B2 में कुल स्ट्रिंग लंबाई की गणना करें:
LEN(B2)
SUBSTITUTE(B2,"A","")
LEN(SUBSTITUTE(B2,"A",""))
परिणामस्वरूप, आपको "हटाए गए" वर्णों की गिनती मिलती है, जो सेल में उन वर्णों की कुल संख्या के बराबर होती है।
उस वर्ण को निर्दिष्ट करने के बजाय जिसमें आप गिनना चाहते हैं एक सूत्र, आप इसे किसी सेल में टाइप कर सकते हैं, और फिर उस सेल को सूत्र में संदर्भित कर सकते हैं। इस प्रकार, आपके उपयोगकर्ताआपके सूत्र के साथ छेड़छाड़ किए बिना उस सेल में इनपुट किए गए किसी भी अन्य वर्ण की घटनाओं की गणना करने में सक्षम होंगे:
ध्यान दें। एक्सेल का स्थानापन्न एक केस-संवेदी कार्य है, और इसलिए उपरोक्त सूत्र केस-संवेदी भी है। उदाहरण के लिए, उपरोक्त स्क्रीनशॉट में, सेल B3 में "A" की 3 आवृत्तियाँ हैं - दो अपरकेस में, और एक लोअरकेस में। सूत्र ने केवल अपरकेस वर्णों की गणना की है क्योंकि हमने "ए" को सबस्टिट्यूट फ़ंक्शन में आपूर्ति की है।
किसी सेल में विशिष्ट वर्णों की गणना करने के लिए केस-असंवेदनशील एक्सेल सूत्र
यदि आपको केस-संवेदी वर्णों की संख्या की आवश्यकता है, तो प्रतिस्थापन चलाने से पहले निर्दिष्ट वर्ण को अपरकेस में बदलने के लिए SUBSTITUTE के अंदर UPPER फ़ंक्शन एम्बेड करें। और, सूत्र में अपरकेस वर्ण दर्ज करना सुनिश्चित करें।
उदाहरण के लिए, कक्ष B2 में "A" और "a" आइटमों की गणना करने के लिए, इस सूत्र का उपयोग करें:
=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))
नेस्टेड स्थानापन्न कार्यों का उपयोग करने का दूसरा तरीका है:
=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")
जैसा कि आप नीचे स्क्रीनशॉट में देख सकते हैं, दोनों सूत्र त्रुटिहीन रूप से निर्दिष्ट वर्ण के अपरकेस और लोअर केस की घटनाओं की गणना करते हैं:<3
कुछ मामलों में, आपको तालिका में कई अलग-अलग वर्णों की गणना करने की आवश्यकता हो सकती है, लेकिन हो सकता है कि आप हर बार सूत्र को संशोधित न करना चाहें। इस स्थिति में, एक स्थानापन्न फ़ंक्शन को दूसरे में नेस्ट करें, उस वर्ण को टाइप करें जिसे आप किसी सेल में गिनना चाहते हैं (इस उदाहरण में D1), और उस सेल के मान को अपरकेस में बदलें औरअपरकेस और लोअर फ़ंक्शंस का उपयोग करके लोअरकेस:
=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))
वैकल्पिक रूप से, स्रोत सेल और वर्ण वाले सेल दोनों को अपरकेस या लोअरकेस में कनवर्ट करें। उदाहरण के लिए:
=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))
इस दृष्टिकोण का लाभ यह है कि संदर्भित सेल में अपरकेस या लोअरकेस वर्ण इनपुट है या नहीं, आपका केस-असंवेदनशील वर्ण गणना सूत्र सही गिनती लौटाएगा:
सेल में कुछ पाठ या सबस्ट्रिंग की घटनाओं की गणना करें
यदि आप कितनी बार गिनना चाहते हैं वर्णों का विशिष्ट संयोजन (अर्थात कुछ पाठ, या सबस्ट्रिंग) किसी दिए गए सेल में दिखाई देता है, उदा। "A2" या "SS", फिर उपरोक्त सूत्रों द्वारा लौटाए गए वर्णों की संख्या को सबस्ट्रिंग की लंबाई से विभाजित करें।
केस-संवेदी सूत्र:
=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)
केस-असंवेदी सूत्र:
=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)
जहां B2 वह सेल है जिसमें संपूर्ण टेक्स्ट स्ट्रिंग है, और C1 वह टेक्स्ट (सबस्ट्रिंग) है जिसे आप गिनना चाहते हैं।
सूत्र की विस्तृत व्याख्या के लिए, कृपया सेल में विशिष्ट पाठ / शब्दों की गणना कैसे करें देखें।
विशिष्ट की गणना कैसे करें एक श्रेणी में वर्ण
अब जब आप सेल में वर्णों की गणना करने के लिए एक एक्सेल फॉर्मूला जानते हैं, तो आप यह पता लगाने के लिए इसे और सुधारना चाह सकते हैं कि एक निश्चित वर्ण कितनी बार एक श्रेणी में दिखाई देता है। इसके लिए, हम चर्चित सेल में एक विशिष्ट चार की गणना करने के लिए एक्सेल LEN फॉर्मूला लेंगेपिछले उदाहरण में, और इसे SUMPRODUCT फ़ंक्शन के अंदर रखें जो सरणियों को संभाल सकता है:
SUMPRODUCT(LEN( range )-LEN(SUBSTITUTE( range , character<) 2>,"")))इस उदाहरण में, सूत्र निम्न आकार लेता है:
=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))
और यहां गिनने के लिए एक और सूत्र दिया गया है एक्सेल की श्रेणी में वर्ण:
=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))
पहले सूत्र की तुलना में, सबसे स्पष्ट अंतर SUMPRODUCT के बजाय SUM का उपयोग कर रहा है। एक और अंतर यह है कि इसके लिए Ctrl + Shift + Enter दबाने की आवश्यकता होती है क्योंकि SUMPRODUCT के विपरीत, जिसे सरणियों को संसाधित करने के लिए डिज़ाइन किया गया है, SUM केवल सरणी सूत्र में उपयोग किए जाने पर ही सरणियों को संभाल सकता है।
यदि आप ऐसा नहीं करते हैं सूत्र में वर्ण को हार्डकोड नहीं करना चाहते हैं, आप निश्चित रूप से इसे किसी सेल में टाइप कर सकते हैं, D1 कह सकते हैं, और उस सेल को अपने वर्ण गणना सूत्र में संदर्भित कर सकते हैं:
=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))
ध्यान दें। ऐसी स्थितियों में जब आप किसी श्रेणी में किसी विशिष्ट सबस्ट्रिंग की घटनाओं की गणना करते हैं (उदाहरण के लिए "केके" या "एए" से शुरू होने वाले ऑर्डर), तो आपको वर्ण संख्या को सबस्ट्रिंग लंबाई से विभाजित करने की आवश्यकता होती है, अन्यथा प्रत्येक वर्ण में सबस्ट्रिंग को अलग-अलग गिना जाएगा। उदाहरण के लिए:
=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))
कैरेक्टर काउंटिंग फॉर्मूला कैसे काम करता है
जैसा कि आपको याद होगा, सबस्टिट्यूट फ़ंक्शन का उपयोग इस उदाहरण में निर्दिष्ट वर्ण ("ए") की सभी घटनाओं को बदलने के लिए किया जाता है ) खाली टेक्स्ट स्ट्रिंग ("") के साथ।
फिर, हम एक्सेल LEN को सबस्टिट्यूट द्वारा लौटाई गई टेक्स्ट स्ट्रिंग की आपूर्तिकार्य करें ताकि यह ए के बिना स्ट्रिंग लम्बाई की गणना कर सके। और फिर, हम उस वर्ण संख्या को टेक्स्ट स्ट्रिंग की कुल लंबाई से घटाते हैं। इन गणनाओं का परिणाम वर्ण गणनाओं की एक सरणी है, प्रति सेल एक वर्ण गणना के साथ।
अंत में, SUMPRODUCT सरणी में संख्याओं का योग करता है और श्रेणी में निर्दिष्ट वर्ण की कुल संख्या लौटाता है।
एक श्रेणी में विशिष्ट वर्णों की गणना करने के लिए एक केस-असंवेदनशील सूत्र
आप पहले से ही जानते हैं कि स्थानापन्न एक केस-संवेदी फ़ंक्शन है, जो वर्ण गणना के लिए हमारे एक्सेल सूत्र को केस-संवेदी भी बनाता है।
सूत्र को मामले की उपेक्षा करने के लिए, पिछले उदाहरण में प्रदर्शित दृष्टिकोणों का पालन करें: सेल में विशिष्ट वर्णों की गणना करने के लिए केस-असंवेदनशील सूत्र।
विशेष रूप से, आप गणना करने के लिए निम्न सूत्रों में से एक का उपयोग कर सकते हैं मामले को अनदेखा करते हुए श्रेणी में विशिष्ट वर्ण:
- UPPER फ़ंक्शन का उपयोग करें और अपरकेस में वर्ण दर्ज करें:
=SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A",""))) - नेस्टेड स्थानापन्न फ़ंक्शन का उपयोग करें:
=SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a",""))) - अपर और लोअर फ़ंक्शन का उपयोग करें, किसी सेल में या तो अपरकेस या लोअरकेस वर्ण टाइप करें, और उस सेल को अपने सूत्र में संदर्भित करें:
<17=SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))
नीचे दिया गया स्क्रीनशॉट कार्रवाई में अंतिम सूत्र को प्रदर्शित करता है:
युक्ति। एक श्रेणी में विशिष्ट पाठ (सबस्ट्रिंग) की घटनाओं की गणना करने के लिए, एक श्रेणी में विशिष्ट पाठ / शब्दों की गणना कैसे करें में प्रदर्शित सूत्र का उपयोग करें।
यहयह है कि आप LEN फ़ंक्शन का उपयोग करके Excel में वर्णों की गणना कैसे कर सकते हैं। यदि आप जानना चाहते हैं कि अलग-अलग वर्णों के बजाय शब्दों की गणना कैसे करें, तो आपको हमारे अगले लेख में कुछ उपयोगी सूत्र मिलेंगे, कृपया देखते रहें!
इस बीच, आप वर्ण गणना सूत्र के साथ एक नमूना कार्यपुस्तिका डाउनलोड कर सकते हैं इस ट्यूटोरियल में चर्चा की गई है, और पेज के अंत में संबंधित संसाधनों की एक सूची देखें। मैं आपको पढ़ने के लिए धन्यवाद देता हूं और आपसे जल्द ही मिलने की आशा करता हूं!
