ٹیوٹوریل بتاتا ہے کہ ایکسل میں حروف کو کیسے گننا ہے۔ آپ ایک رینج میں کل کریکٹر گنتی حاصل کرنے کے فارمولے سیکھیں گے، اور سیل میں یا کئی سیلز میں صرف مخصوص حروف کو ہی گنیں گے۔

ہمارے پچھلے ٹیوٹوریل میں ایکسل LEN فنکشن متعارف کرایا گیا تھا، جو کہ گنتی کی اجازت دیتا ہے۔ سیل میں حروف کی کل تعداد۔

LEN فارمولہ اپنے طور پر مفید ہے، لیکن SUM، SUMPRODUCT اور SUBSTITUTE جیسے دیگر افعال کے ساتھ رابطے میں، یہ کہیں زیادہ پیچیدہ کاموں کو سنبھال سکتا ہے۔ اس ٹیوٹوریل میں مزید، ہم ایکسل میں حروف کی گنتی کے لیے چند بنیادی اور جدید فارمولوں پر گہری نظر ڈالیں گے۔

ایک رینج میں تمام حروف کو کیسے گنیں

جب کئی سیلز میں کریکٹرز کی کل تعداد گننے کی بات آتی ہے تو ذہن میں آنے والا ایک فوری حل یہ ہے کہ ہر سیل کے لیے کریکٹر گنتی حاصل کی جائے، اور پھر ان نمبروں کو شامل کیا جائے:

=LEN(A2)+LEN(A3)+LEN(A4)

یا

=SUM(LEN(A2),LEN(A3),LEN(A4))

مذکورہ فارمولے چھوٹی رینج کے لیے ٹھیک کام کر سکتے ہیں۔ ایک بڑی رینج میں کل حروف کو شمار کرنے کے لیے، ہم بہتر طور پر کچھ اور کمپیکٹ کے ساتھ آئیں گے، جیسے SUMPRODUCT فنکشن، جو صفوں کو ضرب دیتا ہے اور پروڈکٹس کا مجموعہ لوٹاتا ہے۔

حروف کو رینج میں شمار کرنے کے لیے یہاں عام ایکسل فارمولہ ہے:

اور آپ کا حقیقی زندگی کا فارمولا اس سے ملتا جلتا نظر آ سکتا ہے:

=SUMPRODUCT(LEN(A1:A7))

ایک رینج میں حروف کو شمار کرنے کا ایک اور طریقہ یہ ہے کہ LEN فنکشن میںSUM کے ساتھ مجموعہ:

=SUM(LEN(A1:A7))

SUMPRODUCT کے برعکس، SUM فنکشن پہلے سے طے شدہ طور پر اریوں کا حساب نہیں لگاتا، اور آپ کو Ctrl + Shift + Enter دبانے کی ضرورت ہوتی ہے تاکہ اسے ایک صف کے فارمولے میں تبدیل کیا جاسکے۔

جیسا کہ مندرجہ ذیل اسکرین شاٹ میں دکھایا گیا ہے، SUM فارمولہ کل کریکٹر کی ایک ہی تعداد لوٹاتا ہے:

یہ رینج کریکٹر گنتی کا فارمولا کیسے کام کرتا ہے

یہ ایکسل میں حروف کی گنتی کے لیے سب سے آسان فارمولوں میں سے ایک ہے۔ LEN فنکشن مخصوص رینج میں ہر سیل کے لیے سٹرنگ کی لمبائی کا حساب لگاتا ہے اور انہیں اعداد کی ایک صف کے طور پر واپس کرتا ہے۔ اور پھر، SUMPRODUCT یا SUM ان نمبروں کو جوڑتا ہے اور کل کریکٹر گنتی لوٹاتا ہے۔

اوپر کی مثال میں، 7 نمبروں کی ایک صف جو A1 سے A7 سیلز میں تاروں کی لمبائی کو ظاہر کرتی ہے:

نوٹ۔ براہ کرم اس بات پر توجہ دیں کہ ایکسل LEN فنکشن بالکل ہر سیل میں تمام حروف کو شمار کرتا ہے ، بشمول حروف، اعداد، اوقاف کے نشانات، خصوصی علامتیں، اور تمام خالی جگہیں (لیڈنگ، ٹریلنگ اور الفاظ کے درمیان خالی جگہیں)۔

کسی سیل میں مخصوص حروف کو کیسے گننا ہے

