Оглавление
В этом учебном пособии объясняются основы структурированных ссылок Excel и рассказывается о некоторых приемах их использования в реальных формулах.
Одной из самых полезных функций таблиц Excel являются структурированные ссылки. Когда вы только что познакомились со специальным синтаксисом для ссылок на таблицы, это может показаться скучным и запутанным, но, немного поэкспериментировав, вы обязательно увидите, насколько полезной и классной является эта функция.
Структурированный справочник Excel
A структурированная ссылка , или таблица ссылок это специальный способ ссылки на таблицы и их части, который использует комбинацию имен таблиц и столбцов вместо адресов ячеек.
Этот специальный синтаксис необходим, поскольку таблицы Excel (в отличие от диапазонов) очень мощные и устойчивые, а обычные ссылки на ячейки не могут динамически изменяться при добавлении или удалении данных из таблицы.
Например, чтобы суммировать значения в ячейках B2:B5, вы используете функцию SUM с обычной ссылкой на диапазон:
=SUM(B2:B5)
Чтобы сложить числа в столбце "Продажи" таблицы 1, вы используете структурированную ссылку:
=SUM(Table1[Sales])
Ключевые особенности структурированных ссылок
По сравнению со стандартными ссылками на ячейки, ссылки на таблицы имеют ряд дополнительных возможностей.
Легко создается
Чтобы добавить структурированные ссылки в формулу, достаточно выделить ячейки таблицы, на которые вы хотите сослаться. Знание специального синтаксиса не требуется.
Устойчивость и автоматическое обновление
При переименовании столбца ссылки автоматически обновляются с новым именем, и формула не нарушается. Более того, при добавлении новых строк в таблицу они сразу же включаются в существующие ссылки, и формулы рассчитывают полный набор данных.
Таким образом, какие бы манипуляции вы ни производили с таблицами Excel, вам не придется беспокоиться об обновлении структурированных ссылок.
Можно использовать как внутри, так и снаружи стола
Структурированные ссылки можно использовать в формулах как внутри, так и вне таблицы Excel, что облегчает поиск таблиц в больших рабочих книгах.
Автозаполнение формул (вычисляемые столбцы)
Чтобы выполнить один и тот же расчет в каждой строке таблицы, достаточно ввести формулу только в одну ячейку. Все остальные ячейки в этом столбце заполняются автоматически.
Как создать структурированную ссылку в Excel
Создание структурированной ссылки в Excel очень просто и интуитивно понятно.
Если вы работаете с диапазоном, сначала преобразуйте его в таблицу Excel. Для этого выделите все данные и нажмите Ctrl + T. Для получения дополнительной информации см. раздел Как создать таблицу в Excel.
Чтобы создать структурированную ссылку, вот что вам нужно сделать:
- Начните вводить формулу как обычно, начиная со знака равенства (=).
- Когда дело дойдет до первой ссылки, выберите соответствующую ячейку или диапазон ячеек в вашей таблице. Excel подберет имя(я) столбца(ов) и автоматически создаст для вас соответствующую структурированную ссылку.
- Введите закрывающую скобку и нажмите Enter. Если формула создана внутри таблицы, Excel автоматически заполняет весь столбец той же формулой.
В качестве примера давайте сложим цифры продаж за 3 месяца в каждой строке нашей таблицы-образца с именем Продажи Для этого вводим =SUM( в E2, выбираем B2:D2, вводим закрывающую скобку и нажимаем Enter:
В результате весь столбец E будет автоматически заполнен этой формулой:
=SUM(Продажи[@[Янв]:[Мар]])
Хотя формула одна и та же, данные вычисляются в каждой строке отдельно. Чтобы понять внутреннюю механику, ознакомьтесь с синтаксисом справочника таблиц.
Если вы вводите формулу за столом , и эта формула требует только диапазон ячеек, более быстрый способ создания структурированной ссылки заключается в следующем:
- После открывающей скобки начните вводить имя таблицы. По мере ввода первой буквы Excel будет показывать все подходящие имена. При необходимости введите еще несколько букв, чтобы сузить список.
- С помощью клавиш со стрелками выберите имя таблицы в списке.
- Дважды щелкните выбранное имя или нажмите клавишу Tab, чтобы добавить его в формулу.
- Введите закрывающую скобку и нажмите Enter.
Например, чтобы найти наибольшее число в таблице нашей выборки, мы начинаем вводить формулу MAX, после открывающей скобки вводим "s", выбираем опцию Продажи таблицу в списке и нажмите Tab или дважды щелкните имя.
В результате мы получаем следующую формулу:
=MAX(Sales)
Синтаксис структурированных ссылок
Как уже говорилось, вам не нужно знать синтаксис структурированных ссылок, чтобы включать их в формулы, однако это поможет вам понять, что на самом деле делает каждая формула.
Обычно структурированная ссылка представлена строкой, которая начинается с имени таблицы и заканчивается спецификатором столбца.
В качестве примера, давайте разберем следующую формулу, которая суммирует итоговые значения в таблице Юг и Север столбцы в таблице с именем Регионы :
Ссылка включает в себя три компонента:
- Название таблицы
- Спецификатор элементов
- Спецификаторы колонок
Чтобы увидеть, какие ячейки на самом деле вычисляются, выделите ячейку с формулой и щелкните в любом месте панели формул. Excel выделит ссылающиеся ячейки таблицы:
Название таблицы
Имя таблицы ссылается только на данные таблицы без строки заголовка или общего количества строк. Это может быть имя таблицы по умолчанию, например Таблица1 или пользовательское имя, например Регионы Чтобы присвоить таблице пользовательское имя, выполните следующие действия.
Если ваша формула находится внутри таблицы, на которую она ссылается, имя таблицы обычно опускается, поскольку оно подразумевается.
Спецификатор колонок
Спецификатор столбца ссылается на данные в соответствующем столбце, без строки заголовка и итоговой строки. Спецификатор столбца представлен именем столбца, заключенным в скобки, например, [South].
Чтобы сослаться на более чем один смежный столбец, используйте оператор диапазона, например [[Юг]:[Восток]].
Спецификатор элементов
Чтобы сослаться на определенные части таблицы, можно использовать любой из следующих спецификаторов.
| Спецификатор элементов | Относится к |
| [#All] | Вся таблица, включая данные таблицы, заголовки столбцов и общую строку. |
| [#Data] | Строки данных. |
| [#Headers]. | Строка заголовков (заголовки столбцов). |
| [#Totals] | Общий ряд. Если общего ряда нет, возвращается null. |
| [@Column_Name] | Текущая строка, т.е. та же строка, что и в формуле. |
Обратите внимание, что знак фунта (#) используется со всеми спецификаторами элементов, кроме текущей строки. Для ссылки на ячейки в той же строке, где вы вводите формулу, Excel использует символ @, за которым следует имя столбца.
Например, для сложения чисел в Юг и Запад столбцов текущей строки, вы бы использовали эту формулу:
=SUM(Регионы[@Юг], Регионы[@Запад])
Если имена столбцов содержат пробелы, знаки препинания или специальные символы, вокруг имени столбца появится дополнительный набор скобок:
=SUM(Регионы[@[Южные продажи]], Регионы[@[Западные продажи]])
Операторы структурированных ссылок
Следующие операторы позволяют комбинировать различные спецификаторы и придают еще большую гибкость вашим структурированным ссылкам.
Оператор диапазона (двоеточие)
Как и при обычных ссылках на диапазон, для ссылки на два или более соседних столбца в таблице используется двоеточие (:).
Например, приведенная ниже формула суммирует числа во всех столбцах между Юг и Восток .
=SUM(Регионы[[Юг]:[Восток]])
Оператор объединения (запятая)
Чтобы сослаться на несмежные колонки, разделите спецификаторы колонок запятыми.
Например, вот как вы можете суммировать строки данных в Юг и Запад колонны.
=SUM(Регионы[Юг], Регионы[Запад])
Оператор пересечения (пространство)
Он используется для обозначения ячейки на пересечении определенной строки и столбца.
Например, чтобы вернуть значение на пересечении линий Всего ряд и Запад колонку, воспользуйтесь этой ссылкой:
=Регионы[#Итоги] Регионы[[#Все],[Запад]]
Обратите внимание, что спецификатор [#All] необходим в данном случае, потому что спецификатор столбца не включает общую строку. Без него формула вернет #NULL!
Правила синтаксиса ссылок на таблицы
Чтобы отредактировать или сделать структурированные ссылки вручную, следуйте следующим рекомендациям:
1. заключите спецификаторы в скобки
Все спецификаторы столбцов и специальных элементов должны быть заключены в [квадратные скобки].
Спецификатор, содержащий другие спецификаторы, должен быть заключен во внешние скобки. Например, Regions[[South]:[East]].
2. разделяйте внутренние спецификаторы запятыми
Если спецификатор содержит два или более внутренних спецификаторов, эти внутренние спецификаторы должны быть разделены запятыми.
Например, чтобы вернуть заголовок Юг колонку, вы вводите запятую между [#Headers] и [South] и заключаете всю эту конструкцию в дополнительный набор скобок:
=Регионы[[#Главные],[Юг]]
3. не используйте кавычки вокруг заголовков колонок
В табличных ссылках заголовки столбцов не требуют кавычек, будь то текст, числа или даты.
4. используйте одинарные кавычки для некоторых специальных символов в заголовках столбцов
В структурированных ссылках некоторые символы, такие как левая и правая скобки, знак фунта (#) и одинарная кавычка ('), имеют специальное значение. Если любой из вышеперечисленных символов включен в заголовок колонки, перед ним в спецификаторе колонки необходимо использовать одинарную кавычку.
Например, для заголовка столбца "Item #" спецификатором является [Item '#].
5. используйте пробелы, чтобы сделать структурированные ссылки более читабельными
Чтобы улучшить читаемость ссылок на таблицы, вы можете вставить пробелы между спецификаторами. Обычно считается хорошей практикой использовать пробелы после запятых. Например:
=AVERAGE(Regions[South], Regions[West], Regions[North])
Ссылки на таблицы Excel - примеры формул
Чтобы лучше понять, что такое структурированные ссылки в Excel, давайте рассмотрим еще несколько примеров формул. Мы постараемся сделать их простыми, содержательными и полезными.
Найти количество строк и столбцов в таблице Excel
Чтобы получить общее количество столбцов и строк, используйте функции COLUMNS и ROWS, которые требуют только имя таблицы:
КОЛУМНЫ( таблица ) ROWS( таблица )Например, чтобы найти количество столбцов и строки данных в таблице под названием Продажи , используйте эти формулы:
=COLUMNS(Sales)
=ROWS(Sales)
Включить заголовок и всего рядов в подсчете, используйте спецификатор [#ALL]:
=ROWS(Sales[#All])
На скриншоте ниже показаны все формулы в действии:
Подсчет пустых и непустых мест в столбце
Когда вы считаете что-то в определенном столбце, обязательно выводите результат за пределы таблицы, иначе вы можете получить круговые ссылки и неверные результаты.
Для подсчета пустых ячеек в столбце используйте функцию COUNTBLANK. Для подсчета непустых ячеек в столбце используйте функцию COUNTA.
Например, чтобы узнать, сколько клеток в Ян пустые столбцы и сколько из них содержат данные, используйте эти формулы:
Заготовки:
=COUNTBLANK(Sales[Jan])
Без пробелов:
=COUNTA(Sales[Jan])
Для подсчета непустых клеток в видимые ряды в отфильтрованной таблице используйте функцию SUBTOTAL с параметром function_num, равным 103:
=SUBTOTAL(103,Продажи[янв])
Сумма в таблице Excel
Самый быстрый способ сложить числа в таблице Excel - включить опцию Total Row. Для этого щелкните правой кнопкой мыши любую ячейку в таблице, выберите пункт Таблица , и нажмите Итоговая строка В конце таблицы сразу же появится итоговая строка.
Иногда Excel может предположить, что вы хотите подвести итог только по последнему столбцу, и оставляет остальные ячейки в строке Итого. Чтобы исправить это, выберите пустую ячейку в строке Итого, нажмите на стрелку, которая появится рядом с ячейкой, а затем выберите функцию SUM в списке:
Это позволит вставить формулу SUBTOTAL, которая суммирует значения только в разделе видимые ряды , игнорируя отфильтрованные строки:
=SUBTOTAL(109,[Jan])
Обратите внимание, что эта формула работает только в Общий ряд Если вы попытаетесь вручную вставить его в строку данных, это создаст циклическую ссылку и вернет 0 в качестве результата. Формула SUM со структурированной ссылкой также не будет работать по той же причине:
Итак, если вам нужны итоговые данные внутри стола Вам необходимо либо включить строку Total, либо использовать нормальный диапазон, например:
=SUM(B2:B5)
За пределами стола Формула SUM со структурированной ссылкой работает отлично:
=SUM(Продажи[янв])
Обратите внимание, что в отличие от SUBTOTAL, функция SUM суммирует значения во всех строках, видимых и скрытых.
Относительные и абсолютные структурированные ссылки в Excel
По умолчанию структурированные ссылки Excel ведут себя следующим образом:
- Несколько колонок ссылки абсолютный и не изменяются при копировании формул.
- Одиночная колонка ссылки относительный и изменяются при перетаскивании по столбцам. При копировании/вставке с помощью соответствующей команды или горячих клавиш (Ctrl+C и Ctrl+V) они не изменяются.
В ситуациях, когда требуется сочетание относительных и абсолютных ссылок на таблицы, нет возможности скопировать формулу и сохранить правильные ссылки на таблицы. Перетаскивание формулы изменит ссылки на отдельные столбцы, а копирование/вставка ярлыков сделает все ссылки статичными. Но есть несколько простых приемов, которые можно обойти!
Абсолютная структурированная ссылка на один столбец
Чтобы сделать ссылку на один столбец абсолютной, повторите имя столбца, чтобы формально превратить его в ссылку на диапазон.
Ссылка на относительный столбец (по умолчанию)
таблица[столбец]
Абсолютная ссылка на столбец
таблица[[столбец]:[столбец]]
Чтобы сделать абсолютную ссылку для текущий ряд , префикс идентификатора столбца - символ @:
table[@[column]:[column]]
Чтобы увидеть, как на практике работают относительные и абсолютные ссылки на таблицы, рассмотрим следующий пример.
Предположим, вы хотите сложить цифры продаж определенного продукта за 3 месяца. Для этого мы вводим название целевого продукта в некоторую ячейку (F2 в нашем случае) и используем функцию SUMIF для получения итогового значения Ян продажи:
=SUMIF(Sales[Item], $F$2, Sales[Jan])
Проблема в том, что когда мы перетаскиваем формулу вправо, чтобы подсчитать итоги за два других месяца, ссылка [Item] меняется, и формула ломается:
Чтобы исправить это, сделайте ссылку [Item] абсолютной, а [Jan] - относительной:
=SUMIF(Sales[[Item]:[Item]], $F$2, Sales[Jan])
Теперь вы можете перетащить измененную формулу в другие столбцы, и она прекрасно работает:
Относительная структурированная ссылка на несколько столбцов
В таблицах Excel структурированные ссылки на несколько столбцов являются абсолютными по своей природе и остаются неизменными при копировании в другие ячейки.
Но если вам нужно сделать структурированную ссылку на диапазон относительной, добавьте к каждому спецификатору столбца имя таблицы и удалите внешние квадратные скобки, как показано ниже.
Ссылка на абсолютный диапазон (по умолчанию)
table[[column1]:[column2]]
Ссылка на относительный диапазон
таблица[столбец1]:таблица[столбец2]
Ссылаться на текущая строка внутри таблицы , используйте символ @:
[@column1]:[@column2].
Например, приведенная ниже формула с абсолютная структурированная ссылка суммирует числа в текущей строке таблицы Ян и Февраль столбцов. При копировании в другой столбец, сумма будет по-прежнему Ян и Февраль .
=SUM(Продажи[@[Январь]:[Февраль]])
Если вы хотите, чтобы ссылка изменялась в зависимости от относительного положения столбца, в который копируется формула, сделайте ее относительный :
=SUM(Sales[@Jan]:Sales[@Feb])
Обратите внимание на преобразование формулы в столбце F (название таблицы опущено, так как формула находится внутри таблицы):
Вот так можно создавать ссылки на таблицы в Excel. Чтобы поближе познакомиться с примерами, рассмотренными в этом уроке, не стесняйтесь скачать наш образец рабочей книги в Excel Структурированная ссылка. Я благодарю вас за чтение и надеюсь увидеть вас в нашем блоге на следующей неделе.
