Овој туторијал ги објаснува основите на структурираните референци на Excel и споделува неколку трикови за нивно користење во реални формули.

Една од најкорисните карактеристики на табелите на Excel се структурирани референци. Кога штотуку сте налетале на специјална синтакса за упатување на табели, може да изгледа досадно и збунувачки, но откако малку ќе експериментирате, сигурно ќе видите колку е корисна и кул оваа функција.

Excel Структурирана референца

А структурирана референца или референца за табела , е посебен начин за референцирање на табелите и нивните делови што користи комбинација од имиња на табели и колони наместо адреси на ќелиите .

Оваа специјална синтакса е потребна затоа што табелите на Excel (наспроти опсезите) се многу моќни и еластични, а нормалните референци на ќелиите не можат динамички да се приспособат додека податоците се додаваат или отстрануваат од табелата.

За на пример, за да ги сумирате вредностите во ќелиите B2:B5, ја користите функцијата SUM со вообичаена референца за опсег:

=SUM(B2:B5)

За да ги соберете броевите во колоната „Продажба“ од Табела 1, користите структурирана референца:

=SUM(Table1[Sales])

Клучни карактеристики на структурирани референци

Во споредба со стандардните референци на ќелиите, референците на табелите имаат голем број на напредни функции.

Лесно се креира

За да додадете структурирани референци во вашата формула, едноставно ги избирате ќелиите од табелата на кои сакате да се повикате. Познавањето на посебна синтакса не еначин:

• Референците за повеќе колони се апсолутни и не се менуваат кога се копираат формулите.
• Единечна колона референците се релативни и се менуваат кога се влечат низ колоните. Кога се копираат/залепуваат преку соодветна команда или кратенки (Ctrl+C и Ctrl+V), тие не се менуваат.

Во ситуации кога ви треба комбинација од релативни и апсолутни референци на табелата, постои нема начин да ја копирате формулата и да ги одржувате точните референци на табелата. Повлекувањето на формулата ќе ги смени референците во единечни колони, а кратенките за копирање/лепење ќе ги направат сите референци статични. Но, постојат неколку едноставни трикови за да се заобиколи!

Апсолутна структурирана референца за една колона

За да се направи апсолутна референца од една колона, повторете го името на колоната за формално да ја претворите во референца за опсег .

Релативна референца на колона (стандардно)

table[column]

Апсолутна референца на колона

table[[column]:[column]]

За да се направи апсолутна референца за тековен ред , префиксирајте го идентификаторот на колоната со симболот @:

table[@[column]:[column]]

За да видите како функционираат во пракса релативните и апсолутните референци на табелата, ве молиме разгледајте го следниов пример.

Да претпоставиме дека сакате да ги соберете продажните броеви за одреден производ за 3 месеци. За ова, го внесуваме името на целниот производ во некоја ќелија (F2 во нашиот случај) и ја користиме функцијата SUMIF за да ја добиеме вкупната продажба од јан :

=SUMIF(Sales[Item], $F$2, Sales[Jan])

Напроблемот е што кога ја влечеме формулата надесно за да ги пресметаме вкупните збирки за другите два месеци, референцата [Item] се менува и формулата се распаѓа:

За да се поправи ова, направете ја референцата [Item] апсолутна, но чувајте ја [Jan] релативна:

=SUMIF(Sales[[Item]:[Item]], $F$2, Sales[Jan])

Сега, можете да ја повлечете изменетата формула во други колони и таа функционира совршено:

Релативна структурирана референца на повеќе колони

Во табелите на Excel, структурираните референци на неколку колони се апсолутни по својата природа и остануваат непроменети кога се копираат во други ќелии.

За мене, ова однесување е многу разумно. Но, ако треба да направите релативна референца за структуриран опсег, префиксирајте го секој спецификатор на колона со името на табелата и отстранете ги надворешните квадратни загради како што е прикажано подолу.

Референца за апсолутен опсег (стандардно)

table[[column1]:[column2]]

Референца за релативен опсег

table[column1]:table[column2]

За да се повикате на тековниот ред во табелата , користете го симболот @:

[@column1]:[@column2]

