يوضح البرنامج التعليمي كيفية استخدام دالة PMT في Excel لحساب المدفوعات لقرض أو استثمار بناءً على معدل الفائدة وعدد الدفعات وإجمالي مبلغ القرض.

قبل تقترض المال من الجيد أن تعرف كيف يعمل القرض. بفضل وظائف Excel المالية مثل RATE و PPMT و IPMT ، أصبح حساب الدفعات الشهرية أو أي مدفوعات دورية أخرى للحصول على قرض أمرًا سهلاً. في هذا البرنامج التعليمي ، سنلقي نظرة فاحصة على وظيفة PMT ، ونناقش تركيبها بالتفصيل ، ونوضح كيفية إنشاء آلة حاسبة PMT الخاصة بك في Excel.

ما هي وظيفة PMT في Excel؟

دالة Excel PMT هي دالة مالية تحسب السداد لقرض بناءً على معدل فائدة ثابت وعدد الفترات ومبلغ القرض.

تقف "PMT" بالنسبة إلى "الدفعة" ، ومن هنا اسم الوظيفة.

على سبيل المثال ، إذا كنت تقدم طلبًا للحصول على قرض سيارة لمدة عامين بمعدل فائدة سنوي يبلغ 7٪ ومبلغ القرض 30،000 دولار أمريكي ، يمكن لصيغة PMT أن تخبرنا ما ستكون مدفوعاتك الشهرية.

لكي تعمل وظيفة PMT بشكل صحيح في أوراق العمل الخاصة بك ، يرجى مراعاة هذه الحقائق:

• لتتماشى مع التدفق النقدي العام نموذج ، يتم إخراج مبلغ الدفع كرقم رقم سالب لأنه تدفق نقدي.
• تتضمن القيمة التي تم إرجاعها بواسطة دالة PMT الرئيسي و الفائدة ولكنها لا تشمل أي رسوم أو ضرائب أو احتياطي سنوي yments ذلكيمكن أن يقترن بقرض.
• يمكن أن تحسب صيغة PMT في Excel دفعة قرض لتكرار دفع مختلف مثل أسبوعيًا ، شهريًا ، ربع سنوي أو سنويًا . يوضح هذا المثال كيفية القيام بذلك بشكل صحيح.

تتوفر وظيفة PMT في Excel لـ Office 365 و Excel 2019 و Excel 2016 و Excel 2013 و Excel 2010 و Excel 2007.

دالة Excel PMT - بناء الجملة والاستخدامات الأساسية

تحتوي الدالة PMT على الوسيطات التالية:

حيث:

• معدل (مطلوب) - معدل الفائدة الثابت لكل فترة. يمكن توفيرها كنسبة مئوية أو رقم عشري.

  على سبيل المثال ، إذا قمت بسداد دفعات سنوية على قرض بمعدل فائدة سنوي قدره 10 بالمائة ، فاستخدم 10٪ أو 0.1 للسعر. إذا قمت بإجراء دفعات شهرية على نفس القرض ، فاستخدم 10٪ / 12 أو 0.00833 للسعر.

• Nper (مطلوب) - عدد مدفوعات القرض ، أي العدد الإجمالي للفترات التي يجب سداد القرض خلالها.

  على سبيل المثال ، إذا قمت بسداد دفعات سنوية لقرض مدته 5 سنوات ، فقدم 5 لـ nper. إذا قمت بإجراء دفعات شهرية على نفس القرض ، فاضرب عدد السنوات في 12 ، واستخدم 5 * 12 أو 60 لـ nper.

• Pv (مطلوب) - القيمة الحالية ، أي المبلغ الإجمالي الذي تستحقه جميع المدفوعات المستقبلية الآن. في حالة وجود قرض ، فهو ببساطة المبلغ الأصلي المقترض.
• Fv (اختياري) - القيمة المستقبلية ، أو الرصيد النقدي الذي ترغب في الحصول عليه بعد إجراء الدفعة الأخيرة. إذا تم حذفها ، فمن المفترض أن تكون القيمة المستقبلية للقرض صفر (0).
• النوع (اختياري) - تحدد متى تكون المدفوعات مستحقة:
  • 0 أو محذوف - المدفوعات مستحقة في نهاية كل فترة.
  • 1 - المدفوعات مستحقة في بداية كل فترة.

على سبيل المثال ، إذا اقترض 100000 دولار لمدة 5 سنوات بمعدل فائدة سنوي 7٪ ، ستحسب الصيغة التالية الدفعة السنوية :

=PMT(7%, 5, 100000)

للعثور على الدفعة الشهرية لنفس القرض ، استخدم هذه الصيغة:

