Mục lục
Hướng dẫn chỉ ra cách sử dụng hàm PMT trong Excel để tính toán các khoản thanh toán cho khoản vay hoặc khoản đầu tư dựa trên lãi suất, số lần thanh toán và tổng số tiền cho vay.
Trước đây bạn vay tiền, thật tốt khi biết cách hoạt động của khoản vay. Nhờ các chức năng tài chính của Excel như RATE, PPMT và IPMT, việc tính toán khoản thanh toán hàng tháng hoặc bất kỳ khoản thanh toán định kỳ nào khác cho một khoản vay thật dễ dàng. Trong hướng dẫn này, chúng ta sẽ tìm hiểu kỹ hơn về hàm PMT, thảo luận chi tiết về cú pháp của nó và chỉ ra cách xây dựng máy tính PMT của riêng bạn trong Excel.
Hàm PMT là gì trong Excel?
Hàm PMT trong Excel là một hàm tài chính tính toán khoản thanh toán cho một khoản vay dựa trên lãi suất không đổi, số kỳ hạn và số tiền cho vay.
"PMT" là viết tắt của cho "thanh toán", do đó tên của hàm.
Ví dụ: nếu bạn đang đăng ký khoản vay mua ô tô trong hai năm với lãi suất hàng năm là 7% và số tiền vay là 30.000 đô la, thì công thức PMT có thể cho biết các khoản thanh toán hàng tháng của bạn sẽ là bao nhiêu.
Để chức năng PMT hoạt động chính xác trong bảng tính của bạn, hãy ghi nhớ những thông tin sau:
- Để phù hợp với dòng tiền chung mô hình, số tiền thanh toán được xuất ra dưới dạng số âm vì đó là dòng tiền chi ra.
- Giá trị do hàm PMT trả về bao gồm tiền gốc và tiền lãi nhưng không bao gồm bất kỳ khoản phí, thuế hoặc khoản dự trữ nào ý kiến rằngcó thể được liên kết với một khoản vay.
- Công thức PMT trong Excel có thể tính toán khoản thanh toán khoản vay cho các tần suất thanh toán khác nhau, chẳng hạn như hàng tuần , hàng tháng , hàng quý hoặc hàng năm . Ví dụ này cho biết cách thực hiện chính xác.
Hàm PMT có sẵn trong Excel cho Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 và Excel 2007.
Hàm PMT trong Excel - cú pháp và cách sử dụng cơ bản
Hàm PMT có các đối số sau:
PMT(rate, nper, pv, [fv], [type])Ở đâu:
- Rate (bắt buộc) - lãi suất cố định mỗi kỳ. Có thể được cung cấp dưới dạng phần trăm hoặc số thập phân.
Ví dụ: nếu bạn thực hiện thanh toán hàng năm cho khoản vay với lãi suất hàng năm là 10 phần trăm, hãy sử dụng 10% hoặc 0,1 cho tỷ lệ. Nếu bạn thực hiện thanh toán hàng tháng cho cùng một khoản vay, thì hãy sử dụng tỷ lệ 10%/12 hoặc 0,00833.
- Nper (bắt buộc) - số lần thanh toán cho khoản vay, tức là tổng số kỳ hạn mà khoản vay phải được thanh toán.
Ví dụ: nếu bạn thực hiện thanh toán hàng năm cho khoản vay 5 năm, hãy cung cấp 5 cho nper. Nếu bạn thực hiện thanh toán hàng tháng cho cùng một khoản vay, hãy nhân số năm với 12 và sử dụng 5*12 hoặc 60 cho nper.
- Pv (bắt buộc) - giá trị hiện tại, tức là tổng số tiền mà tất cả các khoản thanh toán trong tương lai có giá trị hiện tại. Trong trường hợp cho vay, đó chỉ đơn giản là số tiền ban đầu được vay.
- Fv (tùy chọn) - giá trị tương lai hoặc số dư tiền mặt bạn muốn có sau lần thanh toán cuối cùng được thực hiện. Nếu bỏ qua, giá trị tương lai của khoản vay được giả định bằng không (0).
- Loại (tùy chọn) - chỉ định thời điểm đến hạn thanh toán:
- 0 hoặc bỏ qua - các khoản thanh toán đến hạn vào cuối mỗi kỳ.
- 1 - các khoản thanh toán đến hạn vào đầu mỗi kỳ.
Ví dụ: nếu bạn vay 100.000 đô la trong 5 năm với lãi suất hàng năm là 7%, công thức sau sẽ tính khoản thanh toán hàng năm :
=PMT(7%, 5, 100000)
Để tìm khoản thanh toán hàng tháng đối với cùng khoản vay, hãy sử dụng công thức sau:
=PMT(7%/12, 5*12, 100000)
Hoặc, bạn có thể nhập các thành phần đã biết của khoản vay vào các ô riêng biệt và tham chiếu các ô đó trong công thức PMT của mình. Với lãi suất ở B1, không. năm ở B2 và số tiền cho vay ở B3, công thức đơn giản như sau:
=PMT(B1, B2, B3)
Hãy nhớ rằng khoản thanh toán được trả lại dưới dạng số âm bởi vì số tiền này sẽ được ghi nợ (trừ) từ tài khoản ngân hàng của bạn.
Theo mặc định, Excel hiển thị kết quả ở định dạng Tiền tệ , được làm tròn đến 2 chữ số thập phân, được đánh dấu màu đỏ và nằm trong dấu ngoặc đơn , như thể hiện ở phần bên trái của hình ảnh bên dưới. Hình ảnh bên phải hiển thị kết quả tương tự ở định dạng Chung .
Nếu bạn muốn thanh toán dưới dạng dương số , đặt dấu trừ trước một trong haitoàn bộ công thức PMT hoặc đối số pv (số tiền cho vay):
=-PMT(B1, B2, B3)
hoặc
=PMT(B1, B2, -B3)
Mẹo. Để tính tổng số tiền đã thanh toán cho khoản vay, hãy nhân giá trị PMT được trả về với số kỳ (giá trị nper). Trong trường hợp của chúng tôi, chúng tôi sẽ sử dụng phương trình sau: 24.389,07*5 và thấy rằng tổng số tiền bằng $121.945,35.
Cách sử dụng hàm PMT trong Excel - ví dụ về công thức
Dưới đây, bạn sẽ tìm thấy một một số ví dụ khác về công thức PMT trong Excel cho biết cách tính toán các khoản thanh toán định kỳ khác nhau cho khoản vay mua ô tô, khoản vay mua nhà, khoản vay thế chấp, v.v.
Dạng đầy đủ của hàm PMT trong Excel
Đối với hầu hết các phần, bạn có thể bỏ qua hai đối số cuối cùng trong công thức PMT của mình (như chúng tôi đã làm trong các ví dụ trên) vì giá trị mặc định của chúng bao gồm các trường hợp sử dụng điển hình nhất:
- Fv bị bỏ qua - ngụ ý số dư bằng không sau lần thanh toán cuối cùng.
- Loại bị bỏ qua - các khoản thanh toán đến hạn vào cuối của mỗi kỳ.
Nếu điều kiện khoản vay của bạn khác với điều kiện mặc định, thì hãy sử dụng dạng đầy đủ của công thức PMT.
Ví dụ: hãy tính số tiền thanh toán hàng năm dựa trên các ô nhập này:
- B1 - lãi suất hàng năm
- B2 - thời hạn cho vay (tính theo năm)
- B3 - số tiền cho vay
- B4 - giá trị tương lai (số dư sau lần thanh toán cuối cùng)
- B5 - loại niên kim:
- 0 (niên kim thông thường) - thanh toán được thực hiện vào cuối kỳ mỗinăm.
- 1 (dòng niên kim đến hạn) - các khoản thanh toán được thực hiện vào đầu kỳ, ví dụ: các khoản thanh toán tiền thuê hoặc tiền thuê.
Cung cấp các tham chiếu này cho công thức PMT Excel của bạn:
=PMT(B1, B2, B3, B4, B5)
Và bạn sẽ có kết quả này:
Tính toán các khoản thanh toán hàng tuần, hàng tháng, hàng quý và nửa năm
Tùy thuộc vào tần suất thanh toán, bạn cần sử dụng các phép tính sau cho tỷ lệ
- Đối với rate , chia lãi suất hàng năm cho số lần thanh toán mỗi năm (được coi là bằng số kỳ gộp).
- Đối với nper , hãy nhân số năm với số lần thanh toán mỗi năm.
Bảng dưới đây cung cấp thông tin chi tiết :
| Tần suất thanh toán | Tỷ lệ | Nper |
| Hàng tuần | lãi suất hàng năm / 52 | năm * 52 |
| Hàng tháng | lãi suất hàng năm / 12 | năm * 12 |
| Hàng quý | lãi suất hàng năm / 4 | năm * 4 |
| Nửa năm | lãi suất hàng năm / 2 | năm * 2 |
Ví dụ: để tìm số tiền thanh toán định kỳ cho khoản vay $5.000 với lãi suất hàng năm 8% và thời hạn 3 năm, hãy sử dụng một trong các công thức dưới đây.
Thanh toán hàng tuần:
=PMT(8%/52, 3*52, 5000)
Thanh toán hàng tháng :
=PMT(8%/12, 3*12, 5000)
Hàng quý thanh toán:
=PMT(8%/4, 3*4, 5000)
Nửa năm một lần thanh toán:
=PMT(8%/2, 3*2, 5000)
Trong mọi trường hợp, số dư sau lần thanh toán cuối cùng được giả định là $0 và các khoản thanh toán đến hạn vào cuối mỗi kỳ.
Các khoản thanh toán ảnh chụp màn hình bên dưới hiển thị kết quả của các công thức này:
Cách tạo công cụ tính PMT trong Excel
Trước khi bạn tiếp tục và vay tiền, bạn nên có lý do để so sánh các điều kiện cho vay khác nhau để tìm ra các tùy chọn phù hợp với bạn nhất. Đối với điều này, hãy tạo máy tính thanh toán khoản vay Excel của riêng chúng ta.
- Để bắt đầu, hãy nhập số tiền vay, lãi suất và thời hạn khoản vay vào các ô riêng biệt (lần lượt là B3, B4, B5).
- Để có thể chọn các khoảng thời gian khác nhau và chỉ định thời điểm đến hạn thanh toán, hãy tạo danh sách thả xuống với các tùy chọn được xác định trước sau (B6 và B7):
- Thiết lập các bảng tra cứu cho Thời gian (E2:F6) và Các khoản thanh toán đến hạn (E8:F9) như hiển thị trong ảnh chụp màn hình bên dưới. Điều quan trọng là các nhãn văn bản trong bảng tra cứu khớp chính xác với các mục trong danh sách thả xuống tương ứng.
Trong các ô bên cạnh danh sách thả xuống, hãy nhập các công thức IFERROR VLOOKUP sau đây sẽ lấy số từ tra cứu bảng tương ứng với mục được chọn trong danh sách thả xuống.
Công thức cho Dấu chấm (C6):
=IFERROR(VLOOKUP(B6, E2:F6, 2, 0), "")Công thức cho Đến hạn thanh toán (C7):
=IFERROR(VLOOKUP(B7, E8:F9, 2, 0), "")
- Viết công thức PMT để tính khoản thanh toán định kỳ dựa trên các ô của bạn. trong chúng tôicông thức như sau:
=IFERROR(-PMT(B4/C6, B5*C6, B3, 0, C7), "")Vui lòng lưu ý những điều sau:
- Đối số fv (0) được mã hóa cứng trong công thức bởi vì chúng tôi luôn muốn số dư bằng không sau lần thanh toán cuối cùng. Trong trường hợp bạn muốn cho phép người dùng của mình nhập bất kỳ giá trị nào trong tương lai, hãy phân bổ một ô nhập liệu riêng cho đối số fv.
- Hàm PMT được đặt trước dấu trừ để hiển thị kết quả dưới dạng số dương .
- Hàm PMT được đưa vào IFERROR để ẩn lỗi khi một số giá trị đầu vào không được xác định.
Công thức trên áp dụng cho B9. Và trong ô bên cạnh (A9), chúng tôi hiển thị nhãn tương ứng với khoảng thời gian đã chọn (B6). Đối với điều này, chỉ cần nối giá trị trong B6 và văn bản mong muốn:
=B6&" Payment"
- Cuối cùng, bạn có thể ẩn các bảng tra cứu khỏi chế độ xem, thêm một vài thao tác định dạng hoàn thiện và máy tính PMT Excel của bạn sẽ hoạt động tốt:
Hàm PMT Excel không hoạt động
Nếu PMT Excel của bạn công thức không hoạt động hoặc tạo ra kết quả sai, có thể là do những lý do sau:
- Lỗi #NUM! có thể xảy ra lỗi nếu đối số rate là số âm hoặc nper bằng 0.
- #VALUE! xảy ra lỗi nếu một hoặc nhiều đối số là giá trị văn bản.
- Nếu kết quả của công thức PMT cao hơn hoặc thấp hơn nhiều so với mong đợi, hãy đảm bảo rằng bạn nhất quán với các đơn vị được cung cấp choCác đối số rate và nper , nghĩa là bạn đã chuyển đổi chính xác lãi suất hàng năm thành lãi suất của khoảng thời gian và số năm thành tuần, tháng hoặc quý như trong ví dụ này.
Đó là cách bạn tính hàm PMT trong Excel. Để xem kỹ hơn các công thức được thảo luận trong hướng dẫn này, bạn có thể tải xuống sổ làm việc mẫu của chúng tôi bên dưới. Tôi cảm ơn bạn đã đọc và hy vọng sẽ gặp bạn trên blog của chúng tôi vào tuần tới!
Sách bài tập thực hành để tải xuống
Công thức PMT trong Excel - ví dụ (tệp .xlsx)
