Udžbenik pokazuje kako koristiti PMT funkciju u programu Excel za izračun plaćanja za zajam ili ulaganje na temelju kamatne stope, broja plaćanja i ukupnog iznosa zajma.

Prije posuđujete novac dobro je znati kako zajam funkcionira. Zahvaljujući Excel financijskim funkcijama kao što su RATE, PPMT i IPMT, izračunavanje mjesečne ili bilo koje druge periodične uplate za zajam jednostavno je. U ovom ćemo vodiču pobliže pogledati funkciju PMT, detaljno raspravljati o njenoj sintaksi i pokazati kako izraditi vlastiti PMT kalkulator u programu Excel.

Što je funkcija PMT u Excelu?

Funkcija Excel PMT financijska je funkcija koja izračunava plaćanje zajma na temelju stalne kamatne stope, broja razdoblja i iznosa zajma.

"PMT" stoji za "plaćanje", otuda i naziv funkcije.

Na primjer, ako se prijavljujete za dvogodišnji kredit za automobil s godišnjom kamatnom stopom od 7% i iznosom kredita od 30.000 USD, PMT formula može reći znate kolike će biti vaše mjesečne isplate.

Da bi funkcija PMT ispravno radila u vašim radnim listovima, imajte na umu ove činjenice:

• Da biste bili u skladu s općim novčanim tokom modelu, iznos plaćanja ispisuje se kao negativan broj jer se radi o odljevu novca.
• Vrijednost koju vraća funkcija PMT uključuje glavnicu i kamatu ali ne uključuje nikakve naknade, poreze ili pričuvu yments damože biti povezan sa zajmom.
• PMT formula u Excelu može izračunati otplatu zajma za različite učestalosti plaćanja kao što su tjedno , mjesečno , tromjesečno , ili godišnje . Ovaj primjer pokazuje kako to učiniti ispravno.

Funkcija PMT dostupna je u Excelu za Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 i Excel 2007.

Excelova funkcija PMT - sintaksa i osnovna upotreba

Funkcija PMT ima sljedeće argumente:

Gdje:

• Stopa (obavezno) - stalna kamatna stopa po razdoblju. Može se dostaviti kao postotak ili decimalni broj.

  Na primjer, ako plaćate godišnje zajam uz godišnju kamatnu stopu od 10 posto, koristite 10% ili 0,1 za stopu. Ako plaćate mjesečno za isti zajam, tada koristite 10%/12 ili 0,00833 za stopu.

• Nper (obavezno) - broj otplata zajma, odnosno ukupan broj razdoblja u kojima treba otplatiti zajam.

  Na primjer, ako vršite godišnje uplate na 5-godišnji zajam, navedite 5 za nper. Ako plaćate mjesečno za isti zajam, tada pomnožite broj godina s 12 i koristite 5*12 ili 60 za nper.

• Pv (obavezno) - sadašnja vrijednost, tj. ukupni iznos koji sada vrijede sva buduća plaćanja. U slučaju zajma, to je jednostavno izvorni posuđeni iznos.
• Fv (neobavezno) - buduća vrijednost ili stanje gotovine koje želite imati nakon zadnje uplate. Ako se izostavi, pretpostavlja se da je buduća vrijednost zajma nula (0).
• Tip (neobavezno) - navodi kada dospijevaju plaćanja:
  • 0 ili izostavljeno - plaćanja dospijevaju na kraju svakog razdoblja.
  • 1 - plaćanja dospijevaju na početku svakog razdoblja.

Na primjer, ako posudite 100.000 USD na 5 godina uz godišnju kamatnu stopu od 7%, sljedeća formula će izračunati godišnju otplatu :

=PMT(7%, 5, 100000)

Da biste pronašli mjesečnu otplatu za isti zajam upotrijebite ovu formulu:

=PMT(7%/12, 5*12, 100000)