=PMT(7%/12, 5*12, 100000)

أو يمكنك إدخال المكونات المعروفة للقرض في خلايا منفصلة والإشارة إلى هذه الخلايا في صيغة PMT. مع سعر الفائدة في B1 ، لا. من السنوات في B2 ، ومبلغ القرض في B3 ، فإن الصيغة بسيطة مثل:

=PMT(B1, B2, B3)

يرجى تذكر أن الدفعة يتم إرجاعها على أنها رقم سلبي لأن سيتم خصم هذا المبلغ (طرحه) من حسابك المصرفي.

افتراضيًا ، يعرض Excel النتيجة بتنسيق العملة ، مقربًا إلى منزلتين عشريتين ، مظللة باللون الأحمر ومحاطة بأقواس ، كما هو موضح في الجزء الأيسر من الصورة أدناه. تُظهر الصورة الموجودة على اليمين نفس النتيجة بالتنسيق عام .

إذا كنت ترغب في جعل الدفعة إيجابية رقم ، ضع علامة الطرح قبل أي منهماصيغة PMT بأكملها أو الوسيطة pv (مبلغ القرض):

=-PMT(B1, B2, B3)

أو

=PMT(B1, B2, -B3)

نصيحة. لحساب المبلغ الإجمالي المدفوع للقرض ، اضرب قيمة PMT التي تم إرجاعها في عدد الفترات (القيمة nper). في حالتنا ، سنستخدم هذه المعادلة: 24،389.07 * 5 ونجد أن المبلغ الإجمالي يساوي 121،945.35 دولارًا.

كيفية استخدام دالة PMT في Excel - أمثلة الصيغة

أدناه ستجد بعض الأمثلة الأخرى على صيغة Excel PMT التي توضح كيفية حساب المدفوعات الدورية المختلفة لقرض السيارة ، وقرض المنزل ، وقرض الرهن العقاري ، وما شابه.

الشكل الكامل لوظيفة PMT في Excel

بالنسبة للجزء الأكبر ، يمكنك حذف الوسيطتين الأخيرتين في صيغ PMT (كما فعلنا في الأمثلة أعلاه) لأن قيمها الافتراضية تغطي حالات الاستخدامات الأكثر شيوعًا:

• Fv محذوف - يشير إلى رصيد صفري بعد الدفعة الأخيرة.
• النوع محذوف - المدفوعات مستحقة في نهاية كل فترة.

إذا كانت شروط قرضك مختلفة عن الافتراضيات ، فاستخدم الصيغة الكاملة لصيغة PMT.

كمثال ، دعنا نحسب مبلغ الدفعات السنوية بناءً على خلايا الإدخال هذه:

• B1 - معدل الفائدة السنوي
• B2 - مدة القرض (بالسنوات)
• B3 - مبلغ القرض
• B4 - القيمة المستقبلية (الرصيد بعد الدفعة الأخيرة)
• B5 - نوع الأقساط:
  • 0 (الأقساط السنوية العادية) - يتم سداد الدفعات في نهاية كلالسنة.
  • 1 (الأقساط المستحقة) - يتم سداد الدفعات في بداية الفترة ، على سبيل المثال مدفوعات الإيجار أو الإيجار.

أدخل هذه المراجع إلى صيغة Excel PMT الخاصة بك:

=PMT(B1, B2, B3, B4, B5)

وستحصل على هذه النتيجة:

حساب المدفوعات الأسبوعية والشهرية والفصلية ونصف السنوية

اعتمادًا على تكرار الدفع ، تحتاج إلى استخدام الحسابات التالية لـ معدل <الوسيطتان 2> و nper :

• بالنسبة إلى معدل ، قسّم معدل الفائدة السنوي على عدد الدفعات في السنة (والتي تعتبر مساوية لـ عدد الفترات المركبة).
• بالنسبة إلى nper ، اضرب عدد السنوات في عدد المدفوعات في السنة.

يوفر الجدول أدناه التفاصيل :

على سبيل المثال ، للعثور على مبلغ الدفعة الدورية لقرض بقيمة 5000 دولار أمريكي بمعدل فائدة سنوي 8٪ ومدة 3 سنوات ، استخدم إحدى الصيغ أدناه.

الدفع الأسبوعي:

=PMT(8%/52, 3*52, 5000)

الدفع الشهري :

=PMT(8%/12, 3*12, 5000)

ربع سنوي الدفع:

=PMT(8%/4, 3*4, 5000)

نصف سنوي الدفعة:

=PMT(8%/2, 3*2, 5000)

