El tutorial mostra com utilitzar la funció PMT a Excel per calcular els pagaments d'un préstec o d'una inversió en funció del tipus d'interès, el nombre de pagaments i l'import total del préstec.

Abans. prens diners prestats, és bo saber com funciona un préstec. Gràcies a les funcions financeres d'Excel com RATE, PPMT i IPMT, calcular el pagament mensual o qualsevol altre pagament periòdic d'un préstec és fàcil. En aquest tutorial, veurem de prop la funció PMT, parlarem de la seva sintaxi en detall i mostrarem com crear la vostra pròpia calculadora PMT a Excel.

Què és la funció PMT. a Excel?

La funció PMT d'Excel és una funció financera que calcula el pagament d'un préstec a partir d'un tipus d'interès constant, el nombre de períodes i l'import del préstec.

"PMT" significa "PMT". per "pagament", d'aquí el nom de la funció.

Per exemple, si sol·liciteu un préstec per a cotxe a dos anys amb un tipus d'interès anual del 7% i l'import del préstec de 30.000 dòlars, una fórmula PMT pot dir quins seran els vostres pagaments mensuals.

Per tal que la funció PMT funcioni correctament als vostres fulls de treball, tingueu en compte aquests fets:

• Per estar en línia amb el flux de caixa general model, l'import del pagament es mostra com a número negatiu perquè és una sortida d'efectiu.
• El valor que retorna la funció PMT inclou principal i interessos però no inclou taxes, impostos o reserva pa iment aixòpot estar associada a un préstec.
• Una fórmula PMT a Excel pot calcular un pagament del préstec per a diferents freqüències de pagament, com ara setmanal , mensual , trimestral , o anualment . Aquest exemple mostra com fer-ho correctament.

La funció PMT està disponible a Excel per a Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 i Excel 2007.

Funció PMT d'Excel: sintaxi i usos bàsics

La funció PMT té els arguments següents:

On:

• Taxa (obligatori): el tipus d'interès constant per període. Es pot proporcionar com a percentatge o nombre decimal.

  Per exemple, si feu pagaments anuals d'un préstec a un tipus d'interès anual del 10%, utilitzeu el 10% o el 0,1 per a la taxa. Si feu pagaments mensuals del mateix préstec, feu servir 10%/12 o 0,00833 per a la taxa.

• Nper (obligatori): el nombre de pagaments del préstec, és a dir, el nombre total de períodes durant els quals s'ha de pagar el préstec.

  Per exemple, si feu pagaments anuals d'un préstec a 5 anys, proporcioneu 5 per a nper. Si feu pagaments mensuals del mateix préstec, multipliqueu el nombre d'anys per 12 i utilitzeu 5*12 o 60 per a nper.

• Pv (obligatori): el valor actual, és a dir, l'import total que valen ara tots els pagaments futurs. En el cas d'un préstec, simplement és l'import original prestat.
• Fv (opcional): el valor futur o el saldo d'efectiu que voleu tenir després de fer l'últim pagament. Si s'omet, s'assumeix que el valor futur del préstec és zero (0).
• Tipus (opcional) - especifica quan s'han de pagar els pagaments:
  • 0 o omès: els pagaments s'han de pagar al final de cada període.
  • 1: els pagaments s'han de pagar al començament de cada període.

Per exemple, si Demaneu prestat 100.000 dòlars durant 5 anys amb un tipus d'interès anual del 7%, la fórmula següent calcularà el pagament anual :

=PMT(7%, 5, 100000)

Per trobar el pagament mensual per al mateix préstec, utilitzeu aquesta fórmula:

=PMT(7%/12, 5*12, 100000)

O podeu introduir els components coneguts d'un préstec en cel·les separades i fer referència a aquestes cel·les a la vostra fórmula PMT. Amb el tipus d'interès en B1, núm. d'anys a B2 i l'import del préstec a B3, la fórmula és tan senzilla com aquesta:

=PMT(B1, B2, B3)

Recordeu que el pagament es retorna com a número negatiu perquè aquest import es carregarà (se restarà) del vostre compte bancari.

Per defecte, Excel mostra el resultat en el format Moneda , arrodonit a 2 decimals, ressaltat en vermell i entre parèntesis. , tal com es mostra a la part esquerra de la imatge següent. La imatge de la dreta mostra el mateix resultat en el format General .

Si voleu que el pagament sigui positiu número , poseu un signe menys abans de qualsevol dels dostota la fórmula PMT o l'argument pv (import del préstec):

=-PMT(B1, B2, B3)

o

=PMT(B1, B2, -B3)

Consell. Per calcular l' import total pagat pel préstec, multipliqueu el valor PMT retornat pel nombre de períodes (valor nper). En el nostre cas, utilitzaríem aquesta equació: 24.389,07*5 i trobaríem que l'import total és igual a 121.945,35 $.

Com utilitzar la funció PMT a Excel - exemples de fórmules

A continuació trobareu un uns quants exemples més d'una fórmula PMT d'Excel que mostren com calcular diferents pagaments periòdics per a un préstec per a cotxe, un préstec per a la llar, un préstec hipotecari i similars.

Forma completa de la funció PMT a Excel

En la seva majoria, podeu ometre els dos últims arguments a les vostres fórmules PMT (com vam fer als exemples anteriors) perquè els seus valors predeterminats cobreixen els casos d'ús més típics:

• Fv omès: implica saldo zero després de l'últim pagament.
• Tipus omès: els pagaments s'han de pagar al final de cada període.

