Tutorial menerangkan cara mengira aksara dalam Excel. Anda akan mempelajari formula untuk mendapatkan jumlah kiraan aksara dalam julat dan mengira hanya aksara tertentu dalam sel atau dalam beberapa sel.

Tutorial kami sebelum ini memperkenalkan fungsi Excel LEN, yang membolehkan pengiraan jumlah bilangan aksara dalam sel.

Formula LEN berguna dengan sendirinya, tetapi dalam hubungan dengan fungsi lain seperti SUM, SUMPRODUCT dan SUBSTITUTE, ia boleh mengendalikan tugas yang jauh lebih kompleks. Selanjutnya dalam tutorial ini, kita akan melihat dengan lebih dekat beberapa formula asas dan lanjutan untuk mengira aksara dalam Excel.

Cara mengira semua aksara dalam julat

Apabila mengira jumlah bilangan aksara dalam beberapa sel, penyelesaian segera yang terlintas di fikiran ialah mendapatkan kiraan aksara bagi setiap sel, dan kemudian menjumlahkan nombor tersebut:

=LEN(A2)+LEN(A3)+LEN(A4)

Atau

=SUM(LEN(A2),LEN(A3),LEN(A4))

Formula di atas mungkin berfungsi dengan baik untuk julat yang kecil. Untuk mengira jumlah aksara dalam julat yang lebih besar, lebih baik kami menghasilkan sesuatu yang lebih padat, mis. fungsi SUMPRODUCT, yang mendarabkan tatasusunan dan mengembalikan jumlah produk.

Berikut ialah formula Excel generik untuk mengira aksara dalam julat:

Dan formula kehidupan sebenar anda mungkin kelihatan serupa dengan ini:

=SUMPRODUCT(LEN(A1:A7))

Cara lain untuk mengira aksara dalam julat ialah menggunakan Fungsi LEN dalamgabungan dengan SUM:

=SUM(LEN(A1:A7))

Tidak seperti SUMPRODUCT, fungsi SUM tidak mengira tatasusunan secara lalai dan anda perlu menekan Ctrl + Shift + Enter untuk mengubahnya menjadi formula tatasusunan.

Seperti yang ditunjukkan dalam tangkapan skrin berikut, formula SUM mengembalikan jumlah bilangan aksara yang sama:

Cara formula kiraan aksara julat ini berfungsi

Ini ialah salah satu formula yang paling mudah untuk mengira aksara dalam Excel. Fungsi LEN mengira panjang rentetan untuk setiap sel dalam julat yang ditentukan dan mengembalikannya sebagai tatasusunan nombor. Dan kemudian, SUMPRODUCT atau SUM menjumlahkan nombor tersebut dan mengembalikan jumlah kiraan aksara.

Dalam contoh di atas, tatasusunan 7 nombor yang mewakili panjang rentetan dalam sel A1 hingga A7 dijumlahkan:

Nota. Sila ambil perhatian bahawa fungsi Excel LEN mengira sepenuhnya semua aksara dalam setiap sel , termasuk huruf, nombor, tanda baca, simbol khas dan semua ruang (menuju, mengekor dan menjarakkan antara perkataan).

Cara mengira aksara tertentu dalam sel

Kadangkala, bukannya mengira semua aksara dalam sel, anda mungkin perlu mengira hanya kejadian huruf, nombor atau simbol khas tertentu.

Untuk mengira bilangan kali aksara yang diberikan muncul dalam sel, gunakan fungsi LEN bersama-sama dengan SUBSTITUTE:

Untuk lebih memahami formula, pertimbangkan contoh berikut.

Andaikan, anda mengekalkan pangkalan data item yang dihantar, di mana setiap jenis item mempunyai keunikan tersendiri pengecam. Dan setiap sel mengandungi beberapa item yang dipisahkan dengan koma, ruang atau mana-mana pembatas lain. Tugasnya ialah mengira berapa kali pengecam unik yang diberikan muncul dalam setiap sel.

Dengan mengandaikan bahawa senarai item yang dihantar berada dalam lajur B (bermula dalam B2), dan kami mengira bilangan "A" kejadian, formulanya adalah seperti berikut:

