Mae'r tiwtorial yn esbonio sut i gyfrif cymeriadau yn Excel. Byddwch yn dysgu'r fformiwlâu i gael cyfanswm y cyfrif nodau mewn amrediad, ac yn cyfrif nodau penodol yn unig mewn cell neu mewn sawl cell.

Cyflwynodd ein tiwtorial blaenorol y ffwythiant Excel LEN, sy'n caniatáu cyfrif y cyfanswm nifer y nodau mewn cell.

Mae'r fformiwla LEN yn ddefnyddiol ar ei phen ei hun, ond mewn cysylltiad â swyddogaethau eraill megis SUM, SUMPRODUCT a SUBSTITUTE, gall ymdrin â thasgau llawer mwy cymhleth. Ymhellach ymlaen yn y tiwtorial hwn, byddwn yn edrych yn agosach ar ychydig o fformiwlâu sylfaenol ac uwch i gyfrif nodau yn Excel.

Sut i gyfrif pob nod mewn ystod

O ran cyfrif cyfanswm nifer y nodau mewn sawl cell, ateb ar unwaith sy'n dod i'r meddwl yw cael y cyfrif nodau ar gyfer pob cell, ac yna adio'r rhifau hynny:

=LEN(A2)+LEN(A3)+LEN(A4) <3

Neu

=SUM(LEN(A2),LEN(A3),LEN(A4))

Gallai'r fformiwlâu uchod weithio'n iawn ar gyfer ystod fach. I gyfri cyfanswm y cymeriadau mewn ystod fwy, byddai'n well i ni feddwl am rywbeth mwy cryno, e.e. y ffwythiant SUMPRODUCT, sy'n lluosi'r araeau ac yn dychwelyd swm y cynhyrchion.

Dyma'r fformiwla Excel generig i gyfrif nodau mewn amrediad:

Ac efallai y bydd eich fformiwla bywyd go iawn yn edrych yn debyg i hyn:

=SUMPRODUCT(LEN(A1:A7))

=SUM(LEN(A1:A7))

Yn wahanol i SUMPRODUCT, nid yw'r ffwythiant SUM yn cyfrifo araeau yn ddiofyn, ac mae angen i chi wasgu Ctrl + Shift + Enter i'w droi'n fformiwla arae.<3

Fel y dangosir yn y sgrinlun canlynol, mae'r fformiwla SUM yn dychwelyd yr un cyfanswm cyfrif nodau:

Sut mae'r fformiwla cyfrif nodau amrediad hwn yn gweithio

Hwn yw un o'r fformiwlâu mwyaf syml i gyfrif cymeriadau yn Excel. Mae'r ffwythiant LEN yn cyfrifo hyd llinyn pob cell yn yr amrediad penodedig ac yn eu dychwelyd fel cyfres o rifau. Ac yna, mae SUMPRODUCT neu SUM yn adio'r rhifau hynny ac yn dychwelyd cyfanswm y nifer nodau.

Yn yr enghraifft uchod, mae arae o 7 rhif sy'n cynrychioli hyd llinynnau yng nghelloedd A1 i A7 yn cael ei grynhoi:

Nodyn. Sylwch fod swyddogaeth Excel LEN yn cyfrif yn llwyr yr holl nodau ym mhob cell , gan gynnwys llythrennau, rhifau, atalnodau, symbolau arbennig, a'r holl fylchau (arwain, llusgo a bylchau rhwng geiriau).

Sut i gyfrif nodau penodol mewn cell

Weithiau, yn lle cyfrif pob nod o fewn cell, efallai y bydd angen i chi gyfrif digwyddiadau llythyren, rhif neu symbol arbennig penodol yn unig.

I gyfrif y nifer o weithiau mae nod penodol yn ymddangos mewn cell, defnyddiwch y ffwythiant LEN ynghyd â SUBSTITUTE:

Er mwyn deall y fformiwla yn well, ystyriwch yr enghraifft ganlynol.

Tybiwch, eich bod yn cynnal cronfa ddata o eitemau a ddanfonwyd, lle mae gan bob math o eitem ei unigryw ei hun dynodwr. Ac mae pob cell yn cynnwys sawl eitem wedi'u gwahanu gan goma, gofod, neu unrhyw amffinydd arall. Y dasg yw cyfrif sawl gwaith mae dynodwr unigryw penodol yn ymddangos ym mhob cell.

A chymryd bod y rhestr o eitemau a ddanfonwyd yng ngholofn B (yn dechrau yn B2), ac rydym yn cyfrif nifer "A" digwyddiadau, mae'r fformiwla fel a ganlyn:

=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))

