Samouczek pokazuje, jak używać funkcji PMT w Excelu do obliczania płatności dla pożyczki lub inwestycji na podstawie stopy procentowej, liczby płatności i całkowitej kwoty pożyczki.

Przed pożyczeniem pieniędzy dobrze jest wiedzieć, jak działa pożyczka. Dzięki funkcjom finansowym Excela, takim jak RATE, PPMT i IPMT, obliczanie miesięcznej lub dowolnej innej okresowej płatności za pożyczkę jest łatwe. W tym samouczku przyjrzymy się bliżej funkcji PMT, szczegółowo omówimy jej składnię i pokażemy, jak zbudować własny kalkulator PMT w Excelu.

Czym jest funkcja PMT w programie Excel?

Funkcja PMT w Excelu jest funkcją finansową, która oblicza płatność za pożyczkę na podstawie stałej stopy procentowej, liczby okresów i kwoty pożyczki.

"PMT" to skrót od "płatności", stąd nazwa funkcji.

Na przykład, jeśli ubiegasz się o dwuletni kredyt samochodowy z roczną stopą procentową w wysokości 7% i kwotą pożyczki w wysokości 30 000 USD, formuła PMT może powiedzieć, jakie będą Twoje miesięczne płatności.

Aby funkcja PMT działała poprawnie w Twoich arkuszach, pamiętaj o następujących faktach:

• Aby zachować zgodność z ogólnym modelem przepływu środków pieniężnych, kwota płatności jest wyprowadzana jako liczba ujemna ponieważ jest to wypływ gotówki.
• Wartość zwracana przez funkcję PMT zawiera. główny oraz odsetki ale nie obejmuje żadnych opłat, podatków ani płatności rezerwowych, które mogą być związane z kredytem.
• Formuła PMT w Excelu może obliczyć ratę kredytu dla różnych częstotliwości płatności, np. tygodniowy , miesięcznie , kwartalnik lub corocznie Ten przykład pokazuje, jak to zrobić poprawnie.

Funkcja PMT jest dostępna w programie Excel dla Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 i Excel 2007.

Funkcja PMT w Excelu - składnia i podstawowe zastosowania

Funkcja PMT posiada następujące argumenty:

Gdzie:

• Stawka (wymagane) - stała stopa procentowa na okres. Może być podana w postaci procentów lub liczby dziesiętnej.

  Na przykład, jeśli zrobisz roczny Jeśli dokonujesz płatności z tytułu pożyczki o rocznej stopie procentowej w wysokości 10 procent, użyj 10% lub 0,1 dla stopy. Jeśli dokonujesz miesięcznie płatności na ten sam kredyt, to użyj 10%/12 lub 0,00833 dla stopy.

• Nper (wymagane) - liczba płatności dla kredytu, czyli łączna liczba okresów, w których należy spłacić kredyt.

  Na przykład, jeśli zrobisz roczny płatności za 5-letni kredyt, podaj 5 dla nper. Jeśli dokonujesz miesięcznie płatności na ten sam kredyt, następnie pomnożyć liczbę lat przez 12 i użyć 5*12 lub 60 dla nper.

• Pv (wymagane) - wartość bieżąca, czyli suma, jaką wszystkie przyszłe płatności są warte teraz. W przypadku kredytu jest to po prostu pierwotna kwota pożyczona.
• Fv (opcjonalnie) - przyszła wartość, czyli saldo gotówkowe, które chcemy mieć po dokonaniu ostatniej płatności. W przypadku pominięcia, przyjmuje się, że przyszła wartość kredytu wynosi zero (0).
• Typ (opcjonalnie) - określa termin płatności:
  • 0 lub pominięty - płatności są należne na koniec każdego okresu.
  • 1 - płatności są płatne na początku każdego okresu.

Na przykład, jeśli pożyczysz 100 000 dolarów na 5 lat z roczną stopą procentową w wysokości 7%, poniższy wzór obliczy płatność roczna :

=PMT(7%, 5, 100000)

Aby znaleźć płatność miesięczna dla tego samego kredytu, użyj tego wzoru:

=PMT(7%/12, 5*12, 100000)