في جميع الحالات ، يُفترض أن يكون الرصيد بعد الدفعة الأخيرة 0 دولار ، وتكون المدفوعات مستحقة في نهاية كل فترة.

توضح لقطة الشاشة أدناه نتائج هذه الصيغ:

كيفية صنع آلة حاسبة PMT في Excel

قبل المضي قدمًا واقتراض المال ، فمن المنطقي لمقارنة شروط القرض المختلفة لمعرفة الخيارات التي تناسبك أكثر. لهذا ، دعنا ننشئ حاسبة سداد قرض Excel الخاصة بنا.

1. للبدء ، أدخل مبلغ القرض وسعر الفائدة ومدة القرض في خلايا منفصلة (B3 ، B4 ، B5 ، على التوالي).
2. لتتمكن من اختيار فترات مختلفة وتحديد موعد استحقاق المدفوعات ، قم بإنشاء قوائم منسدلة مع الخيارات المحددة مسبقًا التالية (B6 و B7):

   

3. قم بإعداد جداول البحث لـ فترات (E2: F6) و المدفوعات مستحقة (E8: F9) كما هو موضح في لقطة الشاشة أدناه. من المهم أن تتطابق التسميات النصية في جداول البحث تمامًا مع عناصر القائمة المنسدلة المقابلة.

   في الخلايا المجاورة للقوائم المنسدلة ، أدخل صيغ IFERROR VLOOKUP التالية التي ستسحب الرقم من البحث الجدول المقابل للعنصر المحدد في القائمة المنسدلة.

   معادلة للفترات (C6):

   =IFERROR(VLOOKUP(B6, E2:F6, 2, 0), "")

   صيغة لـ المدفوعات مستحقة (C7):

   =IFERROR(VLOOKUP(B7, E8:F9, 2, 0), "")

   

4. اكتب صيغة PMT لحساب الدفع الدوري بناءً على الخلايا الخاصة بك. في منطقتناالحالة ، فإن الصيغة تسير على النحو التالي:

   =IFERROR(-PMT(B4/C6, B5*C6, B3, 0, C7), "")

   يرجى ملاحظة الأشياء التالية:

   • الوسيطة fv (0) مشفرة بشكل ثابت في الصيغة لأننا نريد دائمًا رصيدًا صفريًا بعد الدفعة الأخيرة. إذا كنت ترغب في السماح للمستخدمين بإدخال أي قيمة مستقبلية ، فخصص خلية إدخال منفصلة للوسيطة fv.
   • تُسبَق وظيفة PMT بعلامة الطرح لعرض النتيجة كرقم موجب .
   • يتم تغليف الدالة PMT في IFERROR لإخفاء الأخطاء عندما لا يتم تعريف بعض قيم الإدخال.

   تدخل الصيغة أعلاه في B9. وفي الخلية المجاورة (A9) نعرض تسمية مطابقة للفترة المحددة (B6). لهذا ، ما عليك سوى ربط القيمة في B6 والنص المطلوب:

   =B6&" Payment"

   

5. أخيرًا ، يمكنك إخفاء جداول البحث من العرض ، أضف بعض لمسات التنسيق النهائية ، وستكون آلة حاسبة Excel PMT الخاصة بك جيدة:

   

وظيفة Excel PMT لا تعمل

إذا كانت Excel PMT لديك الصيغة لا تعمل أو تنتج نتائج خاطئة ، من المحتمل أن يكون ذلك بسبب الأسباب التالية:

• A #NUM! قد يحدث خطأ إذا كانت الوسيطة rate عبارة عن رقم سالب أو إذا كانت الوسيطة nper تساوي 0.
• A #VALUE! يحدث خطأ إذا كانت هناك وسيطة واحدة أو أكثر عبارة عن قيم نصية.
• إذا كانت نتيجة صيغة PMT أعلى أو أقل بكثير من المتوقع ، فتأكد من توافقك مع الوحدات المتوفرة لـالوسيطتان rate و nper ، مما يعني أنك قمت بتحويل معدل الفائدة السنوي بشكل صحيح إلى معدل الفترة وعدد السنوات إلى الأسابيع أو الأشهر أو الأرباع كما هو موضح في هذا المثال.

هذه هي الطريقة التي تحسب بها وظيفة PMT في Excel. لإلقاء نظرة فاحصة على الصيغ التي تمت مناقشتها في هذا البرنامج التعليمي ، فنحن نرحب بك لتنزيل نموذج المصنف أدناه. أشكرك على القراءة وآمل أن أراك على مدونتنا الأسبوع المقبل!

تدرب على المصنف للتحميل

صيغة PMT في Excel - أمثلة (ملف .xlsx)