=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))

Cara formula kiraan aksara Excel ini berfungsi

Untuk memahami logik formula, mari kita pecahkannya kepada bahagian yang lebih kecil:

• Mula-mula, anda mengira jumlah panjang rentetan dalam B2:

LEN(B2)

SUBSTITUTE(B2,"A","")

LEN(SUBSTITUTE(B2,"A",""))

Akibatnya, anda mendapat kiraan aksara "dialih keluar", yang bersamaan dengan jumlah bilangan kejadian aksara tersebut dalam sel.

Daripada menentukan aksara yang anda mahu kira dalam formula, anda boleh menaipnya dalam beberapa sel, dan kemudian merujuk sel itu dalam formula. Dengan cara ini, pengguna andaakan dapat mengira kejadian mana-mana aksara lain yang mereka masukkan dalam sel itu tanpa mengganggu formula anda:

Nota. SUBSTITUTE Excel ialah fungsi sensitif huruf besar-besaran, dan oleh itu formula di atas juga sensitif huruf besar-besaran. Sebagai contoh, dalam tangkapan skrin di atas, sel B3 mengandungi 3 kejadian "A" - dua dalam huruf besar dan satu dalam huruf kecil. Formula telah mengira hanya huruf besar kerana kami membekalkan "A" kepada fungsi SUBSTITUTE.

Formula Excel tidak peka huruf besar-besaran untuk mengira aksara tertentu dalam sel

Jika anda memerlukan kiraan aksara tidak peka huruf besar-besaran, benamkan fungsi UPPER di dalam SUBSTITUTE untuk menukar aksara yang ditentukan kepada huruf besar sebelum menjalankan penggantian. Dan, pastikan anda memasukkan aksara huruf besar dalam formula.

Sebagai contoh, untuk mengira item "A" dan "a" dalam sel B2, gunakan formula ini:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))

Cara lain ialah menggunakan fungsi Gantian bersarang:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")

Seperti yang anda lihat dalam tangkapan skrin di bawah, kedua-dua formula mengira kejadian huruf besar dan huruf kecil bagi aksara yang ditentukan dengan sempurna:

Dalam sesetengah kes, anda mungkin perlu mengira banyak aksara berbeza dalam jadual, tetapi anda mungkin tidak mahu mengubah suai formula setiap kali. Dalam kes ini, sarang satu fungsi Gantikan dalam yang lain, taip aksara yang anda mahu kira dalam beberapa sel (D1 dalam contoh ini), dan tukar nilai sel itu kepada huruf besar danhuruf kecil dengan menggunakan fungsi UPPER dan LOWER:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))

Sebagai alternatif, tukarkan kedua-dua sel sumber dan sel yang mengandungi aksara sama ada kepada huruf besar atau huruf kecil. Contohnya:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))

Kelebihan pendekatan ini ialah tidak kira sama ada aksara besar atau huruf kecil dimasukkan dalam sel yang dirujuk, formula kiraan aksara tidak peka huruf besar anda akan mengembalikan kiraan yang betul:

Kira kejadian teks atau subrentetan tertentu dalam sel

Jika anda ingin mengira berapa kali gabungan aksara tertentu (iaitu teks tertentu atau subrentetan) muncul dalam sel tertentu, mis. "A2" atau "SS", kemudian bahagikan bilangan aksara yang dikembalikan oleh formula di atas dengan panjang subrentetan.

Rumus sensitif huruf besar-kecil :

=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1) Formula

Tidak peka huruf besar-kecil :

=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)

Di mana B2 ialah sel yang mengandungi keseluruhan rentetan teks dan C1 ialah teks (subrentetan) anda mahu mengira.

Untuk mendapatkan penjelasan terperinci tentang formula, sila lihat Cara mengira teks / perkataan tertentu dalam sel.

Cara mengira khusus aksara dalam julat