На пример, формулата подолу со апсолутна структурирана референца ги собира броевите во тековниот ред од колоните Jan и Feb . Кога ќе се копира во друга колона, таа сепак ќе ги сумира Јан и Феб .

=SUM(Sales[@[Jan]:[Feb]])

Во случај да сакате референцата да се промени врз основа на релативна позиција на колоната каде што формулата е копирана, направете ја релативна :

=SUM(Sales[@Jan]:Sales[@Feb])

Ве молиме забележете ја трансформацијата на формулата во колоната F (наимето на табелата е испуштено бидејќи формулата е внатре во табелата):

Така правите референци за табели во Excel. За да ги погледнете одблизу примерите дискутирани во ова упатство, слободно преземете го нашиот примерок на работна книга во Структурната референца на Excel. Ви благодарам што прочитавте и се надевам дека ќе се видиме на нашиот блог следната недела.

Еластично и автоматски ажурирано

Кога преименувате колона, референците автоматски се ажурираат со новото име и формулата не се распаѓа. Освен тоа, како што додавате нови редови на табелата, тие веднаш се вклучуваат во постоечките референци, а формулите го пресметуваат целосниот сет на податоци.

Значи, без оглед на манипулациите што ги правите со вашите табели на Excel, не не мора да се грижите за ажурирање на структурираните референци.

Може да се користи внатре и надвор од табела

Структурираните референци може да се користат во формули и внатре и надвор од табелата на Excel, што го прави лоцирањето на табелите во големите работни книги полесно.

Автоматско пополнување на формулата (пресметани колони)

За да се изврши истата пресметка во секој ред од табелата, доволно е да внесете формула во само една ќелија. Сите други ќелии во таа колона се пополнуваат автоматски.

Како да креирате структурирана референца во Excel

Да се ​​прави структурирана референца во Excel е многу лесно и интуитивно.

Ако работат со опсег, прво претворете го во табела на Excel. За ова, изберете ги сите податоци и притиснете Ctrl + T. За повеќе информации, погледнете Како да креирате табела во Excel.

За да креирате структурирана референца, ова е она што треба да го направите:

1. Започнете да пишувате формула како и обично, почнувајќи со знакот за еднаквост (=).
2. Кога станува збор за првата референца, изберете ја соодветната ќелија или опсег одќелии во вашата табела. Excel ќе ги собере имињата на колоните и автоматски ќе создаде соодветна структурирана референца за вас.
3. Внесете ја заградата за затворање и притиснете Enter. Ако формулата е креирана во табелата, Excel автоматски ја пополнува целата колона со истата формула.

