Bảng tính cung cấp một nền tảng tuyệt vời để quản lý bảng dữ liệu. Nhưng có bất kỳ chức năng Google Trang tính dễ dàng nào để tính toán hàng ngày không? Hãy tìm hiểu bên dưới.

Hàm SUM của Google Trang tính

Tôi cho rằng thao tác bắt buộc nhất trong bảng là tìm tổng của các giá trị khác nhau. Điều đầu tiên bạn nghĩ đến là cộng từng ô quan tâm:

=E2+E4+E8+E13

Nhưng công thức này sẽ cực kỳ tốn thời gian nếu có quá nhiều ô cần tính đến.

Cách thích hợp để thêm các ô là sử dụng một chức năng đặc biệt của Google Trang tính – SUM – tự động liệt kê tất cả các ô bằng dấu phẩy:

=SUM(E2,E4,E8,E13)

Nếu phạm vi bao gồm các ô liền kề , chỉ cần chỉ ra ô đầu tiên và ô cuối cùng của nó ngay cả khi có những ô trống ở giữa. Do đó, bạn sẽ tránh phải liệt kê từng ô trong công thức SUM của Google Trang tính.

Mẹo. Một cách khác để thêm SUM là chọn cột có số và chọn SUM bên dưới biểu tượng Công thức :

Kết quả sẽ được chèn vào một ô ngay bên dưới phạm vi đã chọn.

Mẹo. Power Tools của chúng tôi có tính năng AutoSum. Một cú nhấp chuột – và ô hiện hoạt của bạn sẽ trả về tổng giá trị từ toàn bộ cột ở trên.

Hãy để tôi phức tạp hóa nhiệm vụ. Tôi muốn thêm số từ các phạm vi dữ liệu khác nhau trên nhiều trang tính, ví dụ: A4:A8 từ Sheet1 và B4:B7 từ Sheet2 . Và tôi muốn tổng hợp chúng trongmột ô duy nhất:

=SUM('Sheet1'!A4:A8,'Sheet2'!B4:B7)

Như bạn có thể thấy, tôi vừa thêm một trang tính nữa vào công thức SUM của Google Trang tính và phân tách hai phạm vi khác nhau bằng dấu phẩy.

Công thức tỷ lệ phần trăm

Tôi thường nghe mọi người hỏi về việc tìm phần trăm của các tổng khác nhau. Giá trị này thường được tính theo công thức phần trăm Google Trang tính như sau:

Công thức tương tự cũng hoạt động bất cứ khi nào bạn cần kiểm tra xem số này hoặc số đó đại diện cho phần nào trong tổng số:

Mẹo. Tỷ lệ phần trăm chính của tổng số, tổng số & số tiền theo phần trăm, mức tăng & giảm trong hướng dẫn này.

Trong bảng của tôi, nơi tôi lưu giữ hồ sơ về tất cả các lần bán hàng trong 10 ngày qua, tôi có thể tính tỷ lệ phần trăm của mỗi lần bán hàng trên tổng doanh số.

Đầu tiên, tôi đi đến E12 và tìm tổng doanh số:

=SUM(E2:E11)

Sau đó, tôi kiểm tra xem doanh số ngày đầu tiên chiếm bao nhiêu phần trong tổng số ở F2:

=E2/$E$12

Tôi cũng khuyên bạn nên thực hiện một vài điều chỉnh:

1. Chuyển E2 thành tham chiếu tuyệt đối – $E$12 – để đảm bảo bạn phân chia doanh số bán hàng mỗi ngày bằng tổng số giống nhau.
2. Áp dụng định dạng số phần trăm cho các ô trong cột F.
3. Sao chép công thức từ F2 sang tất cả các ô bên dưới – tối đa F11.

Mẹo. Để sao chép công thức, hãy sử dụng một trong những cách tôi đã đề cập trước đó.

Mẹo. Để đảm bảo tính toán của bạn chính xác, hãy nhập giá trị bên dưới vào F12:

=SUM(F2:F11 )

Nếu trả về 100% –mọi thứ đều chính xác.

Tại sao tôi khuyên bạn nên sử dụng định dạng phần trăm?

