Tutorial menunjukkan cara menggunakan fungsi PMT dalam Excel untuk mengira pembayaran bagi pinjaman atau pelaburan berdasarkan kadar faedah, bilangan pembayaran dan jumlah pinjaman.

Sebelumnya anda meminjam wang adalah baik untuk mengetahui cara pinjaman berfungsi. Terima kasih kepada fungsi kewangan Excel seperti RATE, PPMT dan IPMT, pengiraan bulanan atau sebarang pembayaran berkala lain untuk pinjaman adalah mudah. Dalam tutorial ini, kita akan melihat dengan lebih dekat fungsi PMT, membincangkan sintaksnya secara terperinci dan menunjukkan cara membina kalkulator PMT anda sendiri dalam Excel.

Apakah fungsi PMT dalam Excel?

Fungsi Excel PMT ialah fungsi kewangan yang mengira pembayaran untuk pinjaman berdasarkan kadar faedah yang tetap, bilangan tempoh dan jumlah pinjaman.

"PMT" bermaksud untuk "pembayaran", maka nama fungsi itu.

Sebagai contoh, jika anda memohon pinjaman kereta dua tahun dengan kadar faedah tahunan 7% dan jumlah pinjaman sebanyak $30,000, formula PMT boleh memberitahu anda akan berapakah bayaran bulanan anda.

Agar fungsi PMT berfungsi dengan betul dalam lembaran kerja anda, sila ingat fakta ini:

• Untuk selaras dengan aliran tunai umum model, jumlah pembayaran dikeluarkan sebagai nombor negatif kerana ia adalah aliran keluar tunai.
• Nilai yang dikembalikan oleh fungsi PMT termasuk prinsipal dan faedah tetapi tidak termasuk sebarang yuran, cukai atau pa rizab yments itumungkin dikaitkan dengan pinjaman.
• Formula PMT dalam Excel boleh mengira bayaran pinjaman untuk kekerapan pembayaran yang berbeza seperti mingguan , bulanan , suku tahunan , atau setiap tahun . Contoh ini menunjukkan cara untuk melakukannya dengan betul.

Fungsi PMT tersedia dalam Excel untuk Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 dan Excel 2007.

Fungsi Excel PMT - sintaks dan kegunaan asas

Fungsi PMT mempunyai argumen berikut:

Di mana:

• Kadar (diperlukan) - kadar faedah tetap bagi setiap tempoh. Boleh dibekalkan sebagai peratusan atau nombor perpuluhan.

  Contohnya, jika anda membuat pembayaran tahunan untuk pinjaman pada kadar faedah tahunan 10 peratus, gunakan 10% atau 0.1 untuk kadar. Jika anda membuat pembayaran bulanan pada pinjaman yang sama, kemudian gunakan 10%/12 atau 0.00833 untuk kadar.

• Nper (diperlukan) - bilangan pembayaran untuk pinjaman, iaitu jumlah bilangan tempoh di mana pinjaman perlu dibayar.

  Contohnya, jika anda membuat pembayaran tahunan untuk pinjaman 5 tahun, bekalkan 5 untuk nper. Jika anda membuat bayaran bulanan pada pinjaman yang sama, kemudian darabkan bilangan tahun dengan 12, dan gunakan 5*12 atau 60 untuk nper.

• Pv (diperlukan) - nilai semasa, iaitu jumlah amaun yang semua pembayaran masa hadapan bernilai sekarang. Dalam kes pinjaman, ia hanyalah jumlah asal yang dipinjam.
• Fv (pilihan) - nilai masa hadapan, atau baki tunai yang anda ingin miliki selepas pembayaran terakhir dibuat. Jika ditinggalkan, nilai masa depan pinjaman diandaikan sifar (0).
• Jenis (pilihan) - menyatakan apabila pembayaran perlu dibayar:
  • 0 atau ditinggalkan - bayaran perlu dibayar pada penghujung setiap tempoh.
  • 1 - bayaran perlu dibayar pada awal setiap tempoh.

Sebagai contoh, jika anda meminjam $100,000 selama 5 tahun dengan kadar faedah tahunan 7%, formula berikut akan mengira bayaran tahunan :

=PMT(7%, 5, 100000)

Untuk mencari bayaran bulanan untuk pinjaman yang sama, gunakan formula ini:

=PMT(7%/12, 5*12, 100000)