Sekarang anda mengetahui formula Excel untuk mengira aksara dalam sel, anda mungkin mahu memperbaikinya lagi untuk mengetahui berapa kali aksara tertentu muncul dalam julat. Untuk ini, kami akan menggunakan formula Excel LEN untuk mengira aksara tertentu dalam sel yang dibincangkandalam contoh sebelumnya, dan letakkannya di dalam fungsi SUMPRODUCT yang boleh mengendalikan tatasusunan:

Dalam contoh ini, formula mengambil bentuk berikut:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

Dan inilah formula lain untuk dikira aksara dalam julat Excel:

=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

Berbanding dengan formula pertama, perbezaan yang paling jelas ialah menggunakan SUM dan bukannya SUMPRODUCT. Perbezaan lain ialah ia memerlukan menekan Ctrl + Shift + Enter kerana tidak seperti SUMPRODUCT, yang direka untuk memproses tatasusunan, SUM boleh mengendalikan tatasusunan hanya apabila digunakan dalam formula tatasusunan .

Jika anda tidak Jika anda tidak mahu mengekodkan watak dalam formula, anda sudah tentu boleh menaipnya dalam beberapa sel, katakan D1, dan merujuk sel tersebut dalam formula kiraan aksara anda:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))

Nota. Dalam situasi apabila anda mengira kejadian subrentetan tertentu dalam julat (cth. pesanan bermula dengan "KK" atau "AA"), anda perlu membahagikan kiraan aksara dengan panjang subrentetan, jika tidak, setiap aksara dalam subrentetan akan dikira secara individu. Contohnya:

=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))

Cara formula pengiraan aksara ini berfungsi

Seperti yang anda ingat, fungsi SUBSTITUTE digunakan untuk menggantikan semua kejadian aksara yang ditentukan ("A" dalam contoh ini ) dengan rentetan teks kosong ("").

Kemudian, kami membekalkan rentetan teks yang dikembalikan oleh GANTI kepada Excel LENberfungsi supaya ia mengira panjang rentetan tanpa A. Dan kemudian, kami menolak kiraan aksara itu daripada jumlah panjang rentetan teks. Hasil pengiraan ini ialah tatasusunan kiraan aksara, dengan satu kiraan aksara setiap sel.

Akhir sekali, SUMPRODUCT menjumlahkan nombor dalam tatasusunan dan mengembalikan jumlah kiraan aksara yang ditentukan dalam julat.

Formula tidak peka huruf besar-besaran untuk mengira aksara tertentu dalam julat

Anda sudah tahu bahawa SUBSTITUTE ialah fungsi sensitif huruf besar-besaran, yang menjadikan formula Excel kami untuk kiraan aksara sensitif huruf besar juga.

Untuk menjadikan formula mengabaikan huruf besar, ikut pendekatan yang ditunjukkan dalam contoh sebelumnya: Formula tidak sensitif huruf besar untuk mengira aksara tertentu dalam sel.

Secara khususnya, anda boleh menggunakan salah satu daripada formula berikut untuk mengira aksara tertentu dalam julat mengabaikan huruf besar:

• Gunakan fungsi UPPER dan masukkan aksara dalam huruf besar:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A","")))

• Gunakan fungsi SUBSTITUTE bersarang:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a","")))

• Gunakan fungsi ATAS dan BAWAH, taip sama ada aksara besar atau huruf kecil dalam sesetengah sel dan rujuk sel tersebut dalam formula anda:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))

Tangkapan skrin di bawah menunjukkan formula terakhir dalam tindakan:

Petua. Untuk mengira kejadian teks khusus (subrentetan) dalam julat, gunakan formula yang ditunjukkan dalam Cara mengira teks / perkataan tertentu dalam julat.

Iniialah cara anda boleh mengira aksara dalam Excel menggunakan fungsi LEN. Jika anda ingin mengetahui cara mengira perkataan dan bukannya aksara individu, anda akan menemui beberapa formula berguna dalam artikel kami yang seterusnya, sila nantikan!

Sementara itu, anda boleh memuat turun contoh buku kerja dengan formula kiraan aksara dibincangkan dalam tutorial ini, dan lihat senarai sumber yang berkaitan di penghujung halaman. Saya berterima kasih kerana membaca dan berharap dapat berjumpa anda tidak lama lagi!