Kennsla sýnir hvernig á að nota PMT aðgerð í Excel til að reikna út greiðslur fyrir lán eða fjárfestingu út frá vöxtum, fjölda greiðslna og heildarlánsupphæð.

Fyrir. þú færð lánað það er gott að vita hvernig lán virkar. Þökk sé Excel fjármálaaðgerðunum eins og RATE, PPMT og IPMT er auðvelt að reikna út mánaðarlega eða hvers kyns reglubundna greiðslu fyrir lán. Í þessari kennslu munum við skoða PMT aðgerðina nánar, ræða setningafræði hennar í smáatriðum og sýna hvernig á að búa til þína eigin PMT reiknivél í Excel.

Hvað er PMT aðgerðin í Excel?

Excel PMT fallið er fjárhagslegt fall sem reiknar út greiðslu fyrir lán út frá föstum vöxtum, fjölda tímabila og lánsfjárhæð.

"PMT" stendur fyrir "greiðslu", þar af leiðandi heiti fallsins.

Til dæmis, ef þú ert að sækja um tveggja ára bílalán með 7% ársvöxtum og lánsupphæðinni $30.000, getur PMT formúla sagt þú hverjar mánaðarlegar greiðslur þínar verða.

Til að PMT aðgerðin virki rétt í vinnublöðunum þínum skaltu hafa þessar staðreyndir í huga:

• Til að vera í samræmi við almennt sjóðstreymi líkan, er greiðsluupphæðin gefin út sem neikvæð tala vegna þess að það er peningaútstreymi.
• Gildið sem PMT fallið skilar inniheldur höfuðstóll og vextir en inniheldur ekki gjöld, skatta eða varasjóði ýms þaðgæti tengst láni.
• PMT formúla í Excel getur reiknað út greiðslu láns fyrir mismunandi greiðslutíðni eins og vikulega , mánaðarlega , fjórðungslega , eða árlega . Þetta dæmi sýnir hvernig á að gera það rétt.

PMT-aðgerðin er fáanleg í Excel fyrir Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 og Excel 2007.

Excel PMT fall - setningafræði og grunnnotkun

PMT fallið hefur eftirfarandi rök:

Hvar:

• Vextir (áskilið) - fastir vextir á tímabili. Hægt að fá sem prósentu eða aukastaf.

  Til dæmis, ef þú greiðir árlegar greiðslur af láni með 10 prósenta ársvöxtum skaltu nota 10% eða 0,1 fyrir vexti. Ef þú greiðir mánaðarlega greiðslur af sama láni, notaðu þá 10%/12 eða 0,00833 fyrir vexti.

• Nper (áskilið) - fjöldi greiðslna fyrir lánið, þ.e.a.s. heildarfjöldi tímabila sem lánið á að greiða yfir.

  Til dæmis, ef þú greiðir árlega greiðslur af 5 ára láni, gefðu upp 5 fyrir nper. Ef þú greiðir mánaðarlega greiðslur af sama láni, margfaldaðu þá fjölda ára með 12 og notaðu 5*12 eða 60 fyrir nper.

• Pv (áskilið) - núvirði, þ.e.a.s. heildarupphæðin sem allar framtíðargreiðslur eru virði núna. Ef um lán er að ræða, þá er það einfaldlega upphaflega upphæðin sem tekin var að láni.
• Fv (valfrjálst) - framtíðarvirðið eða staðan í reiðufé sem þú vilt hafa eftir að síðasta greiðsla hefur verið gerð. Ef því er sleppt er gert ráð fyrir að framtíðarvirði lánsins sé núll (0).
• Tegund (valfrjálst) - tilgreinir hvenær greiðslur eru á gjalddaga:
  • 0 eða sleppt - greiðslur eru á gjalddaga í lok hvers tímabils.
  • 1 - greiðslur eru á gjalddaga í upphafi hvers tímabils.

Til dæmis, ef þú fáðu $100.000 að láni í 5 ár með 7% ársvöxtum, eftirfarandi formúla mun reikna út ársgreiðsluna :

=PMT(7%, 5, 100000)

Til að finna mánaðargreiðsluna fyrir sama lán, notaðu þessa formúlu:

=PMT(7%/12, 5*12, 100000)

