টিউটোরিয়াল ব্যাখ্যা করে কিভাবে এক্সেলে অক্ষর গণনা করা যায়। আপনি একটি পরিসরে মোট অক্ষর গণনা পেতে সূত্রগুলি শিখবেন এবং একটি কক্ষে বা একাধিক কক্ষে শুধুমাত্র নির্দিষ্ট অক্ষর গণনা করতে পারবেন৷

আমাদের পূর্ববর্তী টিউটোরিয়ালটি এক্সেল LEN ফাংশনটি চালু করেছিল, যা গণনা করার অনুমতি দেয় একটি কক্ষে মোট অক্ষরের সংখ্যা৷

LEN সূত্রটি নিজে থেকেই কার্যকর, কিন্তু SUM, SUMPRODUCT এবং SUBSTITUTE-এর মতো অন্যান্য ফাংশনের সাথে যোগাযোগের ক্ষেত্রে, এটি আরও জটিল কাজগুলি পরিচালনা করতে পারে৷ এই টিউটোরিয়ালে আরও, আমরা এক্সেল-এ অক্ষর গণনা করার জন্য কয়েকটি মৌলিক এবং উন্নত সূত্রগুলি ঘনিষ্ঠভাবে দেখতে যাচ্ছি৷

একটি পরিসরে সমস্ত অক্ষর কীভাবে গণনা করা যায়

যখন বেশ কয়েকটি কক্ষে মোট অক্ষর গণনার কথা আসে, তখন একটি তাৎক্ষণিক সমাধান যা মনে আসে তা হল প্রতিটি কক্ষের জন্য অক্ষর গণনা করা এবং তারপর সেই সংখ্যাগুলি যোগ করা:

=LEN(A2)+LEN(A3)+LEN(A4)

বা

=SUM(LEN(A2),LEN(A3),LEN(A4))

উপরের সূত্রগুলি একটি ছোট পরিসরের জন্য ভাল কাজ করতে পারে। একটি বড় পরিসরে মোট অক্ষর গণনা করতে, আমরা আরও কমপ্যাক্ট কিছু নিয়ে আসতে চাই, যেমন SUMPRODUCT ফাংশন, যা অ্যারেগুলিকে গুণ করে এবং পণ্যগুলির যোগফল প্রদান করে৷

এখানে একটি পরিসরে অক্ষর গণনা করার জন্য জেনেরিক এক্সেল সূত্র দেওয়া হল:

এবং আপনার বাস্তব জীবনের সূত্রটি এর অনুরূপ হতে পারে:

=SUMPRODUCT(LEN(A1:A7))

একটি পরিসরে অক্ষর গণনা করার আরেকটি উপায় হল ব্যবহার করা LEN ফাংশন ইনSUM এর সাথে সমন্বয়:

=SUM(LEN(A1:A7))

SUMPRODUCT এর বিপরীতে, SUM ফাংশন ডিফল্টভাবে অ্যারে গণনা করে না এবং এটিকে একটি অ্যারে সূত্রে পরিণত করতে আপনাকে Ctrl + Shift + Enter টিপতে হবে।

নিম্নলিখিত স্ক্রিনশটে প্রদর্শিত হিসাবে, SUM সূত্রটি একই মোট অক্ষর গণনা প্রদান করে:

এই পরিসরের অক্ষর গণনা সূত্র কীভাবে কাজ করে

এটি Excel এ অক্ষর গণনা করার জন্য সবচেয়ে সহজবোধ্য সূত্রগুলির মধ্যে একটি। LEN ফাংশন নির্দিষ্ট পরিসরের প্রতিটি কক্ষের জন্য স্ট্রিং দৈর্ঘ্য গণনা করে এবং তাদের সংখ্যার অ্যারে হিসাবে প্রদান করে। এবং তারপর, SUMPRODUCT বা SUM সেই সংখ্যাগুলিকে যোগ করে এবং মোট অক্ষর গণনা প্রদান করে৷

উপরের উদাহরণে, 7টি সংখ্যার একটি অ্যারে যা A1 থেকে A7 কক্ষে স্ট্রিংগুলির দৈর্ঘ্যকে প্রতিনিধিত্ব করে:

নোট। অনুগ্রহ করে মনোযোগ দিন যে এক্সেল LEN ফাংশনটি সম্পূর্ণরূপে প্রতিটি কক্ষে সমস্ত অক্ষর গণনা করে , অক্ষর, সংখ্যা, বিরাম চিহ্ন, বিশেষ চিহ্ন এবং সমস্ত স্পেস (প্রধান, পিছনে এবং শব্দের মধ্যে স্পেস) সহ।

কোন কক্ষে কিভাবে নির্দিষ্ট অক্ষর গণনা করা যায়