Można też wpisać znane składniki kredytu w osobnych komórkach i odwołać się do nich w formule PMT. Mając stopę procentową w B1, liczbę lat w B2 i kwotę kredytu w B3, formuła jest tak prosta jak poniżej:

=PMT(B1, B2, B3)

Proszę pamiętać, że płatność jest zwracana jako liczba ujemna ponieważ kwota ta zostanie obciążona (odjęta) z Twojego konta bankowego.

Domyślnie Excel wyświetla wynik w Waluta zaokrąglone do 2 miejsc po przecinku, zaznaczone na czerwono i ujęte w nawiasy, jak pokazano w lewej części poniższego obrazu. Obraz po prawej stronie pokazuje ten sam wynik w formacie Ogólne format.

Jeśli chciałbyś mieć płatność jako pozytywny numer , postawić znak minus przed całą formułą PMT lub przed pv argument (kwota pożyczki):

=-PMT(B1, B2, B3)

lub

=PMT(B1, B2, -B3)

Wskazówka. Aby obliczyć suma zapłacił za pożyczkę, pomnóż zwróconą wartość PMT przez liczbę okresów (wartość nper). W naszym przypadku użylibyśmy tego równania: 24 389,07*5 i stwierdzilibyśmy, że całkowita kwota wynosi 121 945,35 USD.

Jak wykorzystać funkcję PMT w Excelu - przykłady formuł

Poniżej znajdziesz jeszcze kilka przykładów formuły Excel PMT, które pokazują, jak obliczyć różne płatności okresowe dla kredytu samochodowego, kredytu mieszkaniowego, pożyczki hipotecznej i tym podobnych.

Pełna postać funkcji PMT w Excelu

W większości przypadków można pominąć dwa ostatnie argumenty w formułach PMT (tak jak zrobiliśmy to w powyższych przykładach), ponieważ ich wartości domyślne pokrywają najbardziej typowe przypadki użycia:

• Fv pominięty - oznacza saldo zerowe po ostatniej wpłacie.
• Typ pominięto - płatności należy dokonać w koniec każdego okresu.

Jeśli warunki Twojego kredytu są inne niż defaulty, to użyj pełnej formy formuły PMT.

Jako przykład, obliczmy kwotę płatności roczne na podstawie tych komórek wejściowych:

• B1 - roczna stopa procentowa
• B2 - okres kredytowania (w latach)
• B3 - kwota kredytu
• B4 - wartość przyszła (saldo po ostatniej płatności)
• B5 - typ renty:
  • 0 (renta regularna) - wypłaty dokonywane są na koniec każdego roku.
  • 1 (renta należna) - płatności dokonywane są na początku okresu, np. opłaty za czynsz lub dzierżawę.

Dostarcz te odniesienia do swojej formuły PMT w Excelu:

=PMT(B1, B2, B3, B4, B5)

I będziesz miał taki wynik:

Obliczanie płatności tygodniowych, miesięcznych, kwartalnych i półrocznych

W zależności od częstotliwości płatności, należy zastosować następujące obliczenia dla stawka oraz nper argumenty:

• Dla stawka , podzielić roczną stopę procentową przez liczbę płatności w roku (którą uznaje się za równą liczbie okresów składanych).
• Dla nper , pomnożyć liczbę lat przez liczbę płatności w roku.

Poniższa tabela przedstawia szczegóły:

Na przykład, aby znaleźć kwotę okresowej płatności z tytułu pożyczki w wysokości 5000 dolarów z roczną stopą procentową 8% i czasem trwania 3 lat, należy użyć jednego z poniższych wzorów.

Tygodnik zapłata:

=PMT(8%/52, 3*52, 5000)

Miesięcznie zapłata:

=PMT(8%/12, 3*12, 5000)

Kwartalnik zapłata:

=PMT(8%/4, 3*4, 5000)

Półroczny zapłata:

=PMT(8%/2, 3*2, 5000)

We wszystkich przypadkach przyjmuje się, że saldo po ostatniej płatności wynosi 0$, a płatności są płatne na koniec każdego okresu.

Poniższy zrzut ekranu przedstawia wyniki tych formuł:

Jak zrobić kalkulator PMT w Excelu

Zanim przejdziemy do pożyczania pieniędzy, nie bez powodu warto porównać różne warunki pożyczki, aby poznać opcje, które najbardziej nam odpowiadają. W tym celu stwórzmy własny kalkulator spłaty pożyczki w Excelu.

1. Na początek w osobnych komórkach (odpowiednio B3, B4, B5) wpisz kwotę pożyczki, oprocentowanie i okres kredytowania.
2. Aby móc wybrać różne okresy i określić termin płatności, utwórz listy rozwijane z następującymi predefiniowanymi opcjami (B6 i B7):

   

3. Skonfiguruj tabele wynikowe dla Okresy (E2:F6) oraz Płatności są wymagalne (E8:F9), jak pokazano na poniższym zrzucie ekranu. Ważne jest, aby etykiety tekstowe w tabelach lookup dokładnie odpowiadały pozycjom odpowiedniej listy rozwijanej.

   W komórkach obok list rozwijanych wpisz następujące formuły IFERROR VLOOKUP, które wyciągną z tabeli lookup liczbę odpowiadającą pozycji wybranej na liście rozwijanej.

   Wzór na Okresy (C6):

   =IFERROR(VLOOKUP(B6, E2:F6, 2, 0), "")

   Wzór na Płatności są wymagalne (C7):

   =IFERROR(VLOOKUP(B7, E8:F9, 2, 0), "")

   

4. Napisz formułę PMT, aby obliczyć okresową płatność na podstawie swoich komórek. W naszym przypadku formuła przebiega następująco:

   =IFERROR(-PMT(B4/C6, B5*C6, B3, 0, C7), "")

   Proszę zwrócić uwagę na następujące rzeczy:

   • Na stronie fv Argument (0) jest zakodowany w formule, ponieważ zawsze chcemy mieć zerowe saldo po ostatniej płatności. W przypadku, gdy chcesz pozwolić swoim użytkownikom na wprowadzenie dowolnej przyszłej wartości, przeznacz osobną komórkę wejściową dla argumentu fv.
   • Funkcja PMT jest poprzedzona znakiem minus, aby wyświetlić wynik jako liczba dodatnia .
   • Funkcja PMT jest zawijana w IFERROR, aby ukryć błędy, gdy niektóre wartości wejściowe nie są zdefiniowane.

   Powyższa formuła trafia do komórki B9. Natomiast w sąsiedniej komórce (A9) wyświetlamy etykietę odpowiadającą wybranemu okresowi (B6). W tym celu wystarczy konkatenować wartość w B6 i pożądany tekst:

   =B6&" Płatność"

   

5. Na koniec można ukryć tabele wynikowe, dodać kilka końcowych elementów formatowania i kalkulator PMT w Excelu jest gotowy do pracy:

   

Funkcja PMT w programie Excel nie działa

Jeśli Twoja formuła PMT w Excelu nie działa lub daje błędne wyniki, to prawdopodobnie wynika to z następujących powodów:

• Błąd #NUM! może wystąpić, jeśli stawka argument jest liczbą ujemną lub nper jest równa 0.
• Błąd #VALUE! występuje, jeśli jeden lub więcej argumentów jest wartościami tekstowymi.
• Jeśli wynik formuły PMT jest znacznie wyższy lub niższy niż oczekiwany, upewnij się, że jesteś zgodny z jednostkami dostarczonymi dla stawka oraz nper argumentów, co oznacza, że prawidłowo przeliczyłeś roczną stopę procentową na stopę procentową okresu oraz liczbę lat na tygodnie, miesiące lub kwartały, jak pokazano w tym przykładzie.

Tak właśnie oblicza się funkcję PMT w Excelu. Aby przyjrzeć się bliżej formułom omawianym w tym tutorialu zapraszamy do pobrania naszego przykładowego skoroszytu poniżej. Dziękuję za lekturę i mam nadzieję, że zobaczymy się na naszym blogu za tydzień!

Zeszyt ćwiczeń do pobrania

Formuła PMT w Excelu - przykłady(.xlsx file)