Ohjeessa näytetään, miten Excelin PMT-toimintoa käytetään lainan tai sijoituksen maksujen laskemiseen koron, maksujen määrän ja lainan kokonaissumman perusteella.

Ennen kuin lainaat rahaa, on hyvä tietää, miten laina toimii. Excelin rahoitustoimintojen, kuten RATE, PPMT ja IPMT, ansiosta lainan kuukausittaisen tai muun jaksottaisen maksun laskeminen on helppoa. Tässä opetusohjelmassa tarkastelemme tarkemmin PMT-funktiota, keskustelemme sen syntaksista yksityiskohtaisesti ja näytämme, miten rakennat oman PMT-laskurin Exceliin.

Mikä on Excelin PMT-toiminto?

Excelin PMT-toiminto on taloudellinen toiminto, joka laskee lainan maksun vakiokoron, jaksojen lukumäärän ja lainasumman perusteella.

"PMT" tarkoittaa "maksua", mistä myös toiminnon nimi johtuu.

Jos esimerkiksi haet kahden vuoden autolainaa, jonka vuosikorko on 7 % ja lainasumma 30 000 dollaria, PMT-kaavalla voidaan laskea kuukausittaiset maksusi.

Jotta PMT-toiminto toimisi oikein laskentataulukoissasi, pidä mielessä seuraavat seikat:

• Yleisen kassavirtamallin mukaisesti maksun määrä tulostetaan muodossa negatiivinen luku koska se on kassavirta.
• PMT-funktion palauttama arvo sisältää pääasiallinen ja korko mutta ei sisällä lainaan mahdollisesti liittyviä maksuja, veroja tai varauksia.
• Excelin PMT-kaavalla voidaan laskea lainanmaksu eri maksuväleillä, kuten esimerkiksi seuraavasti viikoittain , kuukausittain , neljännesvuosittain , tai vuosittain Tässä esimerkissä näytetään, miten se tehdään oikein.

PMT-toiminto on käytettävissä Excel for Office 365:ssä, Excel 2019:ssä, Excel 2016:ssa, Excel 2013:ssa, Excel 2010:ssä ja Excel 2007:ssä.

Excelin PMT-toiminto - syntaksi ja peruskäytöt

PMT-toiminnolla on seuraavat argumentit:

Missä:

• Arvioi (pakollinen) - vakiokorko jaksoa kohti. Voidaan ilmoittaa prosentteina tai desimaalilukuna.

  Jos esimerkiksi teet vuotuinen maksat lainaa, jonka vuotuinen korko on 10 prosenttia, käytä korkoa 10 % tai 0,1. Jos maksat kuukausittain saman lainan maksut, niin käytä korkona 10 %/12 tai 0,00833.

• Nper (pakollinen) - lainan maksujen lukumäärä eli niiden jaksojen kokonaismäärä, joiden aikana laina on maksettava.

  Jos esimerkiksi teet vuotuinen 5-vuotisen lainan maksut, anna nper 5. Jos teet kuukausittain saman lainan maksut, kerro vuosien lukumäärä 12:lla ja käytä nper:n arvona 5*12 tai 60.

• Pv (vaaditaan) - nykyarvo eli kaikkien tulevien maksujen kokonaisarvo nyt. Lainan tapauksessa se on yksinkertaisesti alkuperäinen lainasumma.
• Fv (valinnainen) - tuleva arvo tai käteissaldo, jonka haluat saada viimeisen maksun suorittamisen jälkeen. Jos se jätetään pois, lainan tulevan arvon oletetaan olevan nolla (0).
• Tyyppi (valinnainen) - määrittää, milloin maksut erääntyvät:
  • 0 tai jätetty pois - maksut erääntyvät kunkin jakson lopussa.
  • 1 - maksut suoritetaan kunkin jakson alussa.

Jos esimerkiksi lainaat 100 000 dollaria viideksi vuodeksi ja vuotuinen korko on 7 %, seuraava kaava laskee vuosimaksu :

=PMT(7%, 5, 100000)

Löytääksesi kuukausimaksu samaa lainaa varten, käytä tätä kaavaa:

=PMT(7%/12, 5*12, 100000)