بعض اوقات، سیل کے اندر تمام حروف کو گننے کے بجائے، آپ کو صرف ایک مخصوص حرف، نمبر، یا خاص علامت کی موجودگی کو گننے کی ضرورت پڑسکتی ہے۔

کسی سیل میں دیئے گئے کریکٹر کے ظاہر ہونے کی تعداد گننے کے لیے، LEN فنکشن کو SUBSTITUTE کے ساتھ استعمال کریں:

فارمولے کو بہتر طور پر سمجھنے کے لیے، مندرجہ ذیل مثال پر غور کریں۔

فرض کریں، آپ ڈیلیور کردہ آئٹمز کا ڈیٹا بیس برقرار رکھتے ہیں، جہاں ہر آئٹم کی قسم کی اپنی منفرد ہوتی ہے۔ شناخت کنندہ اور ہر سیل میں کوما، اسپیس، یا کسی دوسرے ڈیلیمیٹر سے الگ کئی آئٹمز ہوتے ہیں۔ کام یہ شمار کرنا ہے کہ ہر سیل میں دیا گیا منفرد شناخت کنندہ کتنی بار ظاہر ہوتا ہے۔

یہ فرض کرتے ہوئے کہ ڈیلیور کردہ اشیاء کی فہرست کالم B میں ہے (B2 سے شروع)، اور ہم "A" کی تعداد گن رہے ہیں۔ واقعات، فارمولہ درج ذیل ہے:

=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))

یہ ایکسل کیریکٹر گنتی کا فارمولا کیسے کام کرتا ہے

فارمولے کی منطق کو سمجھنے کے لیے، آئیے اسے چھوٹے حصوں میں تقسیم کریں:

• پہلے، آپ B2 میں کل سٹرنگ کی لمبائی گنتے ہیں:

LEN(B2)

SUBSTITUTE(B2,"A","")

LEN(SUBSTITUTE(B2,"A",""))

نتیجے کے طور پر، آپ کو "ہٹائے گئے" حروف کی گنتی ملتی ہے، جو کہ سیل میں اس کریکٹر کی موجودگی کی کل تعداد کے برابر ہے۔

اس کردار کی وضاحت کرنے کے بجائے جس میں آپ شمار کرنا چاہتے ہیں ایک فارمولہ، آپ اسے کسی سیل میں ٹائپ کر سکتے ہیں، اور پھر اس سیل کو فارمولے میں حوالہ دے سکتے ہیں۔ اس طرح، آپ کے صارفینآپ کے فارمولے کے ساتھ چھیڑ چھاڑ کیے بغیر کسی بھی دوسرے کردار کی موجودگی کو شمار کرنے کے قابل ہو جائے گا جو وہ اس سیل میں داخل کرتے ہیں:

نوٹ۔ ایکسل کا SUBSTITUTE ایک کیس حساس فنکشن ہے، اور اس لیے اوپر والا فارمولا بھی کیس حساس ہے۔ مثال کے طور پر، اوپر والے اسکرین شاٹ میں، سیل B3 میں "A" کے 3 واقعات ہیں - دو بڑے حروف میں، اور ایک چھوٹے میں۔ فارمولے میں صرف بڑے حروف کو شمار کیا گیا ہے کیونکہ ہم نے SUBSTITUTE فنکشن کو "A" فراہم کیا ہے۔

کسی سیل میں مخصوص حروف کی گنتی کے لیے کیس غیر حساس ایکسل فارمولہ

اگر آپ کو کیس کے غیر حساس کرداروں کی گنتی کی ضرورت ہے، تو متبادل چلانے سے پہلے مخصوص کریکٹر کو بڑے حروف میں تبدیل کرنے کے لیے SUBSTITUTE کے اندر UPPER فنکشن کو ایمبیڈ کریں۔ اور، فارمولے میں بڑے حروف کو ضرور درج کریں۔

مثال کے طور پر، سیل B2 میں "A" اور "a" آئٹمز کو شمار کرنے کے لیے، یہ فارمولا استعمال کریں:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))

ایک اور طریقہ نیسٹڈ سبسٹی ٹیوٹ فنکشنز کو استعمال کرنا ہے:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE (B2,"A",""),"a","")

جیسا کہ آپ نیچے دیے گئے اسکرین شاٹ میں دیکھ سکتے ہیں، دونوں فارمولے مخصوص کریکٹر کے بڑے اور لوئر کیس کی موجودگی کو بے عیب طریقے سے شمار کرتے ہیں:

بعض صورتوں میں، آپ کو ایک ٹیبل میں بہت سے مختلف حروف کو شمار کرنے کی ضرورت پڑ سکتی ہے، لیکن ہو سکتا ہے کہ آپ ہر بار فارمولے میں ترمیم نہ کرنا چاہیں۔ اس صورت میں، نیسٹ ون متبادل فنکشن دوسرے کے اندر، وہ کریکٹر ٹائپ کریں جسے آپ کسی سیل میں شمار کرنا چاہتے ہیں (اس مثال میں D1)، اور اس سیل کی قدر کو بڑے حروف میں تبدیل کریں اورUPPER اور LOWER فنکشنز کا استعمال کرتے ہوئے لوئر کیس:

=LEN(B2)-LEN(SUBSTITUTE(SUBSTITUTE(B2, UPPER($D$1), ""), LOWER($D$1),""))

متبادل طور پر، سورس سیل اور کیریکٹر پر مشتمل سیل دونوں کو بڑے یا چھوٹے میں تبدیل کریں۔ مثال کے طور پر:

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2), UPPER($C$1),""))

اس نقطہ نظر کا فائدہ یہ ہے کہ اس بات سے قطع نظر کہ بڑے یا چھوٹے حروف کو حوالہ شدہ سیل میں داخل کیا گیا ہے، آپ کا کیس غیر حساس کریکٹر گنتی فارمولہ صحیح گنتی لوٹائے گا:

کسی سیل میں مخصوص متن یا ذیلی اسٹرنگ کی موجودگی کو شمار کریں

اگر آپ گننا چاہتے ہیں کہ کتنی بار حروف کا مخصوص مجموعہ (یعنی مخصوص متن، یا ذیلی اسٹرنگ) دیئے گئے سیل میں ظاہر ہوتا ہے، جیسے "A2" یا "SS"، پھر مندرجہ بالا فارمولوں کے ذریعے لوٹائے گئے حروف کی تعداد کو ذیلی اسٹرنگ کی لمبائی سے تقسیم کریں۔

کیس حساس فارمولا:

=(LEN(B2)-LEN(SUBSTITUTE(B2, $C$1,"")))/LEN($C$1)

کیس غیر حساس فارمولا:

=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),LOWER($C$1),"")))/LEN($C$1)

جہاں B2 سیل ہے جس میں پوری ٹیکسٹ اسٹرنگ ہے، اور C1 وہ ٹیکسٹ (سبسٹرنگ) ہے جسے آپ شمار کرنا چاہتے ہیں ایک رینج میں کریکٹرز

اب جب کہ آپ سیل میں کریکٹرز گننے کے لیے ایکسل فارمولہ جانتے ہیں، آپ اسے مزید بہتر کرنا چاہیں گے تاکہ یہ معلوم کیا جا سکے کہ ایک رینج میں کوئی مخصوص کریکٹر کتنی بار ظاہر ہوتا ہے۔ اس کے لیے، ہم زیر بحث سیل میں ایک مخصوص چار گننے کے لیے ایکسل LEN فارمولہ لیں گے۔پچھلی مثال میں، اور اسے SUMPRODUCT فنکشن کے اندر رکھیں جو صفوں کو سنبھال سکتا ہے:

اس مثال میں، فارمولہ مندرجہ ذیل شکل اختیار کرتا ہے:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

اور یہاں شمار کرنے کے لیے ایک اور فارمولہ ہے ایکسل کی رینج میں حروف:

=SUM(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, "A","")))

پہلے فارمولے کے مقابلے میں، سب سے واضح فرق SUMPRODUCT کے بجائے SUM کا استعمال کرنا ہے۔ ایک اور فرق یہ ہے کہ اس کے لیے Ctrl + Shift + Enter دبانے کی ضرورت ہوتی ہے کیونکہ SUMPRODUCT کے برعکس، جو کہ arrays کو پروسیس کرنے کے لیے ڈیزائن کیا گیا ہے، SUM صرف اس صورت میں ہینڈل کر سکتا ہے جب ارے فارمولے میں استعمال کیا جائے۔

اگر آپ نہیں کرتے فارمولے میں کیریکٹر کو ہارڈ کوڈ نہیں کرنا چاہتے، یقیناً آپ اسے کسی سیل میں ٹائپ کر سکتے ہیں، D1 کہتے ہیں، اور اپنے کریکٹر گنتی کے فارمولے میں اس سیل کا حوالہ دے سکتے ہیں:

=SUMPRODUCT(LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1,"")))