Sut mae'r fformiwla cyfrif nodau Excel hon yn gweithio

I ddeall rhesymeg y fformiwla, gadewch i ni ei rannu'n rhannau llai:

• Yn gyntaf, rydych yn cyfrif cyfanswm hyd y llinyn yn B2:

LEN(B2)

SUBSTITUTE(B2,"A","")

LEN(SUBSTITUTE(B2,"A",""))

O ganlyniad, byddwch yn cael y cyfrif o nodau "wedi'u tynnu", sy'n hafal i gyfanswm o'r nod hwnnw sy'n digwydd yn y gell.

Yn lle nodi'r nod rydych am ei gyfrif ynddo fformiwla, gallwch ei deipio mewn rhyw gell, ac yna cyfeirio at y gell honno mewn fformiwla. Yn y modd hwn, eich defnyddwyryn gallu cyfrif digwyddiadau o unrhyw nod arall y maent yn ei fewnbynnu yn y gell honno heb ymyrryd â'ch fformiwla:

Nodyn. Mae SUBSTITUTE Excel yn swyddogaeth sy'n sensitif i achosion, ac felly mae'r fformiwla uchod yn sensitif i achosion hefyd. Er enghraifft, yn y sgrin uchod, mae cell B3 yn cynnwys 3 digwyddiad o "A" - dau mewn llythrennau mawr, ac un mewn llythrennau bach. Mae'r fformiwla wedi cyfrif y prif nodau yn unig oherwydd i ni gyflenwi "A" i'r ffwythiant SUBSTITUTE.

Fformiwla Excel ansensitif i achosion i gyfrif nodau penodol mewn cell

Os oes angen cyfrif nodau cas-ansensitif, mewnosodwch y ffwythiant UCHAF y tu mewn i SUBSTITUTE i drosi'r nod penodedig i briflythrennau cyn rhedeg yr amnewidiad. A gwnewch yn siŵr eich bod chi'n nodi'r nod priflythrennau yn y fformiwla.

Er enghraifft, i gyfrif eitemau "A" ac "a" yng nghell B2, defnyddiwch y fformiwla hon:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))

Ffordd arall yw defnyddio ffwythiannau Amnewid nythog:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")

Fel y gwelwch yn y sgrinlun isod, mae'r ddwy fformiwlâu yn cyfrif yn ddi-ffael achosion priflythrennau a llythrennau bach y nod penodedig:<3

Mewn rhai achosion, efallai y bydd angen i chi gyfrif llawer o nodau gwahanol mewn tabl, ond efallai na fyddwch am addasu'r fformiwla bob tro. Yn yr achos hwn, nythu un swyddogaeth Amnewid o fewn un arall, teipiwch y nod yr ydych am ei gyfrif mewn rhyw gell (D1 yn yr enghraifft hon), a throsi gwerth y gell honno i briflythrennau allythrennau bach trwy ddefnyddio'r ffwythiannau UCHAF ac ISAF:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))

Fel arall, troswch y gell ffynhonnell a'r gell sy'n cynnwys y nod naill ai i briflythrennau neu lythrennau bach. Er enghraifft:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))

Mantais y dull hwn yw, p'un a yw'r nod priflythrennau neu lythrennau bach wedi'i fewnbynnu yn y gell y cyfeiriwyd ati, eich fformiwla cyfrif nodau ansensitif i lythrennau > yn dychwelyd y cyfrif cywir:

Cyfrif digwyddiadau o destun penodol neu is-linyn mewn cell

Os ydych am gyfrif sawl gwaith a cyfuniad penodol o nodau (h.y. testun penodol, neu is-linyn) yn ymddangos mewn cell benodol, e.e. "A2" neu "SS", yna rhannwch nifer y nodau a ddychwelwyd gan y fformiwlâu uchod â hyd yr is-linyn.

Fformiwla sy'n sensitif i achos :

=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)

Fformiwla cas-ansensitif :

=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)

Ble B2 yw'r gell sy'n cynnwys y llinyn testun cyfan, a C1 yw'r testun (is-linyn) chi eisiau cyfrif.

Am esboniad manwl o'r fformiwla, gweler Sut i gyfri testun / geiriau penodol mewn cell.

Sut i gyfrif penodol nod(au) mewn amrediad

Nawr eich bod yn gwybod fformiwla Excel i gyfrif nodau mewn cell, efallai y byddwch am ei wella ymhellach i ddarganfod sawl gwaith mae nod penodol yn ymddangos mewn amrediad. Ar gyfer hyn, byddwn yn cymryd fformiwla Excel LEN i gyfrif torgoch benodol mewn cell a drafodwydyn yr enghraifft flaenorol, a'i roi y tu mewn i'r ffwythiant SUMPRODUCT sy'n gallu trin araeau:

Yn yr enghraifft hon, mae'r fformiwla yn cymryd y siâp canlynol:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

A dyma fformiwla arall i'w chyfrif nodau yn ystod Excel:

=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

O'i gymharu â'r fformiwla gyntaf, y gwahaniaeth mwyaf amlwg yw defnyddio SUM yn lle SUMPRODUCT. Gwahaniaeth arall yw bod angen pwyso Ctrl + Shift + Enter oherwydd yn wahanol i SUMPRODUCT, sydd wedi'i gynllunio i brosesu araeau, dim ond pan gaiff ei ddefnyddio mewn fformiwla arae y gall SUM drin araeau.

Os gwnewch hynny 'Ddim eisiau codio'r nod yn y fformiwla'n galed, wrth gwrs gallwch chi ei deipio mewn rhyw gell, dweud D1, a chyfeirio at y gell honno yn eich fformiwla cyfrif nodau:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))

Nodyn. Mewn sefyllfaoedd pan fyddwch chi'n cyfrif digwyddiadau is-linyn penodol mewn ystod (e.e. gorchmynion sy'n dechrau gyda "KK" neu "AA"), mae angen i chi rannu'r cyfrif nodau â hyd yr is-linyn, fel arall mae pob nod yn bydd yr is-linyn yn cael ei gyfrif yn unigol. Er enghraifft:

=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))

Sut mae'r fformiwla cyfrif nodau hon yn gweithio

Fel y cofiwch efallai, defnyddir y ffwythiant SUBSTITUTE i ddisodli pob digwyddiad o'r nod penodedig ("A" yn yr enghraifft hon ) gyda llinyn testun gwag ("").

Yna, rydym yn cyflenwi'r llinyn testun a ddychwelwyd gan SUBSTITUTE i'r Excel LENswyddogaeth fel ei fod yn cyfrifo hyd y llinyn heb A. Ac yna, rydyn ni'n tynnu'r cyfrif nodau hwnnw o gyfanswm hyd y llinyn testun. Canlyniad y cyfrifiadau hyn yw cyfres o gyfrif nodau, gydag un cyfrif nodau fesul cell.

Yn olaf, mae SUMPRODUCT yn adio'r rhifau yn yr arae ac yn dychwelyd cyfanswm cyfrif y nod penodedig yn yr amrediad.

Fformiwla cas-sensitif i gyfrif nodau penodol mewn ystod

Rydych chi eisoes yn gwybod bod SUBSTITUTE yn swyddogaeth achos-sensitif, sy'n gwneud ein fformiwla Excel ar gyfer cyfrif nodau yn achos-sensitif hefyd.

I wneud i'r fformiwla anwybyddu achos, dilynwch y dulliau a ddangosir yn yr enghraifft flaenorol: Fformiwla cas-sensitif i gyfrif nodau penodol mewn cell.

Yn benodol, gallwch ddefnyddio un o'r fformiwlâu canlynol i gyfrif nodau penodol mewn amrediad sy'n anwybyddu llythrennau bach:

• Defnyddiwch y ffwythiant UCHAF a rhowch nod yn y priflythrennau:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A","")))

• Defnyddiwch ffwythiannau SUBSTITUTE nythog:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a","")))

• Defnyddiwch ffwythiannau UCHAF ac ISAF, teipiwch naill ai golosg priflythrennau neu lythrennau bach mewn rhyw gell, a chyfeiriwch at y gell honno yn eich fformiwla:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))

  <17

Mae'r sgrinlun isod yn dangos y fformiwla olaf ar waith:

Awgrym. I gyfrif digwyddiadau testun penodol (is-linyn) mewn amrediad, defnyddiwch y fformiwla a ddangosir yn Sut i gyfrif testun / geiriau penodol mewn amrediad.

Hynyw sut y gallwch gyfrif nodau yn Excel gan ddefnyddio'r ffwythiant LEN. Os ydych chi eisiau gwybod sut i gyfrif geiriau yn hytrach na nodau unigol, fe welwch ychydig o fformiwlâu defnyddiol yn ein herthygl nesaf, cadwch draw!

Yn y cyfamser, gallwch lawrlwytho gweithlyfrau enghreifftiol gyda fformiwla cyfrif nodau a drafodir yn y tiwtorial hwn, ac edrychwch ar restr o adnoddau cysylltiedig ar ddiwedd y dudalen. Diolch i chi am ddarllen a gobeithio eich gweld yn fuan!