Ipinapaliwanag ng tutorial kung paano magbilang ng mga character sa Excel. Matututuhan mo ang mga formula upang makuha ang kabuuang bilang ng character sa isang hanay, at bilangin lamang ang mga partikular na character sa isang cell o sa ilang mga cell.

Ipinakilala ng aming nakaraang tutorial ang Excel LEN function, na nagbibigay-daan sa pagbilang ng kabuuang bilang ng mga character sa isang cell.

Ang formula ng LEN ay kapaki-pakinabang sa sarili nitong, ngunit kaugnay ng iba pang mga function tulad ng SUM, SUMPRODUCT at SUBSTITUTE, maaari nitong pangasiwaan ang mas kumplikadong mga gawain. Higit pa sa tutorial na ito, titingnan natin ang ilang mga basic at advanced na formula para mabilang ang mga character sa Excel.

Paano bilangin ang lahat ng character sa isang range

Pagdating sa pagbibilang ng kabuuang bilang ng mga character sa ilang mga cell, isang agarang solusyon na nasa isip ay ang kunin ang bilang ng character para sa bawat cell, at pagkatapos ay idagdag ang mga numerong iyon:

=LEN(A2)+LEN(A3)+LEN(A4)

O

=SUM(LEN(A2),LEN(A3),LEN(A4))

Maaaring gumana nang maayos ang mga formula sa itaas para sa isang maliit na hanay. Upang mabilang ang kabuuang mga character sa mas malaking hanay, mas mabuting gumawa kami ng mas compact, hal. ang function ng SUMPRODUCT, na nagpaparami ng mga array at nagbabalik ng kabuuan ng mga produkto.

Narito ang generic na formula ng Excel para magbilang ng mga character sa isang range:

At ang iyong formula sa totoong buhay ay maaaring magmukhang katulad nito:

=SUMPRODUCT(LEN(A1:A7))

Ang isa pang paraan upang mabilang ang mga character sa isang hanay ay ang paggamit ng Ang function ng LEN sakumbinasyon sa SUM:

=SUM(LEN(A1:A7))

Hindi tulad ng SUMPRODUCT, hindi kinakalkula ng SUM function ang mga array bilang default, at kailangan mong pindutin ang Ctrl + Shift + Enter para gawing array formula.

Tulad ng ipinakita sa sumusunod na screenshot, ibinabalik ng formula ng SUM ang parehong kabuuang bilang ng character:

Paano gumagana ang formula ng bilang ng character ng range na ito

Ito ay isa sa mga pinakasimpleng formula para magbilang ng mga character sa Excel. Kinakalkula ng function ng LEN ang haba ng string para sa bawat cell sa tinukoy na hanay at ibinabalik ang mga ito bilang isang hanay ng mga numero. At pagkatapos, idinaragdag ng SUMPRODUCT o SUM ang mga numerong iyon at ibinabalik ang kabuuang bilang ng character.

Sa halimbawa sa itaas, ang isang hanay ng 7 numero na kumakatawan sa mga haba ng mga string sa mga cell A1 hanggang A7 ay summed:

Tandaan. Mangyaring bigyang-pansin na ang Excel LEN function ay ganap na binibilang ang lahat ng mga character sa bawat cell , kabilang ang mga titik, numero, bantas, espesyal na simbolo, at lahat ng puwang (nangunguna, trailing at mga puwang sa pagitan ng mga salita).

Paano magbilang ng mga partikular na character sa isang cell

Minsan, sa halip na bilangin ang lahat ng mga character sa loob ng isang cell, maaaring kailanganin mong bilangin lamang ang mga paglitaw ng isang partikular na titik, numero, o espesyal na simbolo.

Upang bilangin ang bilang ng beses na lumilitaw ang ibinigay na character sa isang cell, gamitin ang LEN function kasama ang SUBSTITUTE:

Upang mas maunawaan ang formula, isaalang-alang ang sumusunod na halimbawa.

Kumbaga, nagpapanatili ka ng database ng mga naihatid na item, kung saan ang bawat uri ng item ay may sariling kakaiba identifier. At ang bawat cell ay naglalaman ng ilang mga item na pinaghihiwalay ng kuwit, espasyo, o anumang iba pang delimiter. Ang gawain ay bilangin kung ilang beses lumilitaw ang isang natatanging identifier sa bawat cell.

