De tutorial lit sjen hoe't jo de PMT-funksje yn Excel brûke om betellingen te berekkenjen foar in liening of ynvestearring basearre op it rintepersintaazje, it oantal betellingen en it totale lieningsbedrach.

Foardat jo liene jild it is goed om te witten hoe't in liening wurket. Mei tank oan de finansjele funksjes fan Excel lykas RATE, PPMT en IPMT, is it berekkenjen fan 'e moanlikse of elke oare periodike betelling foar in liening maklik. Yn dit lesboek sille wy de PMT-funksje tichterby besjen, de syntaksis yn detail beprate, en sjen litte hoe't jo jo eigen PMT-rekkenmasine yn Excel bouwe kinne.

Wat is de PMT-funksje yn Excel?

De Excel PMT-funksje is in finansjele funksje dy't de betelling foar in liening berekkent op basis fan in konstante rinte, it oantal perioaden en it lienbedrach.

"PMT" stiet foar "betelling", fandêr de namme fan de funksje.

As jo ​​bygelyks in twajierrige autoliening oanfreegje mei in jierlikse rinte fan 7% en it lieningsbedrach fan $30.000, kin in PMT-formule fertelle jo wat jo moanlikse betellingen sille wêze.

Om de PMT-funksje goed te wurkjen yn jo wurkblêden, hâld dizze feiten yn gedachten:

• Om yn oerienstimming te wêzen mei de algemiene cashflow model, wurdt it betellingsbedrach as negatyf getal útfierd, om't it in cashútstream is.
• De wearde weromjûn troch de PMT-funksje omfettet haad en rinte mar omfiemet gjin fergoedings, belestingen, of reserve pa jam datkin wurde assosjearre mei in liening.
• In PMT-formule yn Excel kin in lieningsbetelling berekkenje foar ferskate betellingsfrekwinsjes lykas wykliks , moanliks , fjirdeliks , of jierliks . Dit foarbyld lit sjen hoe't jo it goed dwaan kinne.

De PMT-funksje is beskikber yn Excel foar Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 en Excel 2007.

Excel PMT-funksje - syntaksis en basisgebrûk

De PMT-funksje hat de folgjende arguminten:

Wêr:

• Rate (ferplicht) - de konstante rinte per perioade. Kin wurde levere as persintaazje of desimaal nûmer.

  As jo ​​bygelyks jierlikse betellingen meitsje op in liening mei in jierlikse rinte fan 10 prosint, brûk dan 10% of 0,1 foar taryf. As jo ​​ moanlikse betellingen meitsje op deselde liening, brûk dan 10%/12 of 0,00833 foar taryf.

• Nper (ferplicht) - it oantal betellingen foar de liening, dus it totale oantal perioaden wêryn't de liening betelle wurde moat.

  Bygelyks, as jo meitsje jierlikse betellingen op in 5-jierrige liening, leverje 5 foar nper. As jo ​​ moanlikse betellingen meitsje op deselde liening, fermannichfâldigje dan it oantal jierren mei 12, en brûk 5 * 12 of 60 foar nper.

• Pv (ferplicht) - de hjoeddeiske wearde, dus it totale bedrach dat alle takomstige betellingen no wurdich binne. Yn gefal fan in liening is it gewoan it orizjinele liende bedrach.
• Fv (opsjoneel) - de takomstige wearde, as it cashsaldo dat jo wolle hawwe neidat de lêste betelling is makke. As it weilitten wurdt, wurdt oannommen dat de takomstige wearde fan 'e liening nul (0) is.
• Type (opsjoneel) - spesifisearret wannear't de betellingen ferskuldige binne:
  • 0 of weilitten - betellingen binne oan 'e ein fan elke perioade.
  • 1 - betellingen binne oan it begjin fan elke perioade.

As jo ​​bygelyks liene $100.000 foar 5 jier mei in jierlikse rinte fan 7%, de folgjende formule sil de jierlikse betelling berekkenje:

=PMT(7%, 5, 100000)

Om de moanlikse betelling te finen foar deselde liening, brûk dizze formule:

=PMT(7%/12, 5*12, 100000)

