De handleiding laat zien hoe u de PMT-functie in Excel gebruikt om betalingen voor een lening of investering te berekenen op basis van de rentevoet, het aantal betalingen en het totale leenbedrag.

Voordat u geld leent, is het goed om te weten hoe een lening werkt. Dankzij de financiële functies van Excel, zoals RATE, PPMT en IPMT, is het berekenen van de maandelijkse of elke andere periodieke betaling voor een lening eenvoudig. In deze handleiding zullen we de PMT-functie nader bekijken, de syntaxis ervan in detail bespreken en laten zien hoe u uw eigen PMT-calculator in Excel kunt bouwen.

Wat is de PMT-functie in Excel?

De PMT-functie in Excel is een financiële functie die de betaling voor een lening berekent op basis van een constante rentevoet, het aantal perioden en het bedrag van de lening.

"PMT" staat voor "betaling", vandaar de naam van de functie.

Als u bijvoorbeeld een tweejarige autolening aanvraagt met een jaarlijkse rente van 7% en een leenbedrag van $30.000, kan een PMT-formule u vertellen wat uw maandelijkse betalingen zullen zijn.

Voor een correcte werking van de PMT-functie in uw werkbladen moet u rekening houden met de volgende feiten:

• Om in overeenstemming te zijn met het algemene cashflowmodel wordt het betalingsbedrag uitgevoerd als een negatief getal omdat het een kasuitstroom is.
• De door de PMT-functie teruggegeven waarde omvat principal en rente maar omvat geen kosten, belastingen of reservebetalingen die aan een lening verbonden kunnen zijn.
• Een PMT-formule in Excel kan een leningbetaling berekenen voor verschillende betalingsfrequenties, zoals wekelijks , maandelijks , driemaandelijks of jaarlijks Dit voorbeeld laat zien hoe het correct moet.

De PMT-functie is beschikbaar in Excel voor Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 en Excel 2007.

Excel PMT-functie - syntaxis en basisgebruik

De PMT-functie heeft de volgende argumenten:

Waar:

• Beoordeel (vereist) - de constante rentevoet per periode. Kan als percentage of als decimaal getal worden opgegeven.

  Bijvoorbeeld, als u jaarlijks betalingen op een lening met een jaarlijkse rentevoet van 10%, gebruik 10% of 0,1 voor de rentevoet. Als u maandelijks betalingen op dezelfde lening, gebruik dan 10%/12 of 0,00833 voor het tarief.

• Nper (vereist) - het aantal betalingen voor de lening, d.w.z. het totale aantal perioden waarover de lening moet worden betaald.

  Bijvoorbeeld, als u jaarlijks betalingen op een lening van 5 jaar, geef 5 voor nper. Als u maandelijks betalingen op dezelfde lening, vermenigvuldig dan het aantal jaren met 12, en gebruik 5*12 of 60 voor nper.

• Pv (vereist) - de contante waarde, d.w.z. het totale bedrag dat alle toekomstige betalingen nu waard zijn. In het geval van een lening is dit gewoon het oorspronkelijk geleende bedrag.
• Fv (facultatief) - de toekomstige waarde, of het kassaldo dat u wilt hebben nadat de laatste betaling is verricht. Indien weggelaten, wordt aangenomen dat de toekomstige waarde van de lening nul (0) is.
• Type (facultatief) - specificeert wanneer de betalingen verschuldigd zijn:
  • 0 of weggelaten - de betalingen zijn verschuldigd aan het einde van elke periode.
  • 1 - de betalingen zijn verschuldigd aan het begin van elke periode.

Als u bijvoorbeeld $100.000 leent voor 5 jaar met een jaarlijkse rentevoet van 7%, berekent de volgende formule de jaarlijkse betaling :

=PMT(7%, 5, 100000)

Om de maandelijkse betaling voor dezelfde lening, gebruik deze formule:

=PMT(7%/12, 5*12, 100000)