Si les condicions del vostre préstec són diferents de les predeterminades, feu servir la forma completa de la fórmula PMT.

Com a exemple, calculem l'import dels pagaments anuals basat en aquestes cel·les d'entrada:

• B1 - tipus d'interès anual
• B2 - termini del préstec (en anys)
• B3 - import del préstec
• B4 - valor futur (saldo després de l'últim pagament)
• B5 - tipus d'anualitat:
  • 0 (anualitat regular) - els pagaments es realitzen al final de cadascunany.
  • 1 (anualitat deguda) - els pagaments es fan a l'inici del període, p. pagaments de lloguer o lloguer.

Proporcioneu aquestes referències a la vostra fórmula PMT d'Excel:

=PMT(B1, B2, B3, B4, B5)

I obtindreu aquest resultat:

Calculeu els pagaments setmanals, mensuals, trimestrals i semestrals

Depenent de la freqüència de pagament, heu d'utilitzar els càlculs següents per a tarifa i nper :

• Per a taxa , dividiu el tipus d'interès anual pel nombre de pagaments anuals (que es considera igual a el nombre de períodes de capitalització).
• Per a nper , multipliqueu el nombre d'anys pel nombre de pagaments per any.

La taula següent proporciona els detalls. :

Per exemple, per trobar l'import d'un pagament periòdic d'un préstec de 5.000 dòlars amb un tipus d'interès anual del 8% i una durada de 3 anys, utilitzeu una de les fórmules següents.

Pagament setmanal:

=PMT(8%/52, 3*52, 5000)

Pagament mensual:

=PMT(8%/12, 3*12, 5000)

Trimestral pagament:

=PMT(8%/4, 3*4, 5000)

Semestral pagament:

=PMT(8%/2, 3*2, 5000)

En tots els casos, se suposa que el saldo després de l'últim pagament és 0 $ i els pagaments s'han de pagar al final de cada període.

El La captura de pantalla següent mostra els resultats d'aquestes fórmules:

Com fer una calculadora PMT a Excel

Abans d'avançar i demanar diners en préstec, és raonable per comparar diferents condicions de préstec per conèixer les opcions que més s'adapten. Per a això, creem la nostra pròpia calculadora de pagament de préstecs d'Excel.

1. Per començar, introduïu l'import del préstec, el tipus d'interès i el termini del préstec en cel·les separades (B3, B4, B5, respectivament).
2. Per poder triar diferents períodes i especificar quan es vencen els pagaments, creeu llistes desplegables amb les opcions predefinides següents (B6 i B7):

   

3. Configureu les taules de cerca per a Períodes (E2:F6) i S'han de pagar pagaments (E8:F9) com es mostra a la captura de pantalla següent. És important que les etiquetes de text de les taules de cerca coincideixin exactament amb els elements de la llista desplegable corresponent.

   A les cel·les que hi ha al costat de les llistes desplegables, introduïu les següents fórmules IFERROR VLOOKUP que trauran el número de la cerca taula corresponent a l'element seleccionat a la llista desplegable.

   Fórmula per a Períodes (C6):

   =IFERROR(VLOOKUP(B6, E2:F6, 2, 0), "")

   Fórmula per a Els pagaments es vencen (C7):

   =IFERROR(VLOOKUP(B7, E8:F9, 2, 0), "")

   

4. Escriu una fórmula PMT per calcular el pagament periòdic en funció de les teves cel·les. En la nostracas, la fórmula és el següent:

   =IFERROR(-PMT(B4/C6, B5*C6, B3, 0, C7), "")

   Tingueu en compte les coses següents:

   • L'argument fv (0) està codificat en dur a la fórmula perquè sempre volem un saldo zero després de l'últim pagament. En cas que vulgueu permetre que els vostres usuaris introdueixin qualsevol valor futur, assigneu una cel·la d'entrada separada per a l'argument fv.
   • La funció PMT va precedida pel signe menys per mostrar el resultat com a número positiu. .
   • La funció PMT s'embolica a IFERROR per ocultar errors quan no es defineixen alguns valors d'entrada.

   La fórmula anterior va a B9. I a la cel·la veïna (A9) mostrem una etiqueta corresponent al període seleccionat (B6). Per a això, només cal concatenar el valor de B6 i el text desitjat:

   =B6&" Payment"

   

5. Finalment, podeu ocultar les taules de cerca de la vista, afegiu uns quants tocs de format final i la vostra calculadora PMT d'Excel està a punt per començar:

   

La funció d'Excel PMT no funciona

Si el vostre PMT d'Excel La fórmula no funciona o produeix resultats incorrectes, és probable que sigui per les raons següents:

• Un #NUM! Es pot produir un error si l'argument rate és un nombre negatiu o si nper és igual a 0.
• UN #VALOR! es produeix un error si un o més arguments són valors de text.
• Si el resultat d'una fórmula PMT és molt superior o inferior a l'esperat, assegureu-vos que sou coherents amb les unitats subministrades per a laArguments taxa i nper , el que significa que heu convertit correctament el tipus d'interès anual al tipus del període i el nombre d'anys a setmanes, mesos o trimestres, tal com es mostra en aquest exemple.

Així és com es calcula la funció PMT a Excel. Per veure amb més detall les fórmules que es tracten en aquest tutorial, us convidem a descarregar el nostre quadern de treball de mostra a continuació. Us agraeixo la lectura i espero veure-us al nostre bloc la setmana vinent!

Quader de pràctiques per descarregar

Fórmula PMT a Excel - exemples (fitxer .xlsx)