কখনও কখনও, একটি ঘরের মধ্যে সমস্ত অক্ষর গণনার পরিবর্তে, আপনাকে শুধুমাত্র একটি নির্দিষ্ট অক্ষর, সংখ্যা বা বিশেষ চিহ্নের উপস্থিতি গণনা করতে হতে পারে৷

কোন কক্ষে একটি প্রদত্ত অক্ষর কতবার উপস্থিত হয় তা গণনা করতে, SUBSTITUTE এর সাথে LEN ফাংশনটি ব্যবহার করুন:

সূত্রটি আরও ভালভাবে বোঝার জন্য, নিম্নলিখিত উদাহরণটি বিবেচনা করুন৷

ধরুন, আপনি বিতরণ করা আইটেমগুলির একটি ডাটাবেস বজায় রাখেন, যেখানে প্রতিটি আইটেমের প্রকারের নিজস্ব স্বতন্ত্র রয়েছে শনাক্তকারী এবং প্রতিটি কক্ষে কমা, স্পেস বা অন্য কোন ডিলিমিটার দ্বারা আলাদা করা বেশ কিছু আইটেম রয়েছে। কাজটি হল প্রতিটি কক্ষে একটি প্রদত্ত অনন্য শনাক্তকারী কতবার উপস্থিত হয় তা গণনা করা৷

ধরে নেওয়া হচ্ছে যে বিতরণ করা আইটেমগুলির তালিকাটি B কলামে রয়েছে (B2 থেকে শুরু হচ্ছে), এবং আমরা "A" এর সংখ্যা গণনা করছি সংঘটন, সূত্রটি নিম্নরূপ:

=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))

এই এক্সেল অক্ষর গণনা সূত্রটি কীভাবে কাজ করে

সূত্রটির যুক্তি বোঝার জন্য, আসুন এটিকে ছোট ছোট অংশে বিভক্ত করুন:

• প্রথমে, আপনি B2 এ মোট স্ট্রিং দৈর্ঘ্য গণনা করুন:

LEN(B2)

SUBSTITUTE(B2,"A","")

LEN(SUBSTITUTE(B2,"A",""))

ফলস্বরূপ, আপনি "মুছে ফেলা" অক্ষরগুলির গণনা পাবেন, যা কক্ষে থাকা সেই অক্ষর সংঘটনের মোট সংখ্যার সমান৷

আপনি যে অক্ষরটি গণনা করতে চান তা নির্দিষ্ট করার পরিবর্তে একটি সূত্র, আপনি এটি কিছু কক্ষে টাইপ করতে পারেন, এবং তারপর সেই ঘরটিকে একটি সূত্রে উল্লেখ করতে পারেন। এই ভাবে, আপনার ব্যবহারকারীদেরআপনার সূত্র:

দ্রষ্টব্য। Excel এর SUBSTITUTE একটি কেস-সংবেদনশীল ফাংশন, এবং সেই কারণে উপরের সূত্রটিও কেস-সংবেদনশীল। উদাহরণস্বরূপ, উপরের স্ক্রিনশটে, সেল B3-এ "A"-এর 3টি ঘটনা রয়েছে - দুটি বড় হাতের অক্ষরে এবং একটি ছোট হাতের অক্ষরে। সূত্রটি শুধুমাত্র বড় হাতের অক্ষর গণনা করেছে কারণ আমরা SUBSTITUTE ফাংশনে "A" সরবরাহ করেছি।

কোন কক্ষে নির্দিষ্ট অক্ষর গণনা করার জন্য কেস-সংবেদনশীল এক্সেল সূত্র

যদি আপনার একটি কেস-সংবেদনশীল অক্ষর গণনার প্রয়োজন হয়, প্রতিস্থাপন চালানোর আগে নির্দিষ্ট অক্ষরটিকে বড় হাতের অক্ষরে রূপান্তর করতে SUBSTITUTE-এর ভিতরে UPPER ফাংশনটি এম্বেড করুন। এবং, সূত্রে বড় হাতের অক্ষর লিখতে ভুলবেন না।

উদাহরণস্বরূপ, সেল B2-এ "A" এবং "a" আইটেম গণনা করতে, এই সূত্রটি ব্যবহার করুন:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))

অন্য উপায় হল নেস্টেড সাবস্টিটিউট ফাংশনগুলি ব্যবহার করা:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")

যেমন আপনি নীচের স্ক্রিনশটটিতে দেখতে পাচ্ছেন, উভয় সূত্রই নির্দিষ্ট অক্ষরের বড় হাতের এবং ছোট হাতের ঘটনাগুলিকে নির্ভুলভাবে গণনা করে:

কিছু ​​ক্ষেত্রে, আপনাকে একটি টেবিলে অনেকগুলি ভিন্ন অক্ষর গণনা করতে হতে পারে, কিন্তু আপনি প্রতিবার সূত্রটি পরিবর্তন করতে নাও পারেন৷ এই ক্ষেত্রে, নেস্ট ওয়ান সাবস্টিটিউট ফাংশন অন্যের মধ্যে, আপনি যে অক্ষরটি কিছু কক্ষে গণনা করতে চান তা টাইপ করুন (এই উদাহরণে D1), এবং সেই ঘরের মানকে বড় হাতের অক্ষরে রূপান্তর করুন এবংUPPER এবং LOWER ফাংশন ব্যবহার করে ছোট হাতের অক্ষর:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))

বিকল্পভাবে, সোর্স সেল এবং অক্ষর ধারণকারী কক্ষ উভয়কেই বড় হাতের বা ছোট হাতের অক্ষরে রূপান্তর করুন। উদাহরণস্বরূপ:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))

এই পদ্ধতির সুবিধা হল যে রেফারেন্স করা কক্ষে বড় হাতের বা ছোট হাতের অক্ষরটি ইনপুট করা হোক না কেন, আপনার কেস-সংবেদনশীল অক্ষর গণনা সূত্র সঠিক গণনা প্রদান করবে:

কোন কক্ষে নির্দিষ্ট পাঠ্য বা সাবস্ট্রিং এর উপস্থিতি গণনা করুন

যদি আপনি কতবার গণনা করতে চান অক্ষরের নির্দিষ্ট সংমিশ্রণ (অর্থাৎ নির্দিষ্ট টেক্সট, বা সাবস্ট্রিং) একটি প্রদত্ত কক্ষে প্রদর্শিত হয়, যেমন "A2" বা "SS", তারপর উপরের সূত্রগুলি দ্বারা প্রত্যাবর্তিত অক্ষরগুলির সংখ্যাকে সাবস্ট্রিং এর দৈর্ঘ্য দ্বারা ভাগ করুন৷

কেস-সংবেদনশীল সূত্র:

=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)

কেস-সংবেদনশীল সূত্র:

=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)

যেখানে B2 হল সম্পূর্ণ টেক্সট স্ট্রিং ধারণকারী সেল, এবং C1 হল টেক্সট (সাবস্ট্রিং) আপনি গণনা করতে চান।

সূত্রের বিস্তারিত ব্যাখ্যার জন্য, অনুগ্রহ করে দেখুন কিভাবে একটি ঘরে নির্দিষ্ট পাঠ্য/শব্দ গণনা করা যায়।

কীভাবে নির্দিষ্ট গণনা করা যায় একটি পরিসরে অক্ষর(গুলি)

এখন যেহেতু আপনি একটি কক্ষে অক্ষর গণনা করার জন্য একটি এক্সেল সূত্র জানেন, আপনি একটি পরিসরে একটি নির্দিষ্ট অক্ষর কতবার উপস্থিত হয় তা খুঁজে বের করতে এটি আরও উন্নত করতে চাইতে পারেন। এই জন্য, আমরা আলোচিত একটি ঘরে একটি নির্দিষ্ট চর গণনা করার জন্য এক্সেল LEN সূত্রটি নেবপূর্ববর্তী উদাহরণে, এবং এটিকে SUMPRODUCT ফাংশনের ভিতরে রাখুন যা অ্যারেগুলি পরিচালনা করতে পারে:

এই উদাহরণে, সূত্রটি নিম্নলিখিত আকার নেয়:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

এবং এখানে গণনা করার জন্য আরেকটি সূত্র রয়েছে এক্সেলের পরিসরে অক্ষর:

=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

প্রথম সূত্রের তুলনায়, সবচেয়ে স্পষ্ট পার্থক্য হল SUMPRODUCT এর পরিবর্তে SUM ব্যবহার করা। আরেকটি পার্থক্য হল এটির জন্য Ctrl + Shift + Enter টিপতে হবে কারণ SUMPRODUCT এর বিপরীতে, যা অ্যারে প্রক্রিয়া করার জন্য ডিজাইন করা হয়েছে, SUM শুধুমাত্র অ্যারেগুলি পরিচালনা করতে পারে যখন একটি অ্যারে সূত্র ব্যবহার করা হয়।

যদি আপনি না করেন সূত্রের অক্ষরটিকে হার্ডকোড করতে চাই না, আপনি অবশ্যই এটিকে কিছু ঘরে টাইপ করতে পারেন, D1 বলুন এবং আপনার অক্ষর গণনা সূত্রে সেই ঘরটি উল্লেখ করতে পারেন:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))

