این آموزش نحوه شمارش کاراکترها در اکسل را توضیح می دهد. شما فرمول هایی را برای به دست آوردن تعداد کل کاراکترها در یک محدوده و شمارش تنها کاراکترهای خاص در یک سلول یا در چندین سلول یاد خواهید گرفت.

آموزش قبلی ما تابع Excel LEN را معرفی کرد که امکان شمارش تعداد کل کاراکترها در یک سلول.

فرمول LEN به تنهایی مفید است، اما در ارتباط با توابع دیگر مانند SUM، SUMPRODUCT و SUBSTITUTE، می تواند کارهای بسیار پیچیده تری را انجام دهد. در ادامه این آموزش، ما قصد داریم چند فرمول اولیه و پیشرفته برای شمارش کاراکترها در اکسل را بررسی کنیم.

نحوه شمارش همه کاراکترها در یک محدوده

وقتی نوبت به شمارش تعداد کل کاراکترها در چندین سلول می‌رسد، یک راه‌حل فوری که به ذهن می‌رسد این است که تعداد کاراکترها را برای هر سلول به دست آوریم و سپس آن اعداد را جمع کنیم:

=LEN(A2)+LEN(A3)+LEN(A4)

یا

=SUM(LEN(A2),LEN(A3),LEN(A4))

فرمول های بالا ممکن است برای محدوده کوچکی خوب کار کنند. برای شمارش کل کاراکترها در محدوده بزرگ‌تر، بهتر است چیزی فشرده‌تر پیدا کنیم، به عنوان مثال. تابع SUMPRODUCT، که آرایه ها را ضرب می کند و مجموع محصولات را برمی گرداند.

در اینجا فرمول عمومی اکسل برای شمارش کاراکترها در یک محدوده است:

و فرمول واقعی شما ممکن است شبیه به این باشد:

=SUMPRODUCT(LEN(A1:A7))

یک راه دیگر برای شمارش کاراکترها در یک محدوده استفاده از عملکرد LEN درترکیب با SUM:

=SUM(LEN(A1:A7))

برخلاف SUMPRODUCT، تابع SUM به طور پیش فرض آرایه ها را محاسبه نمی کند و برای تبدیل آن به فرمول آرایه باید Ctrl + Shift + Enter را فشار دهید.

همانطور که در تصویر زیر نشان داده شده است، فرمول SUM همان تعداد کاراکترهای کل را برمی گرداند:

این فرمول شمارش کاراکترهای محدوده چگونه کار می کند

این یکی از ساده ترین فرمول ها برای شمارش کاراکترها در اکسل است. تابع LEN طول رشته را برای هر سلول در محدوده مشخص شده محاسبه می کند و آنها را به صورت آرایه ای از اعداد برمی گرداند. و سپس، SUMPRODUCT یا SUM آن اعداد را جمع کرده و تعداد کل کاراکترها را برمی‌گرداند.

در مثال بالا، آرایه‌ای از 7 عدد که طول رشته‌ها را در سلول‌های A1 تا A7 نشان می‌دهند، جمع می‌شوند:

توجه داشته باشید. لطفاً توجه داشته باشید که تابع LEN اکسل کاملاً همه کاراکترهای هر سلول را می‌شمارد ، از جمله حروف، اعداد، علائم نقطه‌گذاری، نمادهای خاص، و همه فاصله‌ها (راهنما، دنباله و فاصله بین کلمات).

نحوه شمارش کاراکترهای خاص در یک سلول

گاهی اوقات، به جای شمارش همه کاراکترهای داخل یک سلول، ممکن است لازم باشد فقط موارد یک حرف، عدد یا نماد خاص را بشمارید.

برای شمارش تعداد دفعاتی که یک کاراکتر مشخص در یک سلول ظاهر می شود، از تابع LEN همراه با SUBSTITUTE استفاده کنید:

برای درک بهتر فرمول، مثال زیر را در نظر بگیرید.

فرض کنید، یک پایگاه داده از اقلام تحویل داده شده نگهداری می کنید، که در آن هر نوع مورد منحصر به فرد خود را دارد. مشخص کننده. و هر سلول حاوی چندین آیتم است که با کاما، فاصله یا هر جداکننده دیگری از هم جدا شده اند. وظیفه این است که شمارش شود که یک شناسه منحصر به فرد معین چند بار در هر سلول ظاهر می شود.

با فرض اینکه لیست موارد تحویل داده شده در ستون B (شروع B2) باشد و ما تعداد "A" را می شماریم. در صورت وقوع، فرمول به شرح زیر است:

=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))

این فرمول تعداد کاراکترهای اکسل چگونه کار می کند

برای درک منطق فرمول، اجازه دهید آن را به قطعات کوچکتر تقسیم کنید:

• ابتدا، طول کل رشته را در B2 حساب می کنید:

LEN(B2)

SUBSTITUTE(B2,"A","")

LEN(SUBSTITUTE(B2,"A",""))

در نتیجه، تعداد نویسه‌های "حذف شده" را دریافت می‌کنید، که برابر است با تعداد کل وقوع آن کاراکتر در سلول.

به‌جای تعیین نویسه‌ای که می‌خواهید در آن شمارش کنید. یک فرمول، می‌توانید آن را در یک سلول تایپ کنید و سپس به آن سلول در فرمول ارجاع دهید. به این ترتیب کاربران شمامی‌تواند هر کاراکتر دیگری را که در آن سلول وارد می‌کند، بدون دستکاری فرمول شما، شمارش کند:

توجه. SUBSTITUTE اکسل یک تابع حساس به حروف بزرگ و کوچک است و بنابراین فرمول فوق به حروف بزرگ و کوچک نیز حساس است. به عنوان مثال، در اسکرین شات بالا، سلول B3 شامل 3 مورد "A" است - دو مورد با حروف بزرگ و یکی با حروف کوچک. فرمول فقط کاراکترهای بزرگ را شمارش کرده است زیرا ما "A" را به تابع SUBSTITUTE ارائه کرده ایم.

فرمول اکسل غیر حساس به حروف بزرگ برای شمارش کاراکترهای خاص در یک سلول

اگر به تعداد کاراکترهای حساس به حروف بزرگ نیاز دارید، تابع UPPER را در SUBSTITUTE تعبیه کنید تا قبل از اجرای جایگزینی، نویسه مشخص شده را به حروف بزرگ تبدیل کنید. و حتماً حروف بزرگ را در فرمول وارد کنید.

به عنوان مثال، برای شمارش موارد "A" و "a" در سلول B2، از این فرمول استفاده کنید:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))

روش دیگر استفاده از توابع جانشین تودرتو است:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")

همانطور که در تصویر زیر می بینید، هر دو فرمول به طور بی عیب و نقص حروف بزرگ و کوچک حروف مشخص شده را محاسبه می کنند:

در برخی موارد، ممکن است لازم باشد تعداد زیادی کاراکتر مختلف را در یک جدول بشمارید، اما ممکن است نخواهید هر بار فرمول را تغییر دهید. در این مورد، یک تابع جایگزین را در یک تابع دیگر قرار دهید، کاراکتری را که می‌خواهید در برخی از سلول‌ها شمارش کنید تایپ کنید (در این مثال D1)، و مقدار آن سلول را به حروف بزرگ و تبدیل کنید.حروف کوچک با استفاده از توابع UPPER و LOWER:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))

به طور متناوب، سلول منبع و سلول حاوی کاراکتر را به حروف بزرگ یا کوچک تبدیل کنید. به عنوان مثال:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))

مزیت این روش این است که صرف نظر از اینکه حروف بزرگ یا کوچک در سلول ارجاع داده شده است، فرمول تعداد کاراکترهای حساس به حروف کوچک <14 شما> تعداد مناسب را برمی‌گرداند:

تعداد تکرار متن یا زیررشته خاص در یک سلول

اگر می‌خواهید تعداد دفعات را بشمارید ترکیب خاصی از کاراکترها (به عنوان مثال متن خاص یا زیر رشته) در یک سلول مشخص ظاهر می شود، به عنوان مثال. "A2" یا "SS"، سپس تعداد کاراکترهای برگردانده شده توسط فرمول های بالا را بر طول رشته فرعی تقسیم کنید. فرمول

غیرحساس به حروف کوچک و بزرگ :

=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)

که در آن B2 سلولی است که تمام رشته متنی را در بر می گیرد و C1 متنی است (رشته فرعی) شما می خواهید بشمارید.

برای توضیح دقیق فرمول، لطفاً به نحوه شمارش متن / کلمات خاص در یک سلول مراجعه کنید.

نحوه شمارش خاص نویسه(ها) در یک محدوده

اکنون که فرمول اکسل برای شمارش کاراکترها در یک سلول را می شناسید، ممکن است بخواهید آن را بیشتر بهبود دهید تا متوجه شوید که یک نویسه خاص چند بار در یک محدوده ظاهر می شود. برای این، ما از فرمول Excel LEN برای شمارش یک کاراکتر خاص در یک سلول مورد بحث استفاده می کنیمدر مثال قبلی، و آن را در تابع SUMPRODUCT قرار دهید که می تواند آرایه ها را مدیریت کند:

در این مثال، فرمول به شکل زیر است:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

و در اینجا فرمول دیگری برای شمارش وجود دارد کاراکترها در محدوده اکسل:

=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

در مقایسه با فرمول اول، واضح ترین تفاوت استفاده از SUM به جای SUMPRODUCT است. تفاوت دیگر این است که باید Ctrl + Shift + Enter را فشار دهید زیرا برخلاف SUMPRODUCT که برای پردازش آرایه‌ها طراحی شده است، SUM تنها زمانی می‌تواند آرایه‌ها را مدیریت کند که در فرمول آرایه استفاده شود.

اگر این کار را انجام ندهید. اگر می‌خواهید کاراکتر موجود در فرمول را کدگذاری کنید، البته می‌توانید آن را در سلولی مثلاً D1 تایپ کنید و به آن سلول در فرمول تعداد کاراکتر خود اشاره کنید:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))

توجه داشته باشید. در مواقعی که تعداد زیررشته خاص را در یک محدوده شمارش می‌کنید (مثلاً سفارش‌هایی که با "KK" یا "AA" شروع می‌شوند)، باید تعداد کاراکترها را بر طول رشته‌های فرعی تقسیم کنید، در غیر این صورت هر کاراکتر در رشته فرعی به صورت جداگانه شمارش می شود. به عنوان مثال:

=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))

این فرمول شمارش کاراکتر چگونه کار می کند

همانطور که ممکن است به خاطر داشته باشید، از تابع SUBSTITUTE برای جایگزینی تمام رخدادهای کاراکتر مشخص شده استفاده می شود ("A" در این مثال ) با یک رشته متن خالی ("").

سپس، رشته متنی را که توسط SUBSTITUTE برگردانده شده است به LEN اکسل ارائه می کنیم.تابع به طوری که طول رشته را بدون A محاسبه می کند. و سپس، تعداد کاراکترها را از طول کل رشته متن کم می کنیم. نتیجه این محاسبات آرایه‌ای از تعداد کاراکترها است، با یک تعداد کاراکتر در هر سلول.

در نهایت، SUMPRODUCT اعداد موجود در آرایه را جمع می‌کند و تعداد کل کاراکتر مشخص شده در محدوده را برمی‌گرداند.

یک فرمول غیرحساس به حروف بزرگ برای شمارش کاراکترهای خاص در یک محدوده

از قبل می دانید که SUBSTITUTE یک تابع حساس به حروف بزرگ و کوچک است، که باعث می شود فرمول اکسل ما برای تعداد کاراکترها نیز به حروف بزرگ و کوچک حساس باشد.

برای نادیده گرفتن فرمول از حروف بزرگ، رویکردهای نشان داده شده در مثال قبلی را دنبال کنید: فرمول حساس به حروف بزرگ برای شمارش کاراکترهای خاص در یک سلول.

به ویژه، می توانید از یکی از فرمول های زیر برای شمارش استفاده کنید. نویسه‌های خاص در محدوده‌ای که حروف بزرگ را نادیده می‌گیرند:

• از تابع UPPER استفاده کنید و یک کاراکتر را با حروف بزرگ وارد کنید:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A","")))

• استفاده از توابع SUBSTITUTE تو در تو:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a","")))

• از توابع UPPER و LOWER استفاده کنید، یک علامت بزرگ یا کوچک را در برخی از سلول ها تایپ کنید و به آن سلول در فرمول خود ارجاع دهید:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))

تصویر صفحه زیر آخرین فرمول در عمل را نشان می دهد:

نکته. برای شمارش وقوع یک متن خاص (رشته فرعی) در یک محدوده، از فرمول نشان داده شده در نحوه شمارش متن / کلمات خاص در یک محدوده استفاده کنید.

ایننحوه شمارش کاراکترها در اکسل با استفاده از تابع LEN است. اگر می خواهید بدانید که چگونه کلمات را به جای کاراکترهای فردی بشمارید، چند فرمول مفید را در مقاله بعدی ما پیدا خواهید کرد، لطفا با ما همراه باشید!

در ضمن، می توانید یک نمونه کتاب کار با فرمول شمارش کاراکتر را دانلود کنید. در این آموزش مورد بحث قرار گرفته و فهرستی از منابع مرتبط را در انتهای صفحه بررسی کنید. از خواندن شما سپاسگزارم و امیدوارم به زودی شما را ببینم!