Ili možete unijeti poznate komponente zajma u zasebne ćelije i referencirati te ćelije u svojoj PMT formuli. Uz kamatnu stopu u B1, br. godina u B2, a iznos kredita u B3, formula je jednostavna kao ova:

=PMT(B1, B2, B3)

Zapamtite da se uplata vraća kao negativan broj jer ovaj iznos bit će terećen (oduzet) s vašeg bankovnog računa.

Prema zadanim postavkama, Excel prikazuje rezultat u formatu Valuta , zaokruženo na 2 decimalna mjesta, označeno crvenom bojom i u zagradi , kao što je prikazano u lijevom dijelu slike ispod. Slika desno prikazuje isti rezultat u formatu Općenito .

Ako želite da uplata bude pozitivna broj , stavite znak minus ispred bilo kojegcijela formula PMT ili argument pv (iznos kredita):

=-PMT(B1, B2, B3)

ili

=PMT(B1, B2, -B3)

Savjet. Za izračun ukupnog iznosa plaćenog zajma, pomnožite vraćenu PMT vrijednost s brojem razdoblja (n po vrijednosti). U našem slučaju, upotrijebili bismo ovu jednadžbu: 24,389.07*5 i otkrili da je ukupni iznos jednak $121,945.35.

Kako koristiti PMT funkciju u Excelu - primjeri formula

U nastavku ćete pronaći još nekoliko primjera formule Excel PMT koji pokazuju kako izračunati različita periodična plaćanja za kredit za automobil, stambeni kredit, hipotekarni kredit i slično.

Puni oblik PMT funkcije u Excelu

U većini slučajeva možete izostaviti posljednja dva argumenta u svojim PMT formulama (kao što smo učinili u gornjim primjerima) jer njihove zadane vrijednosti pokrivaju najtipičnije slučajeve upotrebe:

• Fv izostavljeno - implicira nulti saldo nakon zadnje uplate.
• Vrsta izostavljena - plaćanja dospijevaju na kraju svakog razdoblja.

Ako se uvjeti vašeg kredita razlikuju od zadanih, upotrijebite puni oblik formule PMT.

Kao primjer, izračunajmo iznos godišnjih plaćanja na temelju ovih ulaznih ćelija:

• B1 - godišnja kamatna stopa
• B2 - rok kredita (u godinama)
• B3 - iznos kredita
• B4 - buduća vrijednost (stanje nakon zadnje uplate)
• B5 - vrsta anuiteta:
  • 0 (redovni anuitet) - plaćanja se vrše na kraju svakigodine.
  • 1 (dospijeće anuiteta) - plaćanja se vrše na početku razdoblja, npr. plaćanja najamnine ili leasinga.

Unesite ove reference u svoju Excel PMT formulu:

=PMT(B1, B2, B3, B4, B5)

I dobit ćete ovaj rezultat:

Izračunajte tjedne, mjesečne, tromjesečne i polugodišnje isplate

Ovisno o učestalosti plaćanja, trebate koristiti sljedeće izračune za stopu i nper argumenti:

• Za rate , podijelite godišnju kamatnu stopu s brojem plaćanja godišnje (što se smatra jednakim broj razdoblja uračunavanja).
• Za nper , pomnožite broj godina s brojem plaćanja po godini.

Tablica u nastavku pruža pojedinosti :

Na primjer, da biste pronašli iznos periodične otplate na zajam od 5000 USD s godišnjom kamatnom stopom od 8% i trajanjem od 3 godine, upotrijebite jednu od formula u nastavku.

Tjedno plaćanje:

=PMT(8%/52, 3*52, 5000)

Mjesečno plaćanje:

=PMT(8%/12, 3*12, 5000)

Kvartalno plaćanje:

=PMT(8%/4, 3*4, 5000)

Polugodišnje plaćanje:

=PMT(8%/2, 3*2, 5000)

U svim slučajevima, pretpostavlja se da je stanje nakon posljednje uplate 0 USD, a plaćanja dospijevaju na kraju svakog razdoblja.

snimka zaslona u nastavku prikazuje rezultate ovih formula:

Kako napraviti PMT kalkulator u Excelu

Prije nego što krenete i posudite novac, logično je usporediti različite uvjete kredita kako biste saznali opcije koje vam najviše odgovaraju. U tu svrhu kreirajmo vlastiti Excel kalkulator otplate kredita.

1. Za početak unesite iznos kredita, kamatnu stopu i rok kredita u zasebne ćelije (B3, B4, B5, redom).
2. Da biste mogli odabrati različita razdoblja i odrediti kada plaćanja dospijevaju, izradite padajuće popise sa sljedećim unaprijed definiranim opcijama (B6 i B7):

   

3. Postavite tablice pretraživanja za Razdoblja (E2:F6) i Plaćanja su dospjela (E8:F9) kao što je prikazano na slici ispod. Važno je da tekstualne oznake u tablicama pretraživanja točno odgovaraju stavkama odgovarajućeg padajućeg popisa.

   U ćelije pokraj padajućih popisa unesite sljedeće formule IFERROR VLOOKUP koje će izvući broj iz pretraživanja tablica koja odgovara stavci odabranoj na padajućem popisu.

   Formula za Razdoblja (C6):

   =IFERROR(VLOOKUP(B6, E2:F6, 2, 0), "")

   Formula za Plaćanja su dospjela (C7):

   =IFERROR(VLOOKUP(B7, E8:F9, 2, 0), "")

   

4. Napišite PMT formulu za izračun periodičnog plaćanja na temelju vaših ćelija. U našemslučaju, formula je sljedeća:

   =IFERROR(-PMT(B4/C6, B5*C6, B3, 0, C7), "")

   Obratite pozornost na sljedeće stvari:

   • Argument fv (0) tvrdo je kodiran u formuli jer uvijek želimo nulti saldo nakon zadnje uplate. U slučaju da želite svojim korisnicima dopustiti unos bilo koje buduće vrijednosti, dodijelite zasebnu ulaznu ćeliju za argument fv.
   • Pred funkcijom PMT nalazi se znak minus kako bi se rezultat prikazao kao pozitivan broj .
   • Funkcija PMT omotana je u IFERROR kako bi se sakrile pogreške kada neke ulazne vrijednosti nisu definirane.

   Gornja formula ide u B9. A u susjednoj ćeliji (A9) prikazujemo oznaku koja odgovara odabranom razdoblju (B6). Za ovo jednostavno povežite vrijednost u B6 i željeni tekst:

   =B6&" Payment"

   

5. Konačno, možete sakriti pregledne tablice iz pogleda, dodajte nekoliko završnih detalja oblikovanja i vaš Excel PMT kalkulator je spreman:

   

Excel PMT funkcija ne radi

Ako vaš Excel PMT formula ne radi ili daje krive rezultate, to je vjerojatno zbog sljedećih razloga:

• A #NUM! može doći do pogreške ako je argument rate negativan broj ili je nper jednako 0.
• A #VALUE! pojavljuje se pogreška ako su jedan ili više argumenata tekstualne vrijednosti.
• Ako je rezultat formule PMT mnogo viši ili niži od očekivanog, provjerite jeste li dosljedni s jedinicama koje su dostavljene zaArgumenti rate i nper , što znači da ste ispravno pretvorili godišnju kamatnu stopu u stopu razdoblja i broj godina u tjedne, mjesece ili kvartale kao što je prikazano u ovom primjeru.

Tako izračunavate PMT funkciju u Excelu. Kako biste pobliže pogledali formule o kojima se govori u ovom vodiču, slobodno u nastavku preuzmite naš primjer radne knjige. Zahvaljujem vam na čitanju i nadam se da se vidimo na našem blogu sljedeći tjedan!

Vježbe za preuzimanje

PMT formula u Excelu - primjeri (.xlsx datoteka)