Voit myös syöttää lainan tunnetut osat erillisiin soluihin ja viitata näihin soluihin PMT-kaavassa. Kun korko on B1:ssä, vuosien lukumäärä B2:ssa ja lainan määrä B3:ssa, kaava on näin yksinkertainen:

=PMT(B1, B2, B3)

Muistathan, että maksu palautetaan negatiivinen luku koska tämä summa veloitetaan (vähennetään) pankkitililtäsi.

Oletusarvoisesti Excel näyttää tuloksen Valuutta muodossa, pyöristettynä kahteen desimaaliin, punaisella korostettuna ja suluissa, kuten alla olevan kuvan vasemmassa osassa näkyy. Oikeanpuoleisessa kuvassa näkyy sama tulos muodossa Yleistä muodossa.

Jos haluat, että maksu suoritetaan kuin positiivinen numero , laita miinusmerkki joko koko PMT-kaavan eteen tai pv argumentti (lainan määrä):

=-PMT(B1, B2, B3)

tai

=PMT(B1, B2, -B3)

Vinkki. Laske kokonaismäärä lainasta maksettu, kerro palautettu PMT-arvo jaksojen lukumäärällä (nper arvo). Meidän tapauksessamme käytämme seuraavaa yhtälöä: 24 389,07*5 ja saamme kokonaissumman, joka on 121 945,35 dollaria.

Kuinka käyttää PMT-funktiota Excelissä - kaavaesimerkkejä

Alla on vielä muutama esimerkki Excelin PMT-kaavasta, joista näet, miten lasketaan erilaisia jaksoittaisia maksuja autolainalle, asuntolainalle, asuntolainalle ja muille vastaaville.

PMT-funktion koko muoto Excelissä

Useimmiten voit jättää kaksi viimeistä argumenttia pois PMT-kaavoista (kuten edellä olevissa esimerkeissä), koska niiden oletusarvot kattavat tyypillisimmät käyttötapaukset:

• Fv jätetty pois - merkitsee nollasaldo viimeisen maksun jälkeen.
• Tyyppi jätetty pois - maksut on suoritettava end kunkin jakson aikana.

Jos lainaehtosi poikkeavat laiminlyönneistä, käytä täyttä PMT-kaavaa.

Esimerkkinä voidaan laskea, kuinka paljon vuotuiset maksut näiden syöttösolujen perusteella:

• B1 - vuotuinen korko
• B2 - laina-aika (vuosina)
• B3 - lainan määrä
• B4 - tuleva arvo (saldo viimeisen maksun jälkeen).
• B5 - annuiteettityyppi:
  • 0 (säännöllinen annuiteetti) - maksut suoritetaan kunkin vuoden lopussa.
  • 1 (annuiteetti erääntyy) - maksut suoritetaan kauden alussa, esim. vuokra- tai leasingmaksut.

Syötä nämä viittaukset Excelin PMT-kaavaan:

=PMT(B1, B2, B3, B4, B5)

Ja saat tämän tuloksen:

Laske viikoittaiset, kuukausittaiset, neljännesvuosittaiset ja puolivuosittaiset maksut.

Maksutiheydestä riippuen sinun on käytettävä seuraavia laskutoimituksia varten kurssi ja nper argumentit:

• Osoitteessa kurssi , jaa vuotuinen korko vuotuisten maksujen lukumäärällä (jonka katsotaan olevan yhtä suuri kuin koronlaskentajaksojen lukumäärä).
• Osoitteessa nper , kerrotaan vuosien lukumäärä vuotuisten maksujen määrällä.

Alla olevassa taulukossa on lisätietoja:

Jos haluat esimerkiksi selvittää 5 000 dollarin lainan, jonka vuosikorko on 8 % ja laina-aika 3 vuotta, jaksottaisen maksun määrän käyttämällä jotakin alla olevista kaavoista.

Viikoittain maksu:

=PMT(8%/52, 3*52, 5000)

Kuukausittain maksu:

=PMT(8%/12, 3*12, 5000)

Neljännesvuosittain maksu:

=PMT(8%/4, 3*4, 5000)

Puolivuosittain maksu:

=PMT(8%/2, 3*2, 5000)