Ipagpalagay na ang listahan ng mga naihatid na item ay nasa column B (nagsisimula sa B2), at binibilang namin ang bilang ng "A" mga pangyayari, ang formula ay ang sumusunod:

=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))

Paano gumagana ang Excel character count formula na ito

Upang maunawaan ang lohika ng formula, sabihin hatiin ito sa mas maliliit na bahagi:

• Una, binibilang mo ang kabuuang haba ng string sa B2:

LEN(B2)

SUBSTITUTE(B2,"A","")

LEN(SUBSTITUTE(B2,"A",""))

Bilang resulta, makukuha mo ang bilang ng "naalis" na mga character, na katumbas ng kabuuang bilang ng mga paglitaw ng character na iyon sa cell.

Sa halip na tukuyin ang character na gusto mong bilangin sa isang formula, maaari mo itong i-type sa ilang cell, at pagkatapos ay i-reference ang cell na iyon sa isang formula. Sa ganitong paraan, ang iyong mga gumagamitay magagawang bilangin ang mga paglitaw ng anumang iba pang character na inilagay nila sa cell na iyon nang hindi pinakikialaman ang iyong formula:

Tandaan. Ang SUBSTITUTE ng Excel ay isang case-sensitive na function, at samakatuwid ang formula sa itaas ay case-sensitive din. Halimbawa, sa screenshot sa itaas, ang cell B3 ay naglalaman ng 3 paglitaw ng "A" - dalawa sa uppercase, at isa sa lowercase. Binibilang lang ng formula ang mga uppercase na character dahil nagbigay kami ng "A" sa SUBSTITUTE function.

Case-insensitive na Excel na formula para magbilang ng mga partikular na character sa isang cell

Kung kailangan mo ng case-insensitive na bilang ng character, i-embed ang UPPER function sa loob ng SUBSTITUTE upang i-convert ang tinukoy na character sa uppercase bago patakbuhin ang pagpapalit. At, tiyaking ilagay ang uppercase na character sa formula.

Halimbawa, para mabilang ang "A" at "a" na mga item sa cell B2, gamitin ang formula na ito:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))

Ang isa pang paraan ay ang paggamit ng mga nested Substitute function:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")

Tulad ng makikita mo sa screenshot sa ibaba, ang parehong formula ay walang kamali-mali na binibilang ang uppercase at lower case na paglitaw ng tinukoy na character:

Sa ilang sitwasyon, maaaring kailanganin mong magbilang ng maraming magkakaibang character sa isang talahanayan, ngunit maaaring hindi mo gustong baguhin ang formula sa bawat pagkakataon. Sa kasong ito, ilagay ang isang Substitute function sa loob ng isa pa, i-type ang character na gusto mong bilangin sa ilang cell (D1 sa halimbawang ito), at i-convert ang value ng cell na iyon sa uppercase atlowercase sa pamamagitan ng paggamit ng UPPER at LOWER function:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))

Bilang kahalili, i-convert ang source cell at ang cell na naglalaman ng character sa uppercase o lowercase. Halimbawa:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))

Ang bentahe ng diskarteng ito ay hindi alintana kung ang uppercase o lowercase na character ay input sa reference na cell, ang iyong case-insensitive character count formula ibabalik ang tamang bilang:

Bilangin ang mga paglitaw ng ilang partikular na text o substring sa isang cell

Kung gusto mong bilangin kung ilang beses ang isang tukoy na kumbinasyon ng mga character (ibig sabihin, ilang text, o substring) ay lumalabas sa isang partikular na cell, hal. "A2" o "SS", pagkatapos ay hatiin ang bilang ng mga character na ibinalik ng mga formula sa itaas sa haba ng substring.

Case-sensitive formula:

=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)

Case-insensitive na formula:

=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)

Kung saan ang B2 ay ang cell na naglalaman ng buong text string, at ang C1 ay ang text (substring) mo gustong magbilang.

Para sa detalyadong paliwanag ng formula, pakitingnan ang Paano magbilang ng partikular na text / salita sa isang cell.

Paano magbilang ng partikular (mga) character sa isang range