Một mặt, để tránh nhân từng kết quả với 100 nếu bạn muốn nhận phần trăm. Mặt khác, để tránh chia kết quả cho 100 nếu bạn muốn sử dụng chúng cho bất kỳ phép toán nào khác không theo phần trăm.

Ý tôi là:

Tôi sử dụng định dạng số phần trăm trong các ô C4, B10 và B15. Tất cả các công thức Google Trang tính tham chiếu đến các ô này đều dễ dàng hơn nhiều. Tôi không phải chia cho 100 hoặc thêm ký hiệu phần trăm (%) vào các công thức trong C10 và C15.

Điều tương tự không thể xảy ra với C8, C9 và C14. Tôi phải thực hiện những điều chỉnh bổ sung này để có được kết quả chính xác.

Công thức mảng

Để làm việc với nhiều dữ liệu trong Google Trang tính, các hàm lồng nhau và các phép tính phức tạp khác được sử dụng làm quy tắc. Công thức mảng cũng có sẵn trong Google Trang tính cho mục đích đó.

Ví dụ: tôi có một bảng doanh số bán hàng trên mỗi khách hàng. Tôi tò mò muốn tìm mức bán sô cô la sữa tối đa cho Smith để xem liệu tôi có thể giảm giá thêm cho anh ấy vào lần tới hay không. Tôi sử dụng công thức mảng tiếp theo trong E18:

=ArrayFormula(MAX(IF(($B$2:$B$13="Smith")*($C$2:$C$13="Milk Chocolate"),$E$2:$E$13,"")))

Lưu ý. Để hoàn thành bất kỳ công thức mảng nào trong Google Trang tính, hãy nhấn Ctrl+Shift+Enter thay vì chỉ nhấn Enter.

Kết quả là tôi có $259.

Công thức mảng đầu tiên của tôi trong E16 trả về số tiền mua tối đa của Smith – $366:

=ArrayFormula(MAX(IF(($B$2:$B$13="Smith"),$E$2:$E$13)))

E17 hiển thị tối đasố tiền chi cho sô cô la sữa – $518:

=ArrayFormula(MAX(IF(($C$2:$C$13="Milk Chocolate"),$E$2:$E$13)))

Bây giờ, tôi sẽ thay thế tất cả các giá trị được sử dụng trong công thức Google Trang tính bằng tham chiếu ô của chúng:

Bạn có nhận thấy điều gì đã thay đổi không?

=ArrayFormula(MAX(IF(($B$2:$B$13=B18)*($C$2:$C$13=C18),$E$2:$E$13,"")))

Đây là những gì tôi có trước đây:

=ArrayFormula(MAX(IF(($B$2:$B$13="Smith")*($C$2:$C$13="Milk Chocolate"),$E$2:$E$13,"")))

Cứ như vậy, tung hứng với các giá trị trong các ô mà bạn tham chiếu, bạn có thể nhanh chóng nhận được các kết quả khác nhau dựa trên các điều kiện khác nhau mà không cần thay đổi chính công thức đó.

Các công thức Google Trang tính để sử dụng hàng ngày

Hãy xem xét thêm một vài hàm và ví dụ về công thức hữu ích để sử dụng hàng ngày.

Ví dụ 1

Giả sử dữ liệu của bạn được viết một phần dưới dạng số và một phần dưới dạng văn bản: 300 euro , tổng – 400 đô la . Nhưng bạn chỉ cần trích xuất các số.

Tôi chỉ biết một hàm cho việc đó:

Hàm này kéo văn bản theo mặt nạ bằng một biểu thức chính quy.

• văn bản – đó có thể là tham chiếu ô hoặc bất kỳ văn bản nào trong dấu ngoặc kép.
• regular_expression – mặt nạ văn bản của bạn. Cũng trong dấu ngoặc kép. Nó cho phép bạn tạo hầu hết mọi lược đồ văn bản có thể.

Văn bản trong trường hợp của tôi là một ô có dữ liệu ( A2 ). Và tôi sử dụng biểu thức chính quy này: [0-9]+

