I handledningen visas hur du använder PMT-funktionen i Excel för att beräkna betalningar för ett lån eller en investering baserat på ränta, antal betalningar och det totala lånebeloppet.

Innan du lånar pengar är det bra att veta hur ett lån fungerar. Tack vare de finansiella Excel-funktionerna RATE, PPMT och IPMT är det enkelt att beräkna månadsbetalningen eller någon annan periodisk betalning för ett lån. I den här handledningen tittar vi närmare på PMT-funktionen, diskuterar dess syntax i detalj och visar hur du bygger din egen PMT-kalkylator i Excel.

Vad är PMT-funktionen i Excel?

Excel-funktionen PMT är en finansiell funktion som beräknar betalningen för ett lån baserat på en konstant ränta, antalet perioder och lånebeloppet.

"PMT" står för "betalning", därav funktionens namn.

Om du till exempel ansöker om ett tvåårigt billån med en årlig ränta på 7 % och ett lånebelopp på 30 000 dollar kan en PMT-formel ange hur stora dina månadsbetalningar kommer att bli.

För att PMT-funktionen ska fungera korrekt i dina kalkylblad ska du komma ihåg följande fakta:

• För att vara i linje med den allmänna kassaflödesmodellen, anges betalningsbeloppet som en negativt tal eftersom det är ett utflöde av pengar.
• Det värde som returneras av PMT-funktionen omfattar huvudman och ränta men inkluderar inte eventuella avgifter, skatter eller reservbetalningar som kan vara förknippade med ett lån.
• En PMT-formel i Excel kan beräkna en lånebetalning för olika betalningsfrekvenser, t.ex. veckovis , månadsvis , kvartalsvis , eller årligen Det här exemplet visar hur du gör det på rätt sätt.

PMT-funktionen finns i Excel för Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 och Excel 2007.

Excel PMT-funktion - syntax och grundläggande användningsområden

PMT-funktionen har följande argument:

Var:

• Räkna med (obligatoriskt) - den konstanta räntesatsen per period. Kan anges i procent eller som decimaltal.

  Om du till exempel gör årligen betalningar på ett lån med en årlig ränta på 10 procent, använd 10 % eller 0,1 för ränta. Om du betalar månadsvis betalningar på samma lån, använd då 10 %/12 eller 0,00833 som ränta.

• Nper (obligatoriskt) - antalet betalningar för lånet, dvs. det totala antalet perioder under vilka lånet ska betalas.

  Om du till exempel gör årligen betalningar på ett lån på 5 år, ange 5 för nper. Om du gör månadsvis betalningar på samma lån, multiplicera sedan antalet år med 12 och använd 5*12 eller 60 för nper.

• Pv (krävs) - nuvärdet, dvs. det totala belopp som alla framtida betalningar är värda nu. När det gäller ett lån är det helt enkelt det ursprungliga lånade beloppet.
• Fv (valfritt) - det framtida värdet, eller det kontantsaldo som du vill ha efter den sista betalningen. Om det inte anges antas lånets framtida värde vara noll (0).
• Typ (valfritt) - anger när betalningarna ska göras:
  • 0 eller utelämnas - betalningarna förfaller i slutet av varje period.
  • 1 - Betalningarna ska ske i början av varje period.

Om du till exempel lånar 100 000 dollar på 5 år med en årlig ränta på 7 %, beräknas följande formel för att beräkna årlig utbetalning :

=PMT(7%, 5, 100000)

För att hitta den månadsbetalning för samma lån, använd denna formel:

=PMT(7%/12, 5*12, 100000)

Du kan också ange de kända komponenterna i ett lån i separata celler och hänvisa till dessa celler i din PMT-formel. Med räntesatsen i B1, antalet år i B2 och lånebeloppet i B3 är formeln så här enkel som möjligt:

=PMT(B1, B2, B3)

Kom ihåg att betalningen returneras som en negativt tal eftersom detta belopp kommer att debiteras (dras) från ditt bankkonto.

Som standard visar Excel resultatet i fältet Valuta formatet, avrundat till två decimaler, markerat med rött och inom parentes, vilket visas i den vänstra delen av bilden nedan. Bilden till höger visar samma resultat i formatet Allmänt format.

Om du vill ha betalningen som en positiv nummer , sätta ett minustecken före antingen hela PMT-formeln eller före pv argument (lånebelopp):

=-PMT(B1, B2, B3)

eller .

=PMT(B1, B2, -B3)

Tips. För att beräkna totalt belopp För att få fram det belopp som betalats för lånet multiplicerar du det returnerade PMT-värdet med antalet perioder (nper-värde). I vårt fall använder vi denna ekvation: 24 389,07*5 och får fram ett totalbelopp på 121 945,35 dollar.

Hur man använder PMT-funktionen i Excel - formelexempel

Nedan hittar du ytterligare några exempel på en Excel PMT-formel som visar hur man beräknar olika periodiska betalningar för ett billån, bostadslån, hypotekslån och liknande.

Fullständig form av PMT-funktionen i Excel

För det mesta kan du utelämna de två sista argumenten i dina PMT-formler (som vi gjorde i exemplen ovan) eftersom deras standardvärden täcker de mest typiska användningsfallen:

• Fv utelämnat - innebär nollbalans efter den sista betalningen.
• Typ utelämnas - betalningarna ska betalas i samband med avsluta av varje period.

