सामग्री तालिका
ट्युटोरियलले एक्सेलमा अक्षरहरू कसरी गणना गर्ने भनेर बताउँछ। तपाईंले दायरामा कुल वर्ण गणना प्राप्त गर्न सूत्रहरू सिक्नुहुनेछ, र कक्षमा वा धेरै कक्षहरूमा मात्र विशिष्ट वर्णहरू गणना गर्नुहुनेछ।
हाम्रो अघिल्लो ट्यूटोरियलले एक्सेल LEN प्रकार्य प्रस्तुत गर्यो, जसले गणना गर्न अनुमति दिन्छ। कक्षमा क्यारेक्टरहरूको कुल संख्या।
LEN सूत्र आफैमा उपयोगी छ, तर SUM, SUMPRODUCT र SUBSTITUTE जस्ता अन्य प्रकार्यहरूसँग सम्पर्कमा, यसले धेरै जटिल कार्यहरू ह्यान्डल गर्न सक्छ। यस ट्यूटोरियलमा थप, हामी एक्सेलमा क्यारेक्टरहरू गणना गर्न केही आधारभूत र उन्नत सूत्रहरू नजिकबाट हेर्न जाँदैछौं।
दायरामा सबै क्यारेक्टरहरू कसरी गणना गर्ने
जब धेरै कक्षहरूमा क्यारेक्टरहरूको कुल संख्या गणना गर्ने कुरा आउँछ, दिमागमा आउने एउटा तत्काल समाधान भनेको प्रत्येक कक्षको लागि क्यारेक्टर गणना प्राप्त गर्नु हो, र त्यसपछि ती संख्याहरू थप्नुहोस्:
=LEN(A2)+LEN(A3)+LEN(A4)
वा
=SUM(LEN(A2),LEN(A3),LEN(A4))
माथिको सूत्रले सानो दायराको लागि राम्रो काम गर्न सक्छ। ठुलो दायरामा कुल क्यारेक्टरहरू गणना गर्न, हामी अझ बढी कम्प्याक्ट कुराको साथ आउनु राम्रो हुन्छ, उदाहरणका लागि। SUMPRODUCT प्रकार्य, जसले एरेहरूलाई गुणन गर्छ र उत्पादनहरूको योगफल फर्काउँछ।
रेंजमा क्यारेक्टरहरू गणना गर्न यहाँ सामान्य एक्सेल सूत्र छ:
=SUMPRODUCT(LEN( दायरा) )र तपाईंको वास्तविक जीवनको सूत्र यससँग मिल्दोजुल्दो हुन सक्छ:
=SUMPRODUCT(LEN(A1:A7))
रेन्जमा क्यारेक्टरहरू गणना गर्ने अर्को तरिका प्रयोग गर्नु हो। LEN प्रकार्य माSUM को संयोजन:
=SUM(LEN(A1:A7))
SUMPRODUCT को विपरीत, SUM प्रकार्यले पूर्वनिर्धारित रूपमा एरेहरू गणना गर्दैन, र यसलाई एरे सूत्रमा परिणत गर्न तपाईंले Ctrl + Shift + Enter थिच्नु पर्छ।
निम्न स्क्रिनसटमा देखाइए अनुसार, SUM सूत्रले समान कुल क्यारेक्टर गणना फर्काउँछ:
यो दायरा क्यारेक्टर गणना सूत्रले कसरी काम गर्छ
यो Excel मा क्यारेक्टरहरू गणना गर्नको लागि सबैभन्दा सरल सूत्रहरू मध्ये एक हो। LEN प्रकार्यले निर्दिष्ट दायरामा प्रत्येक कक्षको लागि स्ट्रिङ लम्बाइ गणना गर्दछ र तिनीहरूलाई संख्याहरूको एरेको रूपमा फर्काउँछ। र त्यसपछि, SUMPRODUCT वा SUM ले ती संख्याहरू थप्छ र कुल क्यारेक्टर गणना फर्काउँछ।
माथिको उदाहरणमा, A1 देखि A7 कक्षहरूमा स्ट्रिङहरूको लम्बाइ प्रतिनिधित्व गर्ने 7 संख्याहरूको एर्रे सङ्कलन गरिएको छ:
नोट। कृपया ध्यान दिनुहोस् कि एक्सेल LEN प्रकार्यले अक्षरहरू, संख्याहरू, विराम चिन्हहरू, विशेष प्रतीकहरू, र सबै स्पेसहरू (अग्रणी, पछाडि र शब्दहरू बीचको खाली ठाउँहरू) सहित प्रत्येक कक्षमा सबै क्यारेक्टरहरू पूर्ण रूपमा गणना गर्दछ ।
कसरी सेलमा विशिष्ट क्यारेक्टरहरू गणना गर्ने
कहिलेकाहीँ, सेल भित्रका सबै क्यारेक्टरहरू गणना गर्नुको सट्टा, तपाईंले विशेष अक्षर, संख्या, वा विशेष प्रतीकको घटनाहरू मात्र गणना गर्न आवश्यक पर्दछ।
सेलमा दिइएको क्यारेक्टर कति पटक देखा पर्दछ गणना गर्न, SUBSTITUTE:
=LEN( cell )-LEN(SUBSTITUTE( cell<2) सँगसँगै LEN प्रकार्य प्रयोग गर्नुहोस्।>, वर्ण ,""))सूत्र राम्रोसँग बुझ्नको लागि, निम्न उदाहरणलाई विचार गर्नुहोस्।
मान्नुहोस्, तपाईंले डेलिभर गरिएका वस्तुहरूको डाटाबेस राख्नुहुन्छ, जहाँ प्रत्येक वस्तुको प्रकारको आफ्नै अद्वितीय हुन्छ। पहिचानकर्ता। र प्रत्येक कक्षमा अल्पविराम, स्पेस, वा कुनै अन्य डिलिमिटरद्वारा छुट्याइएको धेरै वस्तुहरू समावेश छन्। कार्य भनेको प्रत्येक कक्षमा दिइएको अद्वितीय पहिचानकर्ता कति पटक देखा पर्दछ भनेर गणना गर्नु हो।
डेलिभर गरिएका वस्तुहरूको सूची स्तम्भ B मा रहेको मान्दै (B2 बाट सुरु हुँदै), र हामी "A" को संख्या गणना गर्दैछौं। घटनाहरू, सूत्र निम्नानुसार छ:
=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))
यस एक्सेल क्यारेक्टर गणना सूत्रले कसरी काम गर्दछ
सूत्रको तर्क बुझ्नको लागि, आउनुहोस् यसलाई साना भागहरूमा विभाजन गर्नुहोस्:
- पहिले, तपाईंले B2 मा कुल स्ट्रिङ लम्बाइ गणना गर्नुहुन्छ:
LEN(B2)
SUBSTITUTE(B2,"A","")
LEN(SUBSTITUTE(B2,"A",""))
परिणामको रूपमा, तपाईंले "हटाइएका" क्यारेक्टरहरूको गणना पाउनुहुनेछ, जुन कक्षमा भएका ती क्यारेक्टरहरूको कुल सङ्ख्या बराबर हुन्छ।
तपाईंले गणना गर्न चाहनुभएको क्यारेक्टर निर्दिष्ट गर्नुको सट्टा एउटा सूत्र, तपाईंले यसलाई केही कक्षमा टाइप गर्न सक्नुहुन्छ, र त्यसपछि त्यो कक्षलाई सूत्रमा सन्दर्भ गर्न सक्नुहुन्छ। यस तरिकामा, तपाइँका प्रयोगकर्ताहरूतपाईँको सूत्रसँग छेडछाड नगरी उसले सेलमा इनपुट गरेको कुनै पनि अन्य क्यारेक्टरको घटनाहरू गणना गर्न सक्षम हुनेछ:
नोट। Excel को SUBSTITUTE केस-संवेदनशील प्रकार्य हो, र त्यसैले माथिको सूत्र केस-संवेदनशील पनि छ। उदाहरणका लागि, माथिको स्क्रिनसटमा, सेल B3 मा "A" को 3 घटनाहरू समावेश छन् - दुईवटा ठूलो अक्षरमा, र एउटा सानो अक्षरमा। सूत्रले केवल ठूला अक्षरहरू मात्र गणना गरेको छ किनभने हामीले SUBSTITUTE प्रकार्यमा "A" आपूर्ति गर्यौं।
सेलमा विशिष्ट वर्णहरू गणना गर्न केस-संवेदनशील एक्सेल सूत्र
यदि तपाईंलाई केस-संवेदनशील क्यारेक्टर गणना चाहिन्छ भने, प्रतिस्थापन चलाउनु अघि निर्दिष्ट क्यारेक्टरलाई अपरकेसमा रूपान्तरण गर्न SUBSTITUTE भित्र UPPER प्रकार्य इम्बेड गर्नुहोस्। र, सूत्रमा ठूलो अक्षर प्रविष्ट गर्न निश्चित हुनुहोस्।
उदाहरणका लागि, कक्ष B2 मा "A" र "a" वस्तुहरू गणना गर्न, यो सूत्र प्रयोग गर्नुहोस्:
=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))
अर्को तरिका नेस्टेड सब्स्टिट्यूट प्रकार्यहरू प्रयोग गर्ने हो:
=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")
तपाईँले तलको स्क्रिनसटमा देख्न सक्नुहुन्छ, दुवै सूत्रहरू निर्दोष रूपमा निर्दिष्ट क्यारेक्टरको अपरकेस र लोअरकेस घटनाहरू गणना गर्छन्:
केही अवस्थामा, तपाइँले तालिकामा धेरै फरक क्यारेक्टरहरू गणना गर्न आवश्यक पर्दछ, तर तपाइँ प्रत्येक पटक सूत्र परिमार्जन गर्न चाहनुहुन्न। यस अवस्थामा, अर्को भित्र एउटा सब्सट्युट प्रकार्य नेस्ट गर्नुहोस्, तपाईले केहि सेलमा गणना गर्न चाहनुभएको क्यारेक्टर टाइप गर्नुहोस् (यस उदाहरणमा D1), र त्यो सेलको मानलाई अपरकेसमा रूपान्तरण गर्नुहोस् रUPPER र LOWER प्रकार्यहरू प्रयोग गरेर लोअरकेस:
=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))
वैकल्पिक रूपमा, स्रोत कक्ष र क्यारेक्टर समावेश भएको सेल दुवैलाई अपरकेस वा लोअरकेसमा रूपान्तरण गर्नुहोस्। उदाहरणका लागि:
=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))
यस दृष्टिकोणको फाइदा यो हो कि रेफरेन्स गरिएको सेलमा अपरकेस वा लोअरकेस क्यारेक्टर इनपुट भए तापनि, तपाईंको केस-संवेदनशील क्यारेक्टर गणना सूत्र सही गणना फर्काउनेछ:
कक्षमा निश्चित पाठ वा सबस्ट्रिङका घटनाहरू गणना गर्नुहोस्
यदि तपाइँ कति पटक गणना गर्न चाहनुहुन्छ भने वर्णहरूको विशिष्ट संयोजन (अर्थात् निश्चित पाठ, वा सबस्ट्रिङ) दिइएको कक्षमा देखिन्छ, उदाहरणका लागि। "A2" वा "SS", त्यसपछि माथिको सूत्रहरूद्वारा फर्काइएको क्यारेक्टरहरूको संख्यालाई सबस्ट्रिङको लम्बाइले विभाजन गर्नुहोस्।
केस-संवेदनशील सूत्र:
=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)
केस-असंवेदनशील सूत्र:
=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)
जहाँ B2 सम्पूर्ण पाठ स्ट्रिङ भएको सेल हो, र C1 पाठ (सबस्ट्रिङ) हो। गणना गर्न चाहानुहुन्छ।
सूत्रको विस्तृत व्याख्याको लागि, कृपया कक्षमा विशिष्ट पाठ / शब्दहरू कसरी गणना गर्ने हेर्नुहोस्।
विशिष्ट गणना कसरी गर्ने दायरामा वर्ण(हरू)
अब तपाईलाई सेलमा क्यारेक्टरहरू गणना गर्न एक्सेल सूत्र थाहा छ, तपाईले दायरामा कति पटक निश्चित वर्णहरू देखा पर्दछ भनेर पत्ता लगाउन यसलाई अझ सुधार गर्न सक्नुहुन्छ। यसका लागि, हामी छलफल गरिएको कक्षमा विशिष्ट वर्ण गणना गर्न एक्सेल LEN सूत्र लिनेछौंअघिल्लो उदाहरणमा, र arrays ह्यान्डल गर्न सक्ने SUMPRODUCT प्रकार्य भित्र राख्नुहोस्:
SUMPRODUCT(LEN( range )-LEN(SUBSTITUTE( range , character<) 2>,"")))यस उदाहरणमा, सूत्रले निम्न आकार लिन्छ:
=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))
र यहाँ गणना गर्न अर्को सूत्र छ एक्सेलको दायरामा वर्णहरू:
=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))
पहिलो सूत्रको तुलनामा, सबैभन्दा स्पष्ट भिन्नता SUMPRODUCT को सट्टा SUM प्रयोग गर्नु हो। अर्को भिन्नता यो हो कि यसलाई Ctrl + Shift + Enter थिच्नु आवश्यक छ किनभने SUMPRODUCT को विपरीत, जो arrays लाई प्रशोधन गर्न डिजाइन गरिएको हो, SUM ले arrays लाई ह्यान्डल गर्न सक्छ जब array सूत्र मा प्रयोग गरिन्छ।
यदि तपाईंले गर्नुभएन भने सूत्रमा क्यारेक्टरलाई हार्डकोड गर्न चाहनुहुन्न, तपाईले निश्चित रूपमा यसलाई केहि सेलमा टाइप गर्न सक्नुहुन्छ, D1 भन्नुहोस्, र त्यो कक्षलाई तपाइँको क्यारेक्टर गणना सूत्रमा सन्दर्भ गर्नुहोस्:
=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))
नोट। परिस्थितिहरूमा जब तपाइँ कुनै दायरामा निर्दिष्ट सबस्ट्रिङ को घटनाहरू गणना गर्नुहुन्छ (जस्तै "KK" वा "AA" बाट सुरु हुने अर्डरहरू), तपाईंले क्यारेक्टर गणनालाई सबस्ट्रिङ लम्बाइद्वारा विभाजित गर्न आवश्यक छ, अन्यथा प्रत्येक क्यारेक्टर सबस्ट्रिङ व्यक्तिगत रूपमा गणना गरिनेछ। उदाहरणका लागि:
=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))
यस क्यारेक्टर गणना गर्ने सूत्रले कसरी काम गर्छ
तपाईले याद गर्न सक्नुहुन्छ, SUBSTITUTE प्रकार्यले निर्दिष्ट क्यारेक्टरका सबै घटनाहरूलाई प्रतिस्थापन गर्न प्रयोग गरिन्छ ("A" यस उदाहरणमा ) खाली पाठ स्ट्रिङ ("") संग।
त्यसपछि, हामी SUBSTITUTE द्वारा फर्काइएको पाठ स्ट्रिङ एक्सेल LEN मा आपूर्ति गर्छौं।प्रकार्य जसले A को बिना स्ट्रिङ लम्बाइ गणना गर्दछ। र त्यसपछि, हामी पाठ स्ट्रिङको कुल लम्बाइबाट त्यो क्यारेक्टर गणना घटाउँछौं। यी गणनाहरूको परिणाम क्यारेक्टर गणनाहरूको एर्रे हो, प्रति सेल एक क्यारेक्टर गणनाको साथ।
अन्तमा, SUMPRODUCT ले एरेमा संख्याहरू जोड्छ र दायरामा निर्दिष्ट क्यारेक्टरको कुल गणना फर्काउँछ।
रेन्जमा विशिष्ट क्यारेक्टरहरू गणना गर्न केस-संवेदनशील सूत्र
तपाईंलाई पहिले नै थाहा छ कि SUBSTITUTE केस-संवेदनशील प्रकार्य हो, जसले क्यारेक्टर गणनाको लागि हाम्रो एक्सेल सूत्र केस-संवेदनशील पनि बनाउँछ।
सूत्रलाई बेवास्ता केस बनाउनको लागि, अघिल्लो उदाहरणमा देखाइएको दृष्टिकोणहरू पालना गर्नुहोस्: कक्षमा विशिष्ट क्यारेक्टरहरू गणना गर्न केस-संवेदनशील सूत्र।
विशेष गरी, तपाईंले गणना गर्न निम्न मध्ये एउटा सूत्र प्रयोग गर्न सक्नुहुन्छ। दायरालाई बेवास्ता गर्ने केसमा विशिष्ट वर्णहरू:
- UPPER प्रकार्य प्रयोग गर्नुहोस् र ठूलो अक्षरमा एउटा क्यारेक्टर प्रविष्ट गर्नुहोस्:
=SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A",""))) - नेस्टेड SUBSTITUTE प्रकार्यहरू प्रयोग गर्नुहोस्:
=SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a",""))) - UPPER र LOWER प्रकार्यहरू प्रयोग गर्नुहोस्, कुनै सेलमा अपरकेस वा लोअरकेस अक्षर टाइप गर्नुहोस्, र तपाईंको सूत्रमा त्यो कक्षलाई सन्दर्भ गर्नुहोस्:
=SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))
तलको स्क्रिनसटले कार्यमा अन्तिम सूत्र देखाउँछ:
टिप। दायरामा विशिष्ट पाठ (सबस्ट्रिङ) को घटनाहरू गणना गर्न, दायरामा विशिष्ट पाठ / शब्दहरू कसरी गणना गर्ने मा प्रदर्शन गरिएको सूत्र प्रयोग गर्नुहोस्।
योतपाईले कसरी LEN प्रकार्य प्रयोग गरेर एक्सेलमा क्यारेक्टरहरू गणना गर्न सक्नुहुन्छ। यदि तपाइँ व्यक्तिगत क्यारेक्टरहरूको सट्टा शब्दहरू कसरी गणना गर्ने भनेर जान्न चाहनुहुन्छ भने, तपाइँ हाम्रो अर्को लेखमा केही उपयोगी सूत्रहरू फेला पार्नुहुनेछ, कृपया सम्पर्कमा रहनुहोस्!
यस बीचमा, तपाइँ क्यारेक्टर गणना सूत्रको साथ नमूना कार्यपुस्तिकाहरू डाउनलोड गर्न सक्नुहुन्छ। यस ट्यूटोरियलमा छलफल गरिएको छ, र पृष्ठको अन्त्यमा सम्बन्धित स्रोतहरूको सूची हेर्नुहोस्। पढ्नको लागि म तपाईंलाई धन्यवाद दिन्छु र चाँडै भेट्ने आशा गर्दछु!
