Hierdie tutoriaal verduidelik die basiese beginsels van Excel-gestruktureerde verwysings en deel 'n paar truuks om dit in werklike formules te gebruik.

Een van die nuttigste kenmerke van Excel-tabelle is gestruktureerde verwysings. Wanneer jy sopas afgekom het op 'n spesiale sintaksis om tabelle te verwys, kan dit dalk vervelig en verwarrend lyk, maar nadat jy 'n bietjie geëksperimenteer het, sal jy sekerlik sien hoe nuttig en cool hierdie kenmerk is.

Excel gestruktureerde verwysing

'n gestruktureerde verwysing , of tabelverwysing , is 'n spesiale manier om tabelle en hul dele te verwys wat 'n kombinasie van tabel- en kolomname in plaas van seladresse gebruik .

Hierdie spesiale sintaksis word vereis omdat Excel-tabelle (teenoor reekse) baie kragtig en veerkragtig is, en normale selverwysings kan nie dinamies aanpas soos data bygevoeg of uit 'n tabel verwyder word nie.

Vir byvoorbeeld, om die waardes in selle B2:B5 op te som, gebruik jy die SOM-funksie met 'n gewone reeksverwysing:

=SUM(B2:B5)

Om die getalle in die "Verkope"-kolom van Tabel1 op te tel, jy gebruik 'n gestruktureerde verwysing:

=SUM(Table1[Sales])

Sleutelkenmerke van gestruktureerde verwysings

In vergelyking met standaardselverwysings het tabelverwysings 'n nommer van gevorderde kenmerke.

Maklik geskep

Om gestruktureerde verwysings by jou formule te voeg, kies jy eenvoudig die tabelselle waarna jy wil verwys. Die kennis van 'n spesiale sintaksis is niemanier:

• Verwysings van veelvuldige kolomme is absoluut en verander nie wanneer formules gekopieer word nie.
• Enkelkolom verwysings is relatief en verander wanneer dit oor kolomme gesleep word. Wanneer dit gekopieer/geplak word via 'n ooreenstemmende opdrag of kortpaaie (Ctrl+C en Ctrl+V), verander hulle nie.

In situasies wanneer jy 'n kombinasie van relatiewe en absolute tabelverwysings benodig, is daar geen manier om die formule te kopieer en tabelverwysings korrek te hou nie. Deur die formule te sleep, sal die verwysings na enkele kolomme verander, en kopieer/plak kortpaaie sal al die verwysings staties maak. Maar daar is 'n paar eenvoudige truuks om oor die weg te kom!

Absolute gestruktureerde verwysing na enkelkolom

Om 'n enkelkolomverwysing absoluut te maak, herhaal die kolomnaam om dit formeel in 'n reeksverwysing te verander .

Relatiewe kolomverwysing (verstek)

table[column]

Absolute kolomverwysing

table[[column]:[column]]

Om 'n absolute verwysing vir die huidige ry , voorvoegsel die kolom identifiseerder by die @-simbool:

table[@[column]:[column]]

Om te sien hoe relatiewe en absolute tabelverwysings in die praktyk werk, oorweeg asseblief die volgende voorbeeld.

Gestel jy wil die verkoopsnommers vir 'n spesifieke produk vir 3 maande bymekaar tel. Hiervoor voer ons die teikenproduknaam in een of ander sel in (F2 in ons geval) en gebruik die SUMIF-funksie om die totaal van Jan verkope te kry:

=SUMIF(Sales[Item], $F$2, Sales[Jan])

Dieprobleem is dat wanneer ons die formule na regs sleep om die totale vir die ander twee maande te bereken, die [Item] verwysing verander, en die formule breek:

To fix dit, maak die [Item] verwysing absoluut, maar hou [Jan] relatief:

=SUMIF(Sales[[Item]:[Item]], $F$2, Sales[Jan])

Nou kan jy die gewysigde formule na ander kolomme sleep en dit werk perfek:

Relatiewe gestruktureerde verwysing na veelvuldige kolomme

In Excel-tabelle is gestruktureerde verwysings na verskeie kolomme absoluut deur hul aard en bly onveranderd wanneer dit na ander selle gekopieer word.

Vir my is hierdie gedrag baie redelik. Maar as jy 'n gestruktureerde reeksverwysing relatief moet maak, voorvoeg elke kolomspesifiseerder met die tabelnaam en verwyder die buitenste vierkantige hakies soos hieronder getoon.

Absolute reeksverwysing (verstek)

table[[column1]:[column2]]

Relatiewe reeksverwysing

table[column1]:table[column2]

Om na die huidige ry binne die tabel te verwys, gebruik die @-simbool:

