В урока е показано как да използвате функцията PMT в Excel, за да изчислите плащанията по заем или инвестиция въз основа на лихвения процент, броя на плащанията и общата сума на заема.

Преди да вземете пари назаем, е добре да знаете как работи един заем. Благодарение на финансовите функции на Excel, като RATE, PPMT и IPMT, изчисляването на месечната или всяка друга периодична вноска за заем е лесно. В този урок ще разгледаме по-подробно функцията PMT, ще обсъдим подробно синтаксиса ѝ и ще покажем как да създадете свой собствен калкулатор за PMT в Excel.

Какво представлява функцията PMT в Excel?

Функцията PMT на Excel е финансова функция, която изчислява вноската по даден заем въз основа на постоянен лихвен процент, броя на периодите и сумата на заема.

"PMT" означава "плащане", откъдето идва и името на функцията.

Например, ако кандидатствате за двугодишен заем за автомобил с годишен лихвен процент от 7% и размер на заема от 30 000 USD, формулата PMT може да ви покаже какви ще бъдат месечните ви вноски.

За да работи правилно функцията PMT във вашите работни листове, моля, имайте предвид следните факти:

• За да съответства на общия модел на паричните потоци, сумата на плащането се извежда като отрицателно число защото това е паричен поток.
• Стойността, върната от функцията PMT, включва Основен и лихва но не включва никакви такси, данъци или резервни плащания, които могат да бъдат свързани с даден заем.
• Формулата PMT в Excel може да изчисли вноската по заема за различни периоди на плащане, като например седмично , месечно , тримесечно , или годишно Този пример показва как да го направите правилно.

Функцията PMT е налична в Excel за Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 и Excel 2007.

Функция PMT на Excel - синтаксис и основни приложения

Функцията PMT има следните аргументи:

Къде:

• Оценка (задължително) - постоянният лихвен процент за период. Може да се посочи като процент или десетично число.

  Например, ако направите годишен плащания по заем с годишен лихвен процент от 10%, използвайте 10% или 0,1 за процент. месечно плащания по същия заем, използвайте 10%/12 или 0,00833 за лихвен процент.

• Nper (задължително) - броят на плащанията по заема, т.е. общият брой периоди, през които следва да се изплаща заемът.

  Например, ако направите годишен плащания по 5-годишен заем, въведете 5 за nper. Ако правите месечно вноски по един и същ заем, след това умножете броя на годините по 12 и използвайте 5*12 или 60 за nper.

• Pv (задължително) - настоящата стойност, т.е. общата сума, която всички бъдещи плащания струват сега. В случай на заем това е просто първоначалната сума на заема.
• Fv (по избор) - бъдещата стойност или паричното салдо, което желаете да имате след извършване на последното плащане. Ако не се посочи, бъдещата стойност на заема се приема за нула (0).
• Тип (по избор) - посочва кога са дължими плащанията:
  • 0 или пропуснато - плащанията са дължими в края на всеки период.
  • 1 - плащанията са дължими в началото на всеки период.

Например, ако вземете назаем 100 000 USD за 5 години с годишен лихвен процент от 7%, следната формула ще изчисли годишно плащане :

=PMT(7%, 5, 100000)

За да намерите месечно плащане за един и същ заем, използвайте тази формула:

=PMT(7%/12, 5*12, 100000)

Или можете да въведете известните компоненти на заема в отделни клетки и да се позовавате на тези клетки във формулата за PMT. С лихвения процент в B1, броя на годините в B2 и сумата на заема в B3, формулата е толкова проста, колкото тази:

=PMT(B1, B2, B3)

Моля, не забравяйте, че плащането се връща като отрицателно число защото тази сума ще бъде дебитирана (извадена) от банковата ви сметка.

По подразбиране Excel показва резултата в Валута формат, закръглени до 2 знака след десетичната запетая, подчертани в червено и оградени в скоби, както е показано в лявата част на изображението по-долу. Изображението вдясно показва същия резултат в Обща информация формат.

Ако искате да получите плащането като положителен номер , поставете знак минус пред цялата формула PMT или пред pv аргумент (размер на заема):

=-PMT(B1, B2, B3)

или

=PMT(B1, B2, -B3)

Съвет. За да изчислите обща сума платени за заема, умножете върнатата стойност на PMT по броя на периодите (nper value). В нашия случай ще използваме това уравнение: 24 389,07*5 и ще установим, че общата сума е равна на 121 945,35 USD.

Как да използвате функцията PMT в Excel - примери за формули

По-долу ще намерите още няколко примера за формула PMT на Excel, които показват как да се изчислят различни периодични плащания за заем за кола, жилищен заем, ипотечен заем и други подобни.

Пълна форма на функцията PMT в Excel

В по-голямата си част можете да пропуснете последните два аргумента във формулите на PMT (както направихме в горните примери), тъй като техните стойности по подразбиране покриват най-типичните случаи на използване:

• Fv пропуснат - предполага нулев баланс след последното плащане.
• Тип пропуснати - плащанията са дължими на край на всеки период.

Ако условията по вашия заем са различни от тези при неизпълнение, използвайте пълната форма на формулата PMT.