Ngayong alam mo na ang isang Excel formula para magbilang ng mga character sa isang cell, maaari mo itong pagbutihin pa upang malaman kung ilang beses lumilitaw ang isang partikular na character sa isang range. Para dito, kukuha kami ng Excel LEN formula upang mabilang ang isang partikular na char sa isang cell na tinalakaysa nakaraang halimbawa, at ilagay ito sa loob ng SUMPRODUCT function na maaaring humawak ng mga array:

Sa halimbawang ito, ang formula ay may sumusunod na hugis:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

At narito ang isa pang formula na bibilangin mga character sa hanay ng Excel:

=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

Kung ikukumpara sa unang formula, ang pinaka-halatang pagkakaiba ay ang paggamit ng SUM sa halip na SUMPRODUCT. Ang isa pang pagkakaiba ay nangangailangan ito ng pagpindot sa Ctrl + Shift + Enter dahil hindi tulad ng SUMPRODUCT, na idinisenyo upang magproseso ng mga array, ang SUM ay makakahawak lamang ng mga array kapag ginamit sa isang array formula .

Kung hindi mo Kung ayaw mong i-hardcode ang character sa formula, siyempre maaari mo itong i-type sa ilang cell, sabihin ang D1, at i-reference ang cell na iyon sa iyong formula ng bilang ng character:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))

Tandaan. Sa mga sitwasyon kapag binibilang mo ang mga paglitaw ng isang partikular na substring sa isang hanay (hal. mga order na nagsisimula sa "KK" o "AA"), kailangan mong hatiin ang bilang ng character sa haba ng substring, kung hindi, ang bawat character sa ang substring ay mabibilang nang isa-isa. Halimbawa:

=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))

Paano gumagana ang formula ng pagbibilang ng character na ito

Tulad ng maaalala mo, ginagamit ang SUBSTITUTE function upang palitan ang lahat ng paglitaw ng tinukoy na character ("A" sa halimbawang ito ) na may walang laman na text string ("").

Pagkatapos, ibinibigay namin ang text string na ibinalik ng SUBSTITUTE sa Excel LENfunction upang makalkula nito ang haba ng string nang walang mga A. At pagkatapos, ibawas namin ang bilang ng character na iyon mula sa kabuuang haba ng string ng teksto. Ang resulta ng mga kalkulasyong ito ay isang hanay ng mga bilang ng character, na may isang bilang ng character sa bawat cell.

Sa wakas, ang SUMPRODUCT ay nagsusuma ng mga numero sa array at ibinabalik ang kabuuang bilang ng tinukoy na character sa hanay.

Isang case-insensitive na formula upang mabilang ang mga partikular na character sa isang range

Alam mo na na ang SUBSTITUTE ay isang case-sensitive na function, na ginagawang case-sensitive din ang aming Excel formula para sa bilang ng character.

Upang gawin ang formula na balewalain ang case, sundin ang mga diskarte na ipinakita sa nakaraang halimbawa: Case-insensitive na formula upang mabilang ang mga partikular na character sa isang cell.

Sa partikular, maaari mong gamitin ang isa sa mga sumusunod na formula upang mabilang mga partikular na character sa isang hanay na binabalewala ang case:

• Gamitin ang UPPER function at maglagay ng character sa uppercase:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A","")))

• Gumamit ng nested SUBSTITUTE function:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a","")))

• Gumamit ng UPPER at LOWER na function, mag-type ng uppercase o lowercase na char sa ilang cell, at i-reference ang cell na iyon sa iyong formula:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))

Ipinapakita ng screenshot sa ibaba ang huling formula sa pagkilos:

Tip. Upang bilangin ang mga paglitaw ng isang partikular na text (substring) sa isang hanay, gamitin ang formula na ipinakita sa Paano magbilang ng partikular na teksto / mga salita sa isang hanay.

Itoay kung paano mo mabibilang ang mga character sa Excel gamit ang LEN function. Kung gusto mong malaman kung paano magbilang ng mga salita sa halip na mga indibidwal na character, makakahanap ka ng ilang kapaki-pakinabang na formula sa aming susunod na artikulo, mangyaring manatiling nakatutok!

Samantala, maaari kang mag-download ng sample na workbook na may formula ng bilang ng character tinalakay sa tutorial na ito, at tingnan ang isang listahan ng mga nauugnay na mapagkukunan sa dulo ng pahina. Salamat sa pagbabasa at umaasa akong makita ka sa lalong madaling panahon!