[@column1]:[@column2]

Byvoorbeeld, die onderstaande formule met 'n absolute gestruktureerde verwysing tel die getalle in die huidige ry van die Jan en Feb kolomme bymekaar. Wanneer dit na 'n ander kolom gekopieer word, sal dit steeds Jan en Feb optel.

=SUM(Sales[@[Jan]:[Feb]])

In geval jy wil hê die verwysing moet verander op grond van 'n relatiewe posisie van die kolom waar die formule gekopieer is, maak dit relatief :

=SUM(Sales[@Jan]:Sales[@Feb])

Let asseblief op die formuletransformasie in kolom F (dietabelnaam word weggelaat omdat die formule binne die tabel is):

Dis hoe jy tabelverwysings in Excel maak. Om die voorbeelde wat in hierdie tutoriaal bespreek word van nader te bekyk, laai gerus ons voorbeeldwerkboek af na Excel Structured Reference. Ek bedank jou vir die lees en hoop om jou volgende week op ons blog te sien.

Veerkragtig en outomaties opgedateer

Wanneer jy 'n kolom hernoem, word verwysings outomaties opgedateer met die nuwe naam, en 'n formule breek nie. Verder, soos jy nuwe rye by die tabel voeg, word hulle onmiddellik by die bestaande verwysings ingesluit, en die formules bereken die volle stel data.

So, watter manipulasies jy ook al met jou Excel-tabelle doen, jy doen' jy hoef nie bekommerd te wees oor die opdatering van die gestruktureerde verwysings nie.

Kan binne en buite 'n tabel gebruik word

Gestruktureerde verwysings kan in formules binne en buite 'n Excel-tabel gebruik word, wat die opspoor van tabelle in groot werkboeke makliker.

Formule outo-vul (berekende kolomme)

Om dieselfde berekening in elke tabelry uit te voer, is dit genoeg om 'n formule in net een sel in te voer. Alle ander selle in daardie kolom word outomaties gevul.

Hoe om 'n gestruktureerde verwysing in Excel te skep

Om 'n gestruktureerde verwysing in Excel te maak is baie maklik en intuïtief.

As jy met 'n reeks werk, skakel dit eers om na 'n Excel-tabel. Hiervoor, kies al die data en druk Ctrl + T . Vir meer inligting, sien asseblief Hoe om 'n tabel in Excel te skep.

Om 'n gestruktureerde verwysing te skep, is dit wat jy moet doen:

1. Begin soos gewoonlik 'n formule tik, begin met die gelykheidsteken (=).
2. Wanneer dit by die eerste verwysing kom, kies die ooreenstemmende sel of reeks vanselle in jou tabel. Excel sal die kolomnaam(e) optel en outomaties 'n gepaste gestruktureerde verwysing vir jou skep.
3. Tik die sluithakies en druk Enter. As die formule binne die tabel geskep word, vul Excel outomaties die hele kolom met dieselfde formule.

