La lernilo klarigas kiel kalkuli signojn en Excel. Vi lernos la formulojn por akiri la totalan signokalkulon en gamo, kaj kalkuli nur specifajn signojn en ĉelo aŭ en pluraj ĉeloj.

Nia antaŭa lernilo enkondukis la Excel LEN-funkcion, kiu ebligas nombri la totala nombro da signoj en ĉelo.

La LEN-formulo estas utila memstare, sed lige kun aliaj funkcioj kiel SUM, SUMPRODUCT kaj SUBSTITUTE, ĝi povas trakti multe pli kompleksajn taskojn. Pli plu en ĉi tiu lernilo, ni rigardos pli detale kelkajn bazajn kaj altnivelajn formulojn por kalkuli signojn en Excel.

Kiel kalkuli ĉiujn signojn en gamo

Se temas pri kalkuli la totalan nombron da signoj en pluraj ĉeloj, tuja solvo, kiu venas al la menso, estas akiri la signokalkulon por ĉiu ĉelo, kaj poste aldoni tiujn nombrojn:

=LEN(A2)+LEN(A3)+LEN(A4)

Aŭ

=SUM(LEN(A2),LEN(A3),LEN(A4))

La supraj formuloj povus funkcii bone por malgranda gamo. Por kalkuli totalajn signojn en pli granda gamo, ni prefere elpensu ion pli kompaktan, ekz. la funkcio SUMPRODUCT, kiu multobligas la tabelojn kaj redonas la sumon de la produktoj.

Jen la ĝenerala Excel-formulo por kalkuli signojn en gamo:

Kaj via reala formulo povas aspekti simila al ĉi tio:

=SUMPRODUCT(LEN(A1:A7))

Alia maniero kalkuli signojn en intervalo estas uzi la LEN-funkcio enkombinaĵo kun SUM:

=SUM(LEN(A1:A7))

Malkiel SUMPRODUCT, la funkcio SUM ne kalkulas tabelojn defaŭlte, kaj vi devas premi Ctrl + Shift + Enter por igi ĝin tabelformulo.

Kiel montrite en la sekva ekrankopio, la SUM-formulo liveras la saman totalan nombron de signoj:

Kiel funkcias ĉi tiu intervalo-karakterkalkula formulo

Ĉi tio estas unu el la plej simplaj formuloj por kalkuli signojn en Excel. La LEN-funkcio kalkulas la kordlongon por ĉiu ĉelo en la specifita intervalo kaj resendas ilin kiel tabelo de nombroj. Kaj tiam, SUMPRODUKTO aŭ SUM sumigas tiujn nombrojn kaj redonas la totalan signokalkulon.

En la ĉi-supra ekzemplo, tabelo de 7 nombroj kiuj reprezentas la longojn de ŝnuroj en ĉeloj A1 ĝis A7 estas sumigita:

Notu. Bonvolu atenti, ke la Excel LEN-funkcio nombras absolute ĉiujn signojn en ĉiu ĉelo , inkluzive de literoj, ciferoj, interpunkciaj signoj, specialaj simboloj kaj ĉiuj spacoj (ĉefa, posta kaj spacoj inter vortoj).

Kiel nombri specifajn signojn en ĉelo

Foje, anstataŭ kalkuli ĉiujn signojn ene de ĉelo, vi eble bezonos kalkuli nur la aperon de specifa litero, nombro aŭ speciala simbolo.

Por kalkuli la nombron da fojoj kiam donita signo aperas en ĉelo, uzu la funkcion LEN kune kun SUBSTITUTE:

Por pli bone kompreni la formulon, konsideru la sekvan ekzemplon.

Supozu, ke vi konservas datumbazon de liveritaj eroj, kie ĉiu objektotipo havas sian propran unikan identigilo. Kaj ĉiu ĉelo enhavas plurajn erojn apartigitajn per komo, spaco aŭ ajna alia limigo. La tasko estas kalkuli kiom da fojoj donita unika identigilo aperas en ĉiu ĉelo.