Of jo kinne de bekende komponinten fan in liening yn aparte sellen ynfiere en ferwize nei dy sellen yn jo PMT-formule. Mei de rinte yn B1, nr. fan jierren yn B2, en lieningsbedrach yn B3, de formule is sa ienfâldich as dit:

=PMT(B1, B2, B3)

Tink derom dat de betelling wurdt weromjûn as in negatyf getal om't dit bedrach wurdt debitearre (ôfrekkene) fan jo bankrekken.

Standert lit Excel it resultaat sjen yn it Jilda -formaat, ôfrûn op 2 desimale plakken, read markearre en tusken heakjes , lykas werjûn yn it linker diel fan 'e ôfbylding hjirûnder. De ôfbylding rjochts lit itselde resultaat sjen yn it Algemien -formaat.

As jo ​​de betelling as posityf hawwe wolle nûmer , set in minteken foar beidede folsleine PMT-formule of it pv -argumint (lieningsbedrach):

=-PMT(B1, B2, B3)

of

=PMT(B1, B2, -B3)

Tip. Om it totale bedrach te berekkenjen foar de liening, fermannichfâldigje de weromjûne PMT-wearde mei it oantal perioaden (nper wearde). Yn ús gefal soene wy ​​dizze fergeliking brûke: 24.389.07*5 en fine dat it totale bedrach gelyk is oan $121.945.35.

Hoe kinne jo PMT-funksje brûke yn Excel - formulefoarbylden

Hjirûnder fine jo in in pear mear foarbylden fan in Excel PMT-formule dy't sjen litte hoe't jo ferskate periodike betellingen kinne berekkenje foar in autoliening, hûsliening, hypoteekliening, en sa.

Folsleine foarm fan PMT-funksje yn Excel