Като пример, нека изчислим сумата на годишни плащания въз основа на тези входни клетки:

• B1 - годишен лихвен процент
• B2 - срок на заема (в години)
• B3 - размер на заема
• B4 - бъдеща стойност (баланс след последното плащане)
• B5 - тип анюитет:
  • 0 (редовен анюитет) - плащанията се извършват в края на всяка година.
  • 1 (дължима анюитетна вноска) - плащанията се извършват в началото на периода, напр. наемни или лизингови плащания.

Добавете тези препратки към формулата PMT на Excel:

=PMT(B1, B2, B3, B4, B5)

И ще получите този резултат:

Изчисляване на седмични, месечни, тримесечни и полугодишни плащания

В зависимост от честотата на плащане трябва да използвате следните изчисления за ставка и nper аргументи:

• За ставка , разделете годишния лихвен процент на броя на плащанията за година (който се счита за равен на броя на периодите на натрупване).
• За nper , умножете броя на годините по броя на плащанията на година.

В таблицата по-долу са дадени подробности:

Например, за да определите размера на периодичната вноска по заем от 5000 USD с годишен лихвен процент 8% и срок на погасяване 3 години, използвайте една от следните формули.

Седмичен плащане:

=PMT(8%/52, 3*52, 5000)

Месечно плащане:

=PMT(8%/12, 3*12, 5000)

Тримесечно плащане:

=PMT(8%/4, 3*4, 5000)

Полугодишно плащане:

=PMT(8%/2, 3*2, 5000)

Във всички случаи се приема, че балансът след последното плащане е 0 USD, а плащанията са дължими в края на всеки период.

Снимката на екрана по-долу показва резултатите от тези формули:

Как да направите PMT калкулатор в Excel

Преди да вземете пари назаем, е логично да сравните различните условия по кредита, за да откриете най-подходящите за вас варианти. За тази цел нека създадем собствен калкулатор на вноските по кредита в Excel.

1. Първо въведете сумата на заема, лихвения процент и срока на заема в отделни клетки (съответно B3, B4 и B5).
2. За да можете да избирате различни периоди и да определяте кога са дължими плащанията, създайте падащи списъци със следните предварително зададени опции (B6 и B7):

   

3. Настройка на таблиците за търсене за Периоди (E2:F6) и Плащанията са дължими (E8:F9), както е показано на екранната снимка по-долу. Важно е текстовите етикети в таблиците за търсене да съответстват точно на елементите от съответния падащ списък.

   В клетките до падащите списъци въведете следните IFERROR VLOOKUP формули, които ще изтеглят числото от таблицата за търсене, съответстващо на избрания елемент в падащия списък.

   Формула за Периоди (C6):

   =IFERROR(VLOOKUP(B6, E2:F6, 2, 0), "")

   Формула за Плащанията са дължими (C7):

   =IFERROR(VLOOKUP(B7, E8:F9, 2, 0), "")

   

4. Напишете PMT формула за изчисляване на периодичното плащане въз основа на вашите клетки. В нашия случай формулата е следната:

   =IFERROR(-PMT(B4/C6, B5*C6, B3, 0, C7), "")

   Обърнете внимание на следните неща:

   • Сайтът fv аргументът (0) е твърдо кодиран във формулата, тъй като винаги искаме нулев баланс след последното плащане. В случай че искате да позволите на потребителите си да въвеждат всяка бъдеща стойност, отделете отделна клетка за въвеждане на аргумента fv.
   • Функцията PMT се предшества от знака минус, за да се покаже резултатът като положително число .
   • Функцията PMT е обвита в IFERROR, за да се скрият грешките, когато някои входни стойности не са дефинирани.

   Горната формула се записва в B9. А в съседната клетка (A9) показваме етикет, съответстващ на избрания период (B6). За тази цел просто конкатенирайте стойността в B6 и желания текст:

   =B6&" Плащане"

   

5. Накрая можете да скриете таблиците за търсене от погледа, да добавите няколко финални щрихи за форматиране и вашият PMT калкулатор на Excel е готов за работа:

   

Функцията PMT на Excel не работи

Ако вашата формула за PMT в Excel не работи или дава грешни резултати, това вероятно се дължи на следните причини:

• Грешка #NUM! може да възникне, ако ставка е отрицателно число или nper е равно на 0.
• Грешка #VALUE! се появява, ако един или повече аргументи са текстови стойности.
• Ако резултатът от формулата за PMT е много по-висок или по-нисък от очаквания, уверете се, че сте се съобразили с предоставените единици за ставка и nper аргументи, което означава, че правилно сте преобразували годишния лихвен процент в лихвен процент за периода, а броя на годините - в седмици, месеци или тримесечия, както е показано в този пример.

Ето как се изчислява функцията PMT в Excel. За да разгледате по-отблизо формулите, разгледани в този урок, можете да изтеглите нашата примерна работна книга по-долу. Благодаря ви, че прочетохте, и се надявам да се видим в нашия блог следващата седмица!

Практическа работна тетрадка за изтегляне

PMT формула в Excel - примери(.xlsx файл)