Eða þú getur slegið inn þekkta þætti láns í aðskildum hólfum og vísað til þeirra reita í PMT formúlunni þinni. Með vöxtum í B1, nr. af árum í B2 og lánsupphæð í B3, formúlan er svona einföld:

=PMT(B1, B2, B3)

Vinsamlegast mundu að greiðslan er skilað sem neikvæð tala vegna þess að þessi upphæð verður skuldfærð (dregin frá) af bankareikningnum þínum.

Sjálfgefið er að Excel birtir niðurstöðuna á Gjaldmiðli sniði, námunduð að 2 aukastöfum, auðkennd með rauðu og innan sviga , eins og sýnt er í vinstri hluta myndarinnar hér að neðan. Myndin til hægri sýnir sömu niðurstöðu í General sniðinu.

Ef þú vilt hafa greiðsluna sem jákvæða tala , settu mínusmerki fyrir annað hvortöll PMT formúlan eða pv rökin (lánsfjárhæð):

=-PMT(B1, B2, B3)

eða

=PMT(B1, B2, -B3)

Ábending. Til að reikna út heildarupphæðina sem greitt er fyrir lánið, margfaldaðu skilað PMT gildi með fjölda tímabila (nper gildi). Í okkar tilviki myndum við nota þessa jöfnu: 24.389,07*5 og komast að því að heildarupphæðin jafngildir $121.945,35.

Hvernig á að nota PMT aðgerð í Excel - formúludæmi

Hér að neðan finnurðu nokkur fleiri dæmi um Excel PMT formúlu sem sýnir hvernig á að reikna út mismunandi reglubundnar greiðslur fyrir bílalán, íbúðalán, húsnæðislán og þess háttar.

Fullt form PMT falls í Excel

Að mestu leyti geturðu sleppt síðustu tveimur rökunum í PMT formúlunum þínum (eins og við gerðum í dæmunum hér að ofan) vegna þess að sjálfgefin gildi þeirra ná yfir algengustu notkunartilvikin:

• Fv sleppt - þýðir núll staða eftir síðustu greiðslu.
• Tegund sleppt - greiðslur eru á gjalddaga í lok hvers tímabils.

Ef lánaskilmálar þínir eru frábrugðnir vanskilum skaltu nota PMT formúluna í heild sinni.

Sem dæmi skulum við reikna út upphæð árlegra greiðslna byggt á þessum inntakshólfum:

• B1 - ársvextir
• B2 - lánstími (í árum)
• B3 - lánsfjárhæð
• B4 - framtíðarvirði (staða eftir síðustu greiðslu)
• B5 - lífeyristegund:
  • 0 (venjulegur lífeyrir) - greiðslur fara fram í lok kl. hverári.
  • 1 (lífeyrir) - greiðslur fara fram í upphafi tímabils, t.d. leigu- eða leigugreiðslur.

Settu þessar tilvísanir í Excel PMT formúluna þína:

=PMT(B1, B2, B3, B4, B5)

Og þú munt fá þessa niðurstöðu:

Reiknið út vikulegar, mánaðarlegar, ársfjórðungslegar og hálfsársgreiðslur

Það fer eftir greiðslutíðni, þú þarft að nota eftirfarandi útreikninga fyrir gengi og nper rök:

• Fyrir vexti , deilið árlegum vöxtum með fjölda greiðslna á ári (sem telst jafngilda fjölda samsettra tímabila).
• Fyrir nper , margfaldaðu fjölda ára með fjölda greiðslna á ári.

Taflan hér að neðan veitir upplýsingarnar :

Til dæmis, til að finna upphæð reglubundinnar greiðslu á $5.000 láni með 8% ársvöxtum og 3 ár til lengdar skaltu nota eina af formúlunum hér að neðan.

Vikuleg greiðsla:

=PMT(8%/52, 3*52, 5000)

Mánaðarleg greiðsla:

=PMT(8%/12, 3*12, 5000)

Ársfjórðungslega greiðsla:

=PMT(8%/4, 3*4, 5000)

Hálf árleg greiðsla:

=PMT(8%/2, 3*2, 5000)

Í öllum tilfellum er gert ráð fyrir að staðan eftir síðustu greiðslu sé $0 og greiðslurnar eru á gjalddaga í lok hvers tímabils.