Supoze ke la listo de liveritaj eroj estas en kolumno B (komencante en B2), kaj ni kalkulas la nombron de "A" okazoj, la formulo estas jena:

=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))

Kiel funkcias ĉi tiu Excel-karaktera formulo

Por kompreni la logikon de la formulo, ni ni dividu ĝin en pli malgrandajn partojn:

• Unue, oni kalkulas la tutan kordlongon en B2:

LEN(B2)

SUBSTITUTE(B2,"A","")

LEN(SUBSTITUTE(B2,"A",""))

Kiel rezulto, vi ricevas la nombron de "forigitaj" signoj, kiu egalas al totala nombro de tiu signo-okazoj en la ĉelo.

Anstataŭ specifi la signon, kiun vi volas kalkuli. formulon, vi povas tajpi ĝin en iu ĉelo, kaj tiam referenci tiun ĉelon en formulo. De ĉi tiu maniero, viaj uzantojpovos kalkuli aperojn de iu ajn alia signo kiun ili enigis en tiu ĉelo sen mistrakti vian formulon:

Notu. La SUBSTITUTO de Excel estas uskle-distinga funkcio, kaj tial la supra formulo estas uskle-distinga ankaŭ. Ekzemple, en la supra ekrankopio, ĉelo B3 enhavas 3 apojn de "A" - du majuskle, kaj unu minuskle. La formulo kalkulis nur la majusklojn ĉar ni liveris "A" al la funkcio SUBSTITUTE.

Majuskkle-nedistinga Excel-formulo por kalkuli specifajn signojn en ĉelo

Se vi bezonas uskleksenteblan kalkulon, enmetu la UPPER-funkcion ene de SUBSTITUTE por konverti la specifitan signon al majuskla antaŭ ol ruli la anstataŭigon. Kaj, nepre enigu la majusklon en la formulo.

Ekzemple, por kalkuli "A" kaj "a" erojn en ĉelo B2, uzu ĉi tiun formulon:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))

Alia maniero estas uzi nestitajn Anstataŭajn funkciojn:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")

Kiel vi povas vidi en la suba ekrankopio, ambaŭ formuloj perfekte kalkulas majusklojn kaj minusklojn de la specifita signo:

En kelkaj kazoj, vi eble bezonos nombri multajn malsamajn signojn en tabelo, sed vi eble ne volas modifi la formulon ĉiufoje. En ĉi tiu kazo, nestu unu Anstataŭan funkcion ene de alia, tajpu la signon, kiun vi volas kalkuli en iu ĉelo (D1 en ĉi tiu ekzemplo), kaj konvertu la valoron de tiu ĉelo al majuskla kajminuskloj uzante la funkciojn UPPER kaj LOWER:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))

Alternative, konverti kaj la fontĉelon kaj la ĉelon enhavanta la signon aŭ al majuskla aŭ minuskla. Ekzemple:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))

La avantaĝo de ĉi tiu aliro estas, ke sendepende de ĉu la majuskla aŭ minuskla signo estas enigita en la referencita ĉelo, via malsentema signo-kalkula formulo redonos la ĝustan kalkulon:

Nombri apojn de certa teksto aŭ subĉeno en ĉelo

Se vi volas kalkuli kiom da fojoj specifa kombino de signoj (t.e. certa teksto, aŭ subĉeno) aperas en donita ĉelo, ekz. "A2" aŭ "SS", tiam dividu la nombron da signoj redonitaj de la ĉi-supraj formuloj per la longo de la subĉeno.

Uskle-distinga formulo:

=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)

Majusksence formulo:

=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)

Kie B2 estas la ĉelo enhavanta la tutan tekstĉenon, kaj C1 estas la teksto (subĉeno) kiun vi volas kalkuli.

Por la detala klarigo de la formulo, bonvolu vidi Kiel kalkuli specifajn tekstojn/vortojn en ĉelo.

Kiel kalkuli specifajn tekstojn/vortojn. signo(j) en gamo