Atau, anda boleh memasukkan komponen pinjaman yang diketahui dalam sel berasingan dan merujuk sel tersebut dalam formula PMT anda. Dengan kadar faedah dalam B1, tidak. tahun dalam B2, dan jumlah pinjaman dalam B3, formulanya semudah ini:

=PMT(B1, B2, B3)

Sila ingat bahawa pembayaran dikembalikan sebagai nombor negatif kerana jumlah ini akan didebitkan (ditolak) daripada akaun bank anda.

Secara lalai, Excel memaparkan keputusan dalam format Mata Wang , dibundarkan kepada 2 tempat perpuluhan, diserlahkan dengan warna merah dan disertakan dalam kurungan , seperti yang ditunjukkan di bahagian kiri imej di bawah. Imej di sebelah kanan menunjukkan hasil yang sama dalam format Umum .

Jika anda ingin mendapatkan pembayaran sebagai positif nombor , letakkan tanda tolak sebelum sama adakeseluruhan formula PMT atau hujah pv (jumlah pinjaman):

=-PMT(B1, B2, B3)

atau

=PMT(B1, B2, -B3)

Petua. Untuk mengira jumlah yang dibayar untuk pinjaman, darabkan nilai PMT yang dikembalikan dengan bilangan tempoh (nilai nper). Dalam kes kami, kami akan menggunakan persamaan ini: 24,389.07*5 dan mendapati jumlah keseluruhannya adalah $121,945.35.

Cara menggunakan fungsi PMT dalam Excel - contoh formula

Di bawah anda akan menemui beberapa lagi contoh formula Excel PMT yang menunjukkan cara mengira pembayaran berkala yang berbeza untuk pinjaman kereta, pinjaman rumah, pinjaman gadai janji dan seumpamanya.

Bentuk penuh fungsi PMT dalam Excel

Untuk sebahagian besar, anda boleh meninggalkan dua argumen terakhir dalam formula PMT anda (seperti yang kami lakukan dalam contoh di atas) kerana nilai lalainya meliputi kes penggunaan yang paling tipikal:

• Fv ditinggalkan - membayangkan baki sifar selepas pembayaran terakhir.
• Jenis ditinggalkan - bayaran perlu dibayar pada akhir setiap tempoh.

Jika syarat pinjaman anda berbeza daripada kemungkiran, maka gunakan bentuk penuh formula PMT.

Sebagai contoh, mari kita hitung amaun bayaran tahunan berdasarkan sel input ini:

• B1 - kadar faedah tahunan
• B2 - tempoh pinjaman (dalam tahun)
• B3 - jumlah pinjaman
• B4 - nilai masa hadapan (baki selepas pembayaran terakhir)
• B5 - jenis anuiti:
  • 0 (anuiti biasa) - pembayaran dibuat pada penghujung setiap satutahun.
  • 1 (anuiti perlu dibayar) - bayaran dibuat pada awal tempoh, mis. bayaran sewa atau pajakan.

Bekalkan rujukan ini kepada formula Excel PMT anda:

=PMT(B1, B2, B3, B4, B5)

Dan anda akan mendapat keputusan ini:

Kira bayaran mingguan, bulanan, suku tahunan dan separuh tahunan

Bergantung pada kekerapan pembayaran, anda perlu menggunakan pengiraan berikut untuk kadar dan nper hujah:

• Untuk kadar , bahagikan kadar faedah tahunan dengan bilangan pembayaran setahun (yang dianggap sama dengan bilangan tempoh pengkompaunan).
• Untuk nper , darabkan bilangan tahun dengan bilangan pembayaran setahun.

Jadual di bawah memberikan butiran :

Sebagai contoh, untuk mencari amaun bayaran berkala bagi pinjaman $5,000 dengan kadar faedah tahunan 8% dan tempoh 3 tahun, gunakan salah satu daripada formula di bawah.

Bayaran Mingguan:

=PMT(8%/52, 3*52, 5000)

Bayaran Bulanan:

=PMT(8%/12, 3*12, 5000)

Setiap suku tahun pembayaran:

=PMT(8%/4, 3*4, 5000)

Separuh Tahun pembayaran:

=PMT(8%/2, 3*2, 5000)

Dalam semua kes, baki selepas pembayaran terakhir diandaikan sebagai $0 dan bayaran perlu dibayar pada penghujung setiap tempoh.