skjáskot hér að neðan sýnir niðurstöður þessara formúla:

Hvernig á að búa til PMT reiknivél í Excel

Áður en þú ferð að lána peninga, þá er það rökrétt að bera saman mismunandi lánaskilmála til að komast að þeim valkostum sem henta þér best. Til þess skulum við búa til okkar eigin Excel lánsreikningsreiknivél.

1. Til að byrja með skaltu slá inn lánsfjárhæð, vexti og lánstíma í aðskildum hólfum (B3, B4, B5, í sömu röð).
2. Til að geta valið mismunandi tímabil og tilgreint hvenær greiðslur eru á gjalddaga, búðu til fellilista með eftirfarandi forskilgreindum valkostum (B6 og B7):

   

3. Settu upp uppflettitöflur fyrir Tímabil (E2:F6) og Greiðar á gjalddaga (E8:F9) eins og sýnt er á skjámyndinni hér að neðan. Mikilvægt er að textamerki í uppflettitöflunum passi nákvæmlega við atriði samsvarandi fellilista.

   Í reitunum við hliðina á fellilistanum skaltu slá inn eftirfarandi IFERROR VLOOKUP formúlur sem draga töluna úr uppflettingunni tafla sem samsvarar hlutnum sem valið er í fellilistanum.

   Formúla fyrir Tímabil (C6):

   =IFERROR(VLOOKUP(B6, E2:F6, 2, 0), "")

   Formúla fyrir Greiðslur eru á gjalddaga (C7):

   =IFERROR(VLOOKUP(B7, E8:F9, 2, 0), "")

   

4. Skrifaðu PMT formúlu til að reikna út reglubundna greiðslu út frá frumunum þínum. Í okkartilviki, formúlan er sem hér segir:

   =IFERROR(-PMT(B4/C6, B5*C6, B3, 0, C7), "")

   Vinsamlegast takið eftir eftirfarandi hlutum:

   • fv rökin (0) eru harðkóða í formúlunni vegna þess að við viljum alltaf núllstöðu eftir síðustu greiðslu. Ef þú vilt leyfa notendum þínum að slá inn hvaða framtíðargildi sem er, úthlutaðu sérstöku innsláttarhólfi fyrir fv viðfangið.
   • Á undan PMT fallinu er mínusmerki til að birta niðurstöðuna sem jákvæða tölu. .
   • PMT fallinu er vafið inn í IFERROR til að fela villur þegar sum inntaksgildi eru ekki skilgreind.

   Formúlan hér að ofan fer í B9. Og í nærliggjandi reit (A9) birtum við merki sem samsvarar valnu tímabili (B6). Fyrir þetta skaltu einfaldlega sameina gildið í B6 og viðkomandi texta:

   =B6&" Payment"

   

5. Að lokum geturðu falið uppflettitöflurnar frá sýn, bættu við nokkrum frágangi á sniði og þá er Excel PMT reiknivélin þín vel að fara:

   

Excel PMT aðgerðin virkar ekki

Ef Excel PMT formúlan virkar ekki eða gefur rangar niðurstöður, það er líklega af eftirfarandi ástæðum:

• A #NUM! villa getur komið upp ef annað hvort hlutfall röksemdin er neikvæð tala eða nper er jafnt og 0.
• A #VALUE! villa kemur upp ef ein eða fleiri rök eru textagildi.
• Ef niðurstaða PMT formúlu er mun hærri eða lægri en búist var við, vertu viss um að þú sért í samræmi við einingarnar sem gefnar eru upp fyrir rate og nper rök, sem þýðir að þú hefur umreiknað ársvexti rétt í vexti tímabilsins og fjölda ára í vikur, mánuði eða fjórðunga eins og sýnt er í þessu dæmi.

Þannig reiknarðu út PMT fall í Excel. Til að skoða betur formúlurnar sem fjallað er um í þessari kennslu er þér velkomið að hlaða niður sýnishornsvinnubókinni okkar hér að neðan. Ég þakka þér fyrir lesturinn og vonast til að sjá þig á blogginu okkar í næstu viku!

Æfingabók til niðurhals

PMT formúla í Excel - dæmi(.xlsx skrá)