Kaikissa tapauksissa viimeisen maksun jälkeisen saldon oletetaan olevan 0 dollaria, ja maksut erääntyvät kunkin jakson lopussa.

Alla olevassa kuvakaappauksessa näkyvät näiden kaavojen tulokset:

Kuinka tehdä PMT-laskuri Excelissä

Ennen kuin ryhdyt lainaamaan rahaa, on järkevää vertailla eri lainaehtoja, jotta löydät itsellesi sopivimmat vaihtoehdot. Tätä varten luodaan oma Excel-lainanmaksulaskuri.

1. Syötä ensin lainasumma, korko ja laina-aika erillisiin soluihin (B3, B4 ja B5).
2. Jotta voit valita eri ajanjaksoja ja määrittää, milloin maksut erääntyvät, luo pudotusluettelot, joissa on seuraavat valmiit vaihtoehdot (B6 ja B7):

   

3. Määritä hakutaulukot seuraaville Jaksot (E2:F6) ja Maksut erääntyvät (E8:F9), kuten alla olevassa kuvassa. On tärkeää, että hakutaulukoiden tekstinimikkeet vastaavat täsmälleen vastaavan pudotusluettelon kohteita.

   Kirjoita pudotusluetteloiden vieressä oleviin soluihin seuraavat IFERROR VLOOKUP -kaavat, jotka hakevat pudotusluettelossa valittua kohdetta vastaavan numeron hakutaulukosta.

   Kaava Jaksot (C6):

   =IFERROR(VLOOKUP(B6, E2:F6, 2, 0), "")

   Kaava Maksut erääntyvät (C7):

   =IFERROR(VLOOKUP(B7, E8:F9, 2, 0), "")

   

4. Kirjoita PMT-kaava, jolla lasketaan jaksottainen maksu solujen perusteella. Meidän tapauksessamme kaava on seuraava:

   =IFERROR(-PMT(B4/C6, B5*C6, B3, 0, C7), "")

   Huomaa seuraavat asiat:

   • The fv argumentti (0) on kovakoodattu kaavaan, koska haluamme aina nollasaldon viimeisen maksun jälkeen. Jos haluat antaa käyttäjien syöttää minkä tahansa tulevan arvon, varaa erillinen syöttösolu fv-argumentille.
   • PMT-toimintoa edeltää miinusmerkki, joka näyttää tuloksen muodossa positiivinen luku .
   • PMT-funktio on kiedottu IFERROR-funktioon, jotta virheet voidaan piilottaa, kun joitakin syöttöarvoja ei ole määritelty.

   Yllä oleva kaava menee soluun B9. Ja viereisessä solussa (A9) näytetään valittua ajanjaksoa vastaava merkintä (B6). Tätä varten yksinkertaisesti ketjutetaan B6:n arvo ja haluttu teksti:

   =B6&" Maksu"

   

5. Lopuksi voit piilottaa hakutaulukot näkyvistä, lisätä muutaman viimeistelevän muotoilun ja Excelin PMT-laskurisi on valmis:

   

Excel PMT-toiminto ei toimi

Jos Excelin PMT-kaava ei toimi tai tuottaa vääriä tuloksia, se johtuu todennäköisesti seuraavista syistä:

• #NUM! -virhe voi ilmetä, jos joko kurssi argumentti on negatiivinen luku tai nper on 0.
• Jos yksi tai useampi argumentti on tekstiarvo, syntyy #VALUE! -virhe.
• Jos PMT-kaavan tulos on paljon odotettua korkeampi tai matalampi, varmista, että olet johdonmukainen annettujen yksiköiden kanssa. kurssi ja nper argumentteja, eli olet muuttanut vuotuisen koron oikein jakson koroksi ja vuosien määrän viikoiksi, kuukausiksi tai neljänneksiksi, kuten tässä esimerkissä näkyy.

Näin lasket PMT-toiminnon Excelissä. Jos haluat tutustua tarkemmin tässä ohjeessa käsiteltyihin kaavoihin, voit ladata alla olevan esimerkkityökirjan. Kiitos lukemisesta ja toivottavasti tapaamme blogissamme ensi viikolla!

Käytännön työkirja ladattavissa

PMT-kaava Excelissä - esimerkkejä(.xlsx-tiedosto)