نوٹ۔ ایسے حالات میں جب آپ کسی رینج میں مخصوص سبسٹرنگ کے واقعات کو شمار کرتے ہیں (جیسے "KK" یا "AA" سے شروع ہونے والے آرڈر)، آپ کو کریکٹر کی گنتی کو ذیلی اسٹرنگ کی لمبائی سے تقسیم کرنے کی ضرورت ہے، بصورت دیگر ہر کردار سبسٹرنگ کو انفرادی طور پر شمار کیا جائے گا۔ مثال کے طور پر:

=SUM((LEN(B2:B8)-LEN(SUBSTITUTE(B2:B8, D1, ""))) / LEN(D1))

یہ کریکٹر گننے کا فارمولا کیسے کام کرتا ہے

جیسا کہ آپ کو یاد ہوگا، SUBSTITUTE فنکشن کو مخصوص کریکٹر کے تمام وقوعات کو تبدیل کرنے کے لیے استعمال کیا جاتا ہے ("A" اس مثال میں ) ایک خالی ٹیکسٹ اسٹرنگ ("") کے ساتھ۔

پھر، ہم ایکسل LEN کو SUBSTITUTE کے ذریعے واپس کردہ ٹیکسٹ سٹرنگ فراہم کرتے ہیں۔فنکشن تاکہ یہ A کے بغیر سٹرنگ کی لمبائی کا حساب لگائے۔ اور پھر، ہم اس کریکٹر کی گنتی کو ٹیکسٹ سٹرنگ کی کل لمبائی سے گھٹا دیتے ہیں۔ ان حسابات کا نتیجہ کریکٹر کی گنتی کی ایک صف ہے، جس میں فی سیل ایک کریکٹر گنتی ہے۔

آخر میں، SUMPRODUCT صف میں موجود نمبروں کو جمع کرتا ہے اور رینج میں مخصوص کریکٹر کی کل گنتی لوٹاتا ہے۔

فارمولے کو نظر انداز کرنے کے لیے، پچھلی مثال میں دکھائے گئے طریقوں پر عمل کریں: سیل میں مخصوص حروف کو شمار کرنے کے لیے کیس غیر حساس فارمولہ۔

خاص طور پر، آپ گننے کے لیے درج ذیل فارمولوں میں سے ایک استعمال کر سکتے ہیں۔ رینج کو نظر انداز کرنے والے کیس میں مخصوص حروف:

• UPPER فنکشن کا استعمال کریں اور بڑے حروف میں ایک کیریکٹر درج کریں:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(UPPER(B2:B8),"A","")))

• نیسٹڈ SUBSTITUTE فنکشن استعمال کریں:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8),"A",""),"a","")))

• UPPER اور LOWER فنکشنز کا استعمال کریں، کچھ سیل میں بڑے یا چھوٹے حرف ٹائپ کریں، اور اپنے فارمولے میں اس سیل کا حوالہ دیں:

  =SUMPRODUCT(LEN(B2:B8) - LEN(SUBSTITUTE(SUBSTITUTE((B2:B8), UPPER($E$1), ""), LOWER($E$1),"")))

ذیل کا اسکرین شاٹ عمل میں آخری فارمولے کو ظاہر کرتا ہے:

ٹپ۔ رینج میں مخصوص متن (سبسٹرنگ) کی موجودگی کو شمار کرنے کے لیے، رینج میں مخصوص متن/الفاظ کو کس طرح شمار کیا جائے میں دکھایا گیا فارمولہ استعمال کریں۔

یہیہ ہے کہ آپ LEN فنکشن کا استعمال کرتے ہوئے ایکسل میں حروف کو کیسے گن سکتے ہیں۔ اگر آپ یہ جاننا چاہتے ہیں کہ انفرادی حروف کے بجائے الفاظ کی گنتی کیسے کی جائے، تو آپ کو ہمارے اگلے مضمون میں کچھ مفید فارمولے ملیں گے، براہ کرم دیکھتے رہیں!

اس دوران، آپ کریکٹر گنتی کے فارمولے کے ساتھ ایک نمونہ ورک بک ڈاؤن لوڈ کر سکتے ہیں۔ اس ٹیوٹوریل میں بحث کی گئی ہے، اور صفحہ کے آخر میں متعلقہ وسائل کی فہرست دیکھیں۔ میں پڑھنے کے لیے آپ کا شکریہ ادا کرتا ہوں اور امید کرتا ہوں کہ جلد ہی آپ سے ملوں گا!