Có nghĩa là tôi đang tìm số lượng bất kỳ ( + ) của các số từ 0 đến 9 ( [0-9] ) được viết lần lượt:

Nếu số có phân số, biểu thức chính quy sẽ như sau:

"[0-9]*\.[0-9]+[0-9]+" chosố có hai chữ số thập phân

"[0-9]*\.[0-9]+" cho số có một chữ số thập phân

Lưu ý. Google Trang tính xem các giá trị được trích xuất dưới dạng văn bản. Bạn cần chuyển đổi chúng thành số bằng hàm VALUE hoặc bằng công cụ Chuyển đổi của chúng tôi.

Ví dụ 2 – nối văn bản với một công thức

Các công thức trong văn bản giúp có được một hàng trông gọn gàng với một số tổng – các số có mô tả ngắn.

Tôi sẽ tạo các hàng như vậy ở dòng 14 và 15. Để bắt đầu, tôi hợp nhất các ô trong các hàng đó thông qua Định dạng > Hợp nhất các ô rồi đếm tổng cho cột E:

=SUM(E2:E13)

Sau đó, tôi đặt văn bản mà tôi muốn có làm mô tả vào dấu ngoặc kép và kết hợp văn bản đó với công thức sử dụng dấu và:

="Total chocolate sales: "&SUM(E2:E13)&" dollars"

Để biến số của tôi thành số thập phân, tôi sử dụng hàm TEXT và đặt định dạng: "#,## 0"

Một cách khác là sử dụng chức năng CONCATENATE của Google Trang tính, như tôi đã sử dụng trong A15:

=CONCATENATE("Total discount for customers: ",TEXT(SUM(F2:F13),"#.##")," dollars")

Ví dụ 3

Điều gì xảy ra nếu bạn tải dữ liệu lên từ một nơi nào đó và tất cả các số đều xuất hiện với dấu cách, chẳng hạn như 8 544 thay vì 8544 ? Bạn biết đấy, Google Trang tính sẽ trả về những giá trị này dưới dạng văn bản.

Dưới đây là cách chuyển những giá trị được viết dưới dạng văn bản này thành "số bình thường":

=VALUE(SUBSTITUTE("8 544"," ",""))

hoặc

=VALUE(SUBSTITUTE(A2," ",""))

trong đó A2 chứa 8 544 .

Nó hoạt động như thế nào? Hàm SUBSTITUTE thay thế tất cả khoảng trắng trong văn bản (kiểm tra đối số thứ hai – có khoảng trắng trong dấu ngoặc kép) bằng một dấu "trốngstring" (đối số thứ ba). Sau đó, VALUE chuyển đổi văn bản thành số.

Ví dụ 4

Có một số hàm Google Trang tính giúp thao tác văn bản trong bảng tính của bạn, chẳng hạn như thay đổi kiểu chữ thành trường hợp của câu. Nếu bạn có điều gì lạ như SOOURcE dAtA , bạn có thể lấy Dữ liệu nguồn để thay thế:

Hãy để tôi giải thích đó một cách chi tiết. Tôi lấy ký tự đầu tiên trong một ô:

=LEFT(A1,1)

và chuyển nó thành chữ hoa:

=UPPER(LEFT(A1,1))

Sau đó, tôi lấy văn bản còn lại:

=RIGHT(A1,LEN(A1)-1)

và buộc nó thành chữ thường:

=LOWER(RIGHT(A1,LEN(A1)-1))

Cuối cùng, tôi gộp tất cả các phần của công thức lại với nhau bằng dấu và :

=UPPER(LEFT(A1,1))&LOWER(RIGHT(A1,LEN(A1)-1))

Mẹo. Bạn có thể chuyển đổi giữa các trường hợp chỉ bằng một cú nhấp chuột với tiện ích tương ứng từ Công cụ quyền lực của chúng tôi.

Tất nhiên, Google Trang tính còn cung cấp nhiều hơn nữa. Đừng' Đừng sợ các công thức phức tạp khác nhau – chỉ cần thử và thử nghiệm. Rốt cuộc, những bộ công cụ này cho phép chúng tôi giải quyết nhiều nhiệm vụ khác nhau. Chúc may mắn! :)