Of u kunt de bekende componenten van een lening in afzonderlijke cellen invoeren en naar die cellen verwijzen in uw PMT-formule. Met de rentevoet in B1, het aantal jaren in B2 en het bedrag van de lening in B3 is de formule zo eenvoudig:

=PMT(B1, B2, B3)

Vergeet niet dat de betaling wordt teruggestuurd als een negatief getal omdat dit bedrag van uw bankrekening zal worden afgeschreven.

Standaard geeft Excel het resultaat weer in de Valuta formaat, afgerond op 2 decimalen, rood gemarkeerd en tussen haakjes, zoals in het linkerdeel van onderstaande afbeelding. De afbeelding rechts toont hetzelfde resultaat in het Algemeen formaat.

Als u de betaling als een positief nummer zet een minteken vóór ofwel de hele PMT-formule ofwel de pv argument (bedrag van de lening):

=-PMT(B1, B2, B3)

of

=PMT(B1, B2, -B3)

Tip. Om de totaalbedrag betaald voor de lening, vermenigvuldig dan de teruggegeven PMT-waarde met het aantal perioden (nper waarde). In ons geval zouden we deze vergelijking gebruiken: 24.389,07*5 en vinden dat het totale bedrag gelijk is aan $121.945,35.

Hoe de PMT-functie gebruiken in Excel - formulevoorbeelden

Hieronder vindt u nog een paar voorbeelden van een Excel PMT-formule die laten zien hoe u verschillende periodieke betalingen voor een autolening, woninglening, hypotheeklening en dergelijke kunt berekenen.

Volledige vorm van PMT-functie in Excel

Voor het grootste deel kunt u de laatste twee argumenten in uw PMT-formules weglaten (zoals we in de bovenstaande voorbeelden hebben gedaan) omdat hun standaardwaarden de meest typische gebruiksgevallen dekken:

• Fv weggelaten - impliceert nulsaldo na de laatste betaling.
• Type weggelaten - betalingen zijn verschuldigd op de eind van elke periode.

Als uw leningsvoorwaarden anders zijn dan de wanbetalingen, gebruik dan de volledige vorm van de PMT-formule.

Laten we als voorbeeld het bedrag berekenen van jaarlijkse betalingen gebaseerd op deze ingangscellen:

• B1 - jaarlijkse rentevoet
• B2 - looptijd van de lening (in jaren)
• B3 - bedrag van de lening
• B4 - toekomstige waarde (saldo na de laatste betaling)
• B5 - lijfrentetype:
  • 0 (gewone annuïteit) - betalingen worden aan het eind van elk jaar gedaan.
  • 1 (verschuldigde annuïteit) - betalingen worden gedaan aan het begin van de periode, bv. huur of leasebetalingen.

Geef deze referenties aan uw Excel PMT-formule:

=PMT(B1, B2, B3, B4, B5)

En je krijgt dit resultaat:

Berekenen van wekelijkse, maandelijkse, driemaandelijkse en halfjaarlijkse betalingen

Afhankelijk van de betalingsfrequentie moet u de volgende berekeningen gebruiken voor tarief en nper argumenten:

• Voor tarief deel de jaarlijkse rentevoet door het aantal betalingen per jaar (dat geacht wordt gelijk te zijn aan het aantal samengestelde perioden).
• Voor nper vermenigvuldig het aantal jaren met het aantal betalingen per jaar.

De onderstaande tabel bevat de details:

Om bijvoorbeeld het bedrag van een periodieke betaling te vinden voor een lening van $5.000 met een jaarlijkse rentevoet van 8% en een looptijd van 3 jaar, gebruikt u een van de onderstaande formules.

Wekelijks betaling:

=PMT(8%/52, 3*52, 5000)

Maandelijks betaling:

=PMT(8%/12, 3*12, 5000)

Driemaandelijks betaling:

=PMT(8%/4, 3*4, 5000)

Halfjaarlijks betaling:

=PMT(8%/2, 3*2, 5000)

In alle gevallen wordt het saldo na de laatste betaling geacht $0 te zijn, en zijn de betalingen aan het eind van elke periode verschuldigd.

