Tento návod ukazuje, ako použiť funkciu PMT v programe Excel na výpočet splátok úveru alebo investície na základe úrokovej sadzby, počtu splátok a celkovej výšky úveru.

Predtým, ako si požičiate peniaze, je dobré vedieť, ako funguje pôžička. Vďaka finančným funkciám programu Excel, ako sú RATE, PPMT a IPMT, je výpočet mesačnej alebo akejkoľvek inej pravidelnej splátky za pôžičku jednoduchý. V tomto návode sa bližšie pozrieme na funkciu PMT, podrobne rozoberieme jej syntax a ukážeme si, ako si v programe Excel vytvoriť vlastnú kalkulačku PMT.

Čo je funkcia PMT v programe Excel?

Funkcia PMT programu Excel je finančná funkcia, ktorá vypočíta splátku úveru na základe konštantnej úrokovej sadzby, počtu období a výšky úveru.

"PMT" znamená "payment" (platba), z čoho vyplýva aj názov funkcie.

Ak napríklad žiadate o dvojročný úver na auto s ročnou úrokovou sadzbou 7 % a výškou úveru 30 000 USD, vzorec PMT vám môže povedať, aké budú vaše mesačné splátky.

Aby funkcia PMT fungovala vo vašich pracovných listoch správne, majte na pamäti tieto skutočnosti:

• V súlade so všeobecným modelom peňažných tokov sa suma platby vypisuje ako záporné číslo pretože ide o odliv hotovosti.
• Hodnota vrátená funkciou PMT obsahuje hlavný a úrok nezahŕňa však žiadne poplatky, dane ani rezervné platby, ktoré môžu byť s úverom spojené.
• Vzorec PMT v programe Excel dokáže vypočítať splátku úveru pre rôzne frekvencie splátok, napr. týždenník , mesačne , štvrťročne , alebo každoročne Tento príklad ukazuje, ako to urobiť správne.

Funkcia PMT je k dispozícii v aplikáciách Excel pre Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 a Excel 2007.

Funkcia PMT programu Excel - syntax a základné použitie

Funkcia PMT má tieto argumenty:

Kde:

• Hodnotenie (povinné) - konštantná úroková sadzba za obdobie. Môže byť uvedená v percentách alebo ako desatinné číslo.

  Ak napríklad vytvoríte ročné splátky úveru s ročnou úrokovou sadzbou 10 %, použite pre sadzbu 10 % alebo 0,1. Ak vykonáte mesačne splátky na ten istý úver, potom použite sadzbu 10 %/12 alebo 0,00833.

• Nper (povinné) - počet splátok úveru, t. j. celkový počet období, počas ktorých sa má úver splácať.

  Ak napríklad vytvoríte ročné splátky na 5-ročný úver, dodajte 5 za nper. Ak vykonáte mesačne splátky na ten istý úver, potom vynásobte počet rokov 12 a použite 5*12 alebo 60 pre nper.

• Pv (povinné) - súčasná hodnota, t. j. celková suma, ktorú majú teraz hodnotu všetky budúce platby. V prípade úveru je to jednoducho pôvodná požičaná suma.
• Fv (nepovinné) - budúca hodnota alebo zostatok hotovosti, ktorý chcete mať po vykonaní poslednej splátky. Ak sa neuvedie, predpokladá sa, že budúca hodnota úveru je nula (0).
• Typ (nepovinné) - určuje, kedy sú platby splatné:
  • 0 alebo vynechané - platby sú splatné na konci každého obdobia.
  • 1 - platby sú splatné na začiatku každého obdobia.

Ak si napríklad požičiate 100 000 USD na 5 rokov s ročnou úrokovou sadzbou 7 %, podľa nasledujúceho vzorca sa vypočíta ročná platba :

=PMT(7%, 5, 100000)

Ak chcete nájsť mesačná platba pre ten istý úver použite tento vzorec:

=PMT(7%/12, 5*12, 100000)

Alebo môžete zadať známe zložky úveru do samostatných buniek a odkazovať na tieto bunky vo vzorci PMT. S úrokovou sadzbou v B1, počtom rokov v B2 a sumou úveru v B3 je vzorec takýto jednoduchý:

=PMT(B1, B2, B3)

Nezabudnite, že platba sa vracia ako záporné číslo pretože táto suma bude odpísaná (odpočítaná) z vášho bankového účtu.

V predvolenom nastavení Excel zobrazuje výsledok v Mena vo formáte zaokrúhlenom na 2 desatinné miesta, zvýraznenom červenou farbou a uzavretom v zátvorkách, ako je znázornené v ľavej časti obrázka nižšie. Obrázok vpravo ukazuje rovnaký výsledok v Všeobecné formát.

Ak chcete, aby sa platba uskutočnila ako pozitívne číslo , vložte znamienko mínus buď pred celý vzorec PMT, alebo pred pv argument (výška úveru):

=-PMT(B1, B2, B3)

alebo

=PMT(B1, B2, -B3)

Tip. Výpočet celková suma zaplatené za pôžičku, vynásobte vrátenú hodnotu PMT počtom období (hodnota nper). V našom prípade by sme použili túto rovnicu: 24 389,07*5 a zistili by sme, že celková suma sa rovná 121 945,35 USD.

Ako používať funkciu PMT v programe Excel - príklady vzorcov

Nižšie nájdete niekoľko ďalších príkladov vzorca PMT programu Excel, ktoré ukazujú, ako vypočítať rôzne pravidelné splátky pre úver na auto, úver na bývanie, hypotekárny úver a podobne.

Úplný tvar funkcie PMT v programe Excel

Posledné dva argumenty môžete vo vzorcoch PMT väčšinou vynechať (ako sme to urobili vo vyššie uvedených príkladoch), pretože ich predvolené hodnoty pokrývajú najtypickejšie prípady použitia:

• Fv vynechaný - znamená nulový zostatok po poslednej platbe.
• Typ vynechané - platby sú splatné na koniec každého obdobia.

Ak sa podmienky vašej pôžičky líšia od podmienok zlyhania, použite úplnú formu vzorca PMT.

Ako príklad si vypočítajme sumu ročné platby na základe týchto vstupných buniek:

• B1 - ročná úroková sadzba
• B2 - doba splatnosti úveru (v rokoch)
• B3 - výška úveru
• B4 - budúca hodnota (zostatok po poslednej platbe)
• B5 - typ anuity:
  • 0 (pravidelná anuita) - platby sa vykonávajú na konci každého roka.
  • 1 (splatná anuita) - platby sa uskutočňujú na začiatku obdobia, napr. nájomné alebo lízingové splátky.

Tieto odkazy vložte do vzorca PMT programu Excel:

=PMT(B1, B2, B3, B4, B5)

A dosiahnete tento výsledok:

Výpočet týždenných, mesačných, štvrťročných a polročných platieb

V závislosti od frekvencie platieb je potrebné použiť nasledujúce výpočty pre sadzba a nper argumenty:

• Pre sadzba , vydeľte ročnú úrokovú sadzbu počtom platieb za rok (ktorý sa považuje za rovný počtu období zloženia).
• Pre nper , vynásobte počet rokov počtom platieb za rok.

Podrobnosti sú uvedené v nasledujúcej tabuľke:

Ak chcete napríklad zistiť výšku pravidelnej splátky úveru vo výške 5 000 USD s ročnou úrokovou sadzbou 8 % a trvaním 3 roky, použite jeden z nasledujúcich vzorcov.

Týždeň platba:

=PMT(8%/52, 3*52, 5000)

Mesačne platba:

=PMT(8%/12, 3*12, 5000)

Štvrťročne platba:

=PMT(8%/4, 3*4, 5000)

Polročne platba:

=PMT(8%/2, 3*2, 5000)

Vo všetkých prípadoch sa predpokladá, že zostatok po poslednej platbe je 0 USD a platby sú splatné na konci každého obdobia.

Na nasledujúcom obrázku sú zobrazené výsledky týchto vzorcov:

Ako vytvoriť kalkulačku PMT v programe Excel