Nun kiam vi konas Excel-formulon por kalkuli signojn en ĉelo, vi eble volas plibonigi ĝin por ekscii kiomfoje certa signo aperas en gamo. Por ĉi tio, ni prenos la formulon de Excel LEN por kalkuli specifan karakteron en ĉelo diskutitaen la antaŭa ekzemplo, kaj metu ĝin en la funkcion SUMPRODUCT, kiu povas manipuli tabelojn:

En ĉi tiu ekzemplo, la formulo prenas la jenan formon:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

Kaj jen alia formulo por kalkuli signoj en la gamo de Excel:

=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

Kompare kun la unua formulo, la plej evidenta diferenco estas uzi SUM anstataŭ SUMPRODUCT. Alia diferenco estas, ke ĝi postulas premadon de Ctrl + Shift + Enter ĉar male al SUMPRODUCT, kiu estas dizajnita por prilabori tabelojn, SUM povas trakti tabelojn nur kiam uzata en tabelformulo .

Se vi ne faras 'ne volas malmolkodigi la signon en la formulo, vi povas kompreneble tajpi ĝin en iu ĉelo, diru D1, kaj referenci tiun ĉelon en via signokalkula formulo:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))

Noto. En situacioj, kiam vi nombras la aperon de specifa subĉeno en gamo (ekz. ordoj komenciĝantaj per "KK" aŭ "AA"), vi devas dividi la signokalkulon per la subĉeno longo, alie ĉiu signo en la subĉeno estos kalkulita individue. Ekzemple:

=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))

Kiel funkcias ĉi tiu signo-kalkula formulo

Kiel vi memoras, la funkcio SUBSTITUTE estas uzata por anstataŭigi ĉiujn aperon de la specifita signo ("A" en ĉi tiu ekzemplo). ) kun malplena tekstoĉeno ("").

Tiam, ni liveras la tekstoĉenon resenditan de SUBSTITUTE al la Excel LENfunkcio tiel ke ĝi kalkulas la kordlongon sen A-oj. Kaj tiam ni subtrahas tiun signon de la tuta longo de la tekstoĉeno. La rezulto de ĉi tiuj kalkuloj estas tabelo de signokalkuloj, kun unu signokalkulo por ĉelo.

Fine, SUMPRODUCT sumigas la nombrojn en la tabelo kaj redonas la totalan kalkulon de la specifita signo en la intervalo.

Majusksentema formulo por kalkuli specifajn signojn en intervalo

Vi jam scias, ke SUBSTITUTE estas uskle-distinga funkcio, kio igas nian Excel-formulon por signokalkulo ankaŭ majuskle-distintan.

Por ke la formulo ignoru majusklojn, sekvu la alirojn montritajn en la antaŭa ekzemplo: Nedistinga uskleco formulo por kalkuli specifajn signojn en ĉelo.

Aparte, vi povas uzi unu el la sekvaj formuloj por nombri specifaj signoj en gamo ignorante majusklojn:

• Uzu la UPPER-funkcion kaj enigu signon majuskle:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A","")))

• Uzu nestitajn SUBSTITUTO-funkciojn:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a","")))

• Uzu UPPER kaj LOWER funkciojn, tajpu aŭ majusklan aŭ minusklan signon en iu ĉelo, kaj referencu tiun ĉelon en via formulo:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))

  Vidu ankaŭ: 6 Kialoj Kial Via VLOOKUP Ne Funkcias

La suba ekrankopio montras la lastan formulon en ago:

Konsileto. Por kalkuli la aperon de specifa teksto (subĉeno) en gamo, uzu la formulon montritan en Kiel kalkuli specifan tekston/vortojn en gamo.

Ĉi tioestas kiel vi povas kalkuli signojn en Excel uzante la funkcion LEN. Se vi volas scii kiel kalkuli vortojn prefere ol unuopaj signoj, vi trovos kelkajn utilajn formulojn en nia sekva artikolo, bonvolu resti agordita!

Dume vi povas elŝuti ekzemplajn laborlibrojn kun karakterkalkula formulo. diskutita en ĉi tiu lernilo, kaj kontrolu liston de rilataj rimedoj ĉe la fino de la paĝo. Mi dankas vin pro legado kaj esperas vidi vin baldaŭ!