tangkapan skrin di bawah menunjukkan keputusan formula ini:

Cara membuat kalkulator PMT dalam Excel

Sebelum anda meneruskan dan meminjam wang, adalah wajar untuk membandingkan syarat pinjaman yang berbeza untuk mengetahui pilihan yang paling sesuai dengan anda. Untuk ini, mari buat kalkulator pembayaran pinjaman Excel kami sendiri.

1. Sebagai permulaan, masukkan amaun pinjaman, kadar faedah dan tempoh pinjaman dalam sel berasingan (masing-masing B3, B4, B5).
2. Untuk dapat memilih tempoh yang berbeza dan menentukan masa pembayaran perlu dibayar, buat senarai lungsur dengan pilihan pratakrif berikut (B6 dan B7):

   

3. Sediakan jadual carian untuk Tempoh (E2:F6) dan Pembayaran Perlu Dibayar (E8:F9) seperti ditunjukkan dalam tangkapan skrin di bawah. Adalah penting bahawa label teks dalam jadual carian betul-betul sepadan dengan item senarai juntai bawah yang sepadan.

   Dalam sel di sebelah senarai juntai bawah, masukkan formula IFERROR VLOOKUP berikut yang akan menarik nombor daripada carian jadual yang sepadan dengan item yang dipilih dalam senarai juntai bawah.

   Formula untuk Tempoh (C6):

   =IFERROR(VLOOKUP(B6, E2:F6, 2, 0), "")

   Formula untuk Pembayaran Perlu Dibayar (C7):

   =IFERROR(VLOOKUP(B7, E8:F9, 2, 0), "")

   

4. Tulis formula PMT untuk mengira pembayaran berkala berdasarkan sel anda. Dalam kamikes, formulanya adalah seperti berikut:

   =IFERROR(-PMT(B4/C6, B5*C6, B3, 0, C7), "")

   Sila perhatikan perkara berikut:

   • Argumen fv (0) dikodkan dalam formula kerana kita sentiasa mahukan baki sifar selepas pembayaran terakhir. Sekiranya anda ingin membenarkan pengguna anda memasukkan sebarang nilai masa hadapan, peruntukkan sel input yang berasingan untuk argumen fv.
   • Fungsi PMT didahului dengan tanda tolak untuk memaparkan keputusan sebagai nombor positif .
   • Fungsi PMT dibungkus ke dalam IFERROR untuk menyembunyikan ralat apabila beberapa nilai input tidak ditakrifkan.

   Formula di atas dimasukkan ke dalam B9. Dan dalam sel jiran (A9) kami memaparkan label yang sepadan dengan tempoh yang dipilih (B6). Untuk ini, hanya gabungkan nilai dalam B6 dan teks yang dikehendaki:

   =B6&" Payment"

   

5. Akhir sekali, anda boleh menyembunyikan jadual carian daripada paparan, tambahkan beberapa sentuhan pemformatan penamat dan kalkulator Excel PMT anda boleh digunakan:

   

Fungsi Excel PMT tidak berfungsi

Jika Excel PMT anda formula tidak berfungsi atau menghasilkan hasil yang salah, ia mungkin disebabkan oleh sebab berikut:

• A #NUM! ralat mungkin berlaku jika sama ada argumen kadar ialah nombor negatif atau nper bersamaan dengan 0.
• A #VALUE! ralat berlaku jika satu atau lebih argumen ialah nilai teks.
• Jika hasil formula PMT jauh lebih tinggi atau lebih rendah daripada yang dijangkakan, pastikan anda konsisten dengan unit yang dibekalkan untukHujah kadar dan nper , bermakna anda telah menukar kadar faedah tahunan dengan betul kepada kadar tempoh dan bilangan tahun kepada minggu, bulan atau suku seperti yang ditunjukkan dalam contoh ini.

Begitulah anda mengira fungsi PMT dalam Excel. Untuk melihat dengan lebih dekat formula yang dibincangkan dalam tutorial ini, anda dialu-alukan untuk memuat turun contoh buku kerja kami di bawah. Saya mengucapkan terima kasih kerana membaca dan berharap dapat berjumpa anda di blog kami minggu hadapan!

Berlatih buku kerja untuk muat turun

Formula PMT dalam Excel - contoh(.xlsx file)