Predtým, ako si pôjdete požičať peniaze, je rozumné porovnať si rôzne podmienky pôžičky a zistiť, ktoré možnosti vám najviac vyhovujú. Na tento účel si vytvorme vlastnú kalkulačku splátok pôžičky v programe Excel.

1. Na začiatku zadajte sumu úveru, úrokovú sadzbu a dobu splatnosti úveru do samostatných buniek (B3, B4, B5).
2. Ak chcete mať možnosť vybrať rôzne obdobia a určiť, kedy sú platby splatné, vytvorte rozbaľovacie zoznamy s nasledujúcimi preddefinovanými možnosťami (B6 a B7):

   

3. Nastavenie vyhľadávacích tabuliek pre Obdobia (E2:F6) a Platby sú splatné (E8:F9), ako je znázornené na snímke obrazovky nižšie. Je dôležité, aby textové označenia vo vyhľadávacích tabuľkách presne zodpovedali položkám príslušného rozbaľovacieho zoznamu.

   Do buniek vedľa rozbaľovacích zoznamov zadajte nasledujúce vzorce IFERROR VLOOKUP, ktoré vytiahnu číslo z vyhľadávacej tabuľky zodpovedajúce položke vybranej v rozbaľovacom zozname.

   Vzorec pre Obdobia (C6):

   =IFERROR(VLOOKUP(B6, E2:F6, 2, 0), "")

   Vzorec pre Platby sú splatné (C7):

   =IFERROR(VLOOKUP(B7, E8:F9, 2, 0), "")

   

4. Napíšte vzorec PMT na výpočet pravidelnej platby na základe vašich buniek. V našom prípade vzorec vyzerá takto:

   =IFERROR(-PMT(B4/C6, B5*C6, B3, 0, C7), "")

   Všimnite si, prosím, nasledujúce veci:

   • Stránka fv argument (0) je vo vzorci pevne zakódovaný, pretože po poslednej platbe chceme vždy nulový zostatok. V prípade, že chcete používateľom umožniť zadať akúkoľvek budúcu hodnotu, vyčleňte pre argument fv samostatnú vstupnú bunku.
   • Funkcii PMT predchádza znamienko mínus, aby sa výsledok zobrazil ako kladné číslo .
   • Funkcia PMT je zabalená do IFERROR, aby sa skryli chyby, keď niektoré vstupné hodnoty nie sú definované.

   Vyššie uvedený vzorec sa vloží do bunky B9. A v susednej bunke (A9) zobrazíme štítok zodpovedajúci vybranej perióde (B6). Na tento účel stačí spojiť hodnotu v B6 a požadovaný text:

   =B6&" Platba"

   

5. Nakoniec môžete skryť vyhľadávacie tabuľky pred zobrazením, pridať niekoľko dokončovacích formátovacích úprav a vaša kalkulačka PMT v programe Excel je pripravená na použitie:

   

Nefunguje funkcia PMT programu Excel

Ak váš vzorec PMT v programe Excel nefunguje alebo poskytuje nesprávne výsledky, je to pravdepodobne z nasledujúcich dôvodov:

• Chyba #NUM! sa môže vyskytnúť, ak sa buď sadzba argument je záporné číslo alebo nper sa rovná 0.
• Chyba #VALUE! nastane, ak jeden alebo viac argumentov sú textové hodnoty.
• Ak je výsledok vzorca PMT oveľa vyšší alebo nižší, ako sa očakávalo, uistite sa, že ste v súlade s jednotkami dodanými pre sadzba a nper argumentov, čo znamená, že ste správne prepočítali ročnú úrokovú sadzbu na sadzbu obdobia a počet rokov na týždne, mesiace alebo štvrťroky, ako je uvedené v tomto príklade.

Takto vypočítate funkciu PMT v programe Excel. Ak sa chcete bližšie pozrieť na vzorce uvedené v tomto návode, môžete si stiahnuť náš vzorový zošit uvedený nižšie. Ďakujem vám za prečítanie a dúfam, že sa uvidíme na našom blogu budúci týždeň!

Cvičebnica na stiahnutie

Vzorec PMT v programe Excel - príklady(.xlsx súbor)