Foar it grutste part kinne jo de lêste twa arguminten yn jo PMT-formules weilitte (lykas wy diene yn 'e boppesteande foarbylden), om't har standertwearden de meast typyske gebrûksgefallen dekke:

• Fv weilitten - ymplisearret nul saldo nei de lêste betelling.
• Type weilitten - betellingen binne te beteljen oan it ein fan elke perioade.

As jo ​​lieningsbetingsten oars binne fan 'e standert, brûk dan de folsleine foarm fan PMT-formule.

Litte wy as foarbyld it bedrach fan jierlikse betellingen berekkenje basearre op dizze ynfiersellen:

• B1 - jierlikse rinte
• B2 - lieningstermyn (yn jierren)
• B3 - lienbedrach
• B4 - takomstwearde (saldo nei de lêste betelling)
• B5 - annuïteitstype:
  • 0 (gewoane annuïteit) - betellingen wurde makke oan it ein fan elkjier.
  • 1 (ferskuldige annuïteit) - betellingen wurde makke oan it begjin fan 'e perioade, bgl. hier- of leasebetellingen.

Foar dizze ferwizings nei jo Excel PMT-formule:

=PMT(B1, B2, B3, B4, B5)

En jo sille dit resultaat hawwe:

Berekkenje wyklikse, moanlikse, fearnsjierlike en semi-jierlikse betellingen

Ofhinklik fan 'e betellingsfrekwinsje moatte jo de folgjende berekkeningen brûke foar taryf en nper arguminten:

• Foar rate , diel de jierlikse rinte troch it oantal betellingen per jier (dat wurdt achte gelyk te wêzen oan it oantal gearstalde perioaden).
• Foar nper , fermannichfâldigje it oantal jierren mei it oantal betellingen per jier.

De ûndersteande tabel jout de details :

Om bygelyks it bedrach fan in periodike betelling te finen op in liening fan $5.000 mei in jierlikse rinte fan 8% en in doer fan 3 jier, brûk ien fan 'e ûndersteande formules.

Wyklikse betelling:

=PMT(8%/52, 3*52, 5000)

Moanlikse betelling:

=PMT(8%/12, 3*12, 5000)

Kwartaal betelling:

=PMT(8%/4, 3*4, 5000)

Haljierliks betelling:

=PMT(8%/2, 3*2, 5000)

Yn alle gefallen wurdt oannommen dat it saldo nei de lêste betelling $0 is, en de betellingen binne oan it ein fan elke perioade te beteljen.

De skermôfbylding hjirûnder lit de resultaten fan dizze formules sjen:

Hoe kinne jo in PMT-rekkenmasine meitsje yn Excel

Foardat jo trochgean en jild liene, is it fanselssprekkend om ferskate lieningsbetingsten te fergelykjen om de opsjes te finen dy't it meast by jo passe. Litte wy hjirfoar ús eigen rekkenmasine foar Excel-liening betelje.

1. Om te begjinnen, fier it lieningsbedrach, rinte en lieningstermyn yn aparte sellen yn (resp. B3, B4, B5).
2. Om ferskate perioaden te kinnen kieze en oan te jaan wannear't de betellingen ferfalle binne, meitsje dellûklisten mei de folgjende foarôf definieare opsjes (B6 en B7):

   

3. Stel de opsyktabellen yn foar Perioden (E2: F6) en Betellingen binne due (E8: F9) lykas werjûn yn 'e skermôfbylding hjirûnder. It is wichtich dat tekstlabels yn de opsyktabellen krekt oerienkomme mei de items fan de oerienkommende útklaplist.

   Yn de sellen njonken de dellûklisten, fier de folgjende IFERROR VLOOKUP-formules yn dy't it nûmer út it opsykjen sille lûke tabel dy't oerienkomt mei it item selektearre yn it útklapmenu.

   Formule foar Perioden (C6):

   =IFERROR(VLOOKUP(B6, E2:F6, 2, 0), "")

   Formule foar Betellingen binne due (C7):

   =IFERROR(VLOOKUP(B7, E8:F9, 2, 0), "")

   

4. Skriuw in PMT-formule om de periodike betelling te berekkenjen basearre op jo sellen. Yn úsgefal, de formule giet as folget:

   =IFERROR(-PMT(B4/C6, B5*C6, B3, 0, C7), "")

   Let op de folgjende dingen:

   • It fv argumint (0) is hardcoded yn de formule om't wy altyd wolle nul lykwicht nei de lêste betelling. As jo ​​wolle dat jo brûkers in takomstige wearde ynfiere wolle, jou dan in aparte ynfiersel foar it fv-argumint ta.
   • De PMT-funksje wurdt foarôfgien mei it minteken om it resultaat as in posityf getal wer te jaan .
   • De PMT-funksje is ferpakt yn IFERROR om flaters te ferbergjen as guon ynfierwearden net definieare binne.

   De boppesteande formule giet yn B9. En yn 'e oanbuorjende sel (A9) litte wy in label sjen dat oerienkomt mei de selektearre perioade (B6). Ferbine hjirfoar gewoan de wearde yn B6 en de winske tekst:

   =B6&" Payment"

   

5. Uteinlik kinne jo de opsyktabellen út it sicht ferbergje, foegje in pear finishing opmaak oan, en jo Excel PMT rekkenmasine is goed om te gean:

   

Excel PMT-funksje wurket net

As jo ​​Excel PMT formule wurket net of produsearret ferkearde resultaten, it is wierskynlik om de folgjende redenen:

• A #NUM! flater kin foarkomme as it argumint rate in negatyf getal is of as nper gelyk is oan 0.
• A #VALUE! flater komt foar as ien of mear arguminten tekstwearden binne.
• As it resultaat fan in PMT-formule folle heger of leger is as ferwachte, soargje derfoar dat jo konsekwint binne mei de ienheden dy't levere binne foar de taryf en nper arguminten, wat betsjut dat jo de jierlikse rinte korrekt hawwe omsetten nei it taryf fan 'e perioade en it oantal jierren nei wiken, moannen of kertieren lykas werjûn yn dit foarbyld.

Dat is hoe't jo de PMT-funksje berekkenje yn Excel. Om de formules dy't yn dizze tutorial besprutsen binne tichterby te besjen, binne jo wolkom om ús foarbyldwurkboek hjirûnder te downloaden. Ik tankje jo foar it lêzen en hoopje jo nije wike op ús blog te sjen!

Oefeningswurkboek foar download

PMT-formule yn Excel - foarbylden(.xlsx-bestân)