Om dina lånevillkor skiljer sig från de bristfälliga lånen ska du använda den fullständiga formen av PMT-formeln.

Som exempel kan vi beräkna mängden årliga betalningar baserat på dessa inmatningsceller:

• B1 - årlig ränta
• B2 - lånetid (i år)
• B3 - lånebelopp
• B4 - framtida värde (saldo efter den sista betalningen).
• B5 - typ av livränta:
  • 0 (vanlig livränta) - utbetalningarna görs i slutet av varje år.
  • 1 (annuitetsförfall) - betalningar görs i början av perioden, t.ex. hyra eller leasing.

Ange dessa referenser i din Excel PMT-formel:

=PMT(B1, B2, B3, B4, B5)

Du får detta resultat:

Beräkna vecko-, månads-, kvartals- och halvårsbetalningar.

Beroende på betalningsfrekvensen måste du använda följande beräkningar för att kurs och nper argument:

• För kurs , dividera den årliga räntesatsen med antalet betalningar per år (vilket anses vara lika med antalet ränteperioder).
• För nper multiplicera antalet år med antalet betalningar per år.

Nedanstående tabell innehåller detaljerna:

Om du till exempel vill hitta beloppet för en periodisk betalning på ett lån på 5 000 dollar med en årlig ränta på 8 % och en löptid på 3 år använder du en av nedanstående formler.

Veckovis betalning:

=PMT(8%/52, 3*52, 5000)

Månadsvis betalning:

=PMT(8%/12, 3*12, 5000)

Kvartalsvis betalning:

=PMT(8%/4, 3*4, 5000)

Halvårsvis betalning:

=PMT(8%/2, 3*2, 5000)

I samtliga fall antas saldot efter den sista betalningen vara 0 dollar och betalningarna ska göras i slutet av varje period.

Skärmbilden nedan visar resultatet av dessa formler:

Hur man gör en PMT-kalkylator i Excel

Innan du går vidare och lånar pengar är det rimligt att jämföra olika lånevillkor för att ta reda på vilka alternativ som passar dig bäst. För detta skapar vi vår egen Excel-lånebetalningskalkylator.

1. Till att börja med skriver du in lånebeloppet, räntan och lånetiden i separata celler (B3, B4 respektive B5).
2. För att kunna välja olika perioder och ange när betalningarna ska ske, skapar du rullgardinslistor med följande fördefinierade alternativ (B6 och B7):

   

3. Upprätta uppslagstabellerna för Perioder (E2:F6) och Betalningar förfaller till betalning (E8:F9) som visas i skärmbilden nedan. Det är viktigt att textlappar i uppslagstabellerna exakt motsvarar posterna i motsvarande rullgardinslista.

   I cellerna bredvid rullgardinslistorna anger du följande IFERROR VLOOKUP-formler som hämtar numret från uppslagstabellen som motsvarar det objekt som valts i rullgardinslistan.

   Formel för Perioder (C6):

   =IFERROR(VLOOKUP(B6, E2:F6, 2, 0), "")

   Formel för Betalningar förfaller till betalning (C7):

   =IFERROR(VLOOKUP(B7, E8:F9, 2, 0), "")

   

4. Skriv en PMT-formel för att beräkna den periodiska betalningen utifrån dina celler. I vårt fall ser formeln ut på följande sätt:

   =IFERROR(-PMT(B4/C6, B5*C6, B3, 0, C7), "")

   Observera följande saker:

   • fv argumentet (0) är hårdkodat i formeln eftersom vi alltid vill ha ett nollsaldo efter den sista betalningen. Om du vill låta användarna ange ett valfritt framtida värde kan du skapa en separat inmatningscell för fv-argumentet.
   • PMT-funktionen föregås av minustecknet för att visa resultatet som en Positivt tal. .
   • PMT-funktionen är inbakad i IFERROR för att dölja fel när vissa inmatningsvärden inte är definierade.

   Formeln ovan hamnar i B9. Och i den angränsande cellen (A9) visas en etikett som motsvarar den valda perioden (B6). För att göra detta är det bara att sammanfoga värdet i B6 och den önskade texten:

   =B6&" Betalning"

   

   Se även: Hur man förhindrar dubbla poster i Excel-kolumnen, endast unika data tillåts.
5. Slutligen kan du dölja uppslagstabellerna från insyn, lägga till några sista formateringar och din PMT-kalkylator i Excel är klar att användas:

   

Excel PMT-funktionen fungerar inte

Om din Excel PMT-formel inte fungerar eller ger felaktiga resultat beror det sannolikt på följande orsaker:

• Ett #NUM! fel kan uppstå om antingen kurs argumentet är ett negativt tal eller nper är lika med 0.
• Ett #VALUE!-fel uppstår om ett eller flera argument är textvärden.
• Om resultatet av en PMT-formel är mycket högre eller lägre än förväntat, se till att du är konsekvent med de enheter som tillhandahålls för kurs och nper argument, vilket innebär att du korrekt har omvandlat årsräntan till periodens ränta och antalet år till veckor, månader eller kvartal som i detta exempel.

Det är så du beräknar PMT-funktionen i Excel. Om du vill titta närmare på formlerna som diskuteras i den här handledningen är du välkommen att ladda ner vår exempelarbetsbok nedan. Tack för att du läste och hoppas att vi ses på vår blogg nästa vecka!

Arbetsbok för övning för nedladdning

PMT-formeln i Excel - exempel(.xlsx-fil)