Kom ons tel as voorbeeld die verkoopsnommers vir 3 maande in elke ry van ons voorbeeldtabel bymekaar, genaamd Verkope . Hiervoor tik ons ​​=SUM( in E2, kies B2:D2, tik die slothakies in en druk Enter:

As gevolg hiervan is die hele kolom E outomaties -gevul met hierdie formule:

=SUM(Sales[@[Jan]:[Mar]])

Alhoewel die formule dieselfde is, word die data in elke ry individueel bereken. Om die innerlike meganika te verstaan, kyk asseblief na die tabelverwysingssintaksis .

As jy 'n formule buite die tabel invoer, en daardie formule vereis slegs 'n reeks selle, is 'n vinniger manier om 'n gestruktureerde verwysing hierdie te maak:

1. Na die opening van hakies, begin die tabelnaam tik. Soos jy die eerste letter tik, sal Excel alle ooreenstemmende name wys. Indien nodig, tik nog 'n paar letters in om die lys te verklein.
2. Gebruik die pyltjiesleutels om die tabelnaam in die lys te kies.
3. Dubbelklik op die geselekteerde naam of druk die Tab-sleutel om dit by jou formule te voeg.
4. Tik die sluithakies en druk Enter.

Byvoorbeeld, om die grootste getal in ons steekproef te vindtabel, begin ons tik die MAX formule, na die opening parentese tipe "s", kies die Verkope tabel in die lys, en druk Tab of dubbelklik op die naam.

As die gevolg, ons het hierdie formule:

=MAX(Sales)

Gestruktureerde verwysingsintaksis

Soos reeds genoem, hoef jy nie die sintaksis te ken nie van gestruktureerde verwysings om dit by jou formules in te sluit, maar dit sal jou help om te verstaan ​​wat elke formule eintlik doen.

Gewoonlik word 'n gestruktureerde verwysing voorgestel deur 'n string wat met 'n tabelnaam begin en met 'n kolom eindig. spesifiseerder.

As 'n voorbeeld, kom ons breek die volgende formule af wat die totale van die Suid en Noord kolomme in die tabel genaamd Streke :

Die verwysing sluit drie komponente in:

1. Tabelnaam
2. Itemspesifiseerder
3. Kolom spesifiseerders

Om te sien watter selle werklik bereken word, kies die formulesel en klik enige plek in die formulebalk. Excel sal die tabelselle waarna verwys word, uitlig:

Tabelnaam

Die tabelnaam verwys slegs na die tabeldata , sonder kopry of totale rye. Dit kan 'n verstek tabelnaam soos Tabel1 of 'n pasgemaakte naam soos Streke wees. Voer hierdie stappe uit om 'n pasgemaakte naam aan jou tabel te gee.

As jou formule geleë is in die tabel waarna dit verwys, word die tabelnaam gewoonlik weggelaat omdatdit word geïmpliseer.

Kolomspesifiseerder

Kolomspesifiseerder verwys na die data in die ooreenstemmende kolom, sonder die kopry en totale ry. 'n Kolomspesifiseerder word voorgestel deur die kolomnaam wat tussen hakies ingesluit is, bv. [Suid].

Om na meer as een aaneenlopende kolomme te verwys, gebruik die reeksoperateur soos [[Suid]:[Oos]].

Itemspesifiseerder

Om te verwys na spesifieke dele van 'n tabel, kan jy enige van die volgende spesifiseerders gebruik.

Let asseblief op dat die skutteken (#) met al die itemspesifikasies gebruik word, behalwe die huidige ry. Om te verwys na die selle in dieselfde ry waar jy die formule invoer, gebruik Excel die @-karakter gevolg deur die kolomnaam.

Byvoorbeeld, om getalle in die Suid en <1 by te voeg>Wes kolomme van die huidige ry, sal jy hierdie formule gebruik:

=SUM(Regions[@South], Regions[@West])

As die kolomname spasies, leestekens of spesiale karakters bevat, 'n bykomende stel hakies rondom die kolomnaam sal verskyn:

=SUM(Regions[@[South sales]], Regions[@[West sales]])

Gestruktureerde verwysingsoperateurs

Die volgende operateurs laat jou toe om verskillende spesifiseerders te kombineer en selfs meer buigsaamheid by jou gestruktureerde verwysings te voeg.

Reikwydteoperateur ( dubbelpunt)

Soos met normale reeksverwysings, gebruik jy 'n dubbelpunt (:) om na twee of meer aangrensende kolomme in 'n tabel te verwys.

Byvoorbeeld, die onderstaande formule tel die getalle in al die kolomme tussen Suid en Oos .

=SUM(Regions[[South]:[East]])

Unie-operateur (komma)

Om te verwys na nie-aangrensende kolomme, skei die kolomspesifiseerders met kommas.

Byvoorbeeld, hier is hoe jy die datarye in die Suid - en Wes -kolomme kan optel.

=SUM(Regions[South], Regions[West])

Kruisingsoperateur (spasie)

Dit word gebruik om te verwys na 'n sel by die kruising van 'n spesifieke ry en kolom.

Om byvoorbeeld 'n waarde terug te gee by die kruising van die Totaal -ry en Wes -kolom, gebruik hierdie verwysing:

=Regions[#Totals] Regions[[#All],[West]]

Let asseblief op dat die [#Alle]-spesifiseerder is vereis in hierdie geval omdat die kolomspesifiseerder sluit nie die totale ry in nie. Daarsonder sal die formule #NULL! teruggee.

Tabelverwysingssintaksisreëls

Om gestruktureerde verwysings met die hand te wysig of te maak, volg asseblief hierdie riglyne:

1. Sluit spesifiseerders in tussen hakies

Alle kolom- en spesiale item-spesifiseerders moet in [vierkantige hakies] ingesluit word.

'n Spesifiseerder wat ander spesifiseerders bevat, moet weesin buitenste hakies toegedraai. Byvoorbeeld, Streke[[Suid]:[Oos]].

2. Skei binne-spesifiseerders met kommas

As 'n spesifiseerder twee of meer binne-spesifiseerders bevat, moet daardie binne-spesifiseerders met kommas geskei word.

Om byvoorbeeld die kopskrif van die Suid terug te gee. kolom, tik jy 'n komma tussen [#Headers] en [South] en sluit hierdie hele konstruksie in 'n bykomende stel hakies in:

=Regions[[#Headers],[South]]

3. Moenie aanhalingstekens om kolomopskrifte gebruik nie

In tabelverwysings vereis kolomopskrifte nie aanhalings of dit nou teks, syfers of datums is nie.

4. Gebruik 'n enkele aanhalingsteken vir sommige spesiale karakters in kolomopskrifte

In gestruktureerde verwysings het sommige karakters soos linker- en regterhakies, skutteken (#) en enkele aanhalingsteken (') spesiale betekenis. As enige van die bogenoemde karakters in 'n kolomopskrif ingesluit is, moet 'n enkele aanhalingsteken voor daardie karakter in 'n kolomspesifiseerder gebruik word.

Byvoorbeeld, vir die kolomopskrif "Item #", is die spesifiseerder [Item '#].

5. Gebruik spasies om gestruktureerde verwysings meer leesbaar te maak

Om die leesbaarheid van jou tabelverwysings te verbeter, kan jy spasies tussen spesifiseerders invoeg. Normaalweg word dit as 'n goeie praktyk beskou om spasies na kommas te gebruik. Byvoorbeeld:

=AVERAGE(Regions[South], Regions[West], Regions[North])

Excel-tabelverwysings - formulevoorbeelde

Om meer begrip te kry oorgestruktureerde verwysings in Excel, kom ons gaan oor nog 'n paar formulevoorbeelde. Ons sal probeer om hulle eenvoudig, sinvol en nuttig te hou.

Vind die aantal rye en kolomme in 'n Excel-tabel

Om die totale kolomme en ryetelling te kry, gebruik die KOLOMME en RYE funksies, wat slegs die tabelnaam vereis:

Om byvoorbeeld die aantal kolomme en datarye te vind in die tabel genaamd Verkope , gebruik hierdie formules:

=COLUMNS(Sales)

=ROWS(Sales)

Om die kop en totale rye in die telling, gebruik die [#ALLE] spesifiseerder:

=ROWS(Sales[#All])

Die onderstaande skermkiekie wys al die formules in aksie:

Tel spasies en nie-blankes in 'n kolom

Wanneer jy iets in 'n spesifieke kolom tel, maak seker dat jy die resultaat buite die tabel uitvoer, anders kan jy met omsendbriefverwysings en verkeerde resultate.

Om spasies in 'n kolom te tel, gebruik die COUNTBLANK-funksie. Om nie-leë selle in 'n kolom te tel, gebruik die COUNTA-funksie.

Om byvoorbeeld uit te vind hoeveel selle in die Jan -kolom leeg is en hoeveel data bevat, gebruik hierdie formules:

Blankes:

=COUNTBLANK(Sales[Jan])

Nie-leë:

=COUNTA(Sales[Jan])

Om nie-leë selle in sigbare rye in te tel 'n gefiltreerde tabel, gebruik die SUBTOTAAL-funksie met function_num gestel op 103:

=SUBTOTAL(103,Sales[Jan])

Som in 'n Excel-tabel

Die vinnigste manier om op te telnommers in 'n Excel-tabel is om die Total Row-opsie te aktiveer. Om dit te doen, regskliek enige sel binne die tabel, wys na Tabel en klik Totalery . Die totale ry sal dadelik aan die einde van jou tabel verskyn.

Soms kan Excel aanvaar dat jy net die laaste kolom wil optel en laat ander selle in die Totaal-ry leeg. Om dit reg te stel, kies 'n leë sel in die Totaal-ry, klik op die pyltjie wat langs die sel verskyn, en kies dan die SOM-funksie in die lys:

Dit sal voeg 'n SUBTOTAAL-formule in wat waardes slegs in sigbare rye optel, en ignoreer uitgefiltreerde rye:

=SUBTOTAL(109,[Jan])

Neem asseblief kennis dat hierdie formule slegs in die Totaal werk ry . As jy probeer om dit handmatig in 'n datary in te voeg, sal dit 'n omsendbrief verwysing skep en 0 as die resultaat teruggee. 'n SOM-formule met 'n gestruktureerde verwysing sal om dieselfde rede ook nie werk nie:

Dus, as jy die totale binne die tabel wil hê, moet jy moet óf die Total-ry aktiveer óf 'n normale reeksverwysing gebruik soos:

=SUM(B2:B5)

Buite die tabel , werk die SOM-formule met 'n gestruktureerde verwysing goed:

=SUM(Sales[Jan])

Neem asseblief kennis dat, anders as SUBTOTAAL, die SOM-funksie waardes in al die rye optel, sigbaar en versteek.

Relatiewe en absolute gestruktureerde verwysings in Excel

By verstek tree Excel-gestruktureerde verwysings op in die volgende