নোট। এমন পরিস্থিতিতে যখন আপনি একটি পরিসরে একটি নির্দিষ্ট সাবস্ট্রিং এর ঘটনাগুলি গণনা করেন (যেমন "কেকে" বা "এএ" দিয়ে শুরু হওয়া আদেশ), আপনাকে সাবস্ট্রিং দৈর্ঘ্য দ্বারা অক্ষর গণনা ভাগ করতে হবে, অন্যথায় প্রতিটি অক্ষর সাবস্ট্রিং পৃথকভাবে গণনা করা হবে। উদাহরণস্বরূপ:

=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))

এই অক্ষর গণনা সূত্রটি কীভাবে কাজ করে

আপনি মনে করতে পারেন, SUBSTITUTE ফাংশনটি নির্দিষ্ট অক্ষরের সমস্ত উপস্থিতি প্রতিস্থাপন করতে ব্যবহৃত হয় (এই উদাহরণে "A" ) একটি খালি টেক্সট স্ট্রিং ("") সহ।

তারপর, আমরা এক্সেল LEN-এ SUBSTITUTE দ্বারা ফেরত দেওয়া টেক্সট স্ট্রিং সরবরাহ করি।ফাংশন যাতে এটি A ছাড়া স্ট্রিং দৈর্ঘ্য গণনা করে। এবং তারপর, আমরা পাঠ্য স্ট্রিং এর মোট দৈর্ঘ্য থেকে যে অক্ষর গণনা বিয়োগ. এই গণনার ফলাফল হল অক্ষর গণনার একটি অ্যারে, প্রতি কক্ষে একটি অক্ষর গণনা৷

অবশেষে, SUMPRODUCT অ্যারের সংখ্যাগুলি যোগ করে এবং পরিসরে নির্দিষ্ট অক্ষরের মোট গণনা প্রদান করে৷

একটি পরিসরে নির্দিষ্ট অক্ষর গণনা করার জন্য একটি কেস-সংবেদনশীল সূত্র

আপনি ইতিমধ্যেই জানেন যে SUBSTITUTE হল একটি কেস-সংবেদনশীল ফাংশন, যা অক্ষর গণনার জন্য আমাদের এক্সেল সূত্রটিকেও কেস-সংবেদনশীল করে তোলে৷

সূত্রটিকে কেস উপেক্ষা করতে, পূর্ববর্তী উদাহরণে প্রদর্শিত পদ্ধতিগুলি অনুসরণ করুন: একটি কক্ষে নির্দিষ্ট অক্ষর গণনা করার জন্য কেস-সংবেদনশীল সূত্র।

বিশেষত, আপনি গণনা করতে নিম্নলিখিত সূত্রগুলির মধ্যে একটি ব্যবহার করতে পারেন একটি পরিসর উপেক্ষা করার ক্ষেত্রে নির্দিষ্ট অক্ষর:

• UPPER ফাংশন ব্যবহার করুন এবং বড় হাতের অক্ষর লিখুন:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A","")))

• নেস্টেড সাবস্টিটিউট ফাংশন ব্যবহার করুন:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a","")))

• UPPER এবং LOWER ফাংশন ব্যবহার করুন, কিছু কক্ষে একটি বড় হাতের অক্ষর বা ছোট হাতের অক্ষর টাইপ করুন এবং সেই ঘরটিকে আপনার সূত্রে উল্লেখ করুন:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))

  <17

নিচের স্ক্রিনশটটি কার্যের শেষ সূত্রটি প্রদর্শন করে:

টিপ। একটি পরিসরে একটি নির্দিষ্ট পাঠ্য (সাবস্ট্রিং) এর উপস্থিতি গণনা করতে, একটি পরিসরে নির্দিষ্ট পাঠ্য / শব্দগুলি কীভাবে গণনা করতে হয় তাতে প্রদর্শিত সূত্রটি ব্যবহার করুন।

এইআপনি কিভাবে LEN ফাংশন ব্যবহার করে এক্সেলে অক্ষর গণনা করতে পারেন। আপনি যদি পৃথক অক্ষরের পরিবর্তে শব্দ গণনা করতে চান তা জানতে চাইলে, আপনি আমাদের পরবর্তী নিবন্ধে কয়েকটি দরকারী সূত্র পাবেন, অনুগ্রহ করে সাথে থাকুন!

এর মধ্যে, আপনি অক্ষর গণনার সূত্র সহ একটি নমুনা ওয়ার্কবুক ডাউনলোড করতে পারেন এই টিউটোরিয়ালে আলোচনা করা হয়েছে, এবং পৃষ্ঠার শেষে সম্পর্কিত সংস্থানগুলির একটি তালিকা দেখুন। আমি পড়ার জন্য আপনাকে ধন্যবাদ এবং শীঘ্রই আপনাকে দেখতে আশা করি!