Het onderstaande screenshot toont de resultaten van deze formules:

Hoe maak je een PMT-calculator in Excel?

Voordat je geld gaat lenen, is het logisch dat je verschillende leningsvoorwaarden vergelijkt om uit te zoeken welke opties het beste bij je passen. Laten we daarvoor onze eigen Excel lening betalingscalculator maken.

1. Om te beginnen voert u het bedrag, de rentevoet en de looptijd van de lening in afzonderlijke cellen in (respectievelijk B3, B4 en B5).
2. Om verschillende periodes te kunnen kiezen en aan te geven wanneer de betalingen verschuldigd zijn, maakt u keuzelijsten met de volgende voorgedefinieerde opties (B6 en B7):

   

3. Stel de opzoektabellen in voor Periodes (E2:F6) en Betalingen zijn verschuldigd (E8:F9) zoals in onderstaande schermafbeelding. Het is belangrijk dat de tekstlabels in de opzoektabellen precies overeenkomen met de items van de corresponderende keuzelijst.

   Voer in de cellen naast de keuzelijsten de volgende IFERROR VLOOKUP formules in die het getal uit de opzoektabel halen dat overeenkomt met het in de keuzelijst geselecteerde item.

   Formule voor Periodes (C6):

   =IFERROR(VLOOKUP(B6, E2:F6, 2, 0), "")

   Formule voor Betalingen zijn verschuldigd (C7):

   =IFERROR(VLOOKUP(B7, E8:F9, 2, 0), "")

   

   Zie ook: AutoFill gebruiken in Excel
4. Schrijf een PMT-formule om de periodieke betaling te berekenen op basis van uw cellen. In ons geval gaat de formule als volgt:

   =IFERROR(-PMT(B4/C6, B5*C6, B3, 0, C7), "")

   Let op de volgende dingen:

   • De fv argument (0) is hard gecodeerd in de formule omdat wij altijd een nulsaldo willen na de laatste betaling. Indien u uw gebruikers wilt toestaan een willekeurige toekomstige waarde in te voeren, wijs dan een aparte invoercel toe voor het argument fv.
   • De PMT-functie wordt voorafgegaan door het minteken om het resultaat weer te geven als een positief getal .
   • De PMT-functie is verpakt in IFERROR om fouten te verbergen wanneer sommige invoerwaarden niet gedefinieerd zijn.

   De bovenstaande formule komt in B9. En in de aangrenzende cel (A9) tonen we een label dat overeenkomt met de geselecteerde periode (B6). Hiervoor hoeft u alleen maar de waarde in B6 en de gewenste tekst aan elkaar te rijgen:

   =B6&" Betaling"

   

5. Tenslotte kunt u de opzoektabellen aan het zicht onttrekken, de opmaak afwerken en uw Excel PMT-rekenmachine is klaar voor gebruik:

   

Excel PMT functie werkt niet

Als uw Excel PMT-formule niet werkt of verkeerde resultaten oplevert, heeft dat waarschijnlijk de volgende redenen:

• Er kan een #NUM! fout optreden als de tarief argument een negatief getal is of nper is gelijk aan 0.
• Er treedt een #VALUE! fout op indien één of meer argumenten tekstwaarden zijn.
• Als het resultaat van een PMT-formule veel hoger of lager is dan verwacht, moet u ervoor zorgen dat u de eenheden die voor de tarief en nper argumenten, wat betekent dat u de jaarlijkse rente correct hebt omgezet in de rente van de periode en het aantal jaren in weken, maanden of kwartalen, zoals in dit voorbeeld.

Dat is hoe je de PMT-functie berekent in Excel. Om de formules die in deze tutorial worden besproken nader te bekijken, kun je hieronder onze voorbeeldwerkmap downloaden. Ik dank je voor het lezen en hoop je volgende week op onze blog te zien!

Praktijk werkboek om te downloaden

PMT-formule in Excel - voorbeelden (.xlsx-bestand)