Како пример, ајде да ги собереме продажните броеви за 3 месеци во секој ред од нашата примерна табела. со име Продажба . За ова, внесуваме =SUM( во E2, избираме B2:D2, ја пишуваме заградата за затворање и притискаме Enter:

Како резултат, целата колона E е автоматска -пополнета со оваа формула:

=SUM(Sales[@[Jan]:[Mar]])

Иако формулата е иста, податоците се пресметуваат во секој ред поединечно. За да ја разберете внатрешната механика, погледнете ја референтната синтакса на табелата .

Ако внесувате формула надвор од табелата и таа формула бара само опсег на ќелии, побрз начин да се направи структурирана референца е овој:

1. По воведната заграда, почнете да го пишувате името на табелата. Додека ја пишувате првата буква, Excel ќе ги прикаже сите соодветни имиња. Доколку е потребно, напишете уште неколку букви за да го стесните списокот.
2. Користете ја копчињата со стрелки за да го изберете името на табелата во списокот.
3. Кликнете двапати на избраното име или притиснете го копчето Tab за да го додадете во вашата формула.
4. Внесете ја затворачката заграда и притиснете Enter.

На пример, да го најдеме најголемиот број во нашиот примероктабела, почнуваме да ја пишуваме формулата MAX, по почетната заграда напишете „s“, изберете ја табелата Продажба во списокот и притиснете Tab или кликнете двапати на името.

Како што како резултат, ја имаме оваа формула:

=MAX(Sales)

Структурирана референтна синтакса

Како што веќе споменавме, не треба да ја знаете синтаксата на структурирани референци за да ги вклучите во вашите формули, сепак тоа ќе ви помогне да разберете што всушност прави секоја формула.

Обично, структурираната референца се претставува со низа што започнува со име на табела и завршува со колона спецификатор.

Како пример, да ја разложиме следнава формула која ги собира збировите на колоните Југ и Северна во табелата со име Региони :

Референцата вклучува три компоненти:

1. Име на табела
2. Спецификатор на ставка
3. Колона спецификатори

За да видите кои ќелии всушност се пресметуваат, изберете ја ќелијата со формулата и кликнете каде било во лентата со формули. Excel ќе ги истакне референтните ќелии на табелата:

Име на табелата

Името на табелата упатува само на податоци од табелата , без ред за заглавие или вкупни редови. Може да биде стандардно име на табела како Табела1 или приспособено име како Региони . За да и дадете приспособено име на вашата табела, направете ги овие чекори.

Ако вашата формула се наоѓа во табелата на која се однесува, името на табелата обично се испушта бидејќисе подразбира.

Спецификатор на колона

Спецификатор на колона ги упатува податоците во соодветната колона, без редот за заглавие и вкупниот ред. Спецификаторот на колоната е претставен со името на колоната затворено во загради, на пр. [Југ].

За да се однесувате на повеќе од една соседна колона, користете го операторот опсег како [[Југ]:[Исток]].

Спецификатор на ставка

За да се повикате за одредени делови од табелата, можете да користите кој било од следните спецификатори.

Забележете дека знакот за фунта (#) се користи со сите спецификатори на ставките, освен тековниот ред. За да се однесува на ќелиите во истиот ред каде што ја внесувате формулата, Excel го користи знакот @ проследен со името на колоната.

На пример, за додавање броеви во Југ и Западни колони од тековниот ред, би ја користеле оваа формула:

=SUM(Regions[@South], Regions[@West])

Ако имињата на колоните содржат празни места, интерпункциски знаци или специјални знаци, дополнителен сет на загради околу ќе се појави името на колоната:

=SUM(Regions[@[South sales]], Regions[@[West sales]])

Структурирани референтни оператори

Следните оператори ви дозволуваат да комбинирате различни спецификатори и да додадете уште поголема флексибилност на вашите структурирани референци.

Оператор на опсег ( дебелото црево)

Како и со референците за нормален опсег, користите две точки (:) за да упатувате на две или повеќе соседни колони во табелата.

На пример, формулата подолу ги собира броевите во сите колони помеѓу Југ и Исток .

=SUM(Regions[[South]:[East]])

Оператор на унија (запирка)

За да се однесува на несоседни колони, одделете ги спецификаторите на колоните со запирки.

На пример, еве како можете да ги сумирате редовите со податоци во колоните Југ и Западот .

=SUM(Regions[South], Regions[West])

Оператор на пресек (простор)

Се користи за упатување на ќелија на пресекот на одредена редица и колона.

На пример, за враќање на вредност на пресекот на редот Total и колоната West , користете ја оваа референца:

=Regions[#Totals] Regions[[#All],[West]]

Ве молиме забележете дека спецификаторот [#All] е се бара во овој случај бидејќи на спецификаторот на колоната не го вклучува вкупниот ред. Без него, формулата би вратила #NULL!.

Правила за синтакса на референтни табели

За рачно уредување или правење структурирани референци, следете ги овие упатства:

1. Загради спецификатори во загради

Сите спецификатори за колони и специјални ставки мора да бидат затворени во [квадратни загради].

Спецификаторот што содржи други спецификатори треба да бидезавиткани во надворешни загради. На пример, региони[[Југ]:[Исток]].

2. Одделете ги внатрешните спецификатори со запирки

Ако спецификаторот содржи два или повеќе внатрешни спецификатори, тие внатрешни спецификатори треба да се одделат со запирки.

На пример, за да се врати заглавието на Југ колона, пишувате запирка помеѓу [#Headers] и [South] и ја ставате целата оваа конструкција во дополнителен сет на загради:

=Regions[[#Headers],[South]]

3. Не користете наводници околу заглавијата на колоните

Во референците на табелите, заглавјата на колоните не бараат наводници без разлика дали се текст, броеви или датуми.

4. Користете единечен наводник за некои специјални знаци во заглавијата на колоните

Во структурираните референци, некои знаци како левата и десната заграда, знакот за фунта (#) и единечниот наводник (') имаат посебно значење. Ако некој од горенаведените знаци е вклучен во заглавието на колоната, треба да се користи единечен наводник пред тој знак во спецификаторот на колоната.

На пример, за заглавието на колоната „Item #“, спецификаторот е [Ставка '#].

5. Користете празни места за да ги направите структурираните референци почитливи

За да ја подобрите читливоста на референците на вашата табела, можете да вметнете празни места помеѓу спецификаторите. Нормално, се смета за добра практика да се користат празни места по запирки. На пример:

=AVERAGE(Regions[South], Regions[West], Regions[North])

Референци за табели на Excel - примери на формули

За да стекнете повеќе разбирање заСтруктурирани референци во Excel, ајде да разгледаме уште неколку примери на формула. Ќе се обидеме да ги задржиме едноставни, значајни и корисни.

Најдете го бројот на редови и колони во табелата на Excel

За да го добиете вкупниот број на колони и редови, користете ги COLUMNS и ROWS функции, за кои е потребно само името на табелата:

На пример, да се најде бројот на колони и редови со податоци во табелата со име Продажба , користете ги овие формули:

=COLUMNS(Sales)

=ROWS(Sales)

За да го вклучите заглавјето и вкупни редови во броењето, користете го спецификаторот [#ALL]:

=ROWS(Sales[#All])

Подолу скриншот ги прикажува сите формули во акција:

Бротајте празни и непразни места во колона

Кога броите нешто во одредена колона, не заборавајте да го изнесете резултатот надвор од табелата, во спротивно може да завршите со кружни референци и погрешни резултати.

За броење празни места во колона, користете ја функцијата COUNTBLANK. За да броите непразни ќелии во колона, користете ја функцијата COUNTA.

На пример, за да дознаете колку ќелии во колоната Јан се празни и колку содржат податоци, користете ги овие формули:

Празни:

=COUNTBLANK(Sales[Jan])

Непразни:

=COUNTA(Sales[Jan])

За броење непразни ќелии во видливи редови во филтрирана табела, користете ја функцијата SUBTOTAL со функција_num поставена на 103:

=SUBTOTAL(103,Sales[Jan])

Сум во табела Excel

Најбрзиот начин за собирањеброеви во табелата на Excel е да ја овозможите опцијата Вкупно ред. За да го направите ова, кликнете со десното копче на која било ќелија во табелата, посочете на Табела и кликнете Вкупно ред . Вкупниот ред веднаш ќе се појави на крајот од вашата табела.

Понекогаш Excel може да претпостави дека сакате да ја соберете само последната колона и ги остава празни ќелии во редот Вкупно. За да го поправите ова, изберете празна ќелија во редот Вкупно, кликнете на стрелката што се појавува веднаш до ќелијата и потоа изберете ја функцијата SUM во листата:

Ова ќе вметнете SUBTOTAL формула која ги собира вредностите само во видливите редови , игнорирајќи ги филтрираните редови:

=SUBTOTAL(109,[Jan])

Ве молиме имајте предвид дека оваа формула работи само во Вкупно ред . Ако се обидете рачно да го вметнете во ред со податоци, ова ќе создаде кружна референца и ќе врати 0 како резултат. Формулата SUM со структурирана референца нема да работи ниту од истата причина:

Значи, ако ги сакате збирките внатре во табелата , вие треба или да го овозможите редот Вкупно или да користите референца за нормален опсег како што е:

=SUM(B2:B5)

Надвор од табелата , формулата SUM со структурирана референца работи добро:

=SUM(Sales[Jan])

Забележете дека за разлика од SUBTOTAL, функцијата SUM собира вредности во сите редови, видливи и скриени.

Релативни и апсолутни структурирани референци во Excel

Стандардно, структурираните референци